src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle_tab.h"
  30 #include "quotearg.h"
  31 #include "reader.h"
  32 #include "symlist.h"
  33 #include "scan-gram.h"
  34 #include "scan-code.h"
  35
  36 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  37 static YYLTYPE lloc_default (YYLTYPE const *, int);
  38
  39 #define YY_LOCATION_PRINT(File, Loc) \
  40           location_print (File, Loc)
  41
  42 static void version_check (location const *loc, char const *version);
  43
  44 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  45    FIXME: depends on the undocumented availability of YYLLOC.  */
  46 #undef  yyerror
  47 #define yyerror(Msg) \
  48         gram_error (&yylloc, Msg)
  49 static void gram_error (location const *, char const *);
  50
  51 static char const *char_name (char);
  52
  53 /** Add a lex-param or a parse-param.
  54  *
  55  * \param type  \a lex_param or \a parse_param
  56  * \param decl  the formal argument
  57  * \param loc   the location in the source.
  58  */
  59 static void add_param (char const *type, char *decl, location loc);
  60
  61
  62 static symbol_class current_class = unknown_sym;
  63 static uniqstr current_type = NULL;
  64 static symbol *current_lhs;
  65 static location current_lhs_location;
  66 static int current_prec = 0;
  67
  68 #define YYTYPE_INT16 int_fast16_t
  69 #define YYTYPE_INT8 int_fast8_t
  70 #define YYTYPE_UINT16 uint_fast16_t
  71 #define YYTYPE_UINT8 uint_fast8_t
  72 %}
  73
  74 %debug
  75 %verbose
  76 %defines
  77 %locations
  78 %pure-parser
  79 %error-verbose
  80 %name-prefix="gram_"
  81 %expect 0
  82
  83 %initial-action
  84 {
  85   /* Bison's grammar can initial empty locations, hence a default
  86      location is needed. */
  87   boundary_set (&@$.start, current_file, 1, 1);
  88   boundary_set (&@$.end, current_file, 1, 1);
  89 }
  90
  91 %union
  92 {
  93   symbol *symbol;
  94   symbol_list *list;
  95   int integer;
  96   char const *chars;
  97   char *code;
  98   assoc assoc;
  99   uniqstr uniqstr;
 100   unsigned char character;
 101 };
 102
 103 /* Define the tokens together with their human representation.  */
 104 %token GRAM_EOF 0 "end of file"
 105 %token STRING     "string"
 106 %token INT        "integer"
 107
 108 %token PERCENT_TOKEN       "%token"
 109 %token PERCENT_NTERM       "%nterm"
 110
 111 %token PERCENT_TYPE        "%type"
 112 %token PERCENT_DESTRUCTOR  "%destructor"
 113 %token PERCENT_PRINTER     "%printer"
 114
 115 %token PERCENT_LEFT        "%left"
 116 %token PERCENT_RIGHT       "%right"
 117 %token PERCENT_NONASSOC    "%nonassoc"
 118 %token PERCENT_PRECEDENCE  "%precedence"
 119
 120 %token PERCENT_PREC          "%prec"
 121 %token PERCENT_DPREC         "%dprec"
 122 %token PERCENT_MERGE         "%merge"
 123
 124
 125 /*----------------------.
 126 | Global Declarations.  |
 127 `----------------------*/
 128
 129 %token
 130   PERCENT_CODE            "%code"
 131   PERCENT_DEFAULT_PREC    "%default-prec"
 132   PERCENT_DEFINE          "%define"
 133   PERCENT_DEFINES         "%defines"
 134   PERCENT_EXPECT          "%expect"
 135   PERCENT_EXPECT_RR       "%expect-rr"
 136   PERCENT_FLAG            "%<flag>"
 137   PERCENT_FILE_PREFIX     "%file-prefix"
 138   PERCENT_GLR_PARSER      "%glr-parser"
 139   PERCENT_INITIAL_ACTION  "%initial-action"
 140   PERCENT_LANGUAGE        "%language"
 141   PERCENT_LEX_PARAM       "%lex-param"
 142   PERCENT_LOCATIONS       "%locations"
 143   PERCENT_NAME_PREFIX     "%name-prefix"
 144   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 145   PERCENT_NO_LINES        "%no-lines"
 146   PERCENT_NONDETERMINISTIC_PARSER
 147                           "%nondeterministic-parser"
 148   PERCENT_OUTPUT          "%output"
 149   PERCENT_PARSE_PARAM     "%parse-param"
 150   PERCENT_REQUIRE         "%require"
 151   PERCENT_SKELETON        "%skeleton"
 152   PERCENT_START           "%start"
 153   PERCENT_TOKEN_TABLE     "%token-table"
 154   PERCENT_VERBOSE         "%verbose"
 155   PERCENT_YACC            "%yacc"
 156 ;
 157
 158 %token BRACED_CODE     "{...}"
 159 %token CHAR            "char"
 160 %token EPILOGUE        "epilogue"
 161 %token EQUAL           "="
 162 %token ID              "identifier"
 163 %token ID_COLON        "identifier:"
 164 %token PERCENT_PERCENT "%%"
 165 %token PIPE            "|"
 166 %token PROLOGUE        "%{...%}"
 167 %token SEMICOLON       ";"
 168 %token TAG             "<tag>"
 169 %token TAG_ANY         "<*>"
 170 %token TAG_NONE        "<>"
 171
 172 %type <character> CHAR
 173 %printer { fputs (char_name ($$), stderr); } CHAR
 174
 175 /* braceless is not to be used for rule or symbol actions, as it
 176    calls code_props_plain_init.  */
 177 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 178 %type <code> "{...}"
 179 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 180          STRING
 181 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 182          braceless content.opt "{...}" "%{...%}" EPILOGUE
 183
 184 %type <uniqstr> TAG ID ID_COLON PERCENT_FLAG variable
 185 %printer { fputs ($$, stderr); } ID variable
 186 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 187 %printer { fprintf (stderr, "%%%s", $$); } PERCENT_FLAG
 188 %printer { fprintf (stderr, "<%s>", $$); } TAG
 189
 190 %type <integer> INT
 191 %printer { fprintf (stderr, "%d", $$); } INT
 192
 193 %type <symbol> id id_colon symbol symbol.prec string_as_id
 194 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 195 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 196
 197 %type <assoc> precedence_declarator
 198 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 199 %%
 200
 201 input:
 202   prologue_declarations "%%" grammar epilogue.opt
 203 ;
 204
 205
 206         /*------------------------------------.
 207         | Declarations: before the first %%.  |
 208         `------------------------------------*/
 209
 210 prologue_declarations:
 211   /* Nothing */
 212 | prologue_declarations prologue_declaration
 213 ;
 214
 215 prologue_declaration:
 216   grammar_declaration
 217 | "%{...%}"
 218     {
 219       code_props plain_code;
 220       code_props_plain_init (&plain_code, $1, @1);
 221       code_props_translate_code (&plain_code);
 222       gram_scanner_last_string_free ();
 223       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 224                         plain_code.code, @1);
 225       code_scanner_last_string_free ();
 226     }
 227 | "%<flag>"
 228     {
 229       muscle_percent_define_ensure ($1, @1, true);
 230     }
 231 | "%define" variable content.opt
 232     {
 233       muscle_percent_define_insert ($2, @2, $3);
 234     }
 235 | "%defines"                       { defines_flag = true; }
 236 | "%defines" STRING
 237     {
 238       defines_flag = true;
 239       spec_defines_file = xstrdup ($2);
 240     }
 241 | "%expect" INT                    { expected_sr_conflicts = $2; }
 242 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 243 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 244 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 245 | "%glr-parser"
 246     {
 247       nondeterministic_parser = true;
 248       glr_parser = true;
 249     }
 250 | "%initial-action" "{...}"
 251     {
 252       code_props action;
 253       code_props_symbol_action_init (&action, $2, @2);
 254       code_props_translate_code (&action);
 255       gram_scanner_last_string_free ();
 256       muscle_code_grow ("initial_action", action.code, @2);
 257       code_scanner_last_string_free ();
 258     }
 259 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 260 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 261 | "%locations"                  { locations_flag = true; }
 262 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 263 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 264 | "%no-lines"                   { no_lines_flag = true; }
 265 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 266 | "%output" STRING              { spec_outfile = $2; }
 267 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 268 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 269 | "%require" STRING             { version_check (&@2, $2); }
 270 | "%skeleton" STRING
 271     {
 272       char const *skeleton_user = $2;
 273       if (strchr (skeleton_user, '/'))
 274         {
 275           size_t dir_length = strlen (current_file);
 276           char *skeleton_build;
 277           while (dir_length && current_file[dir_length - 1] != '/')
 278             --dir_length;
 279           while (dir_length && current_file[dir_length - 1] == '/')
 280             --dir_length;
 281           skeleton_build =
 282             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 283           if (dir_length > 0)
 284             {
 285               strncpy (skeleton_build, current_file, dir_length);
 286               skeleton_build[dir_length++] = '/';
 287             }
 288           strcpy (skeleton_build + dir_length, skeleton_user);
 289           skeleton_user = uniqstr_new (skeleton_build);
 290           free (skeleton_build);
 291         }
 292       skeleton_arg (skeleton_user, grammar_prio, @1);
 293     }
 294 | "%token-table"                { token_table_flag = true; }
 295 | "%verbose"                    { report_flag |= report_states; }
 296 | "%yacc"                       { yacc_flag = true; }
 297 | /*FIXME: Err?  What is this horror doing here? */ ";"
 298 ;
 299
 300 grammar_declaration:
 301   precedence_declaration
 302 | symbol_declaration
 303 | "%start" symbol
 304     {
 305       grammar_start_symbol_set ($2, @2);
 306     }
 307 | "%destructor" "{...}" generic_symlist
 308     {
 309       symbol_list *list;
 310       for (list = $3; list; list = list->next)
 311         symbol_list_destructor_set (list, $2, @2);
 312       symbol_list_free ($3);
 313     }
 314 | "%printer" "{...}" generic_symlist
 315     {
 316       symbol_list *list;
 317       for (list = $3; list; list = list->next)
 318         symbol_list_printer_set (list, $2, @2);
 319       symbol_list_free ($3);
 320     }
 321 | "%default-prec"
 322     {
 323       default_prec = true;
 324     }
 325 | "%no-default-prec"
 326     {
 327       default_prec = false;
 328     }
 329 | "%code" braceless
 330     {
 331       /* Do not invoke muscle_percent_code_grow here since it invokes
 332          muscle_user_name_list_grow.  */
 333       muscle_code_grow ("percent_code()", $2, @2);
 334       code_scanner_last_string_free ();
 335     }
 336 | "%code" ID braceless
 337     {
 338       muscle_percent_code_grow ($2, @2, $3, @3);
 339       code_scanner_last_string_free ();
 340     }
 341 ;
 342
 343
 344 /*---------.
 345 | %union.  |
 346 `---------*/
 347
 348 %token PERCENT_UNION "%union";
 349
 350 union_name:
 351   /* Nothing. */ {}
 352 | ID             { muscle_code_grow ("union_name", $1, @1); }
 353 ;
 354
 355 grammar_declaration:
 356   "%union" union_name braceless
 357     {
 358       union_seen = true;
 359       muscle_code_grow ("stype", $3, @3);
 360       code_scanner_last_string_free ();
 361     }
 362 ;
 363
 364
 365
 366
 367 symbol_declaration:
 368   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 369     {
 370       current_class = unknown_sym;
 371       current_type = NULL;
 372     }
 373 | "%token" { current_class = token_sym; } symbol_defs.1
 374     {
 375       current_class = unknown_sym;
 376       current_type = NULL;
 377     }
 378 | "%type" TAG symbols.1
 379     {
 380       symbol_list *list;
 381       tag_seen = true;
 382       for (list = $3; list; list = list->next)
 383         symbol_type_set (list->content.sym, $2, @2);
 384       symbol_list_free ($3);
 385     }
 386 ;
 387
 388 precedence_declaration:
 389   precedence_declarator tag.opt symbols.prec
 390     {
 391       symbol_list *list;
 392       ++current_prec;
 393       for (list = $3; list; list = list->next)
 394         {
 395           symbol_type_set (list->content.sym, current_type, @2);
 396           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 397         }
 398       symbol_list_free ($3);
 399       current_type = NULL;
 400     }
 401 ;
 402
 403 precedence_declarator:
 404   "%left"       { $$ = left_assoc; }
 405 | "%right"      { $$ = right_assoc; }
 406 | "%nonassoc"   { $$ = non_assoc; }
 407 | "%precedence" { $$ = precedence_assoc; }
 408 ;
 409
 410 tag.opt:
 411   /* Nothing. */ { current_type = NULL; }
 412 | TAG            { current_type = $1; tag_seen = true; }
 413 ;
 414
 415 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 416 symbols.prec:
 417   symbol.prec
 418     { $$ = symbol_list_sym_new ($1, @1); }
 419 | symbols.prec symbol.prec
 420     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 421 ;
 422
 423 symbol.prec:
 424     symbol { $$ = $1; }
 425   | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 426   ;
 427
 428 /* One or more symbols to be %typed. */
 429 symbols.1:
 430   symbol
 431     { $$ = symbol_list_sym_new ($1, @1); }
 432 | symbols.1 symbol
 433     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 434 ;
 435
 436 generic_symlist:
 437   generic_symlist_item { $$ = $1; }
 438 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 439 ;
 440
 441 generic_symlist_item:
 442   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 443 | TAG       { $$ = symbol_list_type_new ($1, @1); }
 444 | "<*>"     { $$ = symbol_list_default_tagged_new (@1); }
 445 | "<>"      { $$ = symbol_list_default_tagless_new (@1); }
 446 ;
 447
 448 /* One token definition.  */
 449 symbol_def:
 450   TAG
 451      {
 452        current_type = $1;
 453        tag_seen = true;
 454      }
 455 | id
 456      {
 457        symbol_class_set ($1, current_class, @1, true);
 458        symbol_type_set ($1, current_type, @1);
 459      }
 460 | id INT
 461     {
 462       symbol_class_set ($1, current_class, @1, true);
 463       symbol_type_set ($1, current_type, @1);
 464       symbol_user_token_number_set ($1, $2, @2);
 465     }
 466 | id string_as_id
 467     {
 468       symbol_class_set ($1, current_class, @1, true);
 469       symbol_type_set ($1, current_type, @1);
 470       symbol_make_alias ($1, $2, @$);
 471     }
 472 | id INT string_as_id
 473     {
 474       symbol_class_set ($1, current_class, @1, true);
 475       symbol_type_set ($1, current_type, @1);
 476       symbol_user_token_number_set ($1, $2, @2);
 477       symbol_make_alias ($1, $3, @$);
 478     }
 479 ;
 480
 481 /* One or more symbol definitions. */
 482 symbol_defs.1:
 483   symbol_def
 484 | symbol_defs.1 symbol_def
 485 ;
 486
 487
 488         /*------------------------------------------.
 489         | The grammar section: between the two %%.  |
 490         `------------------------------------------*/
 491
 492 grammar:
 493   rules_or_grammar_declaration
 494 | grammar rules_or_grammar_declaration
 495 ;
 496
 497 /* As a Bison extension, one can use the grammar declarations in the
 498    body of the grammar.  */
 499 rules_or_grammar_declaration:
 500   rules
 501 | grammar_declaration ";"
 502 | error ";"
 503     {
 504       yyerrok;
 505     }
 506 ;
 507
 508 rules:
 509   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 510 ;
 511
 512 rhses.1:
 513   rhs                { grammar_current_rule_end (@1); }
 514 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 515 | rhses.1 ";"
 516 ;
 517
 518 rhs:
 519   /* Nothing.  */
 520     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 521 | rhs symbol
 522     { grammar_current_rule_symbol_append ($2, @2); }
 523 | rhs "{...}"
 524     { grammar_current_rule_action_append ($2, @2); }
 525 | rhs "%prec" symbol
 526     { grammar_current_rule_prec_set ($3, @3); }
 527 | rhs "%dprec" INT
 528     { grammar_current_rule_dprec_set ($3, @3); }
 529 | rhs "%merge" TAG
 530     { grammar_current_rule_merge_set ($3, @3); }
 531 ;
 532
 533
 534 /*---------------------------.
 535 | variable and content.opt.  |
 536 `---------------------------*/
 537
 538 variable:
 539   ID
 540 | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 541 ;
 542
 543 /* Some content or empty by default. */
 544 content.opt:
 545   /* Nothing. */
 546     {
 547       $$ = "";
 548     }
 549 | STRING
 550 ;
 551
 552
 553 /*------------.
 554 | braceless.  |
 555 `------------*/
 556
 557 braceless:
 558   "{...}"
 559     {
 560       code_props plain_code;
 561       $1[strlen ($1) - 1] = '\n';
 562       code_props_plain_init (&plain_code, $1+1, @1);
 563       code_props_translate_code (&plain_code);
 564       gram_scanner_last_string_free ();
 565       $$ = plain_code.code;
 566     }
 567 ;
 568
 569
 570 /*--------------.
 571 | Identifiers.  |
 572 `--------------*/
 573
 574 /* Identifiers are returned as uniqstr values by the scanner.
 575    Depending on their use, we may need to make them genuine symbols.  */
 576
 577 id:
 578   ID
 579     { $$ = symbol_from_uniqstr ($1, @1); }
 580 | CHAR
 581     {
 582       $$ = symbol_get (char_name ($1), @1);
 583       symbol_class_set ($$, token_sym, @1, false);
 584       symbol_user_token_number_set ($$, $1, @1);
 585     }
 586 ;
 587
 588 id_colon:
 589   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 590 ;
 591
 592
 593 symbol:
 594   id
 595 | string_as_id
 596 ;
 597
 598 /* A string used as an ID: quote it.  */
 599 string_as_id:
 600   STRING
 601     {
 602       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 603       symbol_class_set ($$, token_sym, @1, false);
 604     }
 605 ;
 606
 607 epilogue.opt:
 608   /* Nothing.  */
 609 | "%%" EPILOGUE
 610     {
 611       code_props plain_code;
 612       code_props_plain_init (&plain_code, $2, @2);
 613       code_props_translate_code (&plain_code);
 614       gram_scanner_last_string_free ();
 615       muscle_code_grow ("epilogue", plain_code.code, @2);
 616       code_scanner_last_string_free ();
 617     }
 618 ;
 619
 620 %%
 621
 622
 623 /* Return the location of the left-hand side of a rule whose
 624    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 625    the right-hand side, and return an empty location equal to the end
 626    boundary of RHS[0] if the right-hand side is empty.  */
 627
 628 static YYLTYPE
 629 lloc_default (YYLTYPE const *rhs, int n)
 630 {
 631   int i;
 632   YYLTYPE loc;
 633
 634   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 635      The bug is fixed in 7.4.2m, but play it safe for now.  */
 636   loc.start = rhs[n].end;
 637   loc.end = rhs[n].end;
 638
 639   /* Ignore empty nonterminals the start of the the right-hand side.
 640      Do not bother to ignore them at the end of the right-hand side,
 641      since empty nonterminals have the same end as their predecessors.  */
 642   for (i = 1; i <= n; i++)
 643     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 644       {
 645         loc.start = rhs[i].start;
 646         break;
 647       }
 648
 649   return loc;
 650 }
 651
 652
 653 /* Add a lex-param or a parse-param (depending on TYPE) with
 654    declaration DECL and location LOC.  */
 655
 656 static void
 657 add_param (char const *type, char *decl, location loc)
 658 {
 659   static char const alphanum[26 + 26 + 1 + 10] =
 660     "abcdefghijklmnopqrstuvwxyz"
 661     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 662     "_"
 663     "0123456789";
 664   char const *name_start = NULL;
 665   char *p;
 666
 667   /* Stop on last actual character.  */
 668   for (p = decl; p[1]; p++)
 669     if ((p == decl
 670          || ! memchr (alphanum, p[-1], sizeof alphanum))
 671         && memchr (alphanum, p[0], sizeof alphanum - 10))
 672       name_start = p;
 673
 674   /* Strip the surrounding '{' and '}', and any blanks just inside
 675      the braces.  */
 676   while (*--p == ' ' || *p == '\t')
 677     continue;
 678   p[1] = '\0';
 679   while (*++decl == ' ' || *decl == '\t')
 680     continue;
 681
 682   if (! name_start)
 683     complain_at (loc, _("missing identifier in parameter declaration"));
 684   else
 685     {
 686       char *name;
 687       size_t name_len;
 688
 689       for (name_len = 1;
 690            memchr (alphanum, name_start[name_len], sizeof alphanum);
 691            name_len++)
 692         continue;
 693
 694       name = xmalloc (name_len + 1);
 695       memcpy (name, name_start, name_len);
 696       name[name_len] = '\0';
 697       muscle_pair_list_grow (type, decl, name);
 698       free (name);
 699     }
 700
 701   gram_scanner_last_string_free ();
 702 }
 703
 704
 705 static void
 706 version_check (location const *loc, char const *version)
 707 {
 708   if (strverscmp (version, PACKAGE_VERSION) > 0)
 709     {
 710       complain_at (*loc, "require bison %s, but have %s",
 711                    version, PACKAGE_VERSION);
 712       exit (63);
 713     }
 714 }
 715
 716 static void
 717 gram_error (location const *loc, char const *msg)
 718 {
 719   complain_at (*loc, "%s", msg);
 720 }
 721
 722 char const *
 723 token_name (int type)
 724 {
 725   return yytname[YYTRANSLATE (type)];
 726 }
 727
 728 static char const *
 729 char_name (char c)
 730 {
 731   if (c == '\'')
 732     return "'\\''";
 733   else
 734     {
 735       char buf[4];
 736       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 737       return quotearg_style (escape_quoting_style, buf);
 738     }
 739 }