src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle_tab.h"
  30 #include "quotearg.h"
  31 #include "reader.h"
  32 #include "symlist.h"
  33 #include "scan-gram.h"
  34 #include "scan-code.h"
  35
  36 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  37 static YYLTYPE lloc_default (YYLTYPE const *, int);
  38
  39 #define YY_LOCATION_PRINT(File, Loc) \
  40           location_print (File, Loc)
  41
  42 static void version_check (location const *loc, char const *version);
  43
  44 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  45    FIXME: depends on the undocumented availability of YYLLOC.  */
  46 #undef  yyerror
  47 #define yyerror(Msg) \
  48         gram_error (&yylloc, Msg)
  49 static void gram_error (location const *, char const *);
  50
  51 static char const *char_name (char);
  52
  53 /** Add a lex-param or a parse-param.
  54  *
  55  * \param type  \a lex_param or \a parse_param
  56  * \param decl  the formal argument
  57  * \param loc   the location in the source.
  58  */
  59 static void add_param (char const *type, char *decl, location loc);
  60
  61
  62 static symbol_class current_class = unknown_sym;
  63 static uniqstr current_type = NULL;
  64 static symbol *current_lhs;
  65 static location current_lhs_location;
  66 static int current_prec = 0;
  67
  68 #define YYTYPE_INT16 int_fast16_t
  69 #define YYTYPE_INT8 int_fast8_t
  70 #define YYTYPE_UINT16 uint_fast16_t
  71 #define YYTYPE_UINT8 uint_fast8_t
  72 %}
  73
  74 %debug
  75 %verbose
  76 %defines
  77 %locations
  78 %pure-parser
  79 %error-verbose
  80 %name-prefix="gram_"
  81 %expect 0
  82
  83 %initial-action
  84 {
  85   /* Bison's grammar can initial empty locations, hence a default
  86      location is needed. */
  87   boundary_set (&@$.start, current_file, 1, 1);
  88   boundary_set (&@$.end, current_file, 1, 1);
  89 }
  90
  91 %union
  92 {
  93   symbol *symbol;
  94   symbol_list *list;
  95   int integer;
  96   char const *chars;
  97   char *code;
  98   assoc assoc;
  99   uniqstr uniqstr;
 100   unsigned char character;
 101 };
 102
 103 /* Define the tokens together with their human representation.  */
 104 %token GRAM_EOF 0 "end of file"
 105 %token STRING     "string"
 106 %token INT        "integer"
 107
 108 %token PERCENT_TOKEN       "%token"
 109 %token PERCENT_NTERM       "%nterm"
 110
 111 %token PERCENT_TYPE        "%type"
 112 %token PERCENT_DESTRUCTOR  "%destructor"
 113 %token PERCENT_PRINTER     "%printer"
 114
 115 %token PERCENT_LEFT        "%left"
 116 %token PERCENT_RIGHT       "%right"
 117 %token PERCENT_NONASSOC    "%nonassoc"
 118 %token PERCENT_PRECEDENCE  "%precedence"
 119
 120 %token PERCENT_PREC          "%prec"
 121 %token PERCENT_DPREC         "%dprec"
 122 %token PERCENT_MERGE         "%merge"
 123
 124
 125 /*----------------------.
 126 | Global Declarations.  |
 127 `----------------------*/
 128
 129 %token
 130   PERCENT_CODE            "%code"
 131   PERCENT_DEBUG           "%debug"
 132   PERCENT_DEFAULT_PREC    "%default-prec"
 133   PERCENT_DEFINE          "%define"
 134   PERCENT_DEFINES         "%defines"
 135   PERCENT_ERROR_VERBOSE   "%error-verbose"
 136   PERCENT_EXPECT          "%expect"
 137   PERCENT_EXPECT_RR       "%expect-rr"
 138   PERCENT_FILE_PREFIX     "%file-prefix"
 139   PERCENT_GLR_PARSER      "%glr-parser"
 140   PERCENT_INITIAL_ACTION  "%initial-action"
 141   PERCENT_LANGUAGE        "%language"
 142   PERCENT_LEX_PARAM       "%lex-param"
 143   PERCENT_LOCATIONS       "%locations"
 144   PERCENT_NAME_PREFIX     "%name-prefix"
 145   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 146   PERCENT_NO_LINES        "%no-lines"
 147   PERCENT_NONDETERMINISTIC_PARSER
 148                           "%nondeterministic-parser"
 149   PERCENT_OUTPUT          "%output"
 150   PERCENT_PARSE_PARAM     "%parse-param"
 151   PERCENT_PURE_PARSER     "%pure-parser"
 152   PERCENT_REQUIRE         "%require"
 153   PERCENT_SKELETON        "%skeleton"
 154   PERCENT_START           "%start"
 155   PERCENT_TOKEN_TABLE     "%token-table"
 156   PERCENT_VERBOSE         "%verbose"
 157   PERCENT_YACC            "%yacc"
 158 ;
 159
 160 %token BRACED_CODE     "{...}"
 161 %token CHAR            "char"
 162 %token EPILOGUE        "epilogue"
 163 %token EQUAL           "="
 164 %token ID              "identifier"
 165 %token ID_COLON        "identifier:"
 166 %token PERCENT_PERCENT "%%"
 167 %token PIPE            "|"
 168 %token PROLOGUE        "%{...%}"
 169 %token SEMICOLON       ";"
 170 %token TAG             "<tag>"
 171 %token TAG_ANY         "<*>"
 172 %token TAG_NONE        "<>"
 173
 174 %type <character> CHAR
 175 %printer { fputs (char_name ($$), stderr); } CHAR
 176
 177 /* braceless is not to be used for rule or symbol actions, as it
 178    calls code_props_plain_init.  */
 179 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 180 %type <code> "{...}"
 181 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 182          STRING
 183 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 184          braceless content.opt "{...}" "%{...%}" EPILOGUE
 185
 186 %type <uniqstr> TAG ID ID_COLON variable
 187 %printer { fprintf (stderr, "<%s>", $$); } TAG
 188 %printer { fputs ($$, stderr); } ID variable
 189 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 190
 191 %type <integer> INT
 192 %printer { fprintf (stderr, "%d", $$); } INT
 193
 194 %type <symbol> id id_colon symbol symbol.prec string_as_id
 195 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 196 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 197
 198 %type <assoc> precedence_declarator
 199 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 200 %%
 201
 202 input:
 203   prologue_declarations "%%" grammar epilogue.opt
 204 ;
 205
 206
 207         /*------------------------------------.
 208         | Declarations: before the first %%.  |
 209         `------------------------------------*/
 210
 211 prologue_declarations:
 212   /* Nothing */
 213 | prologue_declarations prologue_declaration
 214 ;
 215
 216 prologue_declaration:
 217   grammar_declaration
 218 | "%{...%}"
 219     {
 220       code_props plain_code;
 221       code_props_plain_init (&plain_code, $1, @1);
 222       code_props_translate_code (&plain_code);
 223       gram_scanner_last_string_free ();
 224       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 225                         plain_code.code, @1);
 226       code_scanner_last_string_free ();
 227     }
 228 | "%debug"                         { debug_flag = true; }
 229 | "%define" variable content.opt
 230     {
 231       muscle_percent_define_insert ($2, @2, $3);
 232     }
 233 | "%defines"                       { defines_flag = true; }
 234 | "%defines" STRING
 235     {
 236       defines_flag = true;
 237       spec_defines_file = xstrdup ($2);
 238     }
 239 | "%error-verbose"                 { error_verbose = true; }
 240 | "%expect" INT                    { expected_sr_conflicts = $2; }
 241 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 242 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 243 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 244 | "%glr-parser"
 245     {
 246       nondeterministic_parser = true;
 247       glr_parser = true;
 248     }
 249 | "%initial-action" "{...}"
 250     {
 251       code_props action;
 252       code_props_symbol_action_init (&action, $2, @2);
 253       code_props_translate_code (&action);
 254       gram_scanner_last_string_free ();
 255       muscle_code_grow ("initial_action", action.code, @2);
 256       code_scanner_last_string_free ();
 257     }
 258 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 259 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 260 | "%locations"                  { locations_flag = true; }
 261 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 262 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 263 | "%no-lines"                   { no_lines_flag = true; }
 264 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 265 | "%output" STRING              { spec_outfile = $2; }
 266 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 267 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 268 | "%pure-parser"
 269     {
 270       /* %pure-parser is deprecated in favor of `%define api.pure', so use
 271          `%define api.pure' in a backward-compatible manner here.  First, don't
 272          complain if %pure-parser is specified multiple times.  */
 273       if (!muscle_find_const ("percent_define(api.pure)"))
 274         muscle_percent_define_insert ("api.pure", @1, "");
 275       /* In all cases, use api.pure now so that the backend doesn't complain if
 276          the skeleton ignores api.pure, but do warn now if there's a previous
 277          conflicting definition from an actual %define.  */
 278       if (!muscle_percent_define_flag_if ("api.pure"))
 279         muscle_percent_define_insert ("api.pure", @1, "");
 280     }
 281 | "%require" STRING             { version_check (&@2, $2); }
 282 | "%skeleton" STRING
 283     {
 284       char const *skeleton_user = $2;
 285       if (strchr (skeleton_user, '/'))
 286         {
 287           size_t dir_length = strlen (current_file);
 288           char *skeleton_build;
 289           while (dir_length && current_file[dir_length - 1] != '/')
 290             --dir_length;
 291           while (dir_length && current_file[dir_length - 1] == '/')
 292             --dir_length;
 293           skeleton_build =
 294             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 295           if (dir_length > 0)
 296             {
 297               strncpy (skeleton_build, current_file, dir_length);
 298               skeleton_build[dir_length++] = '/';
 299             }
 300           strcpy (skeleton_build + dir_length, skeleton_user);
 301           skeleton_user = uniqstr_new (skeleton_build);
 302           free (skeleton_build);
 303         }
 304       skeleton_arg (skeleton_user, grammar_prio, @1);
 305     }
 306 | "%token-table"                { token_table_flag = true; }
 307 | "%verbose"                    { report_flag |= report_states; }
 308 | "%yacc"                       { yacc_flag = true; }
 309 | /*FIXME: Err?  What is this horror doing here? */ ";"
 310 ;
 311
 312 grammar_declaration:
 313   precedence_declaration
 314 | symbol_declaration
 315 | "%start" symbol
 316     {
 317       grammar_start_symbol_set ($2, @2);
 318     }
 319 | "%destructor" "{...}" generic_symlist
 320     {
 321       symbol_list *list;
 322       for (list = $3; list; list = list->next)
 323         symbol_list_destructor_set (list, $2, @2);
 324       symbol_list_free ($3);
 325     }
 326 | "%printer" "{...}" generic_symlist
 327     {
 328       symbol_list *list;
 329       for (list = $3; list; list = list->next)
 330         symbol_list_printer_set (list, $2, @2);
 331       symbol_list_free ($3);
 332     }
 333 | "%default-prec"
 334     {
 335       default_prec = true;
 336     }
 337 | "%no-default-prec"
 338     {
 339       default_prec = false;
 340     }
 341 | "%code" braceless
 342     {
 343       /* Do not invoke muscle_percent_code_grow here since it invokes
 344          muscle_user_name_list_grow.  */
 345       muscle_code_grow ("percent_code()", $2, @2);
 346       code_scanner_last_string_free ();
 347     }
 348 | "%code" ID braceless
 349     {
 350       muscle_percent_code_grow ($2, @2, $3, @3);
 351       code_scanner_last_string_free ();
 352     }
 353 ;
 354
 355
 356 /*---------.
 357 | %union.  |
 358 `---------*/
 359
 360 %token PERCENT_UNION "%union";
 361
 362 union_name:
 363   /* Nothing. */ {}
 364 | ID             { muscle_code_grow ("union_name", $1, @1); }
 365 ;
 366
 367 grammar_declaration:
 368   "%union" union_name braceless
 369     {
 370       union_seen = true;
 371       muscle_code_grow ("stype", $3, @3);
 372       code_scanner_last_string_free ();
 373     }
 374 ;
 375
 376
 377
 378
 379 symbol_declaration:
 380   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 381     {
 382       current_class = unknown_sym;
 383       current_type = NULL;
 384     }
 385 | "%token" { current_class = token_sym; } symbol_defs.1
 386     {
 387       current_class = unknown_sym;
 388       current_type = NULL;
 389     }
 390 | "%type" TAG symbols.1
 391     {
 392       symbol_list *list;
 393       tag_seen = true;
 394       for (list = $3; list; list = list->next)
 395         symbol_type_set (list->content.sym, $2, @2);
 396       symbol_list_free ($3);
 397     }
 398 ;
 399
 400 precedence_declaration:
 401   precedence_declarator tag.opt symbols.prec
 402     {
 403       symbol_list *list;
 404       ++current_prec;
 405       for (list = $3; list; list = list->next)
 406         {
 407           symbol_type_set (list->content.sym, current_type, @2);
 408           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 409         }
 410       symbol_list_free ($3);
 411       current_type = NULL;
 412     }
 413 ;
 414
 415 precedence_declarator:
 416   "%left"       { $$ = left_assoc; }
 417 | "%right"      { $$ = right_assoc; }
 418 | "%nonassoc"   { $$ = non_assoc; }
 419 | "%precedence" { $$ = precedence_assoc; }
 420 ;
 421
 422 tag.opt:
 423   /* Nothing. */ { current_type = NULL; }
 424 | TAG            { current_type = $1; tag_seen = true; }
 425 ;
 426
 427 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 428 symbols.prec:
 429   symbol.prec
 430     { $$ = symbol_list_sym_new ($1, @1); }
 431 | symbols.prec symbol.prec
 432     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 433 ;
 434
 435 symbol.prec:
 436     symbol { $$ = $1; }
 437   | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 438   ;
 439
 440 /* One or more symbols to be %typed. */
 441 symbols.1:
 442   symbol
 443     { $$ = symbol_list_sym_new ($1, @1); }
 444 | symbols.1 symbol
 445     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 446 ;
 447
 448 generic_symlist:
 449   generic_symlist_item { $$ = $1; }
 450 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 451 ;
 452
 453 generic_symlist_item:
 454   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 455 | TAG       { $$ = symbol_list_type_new ($1, @1); }
 456 | "<*>"     { $$ = symbol_list_default_tagged_new (@1); }
 457 | "<>"      { $$ = symbol_list_default_tagless_new (@1); }
 458 ;
 459
 460 /* One token definition.  */
 461 symbol_def:
 462   TAG
 463      {
 464        current_type = $1;
 465        tag_seen = true;
 466      }
 467 | id
 468      {
 469        symbol_class_set ($1, current_class, @1, true);
 470        symbol_type_set ($1, current_type, @1);
 471      }
 472 | id INT
 473     {
 474       symbol_class_set ($1, current_class, @1, true);
 475       symbol_type_set ($1, current_type, @1);
 476       symbol_user_token_number_set ($1, $2, @2);
 477     }
 478 | id string_as_id
 479     {
 480       symbol_class_set ($1, current_class, @1, true);
 481       symbol_type_set ($1, current_type, @1);
 482       symbol_make_alias ($1, $2, @$);
 483     }
 484 | id INT string_as_id
 485     {
 486       symbol_class_set ($1, current_class, @1, true);
 487       symbol_type_set ($1, current_type, @1);
 488       symbol_user_token_number_set ($1, $2, @2);
 489       symbol_make_alias ($1, $3, @$);
 490     }
 491 ;
 492
 493 /* One or more symbol definitions. */
 494 symbol_defs.1:
 495   symbol_def
 496 | symbol_defs.1 symbol_def
 497 ;
 498
 499
 500         /*------------------------------------------.
 501         | The grammar section: between the two %%.  |
 502         `------------------------------------------*/
 503
 504 grammar:
 505   rules_or_grammar_declaration
 506 | grammar rules_or_grammar_declaration
 507 ;
 508
 509 /* As a Bison extension, one can use the grammar declarations in the
 510    body of the grammar.  */
 511 rules_or_grammar_declaration:
 512   rules
 513 | grammar_declaration ";"
 514 | error ";"
 515     {
 516       yyerrok;
 517     }
 518 ;
 519
 520 rules:
 521   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 522 ;
 523
 524 rhses.1:
 525   rhs                { grammar_current_rule_end (@1); }
 526 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 527 | rhses.1 ";"
 528 ;
 529
 530 rhs:
 531   /* Nothing.  */
 532     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 533 | rhs symbol
 534     { grammar_current_rule_symbol_append ($2, @2); }
 535 | rhs "{...}"
 536     { grammar_current_rule_action_append ($2, @2); }
 537 | rhs "%prec" symbol
 538     { grammar_current_rule_prec_set ($3, @3); }
 539 | rhs "%dprec" INT
 540     { grammar_current_rule_dprec_set ($3, @3); }
 541 | rhs "%merge" TAG
 542     { grammar_current_rule_merge_set ($3, @3); }
 543 ;
 544
 545
 546 /*---------------------------.
 547 | variable and content.opt.  |
 548 `---------------------------*/
 549
 550 variable:
 551   ID
 552 | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 553 ;
 554
 555 /* Some content or empty by default. */
 556 content.opt:
 557   /* Nothing. */
 558     {
 559       $$ = "";
 560     }
 561 | STRING
 562 ;
 563
 564
 565 /*------------.
 566 | braceless.  |
 567 `------------*/
 568
 569 braceless:
 570   "{...}"
 571     {
 572       code_props plain_code;
 573       $1[strlen ($1) - 1] = '\n';
 574       code_props_plain_init (&plain_code, $1+1, @1);
 575       code_props_translate_code (&plain_code);
 576       gram_scanner_last_string_free ();
 577       $$ = plain_code.code;
 578     }
 579 ;
 580
 581
 582 /*--------------.
 583 | Identifiers.  |
 584 `--------------*/
 585
 586 /* Identifiers are returned as uniqstr values by the scanner.
 587    Depending on their use, we may need to make them genuine symbols.  */
 588
 589 id:
 590   ID
 591     { $$ = symbol_from_uniqstr ($1, @1); }
 592 | CHAR
 593     {
 594       $$ = symbol_get (char_name ($1), @1);
 595       symbol_class_set ($$, token_sym, @1, false);
 596       symbol_user_token_number_set ($$, $1, @1);
 597     }
 598 ;
 599
 600 id_colon:
 601   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 602 ;
 603
 604
 605 symbol:
 606   id
 607 | string_as_id
 608 ;
 609
 610 /* A string used as an ID: quote it.  */
 611 string_as_id:
 612   STRING
 613     {
 614       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 615       symbol_class_set ($$, token_sym, @1, false);
 616     }
 617 ;
 618
 619 epilogue.opt:
 620   /* Nothing.  */
 621 | "%%" EPILOGUE
 622     {
 623       code_props plain_code;
 624       code_props_plain_init (&plain_code, $2, @2);
 625       code_props_translate_code (&plain_code);
 626       gram_scanner_last_string_free ();
 627       muscle_code_grow ("epilogue", plain_code.code, @2);
 628       code_scanner_last_string_free ();
 629     }
 630 ;
 631
 632 %%
 633
 634
 635 /* Return the location of the left-hand side of a rule whose
 636    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 637    the right-hand side, and return an empty location equal to the end
 638    boundary of RHS[0] if the right-hand side is empty.  */
 639
 640 static YYLTYPE
 641 lloc_default (YYLTYPE const *rhs, int n)
 642 {
 643   int i;
 644   YYLTYPE loc;
 645
 646   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 647      The bug is fixed in 7.4.2m, but play it safe for now.  */
 648   loc.start = rhs[n].end;
 649   loc.end = rhs[n].end;
 650
 651   /* Ignore empty nonterminals the start of the the right-hand side.
 652      Do not bother to ignore them at the end of the right-hand side,
 653      since empty nonterminals have the same end as their predecessors.  */
 654   for (i = 1; i <= n; i++)
 655     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 656       {
 657         loc.start = rhs[i].start;
 658         break;
 659       }
 660
 661   return loc;
 662 }
 663
 664
 665 /* Add a lex-param or a parse-param (depending on TYPE) with
 666    declaration DECL and location LOC.  */
 667
 668 static void
 669 add_param (char const *type, char *decl, location loc)
 670 {
 671   static char const alphanum[26 + 26 + 1 + 10] =
 672     "abcdefghijklmnopqrstuvwxyz"
 673     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 674     "_"
 675     "0123456789";
 676   char const *name_start = NULL;
 677   char *p;
 678
 679   /* Stop on last actual character.  */
 680   for (p = decl; p[1]; p++)
 681     if ((p == decl
 682          || ! memchr (alphanum, p[-1], sizeof alphanum))
 683         && memchr (alphanum, p[0], sizeof alphanum - 10))
 684       name_start = p;
 685
 686   /* Strip the surrounding '{' and '}', and any blanks just inside
 687      the braces.  */
 688   while (*--p == ' ' || *p == '\t')
 689     continue;
 690   p[1] = '\0';
 691   while (*++decl == ' ' || *decl == '\t')
 692     continue;
 693
 694   if (! name_start)
 695     complain_at (loc, _("missing identifier in parameter declaration"));
 696   else
 697     {
 698       char *name;
 699       size_t name_len;
 700
 701       for (name_len = 1;
 702            memchr (alphanum, name_start[name_len], sizeof alphanum);
 703            name_len++)
 704         continue;
 705
 706       name = xmalloc (name_len + 1);
 707       memcpy (name, name_start, name_len);
 708       name[name_len] = '\0';
 709       muscle_pair_list_grow (type, decl, name);
 710       free (name);
 711     }
 712
 713   gram_scanner_last_string_free ();
 714 }
 715
 716
 717 static void
 718 version_check (location const *loc, char const *version)
 719 {
 720   if (strverscmp (version, PACKAGE_VERSION) > 0)
 721     {
 722       complain_at (*loc, "require bison %s, but have %s",
 723                    version, PACKAGE_VERSION);
 724       exit (63);
 725     }
 726 }
 727
 728 static void
 729 gram_error (location const *loc, char const *msg)
 730 {
 731   complain_at (*loc, "%s", msg);
 732 }
 733
 734 char const *
 735 token_name (int type)
 736 {
 737   return yytname[YYTRANSLATE (type)];
 738 }
 739
 740 static char const *
 741 char_name (char c)
 742 {
 743   if (c == '\'')
 744     return "'\\''";
 745   else
 746     {
 747       char buf[4];
 748       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 749       return quotearg_style (escape_quoting_style, buf);
 750     }
 751 }