tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 ## ------------- ##
  33 ## Basic tests.  ##
  34 ## ------------- ##
  35
  36 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  37 # ------------------------------------------
  38 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  39 # taken in "slurp" mode, i.e., one can match end-of-lines.
  40 m4_define([AT_MATCHES_CHECK],
  41 [AT_CHECK([$PERL -0777 -ne '
  42 my $count = 0;
  43 s{$2}{ ++$count; "" }gem;
  44 printf "$count\n";' $1], [0], [$3
  45 ])])
  46
  47
  48 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  49 # ------------------------------------------------
  50 # Don't interfere with caller's files.
  51 m4_divert_text([PREPARE_TESTS],
  52 [at_save_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       as_fn_error 1 "fatal error: back-up on top of a back-up"
  58     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  59   done
  60 }
  61
  62 at_restore_special_files ()
  63 {
  64   for at_save_file in stderr experr expout
  65   do
  66     test ! -f at-bison-check-$at_save_file.bak ||
  67       mv at-bison-check-$at_save_file.bak $at_save_file
  68   done
  69 }
  70 ])
  71
  72 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  73 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  74
  75
  76
  77 ## ------------------------------- ##
  78 ## Macros decoding Bison options.  ##
  79 ## ------------------------------- ##
  80
  81 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  82 # ----------------------------------------------------------------
  83 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  84 m4_define([AT_LOC_PUSHDEF],
  85 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  86 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  87 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  88 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  89
  90 # AT_LOC_POPDEF
  91 # -------------
  92 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  93 m4_define([AT_LOC_POPDEF],
  94 [m4_popdef([AT_LOC_FIRST_LINE])
  95 m4_popdef([AT_LOC_FIRST_COLUMN])
  96 m4_popdef([AT_LOC_LAST_LINE])
  97 m4_popdef([AT_LOC_LAST_COLUMN])])
  98
  99
 100
 101 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 102 # -----------------------------------------
 103 m4_define([AT_BISON_OPTION_PUSHDEFS],
 104 [m4_divert_text([KILL],
 105                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 106
 107
 108 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 109 # --------------------------------------------------
 110 # This macro works around the impossibility to define macros
 111 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 112 # This sucks hard, GNU M4 should really provide M5-like $$1.
 113 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 114 [m4_if([$1$2], $[1]$[2], [],
 115        [m4_fatal([$0: Invalid arguments: $@])])dnl
 116 m4_pushdef([AT_DEFINES_IF],
 117 [m4_bmatch([$3], [%defines], [$1], [$2])])
 118 m4_pushdef([AT_SKEL_CC_IF],
 119 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 120 m4_pushdef([AT_SKEL_JAVA_IF],
 121 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 122 m4_pushdef([AT_LANG],
 123 [AT_SKEL_JAVA_IF([java],
 124                  [AT_SKEL_CC_IF([c++],
 125                                 [c])])])
 126 m4_pushdef([AT_GLR_IF],
 127 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 128 m4_pushdef([AT_LALR1_CC_IF],
 129 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 130 m4_pushdef([AT_GLR_CC_IF],
 131 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 132 # Using yacc.c?
 133 m4_pushdef([AT_YACC_IF],
 134 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 135 m4_pushdef([AT_LEXPARAM_IF],
 136 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 137 m4_pushdef([AT_LOCATION_IF],
 138 [m4_bmatch([$3], [%locations], [$1], [$2])])
 139 m4_pushdef([AT_LOCATION_TYPE_IF],
 140 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 141 m4_pushdef([AT_PARAM_IF],
 142 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 143 m4_pushdef([AT_PURE_IF],
 144 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 145            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 146            [$2])])
 147 m4_pushdef([AT_PURE_AND_LOC_IF],
 148 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 149 m4_pushdef([AT_GLR_OR_PARAM_IF],
 150 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 151 m4_pushdef([AT_NAME_PREFIX],
 152 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 153            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 154            [yy])])
 155 m4_pushdef([AT_TOKEN_PREFIX],
 156 [m4_bmatch([$3], [%define api.token.prefix ".*"],
 157            [m4_bregexp([$3], [%define api.token.prefix "\(.*\)"], [\1])])])
 158 m4_pushdef([AT_API_prefix],
 159 [m4_bmatch([$3], [%define api\.prefix ".*"],
 160            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 161            [yy])])
 162 m4_pushdef([AT_API_PREFIX],
 163 [m4_toupper(AT_API_prefix)])
 164 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 165 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 166 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 167                     [$2])])
 168 # yyerror always sees the locations (when activated), except if
 169 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 170 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 171 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 172                                         [$1])],
 173                             [$1])],
 174                 [$2])])
 175
 176 # The interface is pure: either because %define api.pure, or because we
 177 # are using the C++ parsers.
 178 m4_pushdef([AT_PURE_LEX_IF],
 179 [AT_PURE_IF([$1],
 180             [AT_SKEL_CC_IF([$1], [$2])])])
 181
 182 m4_pushdef([AT_YYSTYPE],
 183 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 184                [AT_API_PREFIX[STYPE]])])
 185 m4_pushdef([AT_YYLTYPE],
 186 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 187                [AT_API_PREFIX[LTYPE]])])
 188
 189
 190 AT_PURE_LEX_IF(
 191 [m4_pushdef([AT_LOC], [(*llocp)])
 192  m4_pushdef([AT_VAL], [(*lvalp)])
 193  m4_pushdef([AT_YYLEX_FORMALS],
 194             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 195  m4_pushdef([AT_YYLEX_ARGS],
 196             [lvalp[]AT_LOCATION_IF([, llocp])])
 197  m4_pushdef([AT_USE_LEX_ARGS],
 198             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 199  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 200             [AT_YYLEX_FORMALS, ])
 201  m4_pushdef([AT_YYLEX_PRE_ARGS],
 202             [AT_YYLEX_ARGS, ])
 203 ],
 204 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 205  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 206  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 207  m4_pushdef([AT_YYLEX_ARGS],        [])
 208  m4_pushdef([AT_USE_LEX_ARGS],    [])
 209  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 210  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 211 ])
 212
 213 # Handle the different types of location components.
 214
 215 AT_SKEL_CC_IF(
 216   [AT_LOCATION_TYPE_IF(
 217     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 218     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 219   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 220
 221
 222 AT_GLR_IF([AT_KEYWORDS([glr])])
 223 ])# _AT_BISON_OPTION_PUSHDEFS
 224
 225
 226 # AT_BISON_OPTION_POPDEFS
 227 # -----------------------
 228 m4_define([AT_BISON_OPTION_POPDEFS],
 229 [m4_divert_text([KILL],
 230 [m4_popdef([AT_YYLEX_PRE_ARGS])
 231 m4_popdef([AT_YYLEX_PRE_FORMALS])
 232 m4_popdef([AT_USE_LEX_ARGS])
 233 m4_popdef([AT_YYLEX_ARGS])
 234 m4_popdef([AT_YYLEX_FORMALS])
 235 m4_popdef([AT_YYLTYPE])
 236 m4_popdef([AT_YYSTYPE])
 237 m4_popdef([AT_VAL])
 238 m4_popdef([AT_LOC])
 239 m4_popdef([AT_PURE_LEX_IF])
 240 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 241 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 242 m4_popdef([AT_API_PREFIX])
 243 m4_popdef([AT_API_prefix])
 244 m4_popdef([AT_NAME_PREFIX])
 245 m4_popdef([AT_GLR_OR_PARAM_IF])
 246 m4_popdef([AT_PURE_AND_LOC_IF])
 247 m4_popdef([AT_LOCATION_TYPE_IF])
 248 m4_popdef([AT_LOCATION_IF])
 249 m4_popdef([AT_PARAM_IF])
 250 m4_popdef([AT_LEXPARAM_IF])
 251 m4_popdef([AT_YACC_IF])
 252 m4_popdef([AT_GLR_IF])
 253 m4_popdef([AT_SKEL_CC_IF])
 254 m4_popdef([AT_LANG])
 255 m4_popdef([AT_SKEL_JAVA_IF])
 256 m4_popdef([AT_GLR_CC_IF])
 257 m4_popdef([AT_LALR1_CC_IF])
 258 m4_popdef([AT_DEFINES_IF])
 259 AT_LOC_POPDEF])dnl
 260 ])# AT_BISON_OPTION_POPDEFS
 261
 262
 263
 264 ## -------------------------- ##
 265 ## Generating Grammar Files.  ##
 266 ## -------------------------- ##
 267
 268 # AT_DATA_SOURCE_PROLOGUE
 269 # ------------------------
 270 # The prologue that should be included in any source code that is
 271 # meant to be compiled.
 272 m4_define([AT_DATA_SOURCE_PROLOGUE],
 273 [[#include <config.h>
 274 /* We don't need perfect functions for these tests. */
 275 #undef malloc
 276 #undef memcmp
 277 #undef realloc
 278 ]])
 279
 280 # AT_DATA_GRAMMAR_PROLOGUE
 281 # ------------------------
 282 # The prologue that should be included in any grammar which parser is
 283 # meant to be compiled.
 284 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 285 [[%code top {
 286 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 287 [}
 288 ]])
 289
 290 # AT_DATA_SOURCE(NAME, CONTENT)
 291 # -----------------------------
 292 # Generate the file NAME, which CONTENT is preceded by
 293 # AT_DATA_SOURCE_PROLOGUE.
 294 m4_define([AT_DATA_SOURCE],
 295 [AT_DATA([$1],
 296 [AT_DATA_SOURCE_PROLOGUE
 297 $2])
 298 ])
 299
 300 # AT_DATA_GRAMMAR(NAME, CONTENT)
 301 # ------------------------------
 302 # Generate the file NAME, which CONTENT is preceded by
 303 # AT_DATA_GRAMMAR_PROLOGUE.
 304 m4_define([AT_DATA_GRAMMAR],
 305 [AT_DATA([$1],
 306 [AT_DATA_GRAMMAR_PROLOGUE
 307 $2])
 308 ])
 309
 310 # AT_YYLEX_PROTOTYPE
 311 # AT_YYLEX_DECLARE_EXTERN
 312 # AT_YYLEX_DECLARE
 313 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 314 # ----------------------------------
 315 # INPUT can be empty, or in double quotes, or a list (in braces).
 316 # ACTION may compute yylval for instance, using "res" as token type,
 317 # and "toknum" as the number of calls to yylex (starting at 0).
 318 m4_define([AT_YYLEX_PROTOTYPE],
 319 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 320 ])
 321
 322 m4_define([AT_YYLEX_DECLARE_EXTERN],
 323 [AT_YYLEX_PROTOTYPE;dnl
 324 ])
 325
 326 m4_define([AT_YYLEX_DECLARE],
 327 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 328 ])
 329
 330 m4_define([AT_YYLEX_DEFINE],
 331 [[#include <assert.h>
 332 static
 333 ]AT_YYLEX_PROTOTYPE[
 334 {
 335   ]m4_bmatch([$1], [^\(".*"\)?$],
 336              [[static char const input[] = ]m4_default([$1], [""])],
 337              [[static int const input[] = ]$1])[;
 338   static size_t toknum = 0;
 339   int res;
 340   ]AT_USE_LEX_ARGS[;
 341   assert (toknum < sizeof input / sizeof input[0]);
 342   res = input[toknum++];
 343   ]$2[;]AT_LOCATION_IF([[
 344   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 345   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 346   return res;
 347 }]dnl
 348 ])
 349
 350 # AT_YYERROR_PROTOTYPE
 351 # AT_YYERROR_DECLARE_EXTERN
 352 # AT_YYERROR_DECLARE
 353 # AT_YYERROR_DEFINE
 354 # -------------------------
 355 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 356 m4_define([AT_YYERROR_FORMALS],
 357 [m4_case(AT_LANG,
 358 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE *llocp, ])[const char *msg]])[]dnl
 359 ])
 360
 361 m4_define([AT_YYERROR_PROTOTYPE],
 362 [m4_case(AT_LANG,
 363 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 364 ])
 365
 366 m4_define([AT_YYERROR_DECLARE_EXTERN],
 367 [m4_case(AT_LANG,
 368 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 369 ])
 370
 371 m4_define([AT_YYERROR_DECLARE],
 372 [m4_case(AT_LANG,
 373 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 374 ])
 375
 376 m4_define([AT_YYERROR_DEFINE],
 377 [m4_case(AT_LANG,
 378 [c], [[#include <stdio.h>
 379 /* A C error reporting function.  */
 380 static
 381 ]AT_YYERROR_PROTOTYPE[
 382 {
 383 ]AT_YYERROR_SEES_LOC_IF([[
 384   fprintf (stderr, "%d.%d",
 385            ]AT_LOC_FIRST_LINE[, ]AT_LOC_FIRST_COLUMN[);
 386   if (]AT_LOC_FIRST_LINE[ != ]AT_LOC_LAST_LINE[)
 387     fprintf (stderr, "-%d.%d",
 388              ]AT_LOC_LAST_LINE[,  ]AT_LOC_LAST_COLUMN[ - 1);
 389   else if (]AT_LOC_FIRST_COLUMN[ != ]AT_LOC_LAST_COLUMN[ - 1)
 390     fprintf (stderr, "-%d",
 391              ]AT_LOC_LAST_COLUMN[ - 1);
 392   fprintf (stderr, ": ");]])[
 393   fprintf (stderr, "%s\n", msg);
 394 }]],
 395 [c++], [[/* A C++ error reporting function.  */
 396 void
 397 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 398 {  std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 399 }]],
 400 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 401 {
 402     if (l == null)
 403       System.err.println (s);
 404     else
 405       System.err.println (l + ": " + s);
 406   }
 407 ]], [[
 408   public void yyerror (String s)
 409   {
 410     System.err.println (s);
 411   }]])],
 412 [m4_fatal([$0: invalid language: ]AT_LANG)])dnl
 413 ])
 414
 415
 416 ## --------------- ##
 417 ## Running Bison.  ##
 418 ## --------------- ##
 419
 420 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 421 # -------------------------------------------------
 422 # High-level routine that may call bison several times, under different
 423 # conditions.
 424 #
 425 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 426 # shell constructs (such as redirection or pipes) that would prevent
 427 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 428 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 429 #
 430 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 431 # Bison in the test suite.  For now it ensures that:
 432 #
 433 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 434 #      a non-zero exit status since Bison doesn't always try to free all memory
 435 #      in that case.
 436 #
 437 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 438 #      --graph and --report=all output for every working grammar.
 439 #
 440 #   3. If stderr contains a warning, -Werror and --warnings=error
 441 #      convert the warning to an error.
 442 #
 443 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 444 m4_define([AT_BISON_CHECK],
 445 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 446 AT_BISON_CHECK_NO_XML($@)])
 447
 448 m4_define([AT_BISON_WERROR_MSG],
 449           [[bison: warnings being treated as errors]])
 450
 451
 452 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 453 # --------------------------------------------------
 454 # Low-level macro to run bison once.
 455 m4_define([AT_BISON_CHECK_],
 456 [AT_CHECK(AT_QUELL_VALGRIND[[ bison ]]$@)])
 457
 458
 459 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 460 # ----------------------------------------------------------
 461 # Check that warnings (if some are expected) are correctly
 462 # turned into errors with -Werror, etc.
 463 m4_define([AT_BISON_CHECK_WARNINGS],
 464 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 465       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 466
 467 m4_define([AT_BISON_CHECK_WARNINGS_],
 468 [[# Defining POSIXLY_CORRECT causes bison to complain if options
 469         # are added after the grammar file name, so skip these checks
 470         # in that case.
 471         if test -z "${POSIXLY_CORRECT+set}"; then
 472           ]AT_SAVE_SPECIAL_FILES[
 473
 474           # To avoid expanding it repeatedly, store specified stdout.
 475           ]AT_DATA([expout], [$3])[
 476
 477           # Run with -Werror.
 478   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 479
 480           # Build expected stderr up to and including the "warnings being
 481           # treated as errors" message.
 482           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 483           at_bison_check_first=`sed -n \
 484             '/: warning: /{=;q;}' at-bison-check-warnings`
 485           : ${at_bison_check_first:=1}
 486           at_bison_check_first_tmp=`sed -n \
 487             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 488           : ${at_bison_check_first_tmp:=1}
 489           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 490             at_bison_check_first=$at_bison_check_first_tmp
 491           fi
 492           if test $at_bison_check_first -gt 1; then
 493             sed -n "1,`expr $at_bison_check_first - 1`"p \
 494               at-bison-check-warnings > experr
 495           fi
 496           echo ']AT_BISON_WERROR_MSG[' >> experr
 497
 498           # Finish building expected stderr and check.  Unlike warnings,
 499           # complaints cause bison to exit early.  Thus, with -Werror, bison
 500           # does not necessarily report all warnings that it does without
 501           # -Werror, but it at least reports one.
 502           at_bison_check_last=`sed -n '$=' stderr`
 503           : ${at_bison_check_last:=1}
 504           at_bison_check_last=`expr $at_bison_check_last - 1`
 505           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 506             at-bison-check-warnings >> experr
 507           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 508                       stderr 1>&2]], [[0]], [[]], [experr])[
 509
 510           # Now check --warnings=error.
 511           cp stderr experr
 512   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 513
 514           # Now check -Wnone and --warnings=none by making sure that
 515           # -Werror doesn't change the exit status when -Wnone or
 516           # --warnings=none is specified.
 517   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 518   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 519
 520           ]AT_RESTORE_SPECIAL_FILES[
 521 fi]dnl
 522 ])
 523
 524 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 525 # --------------------------------------------------------
 526 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 527 # when a tortured grammar's XML is known to be too large for xsltproc to
 528 # handle.
 529 m4_define([AT_BISON_CHECK_NO_XML],
 530 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison ]]$@)
 531 AT_BISON_CHECK_WARNINGS($@)])
 532
 533 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 534 # -----------------------------------------------------
 535 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 536 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 537 # have a non-zero exit status.
 538 m4_define([AT_BISON_CHECK_XML],
 539 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 540   AT_SAVE_SPECIAL_FILES
 541   [mkdir xml-tests]
 542   m4_pushdef([AT_BISON_ARGS],
 543              [m4_bpatsubsts([[$1]],
 544                             [--report(-file)?=[^][ ]*], [],
 545                             [--graph=[^][ ]*], [],
 546                             [--xml=[^][ ]*], [])])dnl
 547   # Don't combine these Bison invocations since we want to be sure that
 548   # --report=all isn't required to get the full XML file.
 549   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 550              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 551            [[0]], [ignore], [ignore])
 552   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 553            [[0]], [ignore], [ignore])
 554   m4_popdef([AT_BISON_ARGS])dnl
 555   [cp xml-tests/test.output expout]
 556   AT_CHECK([[$XSLTPROC \
 557              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 558              xml-tests/test.xml]], [[0]], [expout])
 559   [cp xml-tests/test.dot expout]
 560   AT_CHECK([[$XSLTPROC \
 561              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 562              xml-tests/test.xml]], [[0]], [expout])
 563   [rm -rf xml-tests expout]
 564   AT_RESTORE_SPECIAL_FILES
 565 [fi]])
 566
 567 # AT_QUELL_VALGRIND
 568 # -----------------
 569 # Put this before a Bison invocation to keep Valgrind from complaining about
 570 # reachable memory.
 571 #
 572 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 573 # The triple quoting below will cause test cases to fail if you do.  If you do
 574 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 575 # will then fail to shell-escape its contents when attempting to print them.
 576 # The testsuite verbose output, at least, will be incorrect, but nothing may
 577 # fail to make sure you notice.
 578 m4_define([AT_QUELL_VALGRIND],
 579 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 580
 581
 582
 583 ## ------------------------ ##
 584 ## Compiling C, C++ Files.  ##
 585 ## ------------------------ ##
 586
 587
 588 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 589 # ----------------------------------------
 590 # Compile SOURCES into OUTPUT.
 591 #
 592 # If OUTPUT does not contain '.', assume that we are linking too,
 593 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 594 # with trailing .o removed, and ".c" appended.
 595 m4_define([AT_COMPILE],
 596 [AT_CHECK(m4_join([ ],
 597                   [$CC $CFLAGS $CPPFLAGS],
 598                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 599                   [-o $1],
 600                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 601                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 602            0, [ignore], [ignore])])
 603
 604 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 605 # ---------------------------------------------
 606 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 607 # ignore the test.
 608 #
 609 # If OUTPUT does not contain '.', assume that we are linking too,
 610 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 611 # with trailing .o removed, and ".cc" appended.
 612 m4_define([AT_COMPILE_CXX],
 613 [AT_KEYWORDS(c++)
 614 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 615 AT_CHECK(m4_join([ ],
 616                  [$CXX $CXXFLAGS $CPPFLAGS],
 617                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 618                  [-o $1],
 619                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 620                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 621          0, [ignore], [ignore])])
 622
 623 # AT_JAVA_COMPILE(SOURCES)
 624 # ------------------------
 625 # Compile SOURCES into Java class files.  Skip the test if java or javac
 626 # is not installed.
 627 m4_define([AT_JAVA_COMPILE],
 628 [AT_KEYWORDS(java)
 629 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 630 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 631 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 632          [[0]], [ignore], [ignore])])
 633
 634 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 635 # --------------------------------------------
 636 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 637 #
 638 # If OUTPUT does not contain '.', assume that we are linking too,
 639 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 640 # with trailing .o removed, and ".c"/".cc" appended.
 641 m4_define([AT_LANG_COMPILE],
 642 [m4_case(AT_LANG,
 643 [c],    [AT_COMPILE([$1], [$2])],
 644 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 645 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 646         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 647 ])
 648
 649 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 650 # -------------------------------------------
 651 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 652 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 653 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 654 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 655 # AT_SKEL_JAVA_IF.
 656 m4_define([AT_FULL_COMPILE],
 657 [m4_case(AT_LANG,
 658 [java],
 659   [AT_BISON_CHECK([-o $1.java $1.y])
 660    AT_LANG_COMPILE([$1],
 661                     m4_join([ ],
 662                             [$1.java],
 663                             m4_ifval($2, [[$1-$2.java]]),
 664                            m4_ifval($3, [[$1-$3.java]])))],
 665 [c++],
 666   [AT_BISON_CHECK([-o $1.cc $1.y])
 667    AT_LANG_COMPILE([$1],
 668                      m4_join([ ],
 669                              [$1.cc],
 670                              m4_ifval($2, [[$1-$2.cc]]),
 671                            m4_ifval($3, [[$1-$3.cc]])))],
 672 [c],
 673   [AT_BISON_CHECK([-o $1.c $1.y])
 674    AT_LANG_COMPILE([$1],
 675                   m4_join([ ],
 676                           [$1.c],
 677                           m4_ifval($2, [[$1-$2.c]]),
 678                            m4_ifval($3, [[$1-$3.c]])))])
 679 ])
 680
 681
 682 ## ---------------------------- ##
 683 ## Running a generated parser.  ##
 684 ## ---------------------------- ##
 685
 686
 687 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 688 # ------------------------------------------------------------
 689 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 690 #
 691 # Get rid of spurious messages when compiled with --coverage:
 692 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 693 m4_define([AT_PARSER_CHECK],
 694 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 695 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 696          [0], [], [$4])
 697 ])
 698
 699
 700 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 701 # -----------------------------------------------------------------
 702 m4_define([AT_JAVA_PARSER_CHECK],
 703 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 704
 705
 706 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 707 #                          DECLS, GRAMMAR, INPUT,
 708 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 709 #                          [OTHER-CHECKS],
 710 #                          [PARSER-EXIT-VALUE],
 711 #                          [PARSER-STDOUT], [PARSER-STDERR])
 712 # -------------------------------------------------------------
 713 # Using TITLE as the test group title, check the generated parser tables
 714 # and parser for a specified grammar file under a condition labeled by
 715 # COND-VALUE.
 716 #
 717 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 718 # recognized attribute is described below where it is relevant.
 719 #
 720 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 721 # the grammar file.  Insert basic yyerror, yylex, and main function
 722 # definitions as well.  Hardcode yylex to return the (possibly empty)
 723 # comma-delimited series of tokens in INPUT followed by token 0.
 724 #
 725 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 726 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 727 # On the bison command-line, specify `--report=all --defines'.  Check
 728 # that Bison exits with value 0, has no stdout, and has stderr
 729 # BISON-STDERR.
 730 #
 731 # If TEST-SPEC contains the attribute `last-state', check that the value
 732 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 733 # the grammar; in other words, check the number of states (minus one).
 734 # Otherwise, check that everything in the `.output' file starting with
 735 # the definition of state 0 is the same as the entire value of
 736 # TABLES-OR-LAST-STATE.
 737 #
 738 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 739 # `.output' file, which is named `input.output', and/or grammar file,
 740 # which is named `input.y'.
 741 #
 742 # Finally, compile the generated parser and then run it using
 743 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 744 # PARSER-STDERR as the 2nd-4th arguments.
 745 #
 746 # As a precondition, you must properly double-quote all arguments that
 747 # are to be interpreted as strings.
 748 #
 749 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 750 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 751 # first argument.  This is useful, for example, when wrapping multiple
 752 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 753 # condition, in another macro.
 754 #
 755 # For example:
 756 #
 757 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 758 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 759 #   # ---------------------------------------------------------------------
 760 #   m4_define([AT_TEST_SYNTAX_ERROR],
 761 #   [
 762 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 763 #                              [[last-state]],
 764 #                              [[%error-verbose ]$2], [$3], [$4],
 765 #                              [[]], [$5], [], [$6], [$7], [$8])
 766 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 767 #                              [[last-state]],
 768 #                              [$2], [$3], [$4],
 769 #                              [[]], [$5], [], [$6], [$7], [$8])
 770 #   ])
 771 #
 772 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 773 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 774 #                        [[3]],
 775 #                        [[1]], [[]],
 776 #                        [AT_COND_CASE([[no verbose]],
 777 #                                      [[syntax error
 778 #   ]],
 779 #                                      [[syntax error, unexpected 'b', expecting $end
 780 #   ]])])
 781 m4_define([AT_TEST_TABLES_AND_PARSE],
 782 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 783
 784 AT_SETUP([$1])
 785 AT_BISON_OPTION_PUSHDEFS([$4])
 786 AT_DATA_GRAMMAR([[input.y]],
 787 [[%code {
 788   #include <stdio.h>
 789   ]AT_YYERROR_DECLARE[
 790   ]AT_YYLEX_DECLARE[
 791 }
 792
 793 ]$4[
 794
 795 %%
 796
 797 ]$5[
 798
 799 %%
 800 ]AT_YYERROR_DEFINE[
 801 static int
 802 yylex (void)
 803 {
 804   static int const input[] = {
 805     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 806   };
 807   static int const *inputp = input;
 808   return *inputp++;
 809 }
 810
 811 int
 812 main (void)
 813 {
 814   return yyparse ();
 815 }
 816 ]])
 817
 818 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 819 # expanding macros, so it corrupts some special characters in the
 820 # macros.  To avoid this, expand now and pass it the result with proper
 821 # string quotation.  Assume args 7 through 12 expand to properly quoted
 822 # strings.
 823
 824 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 825       [AT_BISON_CHECK],
 826       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 827                                [0], [], m4_dquote($7))
 828
 829 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 830       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 831                 m4_dquote($8))],
 832       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 833                 m4_dquote($8)[[
 834 ]])])
 835
 836 $9
 837
 838 # Canonical LR generates very large tables, resulting in very long
 839 # files with #line directives that may overflow what the standards
 840 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 841 # will issue an error.
 842 #
 843 # There is no "" around `wc` since some indent the result.
 844 m4_bmatch([$4], [%define lr.type canonical-lr],
 845 [if test 32767 -lt `wc -l < input.c`; then
 846   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 847   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 848 fi])
 849 AT_COMPILE([[input]])
 850
 851 AT_PARSER_CHECK([[./input]],
 852                 m4_ifval([$10], [m4_dquote($10)]),
 853                 m4_ifval([$11], [m4_dquote($11)]),
 854                 m4_ifval([$12], [m4_dquote($12)]))
 855
 856 AT_BISON_OPTION_POPDEFS
 857 AT_CLEANUP
 858
 859 m4_popdef([AT_COND_CASE])])
 860
 861
 862
 863 ## ----------------------- ##
 864 ## Launch the test suite.  ##
 865 ## ----------------------- ##
 866
 867 AT_INIT
 868
 869 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 870 # options are processed, so we don't know the value of CXX and
 871 # CXXFLAGS yet.
 872 #
 873 # Note that it also means that command line values for CXX and
 874 # CXXFLAGS will not be propagated to CC and CFLAGS.
 875 AT_ARG_OPTION([compile-c-with-cxx],
 876               [compile C parsers with the C++ compiler])
 877
 878 AT_COLOR_TESTS
 879
 880 AT_TESTED([bison])