data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, [YEARS])
  26 # ----------------------------
  27 # If YEARS are not defined, use b4_copyright_years.
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 ]m4_dquote(m4_text_wrap([Copyright (C)
  34 ]m4_ifval([$2], [[$2]], [m4_defn([b4_copyright_years])])[
  35 Free Software Foundation, Inc.]))[
  36
  37 This program is free software: you can redistribute it and/or modify
  38 it under the terms of the GNU General Public License as published by
  39 the Free Software Foundation, either version 3 of the License, or
  40 (at your option) any later version.
  41
  42 This program is distributed in the hope that it will be useful,
  43 but WITHOUT ANY WARRANTY; without even the implied warranty of
  44 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  45 GNU General Public License for more details.
  46
  47 You should have received a copy of the GNU General Public License
  48 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## ---------------- ##
  65 ## Error handling.  ##
  66 ## ---------------- ##
  67
  68 # The following error handling macros print error directives that should not
  69 # become arguments of other macro invocations since they would likely then be
  70 # mangled.  Thus, they print to stdout directly.
  71
  72 # b4_cat(TEXT)
  73 # ------------
  74 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  75 # escaped.  For example:
  76 #
  77 #   b4_cat([[@complain(invalid input@)]])
  78 m4_define([b4_cat],
  79 [m4_syscmd([cat <<'_m4eof'
  80 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  81 _m4eof
  82 ])dnl
  83 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  84
  85 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  86 # -------------------------------------------
  87 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  88 #
  89 # For example:
  90 #
  91 #   b4_error([[warn]], [[invalid value for '%s': %s]], [[foo]], [[3]])
  92 m4_define([b4_error],
  93 [b4_cat([[@]$1[(]$2[]]dnl
  94 [m4_if([$#], [2], [],
  95        [m4_foreach([b4_arg],
  96                    m4_dquote(m4_shift(m4_shift($@))),
  97                    [[@,]b4_arg])])[@)]])])
  98
  99 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
 100 # ----------------------------------------------------------
 101 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 102 #
 103 # For example:
 104 #
 105 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 106 #               [[invalid %s]], [[foo]])
 107 m4_define([b4_error_at],
 108 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 109 [m4_if([$#], [4], [],
 110        [m4_foreach([b4_arg],
 111                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 112                    [[@,]b4_arg])])[@)]])])
 113
 114 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 115 # ------------------------------------
 116 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 117 #
 118 # For example:
 119 #
 120 #   b4_warn([[invalid value for '%s': %s]], [[foo]], [[3]])
 121 #
 122 # As a simple test suite, this:
 123 #
 124 #   m4_divert(-1)
 125 #   m4_define([asdf], [ASDF])
 126 #   m4_define([fsa], [FSA])
 127 #   m4_define([fdsa], [FDSA])
 128 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 129 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 130 #   b4_warn()
 131 #   b4_warn(1)
 132 #   b4_warn(1, 2)
 133 #
 134 # Should produce this without newlines:
 135 #
 136 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 137 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 138 #   @warn(@)
 139 #   @warn(1@)
 140 #   @warn(1@,2@)
 141 m4_define([b4_warn],
 142 [b4_error([[warn]], $@)])
 143
 144 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 145 # ---------------------------------------------------
 146 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 147 #
 148 # For example:
 149 #
 150 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 151 m4_define([b4_warn_at],
 152 [b4_error_at([[warn]], $@)])
 153
 154 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 155 # ----------------------------------------
 156 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 157 #
 158 # See b4_warn example.
 159 m4_define([b4_complain],
 160 [b4_error([[complain]], $@)])
 161
 162 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 163 # -------------------------------------------------------
 164 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 165 #
 166 # See b4_warn_at example.
 167 m4_define([b4_complain_at],
 168 [b4_error_at([[complain]], $@)])
 169
 170 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 171 # -------------------------------------
 172 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 173 #
 174 # See b4_warn example.
 175 m4_define([b4_fatal],
 176 [b4_error([[fatal]], $@)dnl
 177 m4_exit(1)])
 178
 179 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 180 # ----------------------------------------------------
 181 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 182 #
 183 # See b4_warn_at example.
 184 m4_define([b4_fatal_at],
 185 [b4_error_at([[fatal]], $@)dnl
 186 m4_exit(1)])
 187
 188
 189 ## ---------------- ##
 190 ## Default values.  ##
 191 ## ---------------- ##
 192
 193 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 194 m4_define_default([b4_pre_prologue], [])
 195 m4_define_default([b4_post_prologue], [])
 196 m4_define_default([b4_epilogue], [])
 197 m4_define_default([b4_parse_param], [])
 198
 199 # The initial column and line.
 200 m4_define_default([b4_location_initial_column], [1])
 201 m4_define_default([b4_location_initial_line],   [1])
 202
 203
 204 ## ------------ ##
 205 ## Data Types.  ##
 206 ## ------------ ##
 207
 208 # b4_ints_in(INT1, INT2, LOW, HIGH)
 209 # ---------------------------------
 210 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 211 m4_define([b4_ints_in],
 212 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 213
 214
 215 # b4_subtract(LHS, RHS)
 216 # ---------------------
 217 # Evaluate LHS - RHS if they are integer literals, otherwise expand
 218 # to (LHS) - (RHS).
 219 m4_define([b4_subtract],
 220 [m4_bmatch([$1$2], [^[0123456789]*$],
 221            [m4_eval([$1 - $2])],
 222            [($1) - ($2)])])
 223
 224 # b4_args(ARG1, ...)
 225 # _b4_args(ARG1, ...)
 226 # -------------------
 227 # Join with comma, skipping empty arguments.
 228 # b4_args calls itself recursively until it sees the first non-empty
 229 # argument, then calls _b4_args which prepends each non-empty argument
 230 # with a comma.
 231 m4_define([b4_args],
 232 [m4_if([$#$1],
 233        [1], [],
 234        [m4_ifval([$1],
 235                  [$1[]_$0(m4_shift($@))],
 236                  [$0(m4_shift($@))])])])
 237
 238 # _b4_args(ARGS1, ...)
 239 # --------------------
 240 m4_define([_b4_args],
 241 [m4_if([$#$1],
 242        [1], [],
 243        [m4_ifval([$1], [, $1])[]$0(m4_shift($@))])])
 244
 245
 246
 247
 248 # b4_integral_parser_tables_map(MACRO)
 249 # -------------------------------------
 250 # Map MACRO on all the integral tables.  MACRO is expected to have
 251 # the signature MACRO(TABLE-NAME, CONTENT, COMMENT).
 252 m4_define([b4_integral_parser_tables_map],
 253 [$1([pact], [b4_pact],
 254     [[YYPACT[STATE-NUM] -- Index in YYTABLE of the portion describing
 255 STATE-NUM.]])
 256
 257 $1([defact], [b4_defact],
 258    [[YYDEFACT[S] -- default reduction number in state S.  Performed when
 259 YYTABLE does not specify something else to do.  Zero means the default
 260 is an error.]])
 261
 262 $1([pgoto], [b4_pgoto], [[YYPGOTO[NTERM-NUM].]])
 263
 264 $1([defgoto], [b4_defgoto], [[YYDEFGOTO[NTERM-NUM].]])
 265
 266 $1([table], [b4_table],
 267    [[YYTABLE[YYPACT[STATE-NUM]].  What to do in state STATE-NUM.  If
 268 positive, shift that token.  If negative, reduce the rule which
 269 number is the opposite.  If YYTABLE_NINF, syntax error.]])
 270
 271 $1([check], [b4_check])
 272
 273 $1([stos], [b4_stos],
 274    [[STOS_[STATE-NUM] -- The (internal number of the) accessing
 275 symbol of state STATE-NUM.]])
 276
 277 $1([r1], [b4_r1],
 278    [[YYR1[YYN] -- Symbol number of symbol that rule YYN derives.]])
 279
 280 $1([r2], [b4_r2],
 281    [[YYR2[YYN] -- Number of symbols composing right hand side of rule YYN.]])
 282 ])
 283
 284
 285 # b4_parser_tables_declare
 286 # b4_parser_tables_define
 287 # ------------------------
 288 # Define/declare the (deterministic) parser tables.
 289 m4_define([b4_parser_tables_declare],
 290 [b4_integral_parser_tables_map([b4_integral_parser_table_declare])])
 291
 292 m4_define([b4_parser_tables_define],
 293 [b4_integral_parser_tables_map([b4_integral_parser_table_define])])
 294
 295
 296
 297 ## ------------------ ##
 298 ## Decoding options.  ##
 299 ## ------------------ ##
 300
 301 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 302 # -----------------------------------
 303 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 304 m4_define([b4_flag_if],
 305 [m4_case(b4_$1_flag,
 306          [0], [$3],
 307          [1], [$2],
 308          [m4_fatal([invalid $1 value: ]$1)])])
 309
 310
 311 # b4_define_flag_if(FLAG)
 312 # -----------------------
 313 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 314 # value of the Boolean FLAG.
 315 m4_define([b4_define_flag_if],
 316 [_b4_define_flag_if($[1], $[2], [$1])])
 317
 318 # _b4_define_flag_if($1, $2, FLAG)
 319 # --------------------------------
 320 # This macro works around the impossibility to define macros
 321 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 322 # This sucks hard, GNU M4 should really provide M5 like $$1.
 323 m4_define([_b4_define_flag_if],
 324 [m4_if([$1$2], $[1]$[2], [],
 325        [m4_fatal([$0: Invalid arguments: $@])])dnl
 326 m4_define([b4_$3_if],
 327           [b4_flag_if([$3], [$1], [$2])])])
 328
 329
 330 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 331 # -----------------------------
 332 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 333 b4_define_flag_if([defines])            # Whether headers are requested.
 334 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 335 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 336 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 337
 338
 339 ## --------- ##
 340 ## Symbols.  ##
 341 ## --------- ##
 342
 343 # b4_symbol_(NUM, FIELD)
 344 # ----------------------
 345 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 346 # undefined.
 347 m4_define([b4_symbol_],
 348 [m4_indir([b4_symbol($1, $2)])])
 349
 350
 351 # b4_symbol(NUM, FIELD)
 352 # ---------------------
 353 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 354 # undefined.  If FIELD = id, prepend the prefix.
 355 m4_define([b4_symbol],
 356 [m4_case([$2],
 357          [id],    [m4_do([b4_percent_define_get([api.tokens.prefix])],
 358                          [b4_symbol_([$1], [id])])],
 359          [b4_symbol_($@)])])
 360
 361
 362 # b4_symbol_if(NUM, FIELD, IF-TRUE, IF-FALSE)
 363 # -------------------------------------------
 364 # If FIELD about symbol #NUM is 1 expand IF-TRUE, if is 0, expand IF-FALSE.
 365 # Otherwise an error.
 366 m4_define([b4_symbol_if],
 367 [m4_case(b4_symbol([$1], [$2]),
 368          [1], [$3],
 369          [0], [$4],
 370          [m4_fatal([$0: field $2 of $1 is not a Boolean:] b4_symbol([$1], [$2]))])])
 371
 372
 373 # b4_symbol_action_location(SYMBOL-NUM, KIND)
 374 # -------------------------------------------
 375 # Report the location of the KIND action as FILE:LINE.
 376 m4_define([b4_symbol_action_location],
 377 [b4_symbol([$1], [$2_file]):b4_syncline([b4_symbol([$1], [$2_line])])])
 378
 379
 380 # b4_symbol_action(SYMBOL-NUM, KIND)
 381 # ----------------------------------
 382 # Run the action KIND (destructor or printer) for SYMBOL-NUM.
 383 # Same as in C, but using references instead of pointers.
 384 m4_define([b4_symbol_action],
 385 [b4_symbol_if([$1], [has_$2],
 386 [m4_pushdef([b4_dollar_dollar],
 387     [b4_symbol_value([(*yyvaluep)],
 388                      b4_symbol_if([$1], [has_type],
 389                                   [b4_symbol([$1], [type])]))])dnl
 390 m4_pushdef([b4_at_dollar], [(*yylocationp)])dnl
 391       b4_symbol_case_([$1])
 392 b4_syncline([b4_symbol([$1], [$2_line])], ["b4_symbol([$1], [$2_file])"])
 393         b4_symbol([$1], [$2])
 394 b4_syncline([@oline@], [@ofile@])
 395         break;
 396
 397 m4_popdef([b4_at_dollar])dnl
 398 m4_popdef([b4_dollar_dollar])dnl
 399 ])])
 400
 401
 402 # b4_symbol_destructor(SYMBOL-NUM)
 403 # b4_symbol_printer(SYMBOL-NUM)
 404 # --------------------------------
 405 m4_define([b4_symbol_destructor], [b4_symbol_action([$1], [destructor])])
 406 m4_define([b4_symbol_printer],    [b4_symbol_action([$1], [printer])])
 407
 408
 409 # b4_symbol_case_(SYMBOL-NUM)
 410 # ---------------------------
 411 # Issue a "case NUM" for SYMBOL-NUM.
 412 m4_define([b4_symbol_case_],
 413 [      case b4_symbol([$1], [number]): // b4_symbol([$1], [tag])
 414 ])
 415
 416
 417 # b4_symbol_foreach(MACRO)
 418 # ------------------------
 419 # Invoke MACRO(SYMBOL-NUM) for each SYMBOL-NUM.
 420 m4_define([b4_symbol_foreach],
 421           [m4_map([$1], m4_defn([b4_symbol_numbers]))])
 422
 423
 424 ## ------- ##
 425 ## Types.  ##
 426 ## ------- ##
 427
 428 # b4_type_action_(NUMS)
 429 # ---------------------
 430 # Run actions for the symbol NUMS that all have the same type-name.
 431 # Skip NUMS that have no type-name.
 432 m4_define([b4_type_action_],
 433 [b4_symbol_if([$1], [has_type],
 434 [m4_map([b4_symbol_case_], [$@])[]dnl
 435         b4_dollar_dollar([b4_symbol([$1], [number])],
 436                          [b4_symbol([$1], [tag])],
 437                          [b4_symbol([$1], [type])]);
 438         break;
 439
 440 ])])
 441
 442 # b4_type_foreach(MACRO)
 443 # ----------------------
 444 # Invoke MACRO(SYMBOL-NUMS) for each set of SYMBOL-NUMS for each type set.
 445 m4_define([b4_type_foreach],
 446           [m4_map([$1], m4_defn([b4_type_names]))])
 447
 448
 449
 450 ## ----------- ##
 451 ## Synclines.  ##
 452 ## ----------- ##
 453
 454 # b4_basename(NAME)
 455 # -----------------
 456 # Similar to POSIX basename; the differences don't matter here.
 457 # Beware that NAME is not evaluated.
 458 m4_define([b4_basename],
 459 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 460
 461
 462 # b4_syncline(LINE, FILE)
 463 # -----------------------
 464 m4_define([b4_syncline],
 465 [b4_flag_if([synclines],
 466 [b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 467 b4_sync_start([$1], [$2])])])
 468
 469 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 470 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 471
 472 # b4_user_code(USER-CODE)
 473 # -----------------------
 474 # Emit code from the user, ending it with synclines.
 475 m4_define([b4_user_code],
 476 [$1
 477 b4_syncline([@oline@], [@ofile@])])
 478
 479
 480 # b4_define_user_code(MACRO)
 481 # --------------------------
 482 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 483 m4_define([b4_define_user_code],
 484 [m4_define([b4_user_$1],
 485 [b4_user_code([b4_$1])])])
 486
 487
 488 # b4_user_actions
 489 # b4_user_initial_action
 490 # b4_user_post_prologue
 491 # b4_user_pre_prologue
 492 # b4_user_stype
 493 # ----------------------
 494 # Macros that issue user code, ending with synclines.
 495 b4_define_user_code([actions])
 496 b4_define_user_code([initial_action])
 497 b4_define_user_code([post_prologue])
 498 b4_define_user_code([pre_prologue])
 499 b4_define_user_code([stype])
 500
 501
 502 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 503 # -----------------------------------------------------
 504 # Complain if any name of type WHAT is used by the user (as recorded in
 505 # USER-LIST) but is not used by Bison (as recorded by macros in the
 506 # namespace BISON-NAMESPACE).
 507 #
 508 # USER-LIST must expand to a list specifying all user occurrences of all names
 509 # of type WHAT.   Each item in the list must be a triplet specifying one
 510 # occurrence: name, start boundary, and end boundary.  Empty string names are
 511 # fine.  An empty list is fine.
 512 #
 513 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 514 # name occurrences and with correct quoting:
 515 #
 516 #   m4_define([b4_foo_user_names],
 517 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 518 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 519 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 520 #
 521 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 522 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 523 # are fine, but it would be ugly for Bison to actually use one.
 524 #
 525 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 526 # the names bar and baz are used by Bison:
 527 #
 528 #   m4_define([b4_foo_bison_names(bar)])
 529 #   m4_define([b4_foo_bison_names(baz)])
 530 #
 531 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 532 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 533 # quoting:
 534 #
 535 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 536 #                       [[b4_foo_bison_names]])
 537 m4_define([b4_check_user_names],
 538 [m4_foreach([b4_occurrence], $2,
 539 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 540 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 541 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 542 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 543 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 544           [b4_complain_at([b4_start], [b4_end],
 545                           [[%s '%s' is not used]],
 546                           [$1], [b4_user_name])])[]dnl
 547 m4_popdef([b4_occurrence])dnl
 548 m4_popdef([b4_user_name])dnl
 549 m4_popdef([b4_start])dnl
 550 m4_popdef([b4_end])dnl
 551 ])])
 552
 553
 554
 555 ## --------------------- ##
 556 ## b4_percent_define_*.  ##
 557 ## --------------------- ##
 558
 559
 560 # b4_percent_define_use(VARIABLE)
 561 # -------------------------------
 562 # Declare that VARIABLE was used.
 563 m4_define([b4_percent_define_use],
 564 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 565 ])
 566
 567 # b4_percent_define_get(VARIABLE, [DEFAULT])
 568 # ------------------------------------------
 569 # Mimic muscle_percent_define_get in ../src/muscle-tab.h.  That is, if
 570 # the %define variable VARIABLE is defined, emit its value.  Contrary
 571 # to its C counterpart, return DEFAULT otherwise.  Also, record
 572 # Bison's usage of VARIABLE by defining
 573 # b4_percent_define_bison_variables(VARIABLE).
 574 #
 575 # For example:
 576 #
 577 #   b4_percent_define_get([[foo]])
 578 m4_define([b4_percent_define_get],
 579 [b4_percent_define_use([$1])dnl
 580 m4_ifdef([b4_percent_define(]$1[)],
 581          [m4_indir([b4_percent_define(]$1[)])],
 582          [$2])])
 583
 584 # b4_percent_define_get_loc(VARIABLE)
 585 # -----------------------------------
 586 # Mimic muscle_percent_define_get_loc in ../src/muscle-tab.h exactly.  That is,
 587 # if the %define variable VARIABLE is undefined, complain fatally since that's
 588 # a Bison or skeleton error.  Otherwise, return its definition location in a
 589 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 590 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 591 # reason to suspect that the user-supplied value has yet influenced the output.
 592 #
 593 # For example:
 594 #
 595 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 596 m4_define([b4_percent_define_get_loc],
 597 [m4_ifdef([b4_percent_define_loc(]$1[)],
 598           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 599 b4_loc[]dnl
 600 m4_popdef([b4_loc])],
 601           [b4_fatal([[b4_percent_define_get_loc: undefined %%define variable '%s']], [$1])])])
 602
 603 # b4_percent_define_get_syncline(VARIABLE)
 604 # ----------------------------------------
 605 # Mimic muscle_percent_define_get_syncline in ../src/muscle-tab.h exactly.
 606 # That is, if the %define variable VARIABLE is undefined, complain fatally
 607 # since that's a Bison or skeleton error.  Otherwise, return its definition
 608 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 609 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 610 # influenced the output.
 611 #
 612 # For example:
 613 #
 614 #   b4_percent_define_get_syncline([[foo]])
 615 m4_define([b4_percent_define_get_syncline],
 616 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 617           [m4_indir([b4_percent_define_syncline(]$1[)])],
 618           [b4_fatal([[b4_percent_define_get_syncline: undefined %%define variable '%s']], [$1])])])
 619
 620 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 621 # ------------------------------------------------------
 622 # Mimic muscle_percent_define_ifdef in ../src/muscle-tab.h exactly.  That is,
 623 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 624 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 625 # b4_percent_define_bison_variables(VARIABLE).
 626 #
 627 # For example:
 628 #
 629 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 630 m4_define([b4_percent_define_ifdef],
 631 [m4_ifdef([b4_percent_define(]$1[)],
 632           [b4_percent_define_use([$1])$2],
 633           [$3])])
 634
 635
 636 ## --------- ##
 637 ## Options.  ##
 638 ## --------- ##
 639
 640
 641 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 642 # --------------------------------------------------------
 643 # Mimic muscle_percent_define_flag_if in ../src/muscle-tab.h exactly.  That is,
 644 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 645 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 646 # (a Bison or skeleton error since the default value should have been set
 647 # already) or defined to any other value (possibly a user error).  Also, record
 648 # Bison's usage of VARIABLE by defining
 649 # b4_percent_define_bison_variables(VARIABLE).
 650 #
 651 # For example:
 652 #
 653 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 654 m4_define([b4_percent_define_flag_if],
 655 [b4_percent_define_ifdef([$1],
 656   [m4_case(b4_percent_define_get([$1]),
 657            [], [$2], [true], [$2], [false], [$3],
 658            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 659                                            [[invalid value for %%define Boolean variable '%s']],
 660                                            [$1])],
 661                            [[b4_percent_define_flag_if($1)]])])],
 662   [b4_fatal([[b4_percent_define_flag_if: undefined %%define variable '%s']], [$1])])])
 663
 664
 665 # b4_percent_define_default(VARIABLE, DEFAULT)
 666 # --------------------------------------------
 667 # Mimic muscle_percent_define_default in ../src/muscle-tab.h exactly.  That is,
 668 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 669 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 670 # suspect that the value has yet influenced the output.
 671 #
 672 # For example:
 673 #
 674 #   b4_percent_define_default([[foo]], [[default value]])
 675 m4_define([b4_percent_define_default],
 676 [m4_ifndef([b4_percent_define(]$1[)],
 677            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 678             m4_define([b4_percent_define_loc(]$1[)],
 679                       [[[[<skeleton default value>:-1.-1]],
 680                         [[<skeleton default value>:-1.-1]]]])dnl
 681             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 682
 683
 684 # b4_percent_define_if_define(VARIABLE)
 685 # -------------------------------------
 686 # Define b4_VARIABLE_if that executes its $1 or $2 depending whether
 687 # VARIABLE was %defined.  The characters `.' and `-' in VARIABLE are mapped
 688 # to `_'.
 689 m4_define([b4_percent_define_if_define_],
 690 [m4_define(m4_bpatsubst([b4_$1_if], [[-.]], [_]),
 691            [b4_percent_define_flag_if([$1], [$2], [$3])])])
 692 m4_define([b4_percent_define_if_define],
 693 [b4_percent_define_default([[$1]], [[false]])
 694 b4_percent_define_if_define_([$1], $[1], $[2])])
 695
 696
 697 # b4_percent_define_check_values(VALUES)
 698 # --------------------------------------
 699 # Mimic muscle_percent_define_check_values in ../src/muscle-tab.h exactly
 700 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 701 # is a list of sublists of strings.  For each sublist, the first string is the
 702 # name of a %define variable, and all remaining strings in that sublist are the
 703 # valid values for that variable.  Complain if such a variable is undefined (a
 704 # Bison error since the default value should have been set already) or defined
 705 # to any other value (possibly a user error).  Don't record this as a Bison
 706 # usage of the variable as there's no reason to suspect that the value has yet
 707 # influenced the output.
 708 #
 709 # For example:
 710 #
 711 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 712 #                                  [[[[bar]], [[bar-value1]]]])
 713 m4_define([b4_percent_define_check_values],
 714 [m4_foreach([b4_sublist], m4_quote($@),
 715             [_b4_percent_define_check_values(b4_sublist)])])
 716
 717 m4_define([_b4_percent_define_check_values],
 718 [m4_ifdef([b4_percent_define(]$1[)],
 719   [m4_pushdef([b4_good_value], [0])dnl
 720    m4_if($#, 1, [],
 721          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 722                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 723                             [m4_define([b4_good_value], [1])])])])dnl
 724    m4_if(b4_good_value, [0],
 725          [b4_complain_at(b4_percent_define_get_loc([$1]),
 726                          [[invalid value for %%define variable '%s': '%s']],
 727                          [$1],
 728                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))
 729           m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 730                      [b4_complain_at(b4_percent_define_get_loc([$1]),
 731                                      [[accepted value: '%s']],
 732                                      m4_dquote(b4_value))])])dnl
 733    m4_popdef([b4_good_value])],
 734   [b4_fatal([[b4_percent_define_check_values: undefined %%define variable '%s']], [$1])])])
 735
 736 # b4_percent_code_get([QUALIFIER])
 737 # --------------------------------
 738 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 739 # comment and ending with synclines and a newline.  If QUALIFIER is not
 740 # specified or empty, do this for the unqualified %code blocks.  Also, record
 741 # Bison's usage of QUALIFIER (if specified) by defining
 742 # b4_percent_code_bison_qualifiers(QUALIFIER).
 743 #
 744 # For example, to emit any unqualified %code blocks followed by any %code
 745 # blocks for the qualifier foo:
 746 #
 747 #   b4_percent_code_get
 748 #   b4_percent_code_get([[foo]])
 749 m4_define([b4_percent_code_get],
 750 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 751 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 752 m4_ifdef(b4_macro_name,
 753 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 754                    [["%code ]$1["]])[ blocks.]])
 755 b4_user_code([m4_indir(b4_macro_name)])
 756 ])dnl
 757 m4_popdef([b4_macro_name])])
 758
 759 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 760 # -----------------------------------------------------
 761 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 762 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 763 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 764 # b4_percent_code_bison_qualifiers(QUALIFIER).
 765 m4_define([b4_percent_code_ifdef],
 766 [m4_ifdef([b4_percent_code(]$1[)],
 767           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 768           [$3])])
 769
 770
 771 ## ------------------ ##
 772 ## Common variables.  ##
 773 ## ------------------ ##
 774
 775 # Default values for %define.
 776 # ---------------------------
 777 # If the api.tokens.prefix, it is empty.
 778 m4_percent_define_default([[api.tokens.prefix]], [[]])
 779
 780 # b4_parse_assert_if([IF-ASSERTIONS-ARE-USED], [IF-NOT])
 781 # b4_parse_trace_if([IF-DEBUG-TRACES-ARE-ENABLED], [IF-NOT])
 782 # b4_lex_symbol_if([IF-YYLEX-RETURNS-A-COMPLETE-SYMBOL], [IF-NOT])
 783 # b4_variant_if([IF-VARIANT-ARE-USED], [IF-NOT])
 784 # ----------------------------------------------
 785 b4_percent_define_if_define([lex_symbol])
 786 b4_percent_define_if_define([locations])     # Whether locations are tracked.
 787 b4_percent_define_if_define([parse.assert])
 788 b4_percent_define_if_define([parse.trace])
 789 b4_percent_define_if_define([variant])
 790
 791
 792 # b4_error_verbose_if([IF-ERRORS-ARE-VERBOSE], [IF-NOT])
 793 # ------------------------------------------------------
 794 # Map %define parse.error "(simple|verbose)" to b4_error_verbose_if and
 795 # b4_error_verbose_flag.
 796 b4_percent_define_default([[parse.error]], [[simple]])
 797 b4_percent_define_check_values([[[[parse.error]],
 798                                  [[simple]], [[verbose]]]])
 799 m4_define([b4_error_verbose_flag],
 800           [m4_case(b4_percent_define_get([[parse.error]]),
 801                    [simple],  [[0]],
 802                    [verbose], [[1]])])
 803 b4_define_flag_if([error_verbose])
 804
 805
 806 ## ----------------------------------------------------------- ##
 807 ## After processing the skeletons, check that all the user's   ##
 808 ## %define variables and %code qualifiers were used by Bison.  ##
 809 ## ----------------------------------------------------------- ##
 810
 811 m4_define([b4_check_user_names_wrap],
 812 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 813           [b4_check_user_names([[%]$1 $2],
 814                                [b4_percent_]$1[_user_]$2[s],
 815                                [[b4_percent_]$1[_bison_]$2[s]])])])
 816
 817 m4_wrap_lifo([
 818 b4_check_user_names_wrap([[define]], [[variable]])
 819 b4_check_user_names_wrap([[code]], [[qualifier]])
 820 ])