configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19
  20 # We need a recent Autoconf to run a recent Autotest.
  21 AC_PREREQ(2.54)
  22
  23 AC_INIT([GNU Bison], [1.75f], [bug-bison@gnu.org])
  24 AC_CONFIG_AUX_DIR(config)
  25
  26 AM_INIT_AUTOMAKE([1.7 check-news readme-alpha dist-bzip2])
  27 AC_CONFIG_HEADERS([config.h:config.hin])
  28
  29 # Checks for the compiler.
  30 AC_PROG_CC
  31 # Remove with Automake 1.8.
  32 AC_ISC_POSIX
  33 AC_GNU_SOURCE
  34 AC_MINIX
  35 AM_PROG_CC_STDC
  36 AC_ARG_ENABLE(gcc-warnings,
  37 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  38 [case "${enableval}" in
  39    yes|no) ;;
  40    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  41  esac],
  42               [enableval=no])
  43 if test "${enableval}" = yes; then
  44   BISON_WARNING(-Werror)
  45   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  46   WARNING_CFLAGS=
  47   BISON_WARNING(-Wall)
  48   BISON_WARNING(-W)
  49   BISON_WARNING(-Wbad-function-cast)
  50   BISON_WARNING(-Wcast-align)
  51   BISON_WARNING(-Wcast-qual)
  52   BISON_WARNING(-Wformat)
  53   BISON_WARNING(-Wmissing-declarations)
  54   BISON_WARNING(-Wmissing-prototypes)
  55   BISON_WARNING(-Wnested-externs)
  56   BISON_WARNING(-Wshadow)
  57   BISON_WARNING(-Wstrict-prototypes)
  58   BISON_WARNING(-Wwrite-strings)
  59   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  60 fi
  61
  62 # Checks for programs.
  63 AC_PROG_LEX
  64 AC_PROG_YACC
  65 AC_PROG_RANLIB
  66 BISON_PROG_GNU_M4
  67 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  68   AC_MSG_ERROR([GNU M4 1.4 is required])
  69 fi
  70 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  71
  72 # Checks for header files.
  73 AC_HEADER_STDC
  74 AC_CHECK_HEADERS([ctype.h locale.h memory.h stdlib.h string.h unistd.h])
  75 AC_HEADER_STDBOOL
  76
  77 # Checks for compiler characteristics.
  78 AC_C_INLINE
  79
  80 # Checks for types.
  81 AC_CHECK_TYPES([uintptr_t])
  82
  83 # Checks for library functions.
  84 AC_FUNC_ALLOCA
  85 AC_FUNC_OBSTACK
  86 AC_FUNC_ERROR_AT_LINE
  87 AC_FUNC_STRNLEN
  88 AC_CHECK_FUNCS(setlocale)
  89 AC_CHECK_DECLS([free, getenv, getopt,
  90                 stpcpy, strchr, strspn, strnlen,
  91                 malloc, memchr, memrchr])
  92 AC_REPLACE_FUNCS(memchr memrchr \
  93                  strchr stpcpy strrchr strspn strtol strtoul)
  94 AC_FUNC_MALLOC
  95 AC_FUNC_REALLOC
  96 jm_PREREQ_MBSWIDTH
  97 jm_PREREQ_QUOTEARG
  98 jm_FUNC_ARGMATCH
  99 jm_PREREQ_ERROR
 100 AM_WITH_DMALLOC
 101 BISON_PREREQ_SUBPIPE
 102 BISON_PREREQ_TIMEVAR
 103
 104 # Gettext.
 105 AM_GNU_GETTEXT(external, need-ngettext)
 106 AM_GNU_GETTEXT_VERSION(0.11.5)
 107
 108 # Initialize the test suite.
 109 AC_CONFIG_TESTDIR(tests)
 110 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 111 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 112 AC_CHECK_PROGS([VALGRIND], [valgrind])
 113 AC_CHECK_PROGS([GXX], [g++])
 114 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 115 # Needed by tests/atlocal.in.
 116 AC_SUBST([GCC])
 117 O0CFLAGS=`echo $CFLAGS | sed 's/-O[0-9] *//'`
 118 AC_SUBST([O0CFLAGS])
 119
 120 AC_CONFIG_FILES([Makefile
 121                  config/Makefile
 122                  po/Makefile.in
 123                  data/Makefile
 124                  lib/Makefile src/Makefile doc/Makefile
 125                  m4/Makefile])
 126 AC_OUTPUT