tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21 # We want a recent Autotest.
  22 m4_version_prereq([2.58])
  23
  24
  25 ## ------------------------------- ##
  26 ## Macros decoding Bison options.  ##
  27 ## ------------------------------- ##
  28
  29
  30 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  31 # -----------------------------------------
  32 m4_define([AT_BISON_OPTION_PUSHDEFS],
  33 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  34
  35
  36 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  37 # --------------------------------------------------
  38 # This macro works around the impossibility to define macros
  39 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  40 # This sucks hard, GNU M4 should really provide M5 like $$1.
  41 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  42 [m4_if([$1$2], $[1]$[2], [],
  43        [m4_fatal([$0: Invalid arguments: $@])])dnl
  44 m4_pushdef([AT_SKEL_CC_IF],
  45 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  46 m4_pushdef([AT_GLR_IF],
  47 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  48 m4_pushdef([AT_LALR1_CC_IF],
  49 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  50 m4_pushdef([AT_GLR_CC_IF],
  51 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  52 # Using yacc.c?
  53 m4_pushdef([AT_YACC_IF],
  54 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  55 m4_pushdef([AT_LEXPARAM_IF],
  56 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  57 m4_pushdef([AT_PARAM_IF],
  58 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  59 m4_pushdef([AT_LOCATION_IF],
  60 [m4_bmatch([$3], [%locations], [$1], [$2])])
  61 m4_pushdef([AT_PURE_IF],
  62 [m4_bmatch([$3], [%pure-parser], [$1], [$2])])
  63 m4_pushdef([AT_PURE_AND_LOC_IF],
  64 [m4_bmatch([$3], [%locations.*%pure-parser\|%pure-parser.*%locations],
  65            [$1], [$2])])
  66 m4_pushdef([AT_GLR_OR_PARAM_IF],
  67 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  68 m4_pushdef([AT_NAME_PREFIX],
  69 [m4_bmatch([$3], [%name-prefix ".*"],
  70            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  71            [yy])])
  72 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  73 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  74 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  75                     [$2])])
  76 # yyerror always sees the locations (when activated), except if
  77 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  78 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  79 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  80                                         [$1])],
  81                             [$1])],
  82                 [$2])])
  83
  84 # The interface is pure: either because %pure-parser, or because we
  85 # are using the C++ parsers.
  86 m4_pushdef([AT_PURE_LEX_IF],
  87 [AT_PURE_IF([$1],
  88             [AT_SKEL_CC_IF([$1], [$2])])])
  89
  90 AT_PURE_LEX_IF(
  91 [m4_pushdef([AT_LOC], [(*llocp)])
  92  m4_pushdef([AT_VAL], [(*lvalp)])
  93  m4_pushdef([AT_LEX_FORMALS],
  94             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
  95  m4_pushdef([AT_LEX_ARGS],
  96             [lvalp[]AT_LOCATION_IF([, llocp])])
  97  m4_pushdef([AT_USE_LEX_ARGS],
  98             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
  99  m4_pushdef([AT_LEX_PRE_FORMALS],
 100             [AT_LEX_FORMALS, ])
 101  m4_pushdef([AT_LEX_PRE_ARGS],
 102             [AT_LEX_ARGS, ])
 103 ],
 104 [m4_pushdef([AT_LOC], [(yylloc)])
 105  m4_pushdef([AT_VAL], [(yylval)])
 106  m4_pushdef([AT_LEX_FORMALS],     [void])
 107  m4_pushdef([AT_LEX_ARGS],        [])
 108  m4_pushdef([AT_USE_LEX_ARGS],    [])
 109  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 110  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 111 ])
 112 ])# _AT_BISON_OPTION_PUSHDEFS
 113
 114
 115 # AT_BISON_OPTION_POPDEFS
 116 # -----------------------
 117 m4_define([AT_BISON_OPTION_POPDEFS],
 118 [m4_popdef([AT_LEX_PRE_ARGS])
 119 m4_popdef([AT_LEX_PRE_FORMALS])
 120 m4_popdef([AT_USE_LEX_ARGS])
 121 m4_popdef([AT_LEX_ARGS])
 122 m4_popdef([AT_LEX_FORMALS])
 123 m4_popdef([AT_VAL])
 124 m4_popdef([AT_LOC])
 125 m4_popdef([AT_PURE_LEX_IF])
 126 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 127 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 128 m4_popdef([AT_NAME_PREFIX])
 129 m4_popdef([AT_GLR_OR_PARAM_IF])
 130 m4_popdef([AT_PURE_AND_LOC_IF])
 131 m4_popdef([AT_LOCATION_IF])
 132 m4_popdef([AT_PARAM_IF])
 133 m4_popdef([AT_LEXPARAM_IF])
 134 m4_popdef([AT_YACC_IF])
 135 m4_popdef([AT_GLR_IF])
 136 m4_popdef([AT_SKEL_CC_IF])
 137 m4_popdef([AT_GLR_CC_IF])
 138 m4_popdef([AT_LALR1_CC_IF])
 139 ])# AT_BISON_OPTION_POPDEFS
 140
 141
 142
 143 ## -------------------------- ##
 144 ## Generating Grammar Files.  ##
 145 ## -------------------------- ##
 146
 147
 148 # AT_DATA_GRAMMAR_PROLOGUE
 149 # ------------------------
 150 # The prologue that should be included in any grammar which parser is
 151 # meant to be compiled.
 152 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 153 [[%{
 154 #include <config.h>
 155 /* We don't need perfect functions for these tests. */
 156 #undef malloc
 157 #undef memcmp
 158 #undef realloc
 159 %}]
 160 ])
 161
 162
 163 # AT_DATA_GRAMMAR(NAME, CONTENT)
 164 # ------------------------------
 165 # Generate the file NAME, which CONTENT is preceded by
 166 # AT_DATA_GRAMMAR_PROLOGUE.
 167 m4_define([AT_DATA_GRAMMAR],
 168 [AT_DATA([$1],
 169 [AT_DATA_GRAMMAR_PROLOGUE
 170 $2])
 171 ])
 172
 173
 174 ## ------------------------ ##
 175 ## Compiling C, C++ Files.  ##
 176 ## ------------------------ ##
 177
 178
 179 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 180 # ----------------------------------------
 181 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 182 # assume that we are linking too; this is a hack.
 183 m4_define([AT_COMPILE],
 184 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 185            0, [ignore], [ignore])])
 186
 187 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 188 # --------------------------------------------
 189 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 190 # assume that we are linking too; this is a hack.
 191 # If the C++ compiler does not work, ignore the test.
 192 m4_define([AT_COMPILE_CXX],
 193 [AT_KEYWORDS(c++)
 194 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 195 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 196          0, [ignore], [ignore])])
 197
 198
 199
 200 ## ---------------------------- ##
 201 ## Running a generated parser.  ##
 202 ## ---------------------------- ##
 203
 204 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 205 # ------------------------------------------------------------
 206 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 207 m4_define([AT_PARSER_CHECK],
 208 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 209
 210
 211
 212
 213 ## ----------------------- ##
 214 ## Launch the test suite.  ##
 215 ## ----------------------- ##
 216
 217 AT_INIT
 218
 219 AT_TESTED([bison])