src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation,
   4    Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include <strverscmp.h>
  25
  26 #include "complain.h"
  27 #include "conflicts.h"
  28 #include "files.h"
  29 #include "getargs.h"
  30 #include "gram.h"
  31 #include "muscle_tab.h"
  32 #include "quotearg.h"
  33 #include "reader.h"
  34 #include "symlist.h"
  35 #include "scan-gram.h"
  36 #include "scan-code.h"
  37
  38 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  39 static YYLTYPE lloc_default (YYLTYPE const *, int);
  40
  41 #define YY_LOCATION_PRINT(File, Loc) \
  42           location_print (File, Loc)
  43
  44 static void version_check (location const *loc, char const *version);
  45
  46 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  47    FIXME: depends on the undocumented availability of YYLLOC.  */
  48 #undef  yyerror
  49 #define yyerror(Msg) \
  50         gram_error (&yylloc, Msg)
  51 static void gram_error (location const *, char const *);
  52
  53 static char const *char_name (char);
  54
  55 /** Add a lex-param or a parse-param.
  56  *
  57  * \param type  \a lex_param or \a parse_param
  58  * \param decl  the formal argument
  59  * \param loc   the location in the source.
  60  */
  61 static void add_param (char const *type, char *decl, location loc);
  62
  63
  64 static symbol_class current_class = unknown_sym;
  65 static uniqstr current_type = NULL;
  66 static symbol *current_lhs;
  67 static location current_lhs_location;
  68 static int current_prec = 0;
  69
  70 #define YYTYPE_INT16 int_fast16_t
  71 #define YYTYPE_INT8 int_fast8_t
  72 #define YYTYPE_UINT16 uint_fast16_t
  73 #define YYTYPE_UINT8 uint_fast8_t
  74 %}
  75
  76 %debug
  77 %verbose
  78 %defines
  79 %locations
  80 %pure-parser
  81 %error-verbose
  82 %name-prefix="gram_"
  83 %expect 0
  84
  85 %initial-action
  86 {
  87   /* Bison's grammar can initial empty locations, hence a default
  88      location is needed. */
  89   boundary_set (&@$.start, current_file, 1, 1);
  90   boundary_set (&@$.end, current_file, 1, 1);
  91 }
  92
  93 %union
  94 {
  95   symbol *symbol;
  96   symbol_list *list;
  97   int integer;
  98   char const *chars;
  99   char *code;
 100   assoc assoc;
 101   uniqstr uniqstr;
 102   unsigned char character;
 103 };
 104
 105 /* Define the tokens together with their human representation.  */
 106 %token GRAM_EOF 0 "end of file"
 107 %token STRING     "string"
 108 %token INT        "integer"
 109
 110 %token PERCENT_TOKEN       "%token"
 111 %token PERCENT_NTERM       "%nterm"
 112
 113 %token PERCENT_TYPE        "%type"
 114 %token PERCENT_DESTRUCTOR  "%destructor"
 115 %token PERCENT_PRINTER     "%printer"
 116
 117 %token PERCENT_LEFT        "%left"
 118 %token PERCENT_RIGHT       "%right"
 119 %token PERCENT_NONASSOC    "%nonassoc"
 120
 121 %token PERCENT_PREC          "%prec"
 122 %token PERCENT_DPREC         "%dprec"
 123 %token PERCENT_MERGE         "%merge"
 124
 125
 126 /*----------------------.
 127 | Global Declarations.  |
 128 `----------------------*/
 129
 130 %token
 131   PERCENT_CODE            "%code"
 132   PERCENT_DEBUG           "%debug"
 133   PERCENT_DEFAULT_PREC    "%default-prec"
 134   PERCENT_DEFINE          "%define"
 135   PERCENT_DEFINES         "%defines"
 136   PERCENT_ERROR_VERBOSE   "%error-verbose"
 137   PERCENT_EXPECT          "%expect"
 138   PERCENT_EXPECT_RR       "%expect-rr"
 139   PERCENT_FILE_PREFIX     "%file-prefix"
 140   PERCENT_GLR_PARSER      "%glr-parser"
 141   PERCENT_INITIAL_ACTION  "%initial-action"
 142   PERCENT_LANGUAGE        "%language"
 143   PERCENT_LEX_PARAM       "%lex-param"
 144   PERCENT_LOCATIONS       "%locations"
 145   PERCENT_NAME_PREFIX     "%name-prefix"
 146   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 147   PERCENT_NO_LINES        "%no-lines"
 148   PERCENT_NONDETERMINISTIC_PARSER
 149                           "%nondeterministic-parser"
 150   PERCENT_OUTPUT          "%output"
 151   PERCENT_PARSE_PARAM     "%parse-param"
 152   PERCENT_PURE_PARSER     "%pure-parser"
 153   PERCENT_PUSH_PARSER     "%push-parser"
 154   PERCENT_PUSH_PULL_PARSER
 155                           "%push-pull-parser"
 156   PERCENT_REQUIRE         "%require"
 157   PERCENT_SKELETON        "%skeleton"
 158   PERCENT_START           "%start"
 159   PERCENT_TOKEN_TABLE     "%token-table"
 160   PERCENT_VERBOSE         "%verbose"
 161   PERCENT_YACC            "%yacc"
 162 ;
 163
 164 %token BRACED_CODE     "{...}"
 165 %token CHAR            "char"
 166 %token EPILOGUE        "epilogue"
 167 %token EQUAL           "="
 168 %token ID              "identifier"
 169 %token ID_COLON        "identifier:"
 170 %token PERCENT_PERCENT "%%"
 171 %token PIPE            "|"
 172 %token PROLOGUE        "%{...%}"
 173 %token SEMICOLON       ";"
 174 %token TYPE            "type"
 175 %token TYPE_TAG_ANY    "<*>"
 176 %token TYPE_TAG_NONE   "<>"
 177
 178 %type <character> CHAR
 179 %printer { fputs (char_name ($$), stderr); } CHAR
 180
 181 /* braceless is not to be used for rule or symbol actions, as it
 182    calls code_props_plain_init.  */
 183 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 184 %type <code> "{...}"
 185 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 186          STRING
 187 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 188          braceless content.opt "{...}" "%{...%}" EPILOGUE
 189
 190 %type <uniqstr> TYPE ID ID_COLON variable
 191 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 192 %printer { fputs ($$, stderr); } ID variable
 193 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 194
 195 %type <integer> INT
 196 %printer { fprintf (stderr, "%d", $$); } INT
 197
 198 %type <symbol> id id_colon symbol string_as_id
 199 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 200 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 201
 202 %type <assoc> precedence_declarator
 203 %type <list>  symbols.1 generic_symlist generic_symlist_item
 204 %%
 205
 206 input:
 207   prologue_declarations "%%" grammar epilogue.opt
 208 ;
 209
 210
 211         /*------------------------------------.
 212         | Declarations: before the first %%.  |
 213         `------------------------------------*/
 214
 215 prologue_declarations:
 216   /* Nothing */
 217 | prologue_declarations prologue_declaration
 218 ;
 219
 220 prologue_declaration:
 221   grammar_declaration
 222 | "%{...%}"
 223     {
 224       code_props plain_code;
 225       code_props_plain_init (&plain_code, $1, @1);
 226       code_props_translate_code (&plain_code);
 227       gram_scanner_last_string_free ();
 228       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 229                         plain_code.code, @1);
 230       code_scanner_last_string_free ();
 231     }
 232 | "%debug"                         { debug_flag = true; }
 233 | "%define" variable content.opt
 234     {
 235       muscle_percent_define_insert ($2, @2, $3);
 236     }
 237 | "%defines"                       { defines_flag = true; }
 238 | "%defines" STRING
 239     {
 240       defines_flag = true;
 241       spec_defines_file = xstrdup ($2);
 242     }
 243 | "%error-verbose"                 { error_verbose = true; }
 244 | "%expect" INT                    { expected_sr_conflicts = $2; }
 245 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 246 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 247 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 248 | "%glr-parser"
 249     {
 250       nondeterministic_parser = true;
 251       glr_parser = true;
 252     }
 253 | "%initial-action" "{...}"
 254     {
 255       code_props action;
 256       code_props_symbol_action_init (&action, $2, @2);
 257       code_props_translate_code (&action);
 258       gram_scanner_last_string_free ();
 259       muscle_code_grow ("initial_action", action.code, @2);
 260       code_scanner_last_string_free ();
 261     }
 262 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 263 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 264 | "%locations"                  { locations_flag = true; }
 265 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 266 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 267 | "%no-lines"                   { no_lines_flag = true; }
 268 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 269 | "%output" STRING              { spec_outfile = $2; }
 270 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 271 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 272 | "%pure-parser"                { pure_parser = true; }
 273 | "%push-parser"                { push_parser = true; pull_parser = false; }
 274 | "%push-pull-parser"           { push_parser = true; pull_parser = true; }
 275 | "%require" STRING             { version_check (&@2, $2); }
 276 | "%skeleton" STRING
 277     {
 278       char const *skeleton_user = $2;
 279       if (strchr (skeleton_user, '/'))
 280         {
 281           size_t dir_length = strlen (current_file);
 282           char *skeleton_build;
 283           while (dir_length && current_file[dir_length - 1] != '/')
 284             --dir_length;
 285           while (dir_length && current_file[dir_length - 1] == '/')
 286             --dir_length;
 287           skeleton_build =
 288             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 289           if (dir_length > 0)
 290             {
 291               strncpy (skeleton_build, current_file, dir_length);
 292               skeleton_build[dir_length++] = '/';
 293             }
 294           strcpy (skeleton_build + dir_length, skeleton_user);
 295           skeleton_user = uniqstr_new (skeleton_build);
 296           free (skeleton_build);
 297         }
 298       skeleton_arg (skeleton_user, 1, &@1);
 299     }
 300 | "%token-table"                { token_table_flag = true; }
 301 | "%verbose"                    { report_flag = report_states; }
 302 | "%yacc"                       { yacc_flag = true; }
 303 | /*FIXME: Err?  What is this horror doing here? */ ";"
 304 ;
 305
 306 grammar_declaration:
 307   precedence_declaration
 308 | symbol_declaration
 309 | "%start" symbol
 310     {
 311       grammar_start_symbol_set ($2, @2);
 312     }
 313 | "%destructor" "{...}" generic_symlist
 314     {
 315       symbol_list *list;
 316       for (list = $3; list; list = list->next)
 317         symbol_list_destructor_set (list, $2, @2);
 318       symbol_list_free ($3);
 319     }
 320 | "%printer" "{...}" generic_symlist
 321     {
 322       symbol_list *list;
 323       for (list = $3; list; list = list->next)
 324         symbol_list_printer_set (list, $2, @2);
 325       symbol_list_free ($3);
 326     }
 327 | "%default-prec"
 328     {
 329       default_prec = true;
 330     }
 331 | "%no-default-prec"
 332     {
 333       default_prec = false;
 334     }
 335 | "%code" braceless
 336     {
 337       /* Do not invoke muscle_percent_code_grow here since it invokes
 338          muscle_user_name_list_grow.  */
 339       muscle_code_grow ("percent_code()", $2, @2);
 340       code_scanner_last_string_free ();
 341     }
 342 | "%code" ID braceless
 343     {
 344       muscle_percent_code_grow ($2, @2, $3, @3);
 345       code_scanner_last_string_free ();
 346     }
 347 ;
 348
 349
 350 /*----------*
 351  | %union.  |
 352  *----------*/
 353
 354 %token PERCENT_UNION "%union";
 355
 356 union_name:
 357   /* Nothing. */ {}
 358 | ID             { muscle_code_grow ("union_name", $1, @1); }
 359 ;
 360
 361 grammar_declaration:
 362   "%union" union_name braceless
 363     {
 364       union_seen = true;
 365       muscle_code_grow ("stype", $3, @3);
 366       code_scanner_last_string_free ();
 367     }
 368 ;
 369
 370
 371
 372
 373 symbol_declaration:
 374   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 375     {
 376       current_class = unknown_sym;
 377       current_type = NULL;
 378     }
 379 | "%token" { current_class = token_sym; } symbol_defs.1
 380     {
 381       current_class = unknown_sym;
 382       current_type = NULL;
 383     }
 384 | "%type" TYPE symbols.1
 385     {
 386       symbol_list *list;
 387       tag_seen = true;
 388       for (list = $3; list; list = list->next)
 389         symbol_type_set (list->content.sym, $2, @2);
 390       symbol_list_free ($3);
 391     }
 392 ;
 393
 394 precedence_declaration:
 395   precedence_declarator type.opt symbols.1
 396     {
 397       symbol_list *list;
 398       ++current_prec;
 399       for (list = $3; list; list = list->next)
 400         {
 401           symbol_type_set (list->content.sym, current_type, @2);
 402           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 403         }
 404       symbol_list_free ($3);
 405       current_type = NULL;
 406     }
 407 ;
 408
 409 precedence_declarator:
 410   "%left"     { $$ = left_assoc; }
 411 | "%right"    { $$ = right_assoc; }
 412 | "%nonassoc" { $$ = non_assoc; }
 413 ;
 414
 415 type.opt:
 416   /* Nothing. */ { current_type = NULL; }
 417 | TYPE           { current_type = $1; tag_seen = true; }
 418 ;
 419
 420 /* One or more symbols to be %typed. */
 421 symbols.1:
 422   symbol
 423     { $$ = symbol_list_sym_new ($1, @1); }
 424 | symbols.1 symbol
 425     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 426 ;
 427
 428 generic_symlist:
 429   generic_symlist_item { $$ = $1; }
 430 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 431 ;
 432
 433 generic_symlist_item:
 434   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 435 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 436 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 437 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 438 ;
 439
 440 /* One token definition.  */
 441 symbol_def:
 442   TYPE
 443      {
 444        current_type = $1;
 445        tag_seen = true;
 446      }
 447 | id
 448      {
 449        symbol_class_set ($1, current_class, @1, true);
 450        symbol_type_set ($1, current_type, @1);
 451      }
 452 | id INT
 453     {
 454       symbol_class_set ($1, current_class, @1, true);
 455       symbol_type_set ($1, current_type, @1);
 456       symbol_user_token_number_set ($1, $2, @2);
 457     }
 458 | id string_as_id
 459     {
 460       symbol_class_set ($1, current_class, @1, true);
 461       symbol_type_set ($1, current_type, @1);
 462       symbol_make_alias ($1, $2, @$);
 463     }
 464 | id INT string_as_id
 465     {
 466       symbol_class_set ($1, current_class, @1, true);
 467       symbol_type_set ($1, current_type, @1);
 468       symbol_user_token_number_set ($1, $2, @2);
 469       symbol_make_alias ($1, $3, @$);
 470     }
 471 ;
 472
 473 /* One or more symbol definitions. */
 474 symbol_defs.1:
 475   symbol_def
 476 | symbol_defs.1 symbol_def
 477 ;
 478
 479
 480         /*------------------------------------------.
 481         | The grammar section: between the two %%.  |
 482         `------------------------------------------*/
 483
 484 grammar:
 485   rules_or_grammar_declaration
 486 | grammar rules_or_grammar_declaration
 487 ;
 488
 489 /* As a Bison extension, one can use the grammar declarations in the
 490    body of the grammar.  */
 491 rules_or_grammar_declaration:
 492   rules
 493 | grammar_declaration ";"
 494 | error ";"
 495     {
 496       yyerrok;
 497     }
 498 ;
 499
 500 rules:
 501   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 502 ;
 503
 504 rhses.1:
 505   rhs                { grammar_current_rule_end (@1); }
 506 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 507 | rhses.1 ";"
 508 ;
 509
 510 rhs:
 511   /* Nothing.  */
 512     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 513 | rhs symbol
 514     { grammar_current_rule_symbol_append ($2, @2); }
 515 | rhs "{...}"
 516     { grammar_current_rule_action_append ($2, @2); }
 517 | rhs "%prec" symbol
 518     { grammar_current_rule_prec_set ($3, @3); }
 519 | rhs "%dprec" INT
 520     { grammar_current_rule_dprec_set ($3, @3); }
 521 | rhs "%merge" TYPE
 522     { grammar_current_rule_merge_set ($3, @3); }
 523 ;
 524
 525
 526 /*----------------------------*
 527  | variable and content.opt.  |
 528  *---------------------------*/
 529
 530 variable:
 531   ID
 532   | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 533   ;
 534
 535 /* Some content or empty by default. */
 536 content.opt:
 537   /* Nothing. */
 538     {
 539       $$ = "";
 540     }
 541 | STRING
 542 ;
 543
 544
 545 /*-------------*
 546  | braceless.  |
 547  *-------------*/
 548
 549 braceless:
 550   "{...}"
 551     {
 552       code_props plain_code;
 553       $1[strlen ($1) - 1] = '\n';
 554       code_props_plain_init (&plain_code, $1+1, @1);
 555       code_props_translate_code (&plain_code);
 556       gram_scanner_last_string_free ();
 557       $$ = plain_code.code;
 558     }
 559 ;
 560
 561
 562 /*---------------*
 563  | Identifiers.  |
 564  *---------------*/
 565
 566 /* Identifiers are returned as uniqstr values by the scanner.
 567    Depending on their use, we may need to make them genuine symbols.  */
 568
 569 id:
 570   ID
 571     { $$ = symbol_from_uniqstr ($1, @1); }
 572 | CHAR
 573     {
 574       $$ = symbol_get (char_name ($1), @1);
 575       symbol_class_set ($$, token_sym, @1, false);
 576       symbol_user_token_number_set ($$, $1, @1);
 577     }
 578 ;
 579
 580 id_colon:
 581   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 582 ;
 583
 584
 585 symbol:
 586   id
 587 | string_as_id
 588 ;
 589
 590 /* A string used as an ID: quote it.  */
 591 string_as_id:
 592   STRING
 593     {
 594       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 595       symbol_class_set ($$, token_sym, @1, false);
 596     }
 597 ;
 598
 599 epilogue.opt:
 600   /* Nothing.  */
 601 | "%%" EPILOGUE
 602     {
 603       code_props plain_code;
 604       code_props_plain_init (&plain_code, $2, @2);
 605       code_props_translate_code (&plain_code);
 606       gram_scanner_last_string_free ();
 607       muscle_code_grow ("epilogue", plain_code.code, @2);
 608       code_scanner_last_string_free ();
 609     }
 610 ;
 611
 612 %%
 613
 614
 615 /* Return the location of the left-hand side of a rule whose
 616    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 617    the right-hand side, and return an empty location equal to the end
 618    boundary of RHS[0] if the right-hand side is empty.  */
 619
 620 static YYLTYPE
 621 lloc_default (YYLTYPE const *rhs, int n)
 622 {
 623   int i;
 624   YYLTYPE loc;
 625
 626   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 627      The bug is fixed in 7.4.2m, but play it safe for now.  */
 628   loc.start = rhs[n].end;
 629   loc.end = rhs[n].end;
 630
 631   /* Ignore empty nonterminals the start of the the right-hand side.
 632      Do not bother to ignore them at the end of the right-hand side,
 633      since empty nonterminals have the same end as their predecessors.  */
 634   for (i = 1; i <= n; i++)
 635     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 636       {
 637         loc.start = rhs[i].start;
 638         break;
 639       }
 640
 641   return loc;
 642 }
 643
 644
 645 /* Add a lex-param or a parse-param (depending on TYPE) with
 646    declaration DECL and location LOC.  */
 647
 648 static void
 649 add_param (char const *type, char *decl, location loc)
 650 {
 651   static char const alphanum[26 + 26 + 1 + 10] =
 652     "abcdefghijklmnopqrstuvwxyz"
 653     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 654     "_"
 655     "0123456789";
 656   char const *name_start = NULL;
 657   char *p;
 658
 659   /* Stop on last actual character.  */
 660   for (p = decl; p[1]; p++)
 661     if ((p == decl
 662          || ! memchr (alphanum, p[-1], sizeof alphanum))
 663         && memchr (alphanum, p[0], sizeof alphanum - 10))
 664       name_start = p;
 665
 666   /* Strip the surrounding '{' and '}', and any blanks just inside
 667      the braces.  */
 668   while (*--p == ' ' || *p == '\t')
 669     continue;
 670   p[1] = '\0';
 671   while (*++decl == ' ' || *decl == '\t')
 672     continue;
 673
 674   if (! name_start)
 675     complain_at (loc, _("missing identifier in parameter declaration"));
 676   else
 677     {
 678       char *name;
 679       size_t name_len;
 680
 681       for (name_len = 1;
 682            memchr (alphanum, name_start[name_len], sizeof alphanum);
 683            name_len++)
 684         continue;
 685
 686       name = xmalloc (name_len + 1);
 687       memcpy (name, name_start, name_len);
 688       name[name_len] = '\0';
 689       muscle_pair_list_grow (type, decl, name);
 690       free (name);
 691     }
 692
 693   gram_scanner_last_string_free ();
 694 }
 695
 696
 697 static void
 698 version_check (location const *loc, char const *version)
 699 {
 700   if (strverscmp (version, PACKAGE_VERSION) > 0)
 701     {
 702       complain_at (*loc, "require bison %s, but have %s",
 703                    version, PACKAGE_VERSION);
 704       exit (63);
 705     }
 706 }
 707
 708 static void
 709 gram_error (location const *loc, char const *msg)
 710 {
 711   complain_at (*loc, "%s", msg);
 712 }
 713
 714 char const *
 715 token_name (int type)
 716 {
 717   return yytname[YYTRANSLATE (type)];
 718 }
 719
 720 static char const *
 721 char_name (char c)
 722 {
 723   if (c == '\'')
 724     return "'\\''";
 725   else
 726     {
 727       char buf[4];
 728       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 729       return quotearg_style (escape_quoting_style, buf);
 730     }
 731 }