src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include "system.h"
  24
  25 #include "complain.h"
  26 #include "conflicts.h"
  27 #include "files.h"
  28 #include "getargs.h"
  29 #include "gram.h"
  30 #include "muscle_tab.h"
  31 #include "output.h"
  32 #include "quotearg.h"
  33 #include "reader.h"
  34 #include "symlist.h"
  35 #include "strverscmp.h"
  36
  37 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  38 static YYLTYPE lloc_default (YYLTYPE const *, int);
  39
  40 #define YY_LOCATION_PRINT(File, Loc) \
  41           location_print (File, Loc)
  42
  43 static void version_check (location const *loc, char const *version);
  44
  45 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  46    FIXME: depends on the undocumented availability of YYLLOC.  */
  47 #undef  yyerror
  48 #define yyerror(Msg) \
  49         gram_error (&yylloc, Msg)
  50 static void gram_error (location const *, char const *);
  51
  52 static void add_param (char const *, char *, location);
  53
  54 static symbol_class current_class = unknown_sym;
  55 static uniqstr current_type = 0;
  56 static symbol *current_lhs;
  57 static location current_lhs_location;
  58 static int current_prec = 0;
  59 %}
  60
  61 %debug
  62 %verbose
  63 %defines
  64 %locations
  65 %pure-parser
  66 %error-verbose
  67 %defines
  68 %name-prefix="gram_"
  69
  70 %initial-action
  71 {
  72   /* Bison's grammar can initial empty locations, hence a default
  73      location is needed. */
  74   @$.start.file   = @$.end.file   = current_file;
  75   @$.start.line   = @$.end.line   = 1;
  76   @$.start.column = @$.end.column = 0;
  77 }
  78
  79 /* Only NUMBERS have a value.  */
  80 %union
  81 {
  82   symbol *symbol;
  83   symbol_list *list;
  84   int integer;
  85   char *chars;
  86   assoc assoc;
  87   uniqstr uniqstr;
  88 };
  89
  90 /* Define the tokens together with their human representation.  */
  91 %token GRAM_EOF 0 "end of file"
  92 %token STRING     "string"
  93 %token INT        "integer"
  94
  95 %token PERCENT_TOKEN       "%token"
  96 %token PERCENT_NTERM       "%nterm"
  97
  98 %token PERCENT_TYPE        "%type"
  99 %token PERCENT_DESTRUCTOR  "%destructor {...}"
 100 %token PERCENT_PRINTER     "%printer {...}"
 101
 102 %token PERCENT_UNION       "%union {...}"
 103
 104 %token PERCENT_LEFT        "%left"
 105 %token PERCENT_RIGHT       "%right"
 106 %token PERCENT_NONASSOC    "%nonassoc"
 107
 108 %token PERCENT_PREC          "%prec"
 109 %token PERCENT_DPREC         "%dprec"
 110 %token PERCENT_MERGE         "%merge"
 111
 112
 113 /*----------------------.
 114 | Global Declarations.  |
 115 `----------------------*/
 116
 117 %token
 118   PERCENT_DEBUG           "%debug"
 119   PERCENT_DEFAULT_PREC    "%default-prec"
 120   PERCENT_DEFINE          "%define"
 121   PERCENT_DEFINES         "%defines"
 122   PERCENT_ERROR_VERBOSE   "%error-verbose"
 123   PERCENT_EXPECT          "%expect"
 124   PERCENT_EXPECT_RR       "%expect-rr"
 125   PERCENT_FILE_PREFIX     "%file-prefix"
 126   PERCENT_GLR_PARSER      "%glr-parser"
 127   PERCENT_INITIAL_ACTION  "%initial-action {...}"
 128   PERCENT_LEX_PARAM       "%lex-param {...}"
 129   PERCENT_LOCATIONS       "%locations"
 130   PERCENT_NAME_PREFIX     "%name-prefix"
 131   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 132   PERCENT_NO_LINES        "%no-lines"
 133   PERCENT_NONDETERMINISTIC_PARSER
 134                           "%nondeterministic-parser"
 135   PERCENT_OUTPUT          "%output"
 136   PERCENT_PARSE_PARAM     "%parse-param {...}"
 137   PERCENT_PURE_PARSER     "%pure-parser"
 138   PERCENT_REQUIRE         "%require"
 139   PERCENT_SKELETON        "%skeleton"
 140   PERCENT_START           "%start"
 141   PERCENT_TOKEN_TABLE     "%token-table"
 142   PERCENT_VERBOSE         "%verbose"
 143   PERCENT_YACC            "%yacc"
 144 ;
 145
 146 %token TYPE            "type"
 147 %token EQUAL           "="
 148 %token SEMICOLON       ";"
 149 %token PIPE            "|"
 150 %token ID              "identifier"
 151 %token ID_COLON        "identifier:"
 152 %token PERCENT_PERCENT "%%"
 153 %token PROLOGUE        "%{...%}"
 154 %token EPILOGUE        "epilogue"
 155 %token BRACED_CODE     "{...}"
 156
 157
 158 %type <chars> STRING string_content
 159               "%destructor {...}"
 160               "%initial-action {...}"
 161               "%lex-param {...}"
 162               "%parse-param {...}"
 163               "%printer {...}"
 164               "%union {...}"
 165               BRACED_CODE action
 166               PROLOGUE EPILOGUE
 167 %printer { fprintf (stderr, "\"%s\"", $$); }
 168               STRING string_content
 169 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 170               "%destructor {...}"
 171               "%initial-action {...}"
 172               "%lex-param {...}"
 173               "%parse-param {...}"
 174               "%printer {...}"
 175               "%union {...}"
 176               BRACED_CODE action
 177               PROLOGUE EPILOGUE
 178 %type <uniqstr> TYPE
 179 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 180 %type <integer> INT
 181 %printer { fprintf (stderr, "%d", $$); } INT
 182 %type <symbol> ID symbol string_as_id
 183 %printer { fprintf (stderr, "%s", $$->tag); } ID symbol string_as_id
 184 %type <symbol> ID_COLON
 185 %printer { fprintf (stderr, "%s:", $$->tag); } ID_COLON
 186 %type <assoc> precedence_declarator
 187 %type <list>  symbols.1
 188 %%
 189
 190 input:
 191   declarations "%%" grammar epilogue.opt
 192 ;
 193
 194
 195         /*------------------------------------.
 196         | Declarations: before the first %%.  |
 197         `------------------------------------*/
 198
 199 declarations:
 200   /* Nothing */
 201 | declarations declaration
 202 ;
 203
 204 declaration:
 205   grammar_declaration
 206 | PROLOGUE                                 { prologue_augment ($1, @1); }
 207 | "%debug"                                 { debug_flag = true; }
 208 | "%define" string_content                 { muscle_insert ($2, "1"); }
 209 | "%define" string_content string_content  { muscle_insert ($2, $3); }
 210 | "%defines"                               { defines_flag = true; }
 211 | "%error-verbose"                         { error_verbose = true; }
 212 | "%expect" INT                            { expected_sr_conflicts = $2; }
 213 | "%expect-rr" INT                         { expected_rr_conflicts = $2; }
 214 | "%file-prefix" "=" string_content        { spec_file_prefix = $3; }
 215 | "%glr-parser"
 216   {
 217     nondeterministic_parser = true;
 218     glr_parser = true;
 219   }
 220 | "%initial-action {...}"
 221   {
 222     muscle_code_grow ("initial_action", $1, @1);
 223   }
 224 | "%lex-param {...}"                       { add_param ("lex_param", $1, @1); }
 225 | "%locations"                             { locations_flag = true; }
 226 | "%name-prefix" "=" string_content        { spec_name_prefix = $3; }
 227 | "%no-lines"                              { no_lines_flag = true; }
 228 | "%nondeterministic-parser"               { nondeterministic_parser = true; }
 229 | "%output" "=" string_content             { spec_outfile = $3; }
 230 | "%parse-param {...}"                     { add_param ("parse_param", $1, @1); }
 231 | "%pure-parser"                           { pure_parser = true; }
 232 | "%require" string_content                { version_check (&@2, $2); }
 233 | "%skeleton" string_content               { skeleton = $2; }
 234 | "%token-table"                           { token_table_flag = true; }
 235 | "%verbose"                               { report_flag = report_states; }
 236 | "%yacc"                                  { yacc_flag = true; }
 237 | /*FIXME: Err?  What is this horror doing here? */ ";"
 238 ;
 239
 240 grammar_declaration:
 241   precedence_declaration
 242 | symbol_declaration
 243 | "%start" symbol
 244     {
 245       grammar_start_symbol_set ($2, @2);
 246     }
 247 | "%union {...}"
 248     {
 249       typed = true;
 250       MUSCLE_INSERT_INT ("stype_line", @1.start.line);
 251       muscle_insert ("stype", $1);
 252     }
 253 | "%destructor {...}" symbols.1
 254     {
 255       symbol_list *list;
 256       for (list = $2; list; list = list->next)
 257         symbol_destructor_set (list->sym, $1, @1);
 258       symbol_list_free ($2);
 259     }
 260 | "%printer {...}" symbols.1
 261     {
 262       symbol_list *list;
 263       for (list = $2; list; list = list->next)
 264         symbol_printer_set (list->sym, $1, list->location);
 265       symbol_list_free ($2);
 266     }
 267 | "%default-prec"
 268     {
 269       default_prec = true;
 270     }
 271 | "%no-default-prec"
 272     {
 273       default_prec = false;
 274     }
 275 ;
 276
 277 symbol_declaration:
 278   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 279     {
 280       current_class = unknown_sym;
 281       current_type = NULL;
 282     }
 283 | "%token" { current_class = token_sym; } symbol_defs.1
 284     {
 285       current_class = unknown_sym;
 286       current_type = NULL;
 287     }
 288 | "%type" TYPE symbols.1
 289     {
 290       symbol_list *list;
 291       for (list = $3; list; list = list->next)
 292         symbol_type_set (list->sym, $2, @2);
 293       symbol_list_free ($3);
 294     }
 295 ;
 296
 297 precedence_declaration:
 298   precedence_declarator type.opt symbols.1
 299     {
 300       symbol_list *list;
 301       ++current_prec;
 302       for (list = $3; list; list = list->next)
 303         {
 304           symbol_type_set (list->sym, current_type, @2);
 305           symbol_precedence_set (list->sym, current_prec, $1, @1);
 306         }
 307       symbol_list_free ($3);
 308       current_type = NULL;
 309     }
 310 ;
 311
 312 precedence_declarator:
 313   "%left"     { $$ = left_assoc; }
 314 | "%right"    { $$ = right_assoc; }
 315 | "%nonassoc" { $$ = non_assoc; }
 316 ;
 317
 318 type.opt:
 319   /* Nothing. */ { current_type = NULL; }
 320 | TYPE           { current_type = $1; }
 321 ;
 322
 323 /* One or more nonterminals to be %typed. */
 324
 325 symbols.1:
 326   symbol            { $$ = symbol_list_new ($1, @1); }
 327 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 328 ;
 329
 330 /* One token definition.  */
 331 symbol_def:
 332   TYPE
 333      {
 334        current_type = $1;
 335      }
 336 | ID
 337      {
 338        symbol_class_set ($1, current_class, @1);
 339        symbol_type_set ($1, current_type, @1);
 340      }
 341 | ID INT
 342     {
 343       symbol_class_set ($1, current_class, @1);
 344       symbol_type_set ($1, current_type, @1);
 345       symbol_user_token_number_set ($1, $2, @2);
 346     }
 347 | ID string_as_id
 348     {
 349       symbol_class_set ($1, current_class, @1);
 350       symbol_type_set ($1, current_type, @1);
 351       symbol_make_alias ($1, $2, @$);
 352     }
 353 | ID INT string_as_id
 354     {
 355       symbol_class_set ($1, current_class, @1);
 356       symbol_type_set ($1, current_type, @1);
 357       symbol_user_token_number_set ($1, $2, @2);
 358       symbol_make_alias ($1, $3, @$);
 359     }
 360 ;
 361
 362 /* One or more symbol definitions. */
 363 symbol_defs.1:
 364   symbol_def
 365 | symbol_defs.1 symbol_def
 366 ;
 367
 368
 369         /*------------------------------------------.
 370         | The grammar section: between the two %%.  |
 371         `------------------------------------------*/
 372
 373 grammar:
 374   rules_or_grammar_declaration
 375 | grammar rules_or_grammar_declaration
 376 ;
 377
 378 /* As a Bison extension, one can use the grammar declarations in the
 379    body of the grammar.  */
 380 rules_or_grammar_declaration:
 381   rules
 382 | grammar_declaration ";"
 383     {
 384       if (yacc_flag)
 385         complain_at (@$, _("POSIX forbids declarations in the grammar"));
 386     }
 387 | error ";"
 388     {
 389       yyerrok;
 390     }
 391 ;
 392
 393 rules:
 394   ID_COLON { current_lhs = $1; current_lhs_location = @1; } rhses.1
 395 ;
 396
 397 rhses.1:
 398   rhs                { grammar_rule_end (@1); }
 399 | rhses.1 "|" rhs    { grammar_rule_end (@3); }
 400 | rhses.1 ";"
 401 ;
 402
 403 rhs:
 404   /* Nothing.  */
 405     { grammar_rule_begin (current_lhs, current_lhs_location); }
 406 | rhs symbol
 407     { grammar_current_rule_symbol_append ($2, @2); }
 408 | rhs action
 409     { grammar_current_rule_action_append ($2, @2); }
 410 | rhs "%prec" symbol
 411     { grammar_current_rule_prec_set ($3, @3); }
 412 | rhs "%dprec" INT
 413     { grammar_current_rule_dprec_set ($3, @3); }
 414 | rhs "%merge" TYPE
 415     { grammar_current_rule_merge_set ($3, @3); }
 416 ;
 417
 418 symbol:
 419   ID              { $$ = $1; }
 420 | string_as_id    { $$ = $1; }
 421 ;
 422
 423 action:
 424   BRACED_CODE
 425     { $$ = $1; }
 426 ;
 427
 428 /* A string used as an ID: quote it.  */
 429 string_as_id:
 430   STRING
 431     {
 432       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 433       symbol_class_set ($$, token_sym, @1);
 434     }
 435 ;
 436
 437 /* A string used for its contents.  Don't quote it.  */
 438 string_content:
 439   STRING
 440     { $$ = $1; }
 441 ;
 442
 443
 444 epilogue.opt:
 445   /* Nothing.  */
 446 | "%%" EPILOGUE
 447     {
 448       muscle_code_grow ("epilogue", $2, @2);
 449       scanner_last_string_free ();
 450     }
 451 ;
 452
 453 %%
 454
 455
 456 /* Return the location of the left-hand side of a rule whose
 457    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 458    the right-hand side, and return an empty location equal to the end
 459    boundary of RHS[0] if the right-hand side is empty.  */
 460
 461 static YYLTYPE
 462 lloc_default (YYLTYPE const *rhs, int n)
 463 {
 464   int i;
 465   YYLTYPE loc;
 466
 467   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 468      The bug is fixed in 7.4.2m, but play it safe for now.  */
 469   loc.start = rhs[n].end;
 470   loc.end = rhs[n].end;
 471
 472   /* Ignore empty nonterminals the start of the the right-hand side.
 473      Do not bother to ignore them at the end of the right-hand side,
 474      since empty nonterminals have the same end as their predecessors.  */
 475   for (i = 1; i <= n; i++)
 476     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 477       {
 478         loc.start = rhs[i].start;
 479         break;
 480       }
 481
 482   return loc;
 483 }
 484
 485
 486 /* Add a lex-param or a parse-param (depending on TYPE) with
 487    declaration DECL and location LOC.  */
 488
 489 static void
 490 add_param (char const *type, char *decl, location loc)
 491 {
 492   static char const alphanum[26 + 26 + 1 + 10] =
 493     "abcdefghijklmnopqrstuvwxyz"
 494     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 495     "_"
 496     "0123456789";
 497   char const *name_start = NULL;
 498   char *p;
 499
 500   /* Stop on last actual character.  */
 501   for (p = decl; p[1]; p++)
 502     if ((p == decl
 503          || ! memchr (alphanum, p[-1], sizeof alphanum))
 504         && memchr (alphanum, p[0], sizeof alphanum - 10))
 505       name_start = p;
 506
 507   /* Strip the surrounding '{' and '}', and any blanks just inside
 508      the braces.  */
 509   while (*--p == ' ' || *p == '\t')
 510     continue;
 511   p[1] = '\0';
 512   while (*++decl == ' ' || *decl == '\t')
 513     continue;
 514
 515   if (! name_start)
 516     complain_at (loc, _("missing identifier in parameter declaration"));
 517   else
 518     {
 519       char *name;
 520       size_t name_len;
 521
 522       for (name_len = 1;
 523            memchr (alphanum, name_start[name_len], sizeof alphanum);
 524            name_len++)
 525         continue;
 526
 527       name = xmalloc (name_len + 1);
 528       memcpy (name, name_start, name_len);
 529       name[name_len] = '\0';
 530       muscle_pair_list_grow (type, decl, name);
 531       free (name);
 532     }
 533
 534   scanner_last_string_free ();
 535 }
 536
 537 static void
 538 version_check (location const *loc, char const *version)
 539 {
 540   if (strverscmp (version, PACKAGE_VERSION) > 0)
 541     {
 542       complain_at (*loc, "require bison %s, but have %s",
 543                    version, PACKAGE_VERSION);
 544       exit (63);
 545     }
 546 }
 547
 548 static void
 549 gram_error (location const *loc, char const *msg)
 550 {
 551   complain_at (*loc, "%s", msg);
 552 }
 553
 554 char const *
 555 token_name (int type)
 556 {
 557   return yytname[YYTRANSLATE (type)];
 558 }