configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009
   4 # Free Software Foundation, Inc.
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # testsuite -C appears in 2.62.
  20 AC_PREREQ(2.62)
  21
  22 AC_INIT([GNU Bison],
  23         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  24         [bug-bison@gnu.org])
  25 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2008],
  26           [The copyright year for this package])
  27 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2008])
  28
  29 AC_CONFIG_AUX_DIR([build-aux])
  30 AC_CONFIG_MACRO_DIR([m4])
  31
  32 # We don't have a file m4/Makefile.am, so we need Automake 1.8 or later.
  33 # We want gnits strictness only when rolling a formal release so that we can,
  34 # for example, run make dist at other times without being required to add a
  35 # bogus NEWS entry.
  36 AM_INIT_AUTOMAKE([1.8 dist-bzip2]
  37                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [-], [gnu], [gnits]))
  38 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  39
  40 # Checks for the compiler.
  41 AC_PROG_CC_STDC
  42
  43 # Gnulib (early checks).
  44 gl_EARLY
  45
  46 AC_ARG_ENABLE(gcc-warnings,
  47 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  48 [case "${enableval}" in
  49    yes|no) ;;
  50    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  51  esac],
  52               [enableval=no])
  53 if test "${enableval}" = yes; then
  54   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  55   AC_SUBST([WERROR_CFLAGS])
  56   gl_WARN_ADD([-Wall])
  57   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  58   gl_WARN_ADD([-Wcast-align])
  59   gl_WARN_ADD([-Wcast-qual])
  60   gl_WARN_ADD([-Wformat])
  61   gl_WARN_ADD([-Wpointer-arith])
  62   gl_WARN_ADD([-Wwrite-strings])
  63   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  64   # The following warnings are not suitable for C++.
  65   gl_WARN_ADD([-Wbad-function-cast])
  66   gl_WARN_ADD([-Wmissing-declarations])
  67   gl_WARN_ADD([-Wmissing-prototypes])
  68   gl_WARN_ADD([-Wshadow])
  69   gl_WARN_ADD([-Wstrict-prototypes])
  70   AC_SUBST([WARN_CFLAGS])
  71   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  72 fi
  73
  74 BISON_TEST_FOR_WORKING_C_COMPILER
  75
  76 AC_ARG_ENABLE([yacc],
  77   [AC_HELP_STRING([--disable-yacc],
  78      [do not build a yacc command or an -ly library])],
  79   , [enable_yacc=yes])
  80 case $enable_yacc in
  81 yes)
  82   YACC_SCRIPT=src/yacc
  83   YACC_LIBRARY=lib/liby.a;;
  84 *)
  85   YACC_SCRIPT=
  86   YACC_LIBRARY=;;
  87 esac
  88 AC_SUBST([YACC_SCRIPT])
  89 AC_SUBST([YACC_LIBRARY])
  90
  91 # Checks for programs.
  92 AC_PROG_LEX
  93 AC_PROG_YACC
  94 AC_PROG_RANLIB
  95 AC_PROG_GNU_M4
  96 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  97 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
  98 supports -g, otherwise to "".])
  99 AM_MISSING_PROG([HELP2MAN], [help2man])
 100 AC_PATH_PROG([XSLTPROC], [xsltproc])
 101 AC_SUBST([XSLTPROC])
 102
 103 # Checks for header files.
 104 AC_CHECK_HEADERS_ONCE([locale.h])
 105
 106 # Checks for compiler characteristics.
 107 AC_C_INLINE
 108
 109 # Gnulib (later checks).  Putting them here rather than right after
 110 # gl_EARLY avoids some redundant checks.
 111 gl_INIT
 112
 113 # Checks for library functions.
 114 AC_CHECK_FUNCS_ONCE([setlocale])
 115 AM_WITH_DMALLOC
 116 BISON_PREREQ_SUBPIPE
 117 BISON_PREREQ_TIMEVAR
 118
 119 # Gettext.
 120 # We use gnulib, which is only guaranteed to work properly with the
 121 # latest Gettext.
 122 AM_GNU_GETTEXT([external], [need-ngettext])
 123 AM_GNU_GETTEXT_VERSION([0.17])
 124 BISON_I18N
 125
 126 # Internationalized parsers.
 127 AC_CONFIG_FILES([runtime-po/Makefile.in])
 128 # Autoconf macros for packages using internationalized parsers.
 129 aclocaldir='${datadir}/aclocal'
 130 AC_SUBST([aclocaldir])
 131
 132 # Create the benchmark script.
 133 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 134
 135 # Initialize the test suite.
 136 AC_CONFIG_TESTDIR(tests)
 137 AC_CONFIG_FILES([tests/atlocal])
 138 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 139 AC_CHECK_PROGS([VALGRIND], [valgrind])
 140 AC_PROG_CXX
 141 BISON_TEST_FOR_WORKING_CXX_COMPILER
 142 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 143 # Needed by tests/atlocal.in.
 144 AC_SUBST([GCC])
 145 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 146 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 147
 148 gt_JAVACOMP([1.3], [1.4])
 149 gt_JAVAEXEC
 150
 151 # We use gnulib, but from lib/local.mk instead of lib/Makefile.am.
 152 # So prefix paths with lib/.  See also etc/prefix-gnulib-mk.
 153 gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, , lib/,g'`
 154 for ac_var in ALLOCA_H ERRNO_H FCNTL_H GETOPT_H INTTYPES_H \
 155               STDBOOL_H STDINT_H SYS_WAIT_H WCHAR_H WCTYPE_H
 156 do
 157   eval "test 'x$ac_var' = x || $ac_var=lib/\$$ac_var"
 158 done
 159 AC_CONFIG_FILES([Makefile
 160                  po/Makefile.in
 161                  examples/calc++/Makefile
 162                  doc/yacc.1])
 163 AC_OUTPUT