data/c.m4

   1                                                             -*- Autoconf -*-
   2
   3 # C M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007, 2008 Free Software
   5 # Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ## ---------------- ##
  21 ## Identification.  ##
  22 ## ---------------- ##
  23
  24 # b4_comment(TEXT)
  25 # ----------------
  26 m4_define([b4_comment], [/* m4_bpatsubst([$1], [
  27 ], [
  28    ])  */])
  29
  30 # b4_identification
  31 # -----------------
  32 # Depends on individual skeletons to define b4_pure_flag, b4_push_flag, or
  33 # b4_pull_flag if they use the values of the %define variables api.pure or
  34 # api.push_pull.
  35 m4_define([b4_identification],
  36 [[/* Identify Bison output.  */
  37 #define YYBISON 1
  38
  39 /* Bison version.  */
  40 #define YYBISON_VERSION "]b4_version["
  41
  42 /* Skeleton name.  */
  43 #define YYSKELETON_NAME ]b4_skeleton[]m4_ifdef([b4_pure_flag], [[
  44
  45 /* Pure parsers.  */
  46 #define YYPURE ]b4_pure_flag])[]m4_ifdef([b4_push_flag], [[
  47
  48 /* Push parsers.  */
  49 #define YYPUSH ]b4_push_flag])[]m4_ifdef([b4_pull_flag], [[
  50
  51 /* Pull parsers.  */
  52 #define YYPULL ]b4_pull_flag])[
  53
  54 /* Using locations.  */
  55 #define YYLSP_NEEDED ]b4_locations_flag[
  56 ]])
  57
  58
  59 ## ---------------- ##
  60 ## Default values.  ##
  61 ## ---------------- ##
  62
  63 # If the %union is not named, its name is YYSTYPE.
  64 m4_define_default([b4_union_name], [YYSTYPE])
  65
  66 # If the %name-prefix is not given, it is yy.
  67 m4_define_default([b4_prefix], [yy])
  68
  69 ## ------------------------ ##
  70 ## Pure/impure interfaces.  ##
  71 ## ------------------------ ##
  72
  73 # b4_user_args
  74 # ------------
  75 m4_define([b4_user_args],
  76 [m4_ifset([b4_parse_param], [, b4_c_args(b4_parse_param)])])
  77
  78
  79 # b4_parse_param
  80 # --------------
  81 # If defined, b4_parse_param arrives double quoted, but below we prefer
  82 # it to be single quoted.
  83 m4_define([b4_parse_param],
  84 b4_parse_param)
  85
  86
  87 # b4_parse_param_for(DECL, FORMAL, BODY)
  88 # ---------------------------------------
  89 # Iterate over the user parameters, binding the declaration to DECL,
  90 # the formal name to FORMAL, and evaluating the BODY.
  91 m4_define([b4_parse_param_for],
  92 [m4_foreach([$1_$2], m4_defn([b4_parse_param]),
  93 [m4_pushdef([$1], m4_unquote(m4_car($1_$2)))dnl
  94 m4_pushdef([$2], m4_shift($1_$2))dnl
  95 $3[]dnl
  96 m4_popdef([$2])dnl
  97 m4_popdef([$1])dnl
  98 ])])
  99
 100 # b4_parse_param_use
 101 # ------------------
 102 # `YYUSE' all the parse-params.
 103 m4_define([b4_parse_param_use],
 104 [b4_parse_param_for([Decl], [Formal], [  YYUSE (Formal);
 105 ])dnl
 106 ])
 107
 108
 109 ## ------------ ##
 110 ## Data Types.  ##
 111 ## ------------ ##
 112
 113 # b4_int_type(MIN, MAX)
 114 # ---------------------
 115 # Return the smallest int type able to handle numbers ranging from
 116 # MIN to MAX (included).
 117 m4_define([b4_int_type],
 118 [m4_if(b4_ints_in($@,      [0],   [255]), [1], [unsigned char],
 119        b4_ints_in($@,   [-128],   [127]), [1], [signed char],
 120
 121        b4_ints_in($@,      [0], [65535]), [1], [unsigned short int],
 122        b4_ints_in($@, [-32768], [32767]), [1], [short int],
 123
 124        m4_eval([0 <= $1]),                [1], [unsigned int],
 125
 126                                                [int])])
 127
 128
 129 # b4_int_type_for(NAME)
 130 # ---------------------
 131 # Return the smallest int type able to handle numbers ranging from
 132 # `NAME_min' to `NAME_max' (included).
 133 m4_define([b4_int_type_for],
 134 [b4_int_type($1_min, $1_max)])
 135
 136 ## ---------##
 137 ## Values.  ##
 138 ## ---------##
 139
 140 # b4_null
 141 ---------
 142 # Return a null pointer constant.  NULL infringes on the user name
 143 # space in C, so use 0 rather than NULL.
 144 m4_define([b4_null], [0])
 145
 146
 147 ## ------------------------- ##
 148 ## Assigning token numbers.  ##
 149 ## ------------------------- ##
 150
 151 # b4_token_define(TOKEN-NAME, TOKEN-NUMBER)
 152 # -----------------------------------------
 153 # Output the definition of this token as #define.
 154 m4_define([b4_token_define],
 155 [#define $1 $2
 156 ])
 157
 158
 159 # b4_token_defines(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 160 # -------------------------------------------------------
 161 # Output the definition of the tokens (if there are) as #defines.
 162 m4_define([b4_token_defines],
 163 [m4_if([$#$1], [1], [],
 164 [/* Tokens.  */
 165 m4_map([b4_token_define], [$@])])
 166 ])
 167
 168
 169 # b4_token_enum(TOKEN-NAME, TOKEN-NUMBER)
 170 # ---------------------------------------
 171 # Output the definition of this token as an enum.
 172 m4_define([b4_token_enum],
 173 [$1 = $2])
 174
 175
 176 # b4_token_enums(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 177 # -----------------------------------------------------
 178 # Output the definition of the tokens (if there are) as enums.
 179 m4_define([b4_token_enums],
 180 [m4_if([$#$1], [1], [],
 181 [/* Tokens.  */
 182 #ifndef YYTOKENTYPE
 183 # define YYTOKENTYPE
 184    /* Put the tokens into the symbol table, so that GDB and other debuggers
 185       know about them.  */
 186    enum yytokentype {
 187 m4_map_sep([     b4_token_enum], [,
 188 ],
 189            [$@])
 190    };
 191 #endif
 192 ])])
 193
 194
 195 # b4_token_enums_defines(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 196 # -------------------------------------------------------------
 197 # Output the definition of the tokens (if there are any) as enums and, if POSIX
 198 # Yacc is enabled, as #defines.
 199 m4_define([b4_token_enums_defines],
 200 [b4_token_enums($@)b4_yacc_if([b4_token_defines($@)], [])
 201 ])
 202
 203
 204
 205 ## --------------------------------------------- ##
 206 ## Defining C functions in both K&R and ANSI-C.  ##
 207 ## --------------------------------------------- ##
 208
 209
 210 # b4_modern_c
 211 # -----------
 212 # A predicate useful in #if to determine whether C is ancient or modern.
 213 #
 214 # If __STDC__ is defined, the compiler is modern.  IBM xlc 7.0 when run
 215 # as 'cc' doesn't define __STDC__ (or __STDC_VERSION__) for pedantic
 216 # reasons, but it defines __C99__FUNC__ so check that as well.
 217 # Microsoft C normally doesn't define these macros, but it defines _MSC_VER.
 218 # Consider a C++ compiler to be modern if it defines __cplusplus.
 219 #
 220 m4_define([b4_c_modern],
 221   [[(defined __STDC__ || defined __C99__FUNC__ \
 222      || defined __cplusplus || defined _MSC_VER)]])
 223
 224 # b4_c_function_def(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 225 # ----------------------------------------------------------
 226 # Declare the function NAME.
 227 m4_define([b4_c_function_def],
 228 [#if b4_c_modern
 229 b4_c_ansi_function_def($@)
 230 #else
 231 $2
 232 $1 (b4_c_knr_formal_names(m4_shift2($@)))
 233 b4_c_knr_formal_decls(m4_shift2($@))
 234 #endif[]dnl
 235 ])
 236
 237
 238 # b4_c_ansi_function_def(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 239 # ---------------------------------------------------------------
 240 # Declare the function NAME in ANSI.
 241 m4_define([b4_c_ansi_function_def],
 242 [$2
 243 $1 (b4_c_ansi_formals(m4_shift2($@)))[]dnl
 244 ])
 245
 246
 247 # b4_c_ansi_formals([DECL1, NAME1], ...)
 248 # --------------------------------------
 249 # Output the arguments ANSI-C definition.
 250 m4_define([b4_c_ansi_formals],
 251 [m4_if([$#], [0], [void],
 252        [$#$1], [1], [void],
 253                [m4_map_sep([b4_c_ansi_formal], [, ], [$@])])])
 254
 255 m4_define([b4_c_ansi_formal],
 256 [$1])
 257
 258
 259 # b4_c_knr_formal_names([DECL1, NAME1], ...)
 260 # ------------------------------------------
 261 # Output the argument names.
 262 m4_define([b4_c_knr_formal_names],
 263 [m4_map_sep([b4_c_knr_formal_name], [, ], [$@])])
 264
 265 m4_define([b4_c_knr_formal_name],
 266 [$2])
 267
 268
 269 # b4_c_knr_formal_decls([DECL1, NAME1], ...)
 270 # ------------------------------------------
 271 # Output the K&R argument declarations.
 272 m4_define([b4_c_knr_formal_decls],
 273 [m4_map_sep([b4_c_knr_formal_decl],
 274             [
 275 ],
 276             [$@])])
 277
 278 m4_define([b4_c_knr_formal_decl],
 279 [    $1;])
 280
 281
 282
 283 ## ------------------------------------------------------------ ##
 284 ## Declaring (prototyping) C functions in both K&R and ANSI-C.  ##
 285 ## ------------------------------------------------------------ ##
 286
 287
 288 # b4_c_function_decl(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 289 # -----------------------------------------------------------
 290 # Declare the function NAME.
 291 m4_define([b4_c_function_decl],
 292 [#if defined __STDC__ || defined __cplusplus
 293 b4_c_ansi_function_decl($@)
 294 #else
 295 $2 $1 ();
 296 #endif[]dnl
 297 ])
 298
 299
 300 # b4_c_ansi_function_decl(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 301 # ----------------------------------------------------------------
 302 # Declare the function NAME.
 303 m4_define([b4_c_ansi_function_decl],
 304 [$2 $1 (b4_c_ansi_formals(m4_shift2($@)));[]dnl
 305 ])
 306
 307
 308
 309
 310 ## --------------------- ##
 311 ## Calling C functions.  ##
 312 ## --------------------- ##
 313
 314
 315 # b4_c_function_call(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 316 # -----------------------------------------------------------
 317 # Call the function NAME with arguments NAME1, NAME2 etc.
 318 m4_define([b4_c_function_call],
 319 [$1 (b4_c_args(m4_shift2($@)))[]dnl
 320 ])
 321
 322
 323 # b4_c_args([DECL1, NAME1], ...)
 324 # ------------------------------
 325 # Output the arguments NAME1, NAME2...
 326 m4_define([b4_c_args],
 327 [m4_map_sep([b4_c_arg], [, ], [$@])])
 328
 329 m4_define([b4_c_arg],
 330 [$2])
 331
 332
 333 ## ----------- ##
 334 ## Synclines.  ##
 335 ## ----------- ##
 336
 337 # b4_sync_start(LINE, FILE)
 338 # -----------------------
 339 m4_define([b4_sync_start], [[#]line $1 $2])
 340
 341
 342 ## -------------- ##
 343 ## User actions.  ##
 344 ## -------------- ##
 345
 346 # b4_case(LABEL, STATEMENTS)
 347 # --------------------------
 348 m4_define([b4_case],
 349 [  case $1:
 350 $2
 351     break;])
 352
 353 # b4_symbol_actions(FILENAME, LINENO,
 354 #                   SYMBOL-TAG, SYMBOL-NUM,
 355 #                   SYMBOL-ACTION, SYMBOL-TYPENAME)
 356 # -------------------------------------------------
 357 m4_define([b4_symbol_actions],
 358 [m4_pushdef([b4_dollar_dollar],
 359    [m4_ifval([$6], [(yyvaluep->$6)], [(*yyvaluep)])])dnl
 360 m4_pushdef([b4_at_dollar], [(*yylocationp)])dnl
 361       case $4: /* $3 */
 362 b4_syncline([$2], [$1])
 363         $5;
 364 b4_syncline([@oline@], [@ofile@])
 365         break;
 366 m4_popdef([b4_at_dollar])dnl
 367 m4_popdef([b4_dollar_dollar])dnl
 368 ])
 369
 370
 371 # b4_yydestruct_generate(FUNCTION-DECLARATOR)
 372 # -------------------------------------------
 373 # Generate the "yydestruct" function, which declaration is issued using
 374 # FUNCTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
 375 # or "b4_c_function_def" for K&R.
 376 m4_define_default([b4_yydestruct_generate],
 377 [[/*-----------------------------------------------.
 378 | Release the memory associated to this symbol.  |
 379 `-----------------------------------------------*/
 380
 381 /*ARGSUSED*/
 382 ]$1([yydestruct],
 383     [static void],
 384     [[const char *yymsg],    [yymsg]],
 385     [[int yytype],           [yytype]],
 386     [[YYSTYPE *yyvaluep],    [yyvaluep]][]dnl
 387 b4_locations_if(            [, [[YYLTYPE *yylocationp], [yylocationp]]])[]dnl
 388 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 389 {
 390   YYUSE (yyvaluep);
 391 ]b4_locations_if([  YYUSE (yylocationp);
 392 ])dnl
 393 b4_parse_param_use[]dnl
 394 [
 395   if (!yymsg)
 396     yymsg = "Deleting";
 397   YY_SYMBOL_PRINT (yymsg, yytype, yyvaluep, yylocationp);
 398
 399   switch (yytype)
 400     {
 401 ]m4_map([b4_symbol_actions], m4_defn([b4_symbol_destructors]))[
 402       default:
 403         break;
 404     }
 405 }]dnl
 406 ])
 407
 408
 409 # b4_yy_symbol_print_generate(FUNCTION-DECLARATOR)
 410 # ------------------------------------------------
 411 # Generate the "yy_symbol_print" function, which declaration is issued using
 412 # FUNCTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
 413 # or "b4_c_function_def" for K&R.
 414 m4_define_default([b4_yy_symbol_print_generate],
 415 [[
 416 /*--------------------------------.
 417 | Print this symbol on YYOUTPUT.  |
 418 `--------------------------------*/
 419
 420 /*ARGSUSED*/
 421 ]$1([yy_symbol_value_print],
 422     [static void],
 423                [[FILE *yyoutput],                       [yyoutput]],
 424                [[int yytype],                           [yytype]],
 425                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 426 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 427 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 428 {
 429   if (!yyvaluep)
 430     return;
 431 ]b4_locations_if([  YYUSE (yylocationp);
 432 ])dnl
 433 b4_parse_param_use[]dnl
 434 [# ifdef YYPRINT
 435   if (yytype < YYNTOKENS)
 436     YYPRINT (yyoutput, yytoknum[yytype], *yyvaluep);
 437 # else
 438   YYUSE (yyoutput);
 439 # endif
 440   switch (yytype)
 441     {
 442 ]m4_map([b4_symbol_actions], m4_defn([b4_symbol_printers]))dnl
 443 [      default:
 444         break;
 445     }
 446 }
 447
 448
 449 /*--------------------------------.
 450 | Print this symbol on YYOUTPUT.  |
 451 `--------------------------------*/
 452
 453 ]$1([yy_symbol_print],
 454     [static void],
 455                [[FILE *yyoutput],                       [yyoutput]],
 456                [[int yytype],                           [yytype]],
 457                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 458 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 459 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 460 {
 461   if (yytype < YYNTOKENS)
 462     YYFPRINTF (yyoutput, "token %s (", yytname[yytype]);
 463   else
 464     YYFPRINTF (yyoutput, "nterm %s (", yytname[yytype]);
 465
 466 ]b4_locations_if([  YY_LOCATION_PRINT (yyoutput, *yylocationp);
 467   YYFPRINTF (yyoutput, ": ");
 468 ])dnl
 469 [  yy_symbol_value_print (yyoutput, yytype, yyvaluep]dnl
 470 b4_locations_if([, yylocationp])[]b4_user_args[);
 471   YYFPRINTF (yyoutput, ")");
 472 }]dnl
 473 ])