configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2013 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the 'configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2013])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # We use Automake 1.14's %D% and %C%.
  37 #
  38 # We want gnits strictness only when rolling a stable release.  For
  39 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  40 # doesn't like that, so we let the underscore disable gnits.  Between
  41 # releases, we want to be able run make dist without being required to
  42 # add a bogus NEWS entry.  In that case, the version string
  43 # automatically contains a dash, which we also let disable gnits.
  44 AM_INIT_AUTOMAKE([1.14 dist-xz nostdinc
  45                  color-tests parallel-tests
  46                  silent-rules]
  47                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  48                            [gnu], [gnits]))
  49 AM_SILENT_RULES([yes])
  50 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  51
  52 # Checks for the compiler.
  53 AC_PROG_CC_STDC
  54 AC_PROG_CXX
  55
  56 # Gnulib (early checks).
  57 gl_EARLY
  58
  59 # Gnulib uses '#pragma GCC diagnostic push' to silence some
  60 # warnings, but older gcc doesn't support this.
  61 AC_CACHE_CHECK([whether pragma GCC diagnostic push works],
  62   [lv_cv_gcc_pragma_push_works], [
  63   save_CFLAGS=$CFLAGS
  64   CFLAGS='-Wunknown-pragmas -Werror'
  65   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  66     #pragma GCC diagnostic push
  67     #pragma GCC diagnostic pop
  68   ]])],
  69   [lv_cv_gcc_pragma_push_works=yes],
  70   [lv_cv_gcc_pragma_push_works=no])
  71   CFLAGS=$save_CFLAGS])
  72
  73 AC_ARG_ENABLE([gcc-warnings],
  74 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  75 [case $enable_gcc_warnings in
  76    yes|no) ;;
  77    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  78  esac],
  79               [enable_gcc_warnings=no])
  80 if test "$enable_gcc_warnings" = yes; then
  81   warn_common='-Wall-Wextra -Wno-sign-compare -Wcast-align -Wdocumentation
  82     -Wformat -Wpointer-arith -Wwrite-strings'
  83   warn_c='-Wbad-function-cast -Wshadow -Wstrict-prototypes'
  84   warn_cxx='-Wnoexcept'
  85   # Warnings for the test suite only.
  86   #
  87   # -fno-color-diagnostics: Clang's use of colors in the error
  88   # messages is confusing the tests looking at the compiler's output
  89   # (e.g., synclines.at).
  90   warn_tests='-Wundef -pedantic -Wsign-compare -fno-color-diagnostics'
  91
  92   AC_LANG_PUSH([C])
  93   # Clang supports many of GCC's -W options, but only issues warnings
  94   # on the ones it does not recognize.  In that case, gl_WARN_ADD
  95   # thinks the option is supported, and unknown options are then added
  96   # to CFLAGS.  But then, when -Werror is added in the test suite for
  97   # instance, the warning about the unknown option turns into an
  98   # error.
  99   #
 100   # This should be addressed by gnulib's gl_WARN_ADD, but in the
 101   # meanwhile, turn warnings about unknown options into errors in
 102   # CFLAGS, and restore CFLAGS after the tests.
 103   save_CFLAGS=$CFLAGS
 104   gl_WARN_ADD([-Werror=unknown-warning-option], [CFLAGS])
 105   for i in $warn_common $warn_c;
 106   do
 107     gl_WARN_ADD([$i], [WARN_CFLAGS])
 108   done
 109   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 110
 111   # Warnings for the test suite, and maybe for bison if GCC is modern
 112   # enough.
 113   gl_WARN_ADD([-Wmissing-declarations], [WARN_CFLAGS_TEST])
 114   gl_WARN_ADD([-Wmissing-prototypes], [WARN_CFLAGS_TEST])
 115   test $lv_cv_gcc_pragma_push_works = yes &&
 116     AS_VAR_APPEND([WARN_CFLAGS], [" $WARN_CFLAGS_TEST"])
 117
 118   # Warnings for the test suite only.
 119   for i in $warn_tests;
 120   do
 121     gl_WARN_ADD([$i], [WARN_CFLAGS_TEST])
 122   done
 123   CFLAGS=$save_CFLAGS
 124   AC_LANG_POP([C])
 125
 126   AC_LANG_PUSH([C++])
 127   save_CXXFLAGS=$CXXFLAGS
 128   gl_WARN_ADD([-Werror=unknown-warning-option], [CXXFLAGS])
 129   for i in $warn_common $warn_cxx;
 130   do
 131     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
 132   done
 133   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
 134               [AC_LANG_PROGRAM([], [nullptr])])
 135   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
 136   # Warnings for the test suite only.
 137   for i in $warn_tests;
 138   do
 139     gl_WARN_ADD([$i], [WARN_CXXFLAGS_TEST])
 140   done
 141   # Clang++ 3.2+ reject C code generated by Flex.
 142   gl_WARN_ADD([-Wno-null-conversion], [FLEX_SCANNER_CXXFLAGS])
 143   # So does G++ 4.8...
 144   gl_WARN_ADD([-Wno-sign-compare], [FLEX_SCANNER_CXXFLAGS])
 145   # ... possiby in std=c++11 mode.
 146   gl_WARN_ADD([-Wno-zero-as-null-pointer-constant], [FLEX_SCANNER_CXXFLAGS])
 147   CXXFLAGS=$save_CXXFLAGS
 148   AC_LANG_POP([C++])
 149 fi
 150
 151 BISON_TEST_FOR_WORKING_C_COMPILER
 152 BISON_C_COMPILER_POSIXLY_CORRECT
 153 BISON_TEST_FOR_WORKING_CXX_COMPILER
 154 BISON_CXX_COMPILER_POSIXLY_CORRECT
 155
 156 AC_ARG_ENABLE([yacc],
 157   [AC_HELP_STRING([--disable-yacc],
 158      [do not build a yacc command or an -ly library])],
 159   , [enable_yacc=yes])
 160 AM_CONDITIONAL([ENABLE_YACC], [test "$enable_yacc" = yes])
 161
 162 # Checks for programs.
 163 AM_MISSING_PROG([DOT], [dot])
 164 AC_PROG_LEX
 165 $LEX_IS_FLEX || test "X$LEX" = X: || {
 166   AC_MSG_WARN([bypassing lex because flex is required])
 167   LEX=:
 168 }
 169 AM_CONDITIONAL([FLEX_CXX_WORKS],
 170   [$LEX_IS_FLEX && test $bison_cv_cxx_works = yes])
 171 AC_PROG_YACC
 172 AC_PROG_RANLIB
 173 AC_PROG_GNU_M4
 174 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 175 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 176 supports -g, otherwise to "".])
 177 AC_PATH_PROG([PERL], [perl])
 178 if test -z "$PERL"; then
 179    AC_MSG_ERROR([perl not found])
 180 fi
 181 AM_MISSING_PROG([HELP2MAN], [help2man])
 182 AC_PATH_PROG([XSLTPROC], [xsltproc])
 183 AC_SUBST([XSLTPROC])
 184
 185 # Checks for header files.
 186 AC_CHECK_HEADERS_ONCE([locale.h])
 187
 188 # Checks for compiler characteristics.
 189 AC_C_INLINE
 190
 191 # Gnulib (later checks).  Putting them here rather than right after
 192 # gl_EARLY avoids some redundant checks.
 193 gl_INIT
 194
 195 # Checks for library functions.
 196 AC_CHECK_FUNCS_ONCE([setlocale])
 197 AM_WITH_DMALLOC
 198 BISON_PREREQ_TIMEVAR
 199
 200 # Gettext.
 201 # We use gnulib, which is only guaranteed to work properly with the
 202 # latest Gettext.
 203 AM_GNU_GETTEXT([external], [need-ngettext])
 204 AM_GNU_GETTEXT_VERSION([0.18])
 205 BISON_I18N
 206
 207 # Internationalized parsers.
 208 AC_CONFIG_FILES([runtime-po/Makefile.in])
 209 # Autoconf macros for packages using internationalized parsers.
 210 aclocaldir='${datadir}/aclocal'
 211 AC_SUBST([aclocaldir])
 212
 213 # Create the benchmark script.
 214 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 215
 216 # Initialize the test suite.
 217 AC_CONFIG_TESTDIR(tests)
 218 AC_CONFIG_FILES([tests/atlocal])
 219 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 220 AC_CHECK_PROGS([VALGRIND], [valgrind])
 221 case $VALGRIND:$host_os in
 222   '':*) ;;
 223   *:darwin*)
 224     # See README-hacking.
 225     # VALGRIND+='-q --suppressions=$(abs_top_srcdir)/build-aux/darwin11.4.0.valgrind'
 226     VALGRIND=;;
 227   *:*)
 228     suppfile=build-aux/$host_os.valgrind
 229     if test -f "$srcdir/$suppfile"; then
 230       VALGRIND="$VALGRIND --gen-suppressions=all"
 231       VALGRIND="$VALGRIND --suppressions=\$(abs_top_srcdir)/$suppfile"
 232     fi
 233     AC_SUBST([VALGRIND_PREBISON], ["$VALGRIND -q"])
 234     ;;
 235 esac
 236
 237 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 238 # Needed by tests/atlocal.in.
 239 AC_SUBST([GCC])
 240
 241 gt_JAVACOMP([1.3], [1.4])
 242 gt_JAVAEXEC
 243
 244 AC_CONFIG_FILES([Makefile
 245                  po/Makefile.in
 246                  doc/yacc.1])
 247 AC_OUTPUT