tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We want a recent Autotest.
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------------------------- ##
  24 ## Macros decoding Bison options.  ##
  25 ## ------------------------------- ##
  26
  27
  28 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  29 # -----------------------------------------
  30 m4_define([AT_BISON_OPTION_PUSHDEFS],
  31 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  32
  33
  34 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  35 # --------------------------------------------------
  36 # This macro works around the impossibility to define macros
  37 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  38 # This sucks hard, GNU M4 should really provide M5-like $$1.
  39 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  40 [m4_if([$1$2], $[1]$[2], [],
  41        [m4_fatal([$0: Invalid arguments: $@])])dnl
  42 m4_pushdef([AT_DEFINES_IF],
  43 [m4_bmatch([$3], [%defines], [$1], [$2])])
  44 m4_pushdef([AT_SKEL_CC_IF],
  45 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  46 m4_pushdef([AT_GLR_IF],
  47 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  48 m4_pushdef([AT_LALR1_CC_IF],
  49 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  50 m4_pushdef([AT_GLR_CC_IF],
  51 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  52 # Using yacc.c?
  53 m4_pushdef([AT_YACC_IF],
  54 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  55 m4_pushdef([AT_LEXPARAM_IF],
  56 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  57 m4_pushdef([AT_PARAM_IF],
  58 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  59 m4_pushdef([AT_LOCATION_IF],
  60 [m4_bmatch([$3], [%locations], [$1], [$2])])
  61 m4_pushdef([AT_PURE_IF],
  62 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
  63            [m4_bmatch([$3], [%define  *api\.pure *"false"], [$2], [$1])],
  64            [$2])])
  65 m4_pushdef([AT_PURE_AND_LOC_IF],
  66 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
  67 m4_pushdef([AT_GLR_OR_PARAM_IF],
  68 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  69 m4_pushdef([AT_NAME_PREFIX],
  70 [m4_bmatch([$3], [%name-prefix ".*"],
  71            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  72            [yy])])
  73 m4_pushdef([AT_TOKEN_PREFIX],
  74 [m4_bmatch([$3], [%define token.prefix ".*"],
  75            [m4_bregexp([$3], [%define token.prefix "\(.*\)"], [\1])])])
  76 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  77 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  78 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  79                     [$2])])
  80 # yyerror always sees the locations (when activated), except if
  81 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  82 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  83 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  84                                         [$1])],
  85                             [$1])],
  86                 [$2])])
  87
  88 # The interface is pure: either because %define api.pure, or because we
  89 # are using the C++ parsers.
  90 m4_pushdef([AT_PURE_LEX_IF],
  91 [AT_PURE_IF([$1],
  92             [AT_SKEL_CC_IF([$1], [$2])])])
  93
  94 AT_PURE_LEX_IF(
  95 [m4_pushdef([AT_LOC], [(*llocp)])
  96  m4_pushdef([AT_VAL], [(*lvalp)])
  97  m4_pushdef([AT_LEX_FORMALS],
  98             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
  99  m4_pushdef([AT_LEX_ARGS],
 100             [lvalp[]AT_LOCATION_IF([, llocp])])
 101  m4_pushdef([AT_USE_LEX_ARGS],
 102             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 103  m4_pushdef([AT_LEX_PRE_FORMALS],
 104             [AT_LEX_FORMALS, ])
 105  m4_pushdef([AT_LEX_PRE_ARGS],
 106             [AT_LEX_ARGS, ])
 107 ],
 108 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 109  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 110  m4_pushdef([AT_LEX_FORMALS],     [void])
 111  m4_pushdef([AT_LEX_ARGS],        [])
 112  m4_pushdef([AT_USE_LEX_ARGS],    [])
 113  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 114  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 115 ])
 116 AT_GLR_IF([AT_KEYWORDS([glr])])
 117 ])# _AT_BISON_OPTION_PUSHDEFS
 118
 119
 120 # AT_BISON_OPTION_POPDEFS
 121 # -----------------------
 122 m4_define([AT_BISON_OPTION_POPDEFS],
 123 [m4_popdef([AT_LEX_PRE_ARGS])
 124 m4_popdef([AT_LEX_PRE_FORMALS])
 125 m4_popdef([AT_USE_LEX_ARGS])
 126 m4_popdef([AT_LEX_ARGS])
 127 m4_popdef([AT_LEX_FORMALS])
 128 m4_popdef([AT_VAL])
 129 m4_popdef([AT_LOC])
 130 m4_popdef([AT_PURE_LEX_IF])
 131 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 132 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 133 m4_popdef([AT_NAME_PREFIX])
 134 m4_popdef([AT_GLR_OR_PARAM_IF])
 135 m4_popdef([AT_PURE_AND_LOC_IF])
 136 m4_popdef([AT_LOCATION_IF])
 137 m4_popdef([AT_PARAM_IF])
 138 m4_popdef([AT_LEXPARAM_IF])
 139 m4_popdef([AT_YACC_IF])
 140 m4_popdef([AT_GLR_IF])
 141 m4_popdef([AT_SKEL_CC_IF])
 142 m4_popdef([AT_GLR_CC_IF])
 143 m4_popdef([AT_LALR1_CC_IF])
 144 m4_popdef([AT_DEFINES_IF])
 145 ])# AT_BISON_OPTION_POPDEFS
 146
 147
 148
 149 ## -------------------------- ##
 150 ## Generating Grammar Files.  ##
 151 ## -------------------------- ##
 152
 153 # AT_DATA_SOURCE_PROLOGUE
 154 # ------------------------
 155 # The prologue that should be included in any source code that is
 156 # meant to be compiled.
 157 m4_define([AT_DATA_SOURCE_PROLOGUE],
 158 [[#include <config.h>
 159 /* We don't need perfect functions for these tests. */
 160 #undef malloc
 161 #undef memcmp
 162 #undef realloc
 163 ]])
 164
 165 # AT_DATA_GRAMMAR_PROLOGUE
 166 # ------------------------
 167 # The prologue that should be included in any grammar which parser is
 168 # meant to be compiled.
 169 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 170 [[%code top {
 171 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 172 [}
 173 ]])
 174
 175 # AT_DATA_SOURCE(NAME, CONTENT)
 176 # -----------------------------
 177 # Generate the file NAME, which CONTENT is preceded by
 178 # AT_DATA_SOURCE_PROLOGUE.
 179 m4_define([AT_DATA_SOURCE],
 180 [AT_DATA([$1],
 181 [AT_DATA_SOURCE_PROLOGUE
 182 $2])
 183 ])
 184
 185 # AT_DATA_GRAMMAR(NAME, CONTENT)
 186 # ------------------------------
 187 # Generate the file NAME, which CONTENT is preceded by
 188 # AT_DATA_GRAMMAR_PROLOGUE.
 189 m4_define([AT_DATA_GRAMMAR],
 190 [AT_DATA([$1],
 191 [AT_DATA_GRAMMAR_PROLOGUE
 192 $2])
 193 ])
 194
 195 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 196 # -------------------------------------------------
 197 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 198 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 199 #
 200 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 201 # Bison in the test suite.  For now it ensures that:
 202 #
 203 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 204 #      a non-zero exit status since Bison doesn't always try to free all memory
 205 #      in that case.
 206 #
 207 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 208 #      --graph and --report=all output for every working grammar.
 209 m4_define([AT_BISON_CHECK],
 210 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 211        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 212 AT_BISON_CHECK_NO_XML($@)])
 213
 214 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 215 # --------------------------------------------------------
 216 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 217 # when a tortured grammar's XML is known to be too large for xsltproc to
 218 # handle.
 219 m4_define([AT_BISON_CHECK_NO_XML],
 220 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 221                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 222
 223 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 224 # -----------------------------------------------------
 225 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 226 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 227 # have a non-zero exit status.
 228 m4_define([AT_BISON_CHECK_XML],
 229 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 230   mkdir xml-tests]
 231   m4_pushdef([AT_BISON_ARGS],
 232              [m4_bpatsubsts([[$1]],
 233                             [--report(-file)?=[^][ ]*], [],
 234                             [--graph=[^][ ]*], [],
 235                             [--xml=[^][ ]*], [])])dnl
 236   # Don't combine these Bison invocations since we want to be sure that
 237   # --report=all isn't required to get the full XML file.
 238   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 239              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 240            [[0]], [ignore], [ignore])
 241   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 242            [[0]], [ignore], [ignore])
 243   m4_popdef([AT_BISON_ARGS])dnl
 244   [cp xml-tests/test.output expout]
 245   AT_CHECK([[$XSLTPROC \
 246              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 247              xml-tests/test.xml]], [[0]], [expout])
 248   [cp xml-tests/test.dot expout]
 249   AT_CHECK([[$XSLTPROC \
 250              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 251              xml-tests/test.xml]], [[0]], [expout])
 252   [rm -rf xml-tests expout
 253 fi]])
 254
 255 # AT_QUELL_VALGRIND
 256 # -----------------
 257 # Put this before a Bison invocation to keep Valgrind from complaining about
 258 # reachable memory.
 259 #
 260 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 261 # The triple quoting below will cause test cases to fail if you do.  If you do
 262 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 263 # will then fail to shell-escape its contents when attempting to print them.
 264 # The testsuite verbose output, at least, will be incorrect, but nothing may
 265 # fail to make sure you notice.
 266 m4_define([AT_QUELL_VALGRIND],
 267 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 268
 269 ## ------------------------ ##
 270 ## Compiling C, C++ Files.  ##
 271 ## ------------------------ ##
 272
 273
 274 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 275 # ----------------------------------------
 276 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 277 # assume that we are linking too; this is a hack.
 278 m4_define([AT_COMPILE],
 279 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 280            0, [ignore], [ignore])])
 281
 282 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 283 # --------------------------------------------
 284 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 285 # assume that we are linking too; this is a hack.
 286 # If the C++ compiler does not work, ignore the test.
 287 m4_define([AT_COMPILE_CXX],
 288 [AT_KEYWORDS(c++)
 289 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 290 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 291          0, [ignore], [ignore])])
 292
 293
 294 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 295 # --------------------------------
 296 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 297 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 298 # along with it.
 299 # Relies on AT_SKEL_CC_IF.
 300 m4_define([AT_FULL_COMPILE],
 301 [AT_SKEL_CC_IF(
 302   [AT_BISON_CHECK([-o $1.cc $1.y])
 303    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 304   [AT_BISON_CHECK([-o $1.c $1.y])
 305    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 306 ])
 307
 308
 309 ## ---------------------------- ##
 310 ## Running a generated parser.  ##
 311 ## ---------------------------- ##
 312
 313 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 314 # ------------------------------------------------------------
 315 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 316 m4_define([AT_PARSER_CHECK],
 317 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 318
 319
 320
 321
 322 ## ----------------------- ##
 323 ## Launch the test suite.  ##
 324 ## ----------------------- ##
 325
 326 AT_INIT
 327
 328 AT_TESTED([bison])