tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We want a recent Autotest.
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------------------------- ##
  24 ## Macros decoding Bison options.  ##
  25 ## ------------------------------- ##
  26
  27
  28 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  29 # -----------------------------------------
  30 m4_define([AT_BISON_OPTION_PUSHDEFS],
  31 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  32
  33
  34 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  35 # --------------------------------------------------
  36 # This macro works around the impossibility to define macros
  37 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  38 # This sucks hard, GNU M4 should really provide M5 like $$1.
  39 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  40 [m4_if([$1$2], $[1]$[2], [],
  41        [m4_fatal([$0: Invalid arguments: $@])])dnl
  42 m4_pushdef([AT_DEFINES_IF],
  43 [m4_bmatch([$3], [%defines], [$1], [$2])])
  44 m4_pushdef([AT_SKEL_CC_IF],
  45 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  46 m4_pushdef([AT_GLR_IF],
  47 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  48 m4_pushdef([AT_LALR1_CC_IF],
  49 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  50 m4_pushdef([AT_GLR_CC_IF],
  51 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  52 # Using yacc.c?
  53 m4_pushdef([AT_YACC_IF],
  54 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  55 m4_pushdef([AT_LEXPARAM_IF],
  56 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  57 m4_pushdef([AT_PARAM_IF],
  58 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  59 m4_pushdef([AT_LOCATION_IF],
  60 [m4_bmatch([$3], [%locations], [$1], [$2])])
  61 m4_pushdef([AT_PURE_IF],
  62 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
  63            [m4_bmatch([$3], [%define  *api\.pure *"false"], [$2], [$1])],
  64            [$2])])
  65 m4_pushdef([AT_PURE_AND_LOC_IF],
  66 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
  67 m4_pushdef([AT_GLR_OR_PARAM_IF],
  68 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  69 m4_pushdef([AT_NAME_PREFIX],
  70 [m4_bmatch([$3], [%name-prefix ".*"],
  71            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  72            [yy])])
  73 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  74 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  75 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  76                     [$2])])
  77 # yyerror always sees the locations (when activated), except if
  78 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  79 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  80 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  81                                         [$1])],
  82                             [$1])],
  83                 [$2])])
  84
  85 # The interface is pure: either because %define api.pure, or because we
  86 # are using the C++ parsers.
  87 m4_pushdef([AT_PURE_LEX_IF],
  88 [AT_PURE_IF([$1],
  89             [AT_SKEL_CC_IF([$1], [$2])])])
  90
  91 AT_PURE_LEX_IF(
  92 [m4_pushdef([AT_LOC], [(*llocp)])
  93  m4_pushdef([AT_VAL], [(*lvalp)])
  94  m4_pushdef([AT_LEX_FORMALS],
  95             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
  96  m4_pushdef([AT_LEX_ARGS],
  97             [lvalp[]AT_LOCATION_IF([, llocp])])
  98  m4_pushdef([AT_USE_LEX_ARGS],
  99             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 100  m4_pushdef([AT_LEX_PRE_FORMALS],
 101             [AT_LEX_FORMALS, ])
 102  m4_pushdef([AT_LEX_PRE_ARGS],
 103             [AT_LEX_ARGS, ])
 104 ],
 105 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 106  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 107  m4_pushdef([AT_LEX_FORMALS],     [void])
 108  m4_pushdef([AT_LEX_ARGS],        [])
 109  m4_pushdef([AT_USE_LEX_ARGS],    [])
 110  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 111  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 112 ])
 113 ])# _AT_BISON_OPTION_PUSHDEFS
 114
 115
 116 # AT_BISON_OPTION_POPDEFS
 117 # -----------------------
 118 m4_define([AT_BISON_OPTION_POPDEFS],
 119 [m4_popdef([AT_LEX_PRE_ARGS])
 120 m4_popdef([AT_LEX_PRE_FORMALS])
 121 m4_popdef([AT_USE_LEX_ARGS])
 122 m4_popdef([AT_LEX_ARGS])
 123 m4_popdef([AT_LEX_FORMALS])
 124 m4_popdef([AT_VAL])
 125 m4_popdef([AT_LOC])
 126 m4_popdef([AT_PURE_LEX_IF])
 127 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 128 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 129 m4_popdef([AT_NAME_PREFIX])
 130 m4_popdef([AT_GLR_OR_PARAM_IF])
 131 m4_popdef([AT_PURE_AND_LOC_IF])
 132 m4_popdef([AT_LOCATION_IF])
 133 m4_popdef([AT_PARAM_IF])
 134 m4_popdef([AT_LEXPARAM_IF])
 135 m4_popdef([AT_YACC_IF])
 136 m4_popdef([AT_GLR_IF])
 137 m4_popdef([AT_SKEL_CC_IF])
 138 m4_popdef([AT_GLR_CC_IF])
 139 m4_popdef([AT_LALR1_CC_IF])
 140 m4_popdef([AT_DEFINES_IF])
 141 ])# AT_BISON_OPTION_POPDEFS
 142
 143
 144
 145 ## -------------------------- ##
 146 ## Generating Grammar Files.  ##
 147 ## -------------------------- ##
 148
 149 # AT_DATA_SOURCE_PROLOGUE
 150 # ------------------------
 151 # The prologue that should be included in any source code that is
 152 # meant to be compiled.
 153 m4_define([AT_DATA_SOURCE_PROLOGUE],
 154 [[#include <config.h>
 155 /* We don't need perfect functions for these tests. */
 156 #undef malloc
 157 #undef memcmp
 158 #undef realloc
 159 ]])
 160
 161 # AT_DATA_GRAMMAR_PROLOGUE
 162 # ------------------------
 163 # The prologue that should be included in any grammar which parser is
 164 # meant to be compiled.
 165 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 166 [[%code top {
 167 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 168 [}
 169 ]])
 170
 171 # AT_DATA_SOURCE(NAME, CONTENT)
 172 # -----------------------------
 173 # Generate the file NAME, which CONTENT is preceded by
 174 # AT_DATA_SOURCE_PROLOGUE.
 175 m4_define([AT_DATA_SOURCE],
 176 [AT_DATA([$1],
 177 [AT_DATA_SOURCE_PROLOGUE
 178 $2])
 179 ])
 180
 181 # AT_DATA_GRAMMAR(NAME, CONTENT)
 182 # ------------------------------
 183 # Generate the file NAME, which CONTENT is preceded by
 184 # AT_DATA_GRAMMAR_PROLOGUE.
 185 m4_define([AT_DATA_GRAMMAR],
 186 [AT_DATA([$1],
 187 [AT_DATA_GRAMMAR_PROLOGUE
 188 $2])
 189 ])
 190
 191 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 192 # -------------------------------------------------
 193 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 194 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 195 #
 196 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 197 # Bison in the test suite.  For now it ensures that:
 198 #
 199 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 200 #      a non-zero exit status since Bison doesn't always try to free all memory
 201 #      in that case.
 202 #
 203 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 204 #      --graph and --report=all output for every working grammar.
 205 m4_define([AT_BISON_CHECK],
 206 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 207        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 208 AT_BISON_CHECK_NO_XML($@)])
 209
 210 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 211 # --------------------------------------------------------
 212 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 213 # when a tortured grammar's XML is known to be too large for xsltproc to
 214 # handle.
 215 m4_define([AT_BISON_CHECK_NO_XML],
 216 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 217                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 218
 219 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 220 # -----------------------------------------------------
 221 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 222 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 223 # have a non-zero exit status.
 224 m4_define([AT_BISON_CHECK_XML],
 225 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 226   mkdir xml-tests]
 227   m4_pushdef([AT_BISON_ARGS],
 228              [m4_bpatsubsts([[$1]],
 229                             [--report(-file)?=[^][ ]*], [],
 230                             [--graph=[^][ ]*], [],
 231                             [--xml=[^][ ]*], [])])dnl
 232   # Don't combine these Bison invocations since we want to be sure that
 233   # --report=all isn't required to get the full XML file.
 234   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 235              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 236            [[0]], [ignore], [ignore])
 237   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 238            [[0]], [ignore], [ignore])
 239   m4_popdef([AT_BISON_ARGS])dnl
 240   [cp xml-tests/test.output expout]
 241   AT_CHECK([[$XSLTPROC \
 242              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 243              xml-tests/test.xml]], [[0]], [expout])
 244   [cp xml-tests/test.dot expout]
 245   AT_CHECK([[$XSLTPROC \
 246              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 247              xml-tests/test.xml]], [[0]], [expout])
 248   [rm -rf xml-tests expout
 249 fi]])
 250
 251 # AT_QUELL_VALGRIND
 252 # -----------------
 253 # Put this before a Bison invocation to keep Valgrind from complaining about
 254 # reachable memory.
 255 #
 256 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 257 # The triple quoting below will cause test cases to fail if you do.  If you do
 258 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 259 # will then fail to shell-escape its contents when attempting to print them.
 260 # The testsuite verbose output, at least, will be incorrect, but nothing may
 261 # fail to make sure you notice.
 262 m4_define([AT_QUELL_VALGRIND],
 263 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 264
 265 ## ------------------------ ##
 266 ## Compiling C, C++ Files.  ##
 267 ## ------------------------ ##
 268
 269
 270 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 271 # ----------------------------------------
 272 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 273 # assume that we are linking too; this is a hack.
 274 m4_define([AT_COMPILE],
 275 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 276            0, [ignore], [ignore])])
 277
 278 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 279 # --------------------------------------------
 280 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 281 # assume that we are linking too; this is a hack.
 282 # If the C++ compiler does not work, ignore the test.
 283 m4_define([AT_COMPILE_CXX],
 284 [AT_KEYWORDS(c++)
 285 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 286 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 287          0, [ignore], [ignore])])
 288
 289
 290 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 291 # --------------------------------
 292 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 293 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 294 # along with it.
 295 # Relies on AT_SKEL_CC_IF.
 296 m4_define([AT_FULL_COMPILE],
 297 [AT_SKEL_CC_IF(
 298   [AT_BISON_CHECK([-o $1.cc $1.y])
 299    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 300   [AT_BISON_CHECK([-o $1.c $1.y])
 301    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 302 ])
 303
 304
 305 ## ---------------------------- ##
 306 ## Running a generated parser.  ##
 307 ## ---------------------------- ##
 308
 309 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 310 # ------------------------------------------------------------
 311 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 312 m4_define([AT_PARSER_CHECK],
 313 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 314
 315
 316
 317
 318 ## ----------------------- ##
 319 ## Launch the test suite.  ##
 320 ## ----------------------- ##
 321
 322 AT_INIT
 323
 324 AT_TESTED([bison])