tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 ## ------------- ##
  33 ## Basic tests.  ##
  34 ## ------------- ##
  35
  36 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  37 # ------------------------------------------
  38 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  39 # taken in "slurp" mode, i.e., one can match end-of-lines.
  40 m4_define([AT_MATCHES_CHECK],
  41 [AT_CHECK([$PERL -0777 -ne '
  42 my $count = 0;
  43 s{$2}{ ++$count; "" }gem;
  44 printf "$count\n";' $1], [0], [$3
  45 ])])
  46
  47
  48 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  49 # ------------------------------------------------
  50 # Don't interfere with caller's files.
  51 m4_divert_text([PREPARE_TESTS],
  52 [at_save_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       as_fn_error 1 "fatal error: back-up on top of a back-up"
  58     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  59   done
  60 }
  61
  62 at_restore_special_files ()
  63 {
  64   for at_save_file in stderr experr expout
  65   do
  66     test ! -f at-bison-check-$at_save_file.bak ||
  67       mv at-bison-check-$at_save_file.bak $at_save_file
  68   done
  69 }
  70 ])
  71
  72 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  73 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  74
  75
  76
  77 ## ------------------------------- ##
  78 ## Macros decoding Bison options.  ##
  79 ## ------------------------------- ##
  80
  81 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  82 # ----------------------------------------------------------------
  83 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  84 m4_define([AT_LOC_PUSHDEF],
  85 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  86 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  87 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  88 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  89
  90 # AT_LOC_POPDEF
  91 # -------------
  92 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  93 m4_define([AT_LOC_POPDEF],
  94 [m4_popdef([AT_LOC_FIRST_LINE])
  95 m4_popdef([AT_LOC_FIRST_COLUMN])
  96 m4_popdef([AT_LOC_LAST_LINE])
  97 m4_popdef([AT_LOC_LAST_COLUMN])])
  98
  99
 100
 101 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 102 # -----------------------------------------
 103 m4_define([AT_BISON_OPTION_PUSHDEFS],
 104 [m4_divert_text([KILL],
 105                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 106
 107
 108 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 109 # --------------------------------------------------
 110 # This macro works around the impossibility to define macros
 111 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 112 # This sucks hard, GNU M4 should really provide M5 like $$1.
 113 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 114 [m4_if([$1$2], $[1]$[2], [],
 115        [m4_fatal([$0: Invalid arguments: $@])])dnl
 116 m4_pushdef([AT_DEFINES_IF],
 117 [m4_bmatch([$3], [%defines], [$1], [$2])])
 118 m4_pushdef([AT_SKEL_CC_IF],
 119 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 120 m4_pushdef([AT_SKEL_JAVA_IF],
 121 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 122 # The target language: "c", "c++", or "java".
 123 m4_pushdef([AT_LANG],
 124 [AT_SKEL_JAVA_IF([java],
 125                  [AT_SKEL_CC_IF([c++],
 126                                 [c])])])
 127 m4_pushdef([AT_GLR_IF],
 128 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 129 m4_pushdef([AT_LALR1_CC_IF],
 130 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 131 m4_pushdef([AT_GLR_CC_IF],
 132 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 133 # Using yacc.c?
 134 m4_pushdef([AT_YACC_IF],
 135 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 136 m4_pushdef([AT_LEXPARAM_IF],
 137 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 138 m4_pushdef([AT_LOCATION_IF],
 139 [m4_bmatch([$3], [%locations], [$1], [$2])])
 140 m4_pushdef([AT_LOCATION_TYPE_IF],
 141 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 142 m4_pushdef([AT_PARAM_IF],
 143 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 144 # Comma-terminated list of formals parse-parameters.
 145 # E.g., %parse-param { int x } {int y} -> "int x, int y, ".
 146 m4_pushdef([AT_PARSE_PARAMS])
 147 m4_bpatsubst([$3], [%parse-param { *\([^{}]*[^{} ]\) *}],
 148              [m4_append([AT_PARSE_PARAMS], [\1, ])])
 149
 150 m4_pushdef([AT_PURE_IF],
 151 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 152            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 153            [$2])])
 154 m4_pushdef([AT_PURE_AND_LOC_IF],
 155 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 156 m4_pushdef([AT_GLR_OR_PARAM_IF],
 157 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 158 m4_pushdef([AT_NAME_PREFIX],
 159 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 160            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 161            [yy])])
 162 m4_pushdef([AT_API_prefix],
 163 [m4_bmatch([$3], [%define api\.prefix ".*"],
 164            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 165            [yy])])
 166 m4_pushdef([AT_API_PREFIX],
 167 [m4_toupper(AT_API_prefix)])
 168 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 169 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 170 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 171                     [$2])])
 172 # yyerror always sees the locations (when activated), except if
 173 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 174 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 175 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 176                                         [$1])],
 177                             [$1])],
 178                 [$2])])
 179
 180 # The interface is pure: either because %define api.pure, or because we
 181 # are using the C++ parsers.
 182 m4_pushdef([AT_PURE_LEX_IF],
 183 [AT_PURE_IF([$1],
 184             [AT_SKEL_CC_IF([$1], [$2])])])
 185
 186 m4_pushdef([AT_YYSTYPE],
 187 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 188                [AT_API_PREFIX[STYPE]])])
 189 m4_pushdef([AT_YYLTYPE],
 190 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 191                [AT_API_PREFIX[LTYPE]])])
 192
 193
 194 AT_PURE_LEX_IF(
 195 [m4_pushdef([AT_LOC], [(*llocp)])
 196  m4_pushdef([AT_VAL], [(*lvalp)])
 197  m4_pushdef([AT_YYLEX_FORMALS],
 198             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 199  m4_pushdef([AT_YYLEX_ARGS],
 200             [lvalp[]AT_LOCATION_IF([, llocp])])
 201  m4_pushdef([AT_USE_LEX_ARGS],
 202             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 203  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 204             [AT_YYLEX_FORMALS, ])
 205  m4_pushdef([AT_YYLEX_PRE_ARGS],
 206             [AT_YYLEX_ARGS, ])
 207 ],
 208 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 209  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 210  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 211  m4_pushdef([AT_YYLEX_ARGS],        [])
 212  m4_pushdef([AT_USE_LEX_ARGS],    [])
 213  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 214  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 215 ])
 216
 217 # Handle the different types of location components.
 218
 219 AT_SKEL_CC_IF(
 220   [AT_LOCATION_TYPE_IF(
 221     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 222     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 223   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 224
 225 ])# _AT_BISON_OPTION_PUSHDEFS
 226
 227
 228 # AT_BISON_OPTION_POPDEFS
 229 # -----------------------
 230 m4_define([AT_BISON_OPTION_POPDEFS],
 231 [m4_divert_text([KILL],
 232 [m4_popdef([AT_YYLEX_PRE_ARGS])
 233 m4_popdef([AT_YYLEX_PRE_FORMALS])
 234 m4_popdef([AT_USE_LEX_ARGS])
 235 m4_popdef([AT_YYLEX_ARGS])
 236 m4_popdef([AT_YYLEX_FORMALS])
 237 m4_popdef([AT_YYLTYPE])
 238 m4_popdef([AT_YYSTYPE])
 239 m4_popdef([AT_VAL])
 240 m4_popdef([AT_LOC])
 241 m4_popdef([AT_PURE_LEX_IF])
 242 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 243 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 244 m4_popdef([AT_API_PREFIX])
 245 m4_popdef([AT_API_prefix])
 246 m4_popdef([AT_NAME_PREFIX])
 247 m4_popdef([AT_GLR_OR_PARAM_IF])
 248 m4_popdef([AT_PURE_AND_LOC_IF])
 249 m4_popdef([AT_LOCATION_TYPE_IF])
 250 m4_popdef([AT_LOCATION_IF])
 251 m4_popdef([AT_PARSE_PARAMS])
 252 m4_popdef([AT_PARAM_IF])
 253 m4_popdef([AT_LEXPARAM_IF])
 254 m4_popdef([AT_YACC_IF])
 255 m4_popdef([AT_GLR_IF])
 256 m4_popdef([AT_SKEL_CC_IF])
 257 m4_popdef([AT_LANG])
 258 m4_popdef([AT_SKEL_JAVA_IF])
 259 m4_popdef([AT_GLR_CC_IF])
 260 m4_popdef([AT_LALR1_CC_IF])
 261 m4_popdef([AT_DEFINES_IF])
 262 AT_LOC_POPDEF])dnl
 263 ])# AT_BISON_OPTION_POPDEFS
 264
 265
 266
 267 ## -------------------------- ##
 268 ## Generating Grammar Files.  ##
 269 ## -------------------------- ##
 270
 271 # AT_DATA_SOURCE_PROLOGUE
 272 # ------------------------
 273 # The prologue that should be included in any source code that is
 274 # meant to be compiled.
 275 m4_define([AT_DATA_SOURCE_PROLOGUE],
 276 [[#include <config.h>
 277 /* We don't need perfect functions for these tests. */
 278 #undef malloc
 279 #undef memcmp
 280 #undef realloc
 281 ]])
 282
 283 # AT_DATA_GRAMMAR_PROLOGUE
 284 # ------------------------
 285 # The prologue that should be included in any grammar which parser is
 286 # meant to be compiled.
 287 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 288 [[%code top {
 289 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 290 [}
 291 ]])
 292
 293 # AT_DATA_SOURCE(NAME, CONTENT)
 294 # -----------------------------
 295 # Generate the file NAME, which CONTENT is preceded by
 296 # AT_DATA_SOURCE_PROLOGUE.
 297 m4_define([AT_DATA_SOURCE],
 298 [AT_DATA([$1],
 299 [AT_DATA_SOURCE_PROLOGUE
 300 $2])
 301 ])
 302
 303 # AT_DATA_GRAMMAR(NAME, CONTENT)
 304 # ------------------------------
 305 # Generate the file NAME, which CONTENT is preceded by
 306 # AT_DATA_GRAMMAR_PROLOGUE.
 307 m4_define([AT_DATA_GRAMMAR],
 308 [AT_DATA([$1],
 309 [AT_DATA_GRAMMAR_PROLOGUE
 310 $2])
 311 ])
 312
 313 # AT_YYLEX_PROTOTYPE
 314 # AT_YYLEX_DECLARE_EXTERN
 315 # AT_YYLEX_DECLARE
 316 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 317 # ----------------------------------
 318 # INPUT can be empty, or in double quotes, or a list (in braces).
 319 # ACTION may compute yylval for instance, using "res" as token type,
 320 # and "toknum" as the number of calls to yylex (starting at 0).
 321 m4_define([AT_YYLEX_PROTOTYPE],
 322 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 323 ])
 324
 325 m4_define([AT_YYLEX_DECLARE_EXTERN],
 326 [AT_YYLEX_PROTOTYPE;dnl
 327 ])
 328
 329 m4_define([AT_YYLEX_DECLARE],
 330 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 331 ])
 332
 333 m4_define([AT_YYLEX_DEFINE],
 334 [[#include <assert.h>
 335 static
 336 ]AT_YYLEX_PROTOTYPE[
 337 {
 338   ]m4_bmatch([$1], [^\(".*"\)?$],
 339              [[static char const input[] = ]m4_default([$1], [""])],
 340              [[static int const input[] = ]$1])[;
 341   static size_t toknum = 0;
 342   int res;
 343   ]AT_USE_LEX_ARGS[;
 344   assert (toknum < sizeof input / sizeof input[0]);
 345   res = input[toknum++];
 346   ]$2[;]AT_LOCATION_IF([[
 347   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 348   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 349   return res;
 350 }]dnl
 351 ])
 352
 353 # AT_YYERROR_PROTOTYPE
 354 # AT_YYERROR_DECLARE_EXTERN
 355 # AT_YYERROR_DECLARE
 356 # AT_YYERROR_DEFINE
 357 # -------------------------
 358 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 359 m4_define([AT_YYERROR_FORMALS],
 360 [m4_case(AT_LANG,
 361 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE *llocp, ])AT_PARSE_PARAMS [const char *msg]])[]dnl
 362 ])
 363
 364 m4_define([AT_YYERROR_PROTOTYPE],
 365 [m4_case(AT_LANG,
 366 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 367 ])
 368
 369 m4_define([AT_YYERROR_DECLARE_EXTERN],
 370 [m4_case(AT_LANG,
 371 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 372 ])
 373
 374 m4_define([AT_YYERROR_DECLARE],
 375 [m4_case(AT_LANG,
 376 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 377 ])
 378
 379 m4_define([AT_YYERROR_DEFINE],
 380 [m4_case(AT_LANG,
 381 [c], [[#include <stdio.h>
 382 /* A C error reporting function.  */
 383 static
 384 ]AT_YYERROR_PROTOTYPE[
 385 {]m4_bpatsubst(m4_defn([AT_PARSE_PARAMS]),
 386               [[^,]+[^A-Za-z_0-9]\([A-Za-z_][A-Za-z_0-9]*\), *], [
 387   YYUSE(\1);])dnl
 388 AT_YYERROR_SEES_LOC_IF([[
 389   YY_LOCATION_PRINT (stderr, ]AT_LOC[);
 390   fprintf (stderr, ": ");]])[
 391   fprintf (stderr, "%s\n", msg);
 392 }]],
 393 [c++], [[/* A C++ error reporting function.  */
 394 void
 395 ]AT_NAME_PREFIX[::parser::error (const location_type& l, const std::string& m)
 396 {
 397   (void) l;
 398   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 399 }]],
 400 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 401   {
 402     if (l == null)
 403       System.err.println (s);
 404     else
 405       System.err.println (l + ": " + s);
 406   }
 407 ]], [[
 408   public void yyerror (String s)
 409   {
 410     System.err.println (s);
 411   }]])],
 412 [m4_fatal([$0: invalid language: ]AT_LANG)])dnl
 413 ])
 414
 415
 416 ## --------------- ##
 417 ## Running Bison.  ##
 418 ## --------------- ##
 419
 420 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 421 # -------------------------------------------------
 422 # High-level routine that may call bison several times, under different
 423 # conditions.
 424 #
 425 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 426 # shell constructs (such as redirection or pipes) that would prevent
 427 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 428 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 429 #
 430 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 431 # Bison in the test suite.  For now it ensures that:
 432 #
 433 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 434 #      a non-zero exit status since Bison doesn't always try to free all memory
 435 #      in that case.
 436 #
 437 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 438 #      --graph and --report=all output for every working grammar.
 439 #
 440 #   3. If stderr contains a warning, -Werror and --warnings=error
 441 #      convert the warning to an error.
 442 #
 443 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 444 m4_define([AT_BISON_CHECK],
 445 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 446 AT_BISON_CHECK_NO_XML($@)])
 447
 448 m4_define([AT_BISON_WERROR_MSG],
 449           [[bison: warnings being treated as errors]])
 450
 451
 452 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 453 # --------------------------------------------------
 454 # Low-level macro to run bison once.
 455 m4_define([AT_BISON_CHECK_],
 456 [AT_CHECK(AT_QUELL_VALGRIND[[ bison ]]$@)])
 457
 458
 459 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 460 # ----------------------------------------------------------
 461 # Check that warnings (if some are expected) are correctly
 462 # turned into errors with -Werror, etc.
 463 m4_define([AT_BISON_CHECK_WARNINGS],
 464 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 465       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 466
 467 m4_define([AT_BISON_CHECK_WARNINGS_],
 468 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 469 # added after the grammar file name, so skip these checks in that
 470 # case.
 471 #
 472 # Don't just check if $POSIXLY_CORRECT is set, as Bash, when launched
 473 # as /bin/sh, sets the shell variable POSIXLY_CORRECT to y, but not
 474 # the environment variable.
 475 if env | grep '^POSIXLY_CORRECT=' >/dev/null; then :; else
 476   ]AT_SAVE_SPECIAL_FILES[
 477
 478   # To avoid expanding it repeatedly, store specified stdout.
 479   ]AT_DATA([expout], [$3])[
 480
 481   # Run with -Werror.
 482   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 483
 484   # Build expected stderr up to and including the "warnings being
 485   # treated as errors" message.
 486   ]AT_DATA([[at-bison-check-warnings]], [$4])[
 487   at_bison_check_first=`sed -n \
 488     '/: warning: /{=;q;}' at-bison-check-warnings`
 489   : ${at_bison_check_first:=1}
 490   at_bison_check_first_tmp=`sed -n \
 491     '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 492   : ${at_bison_check_first_tmp:=1}
 493   if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 494     at_bison_check_first=$at_bison_check_first_tmp
 495   fi
 496   if test $at_bison_check_first -gt 1; then
 497     sed -n "1,`expr $at_bison_check_first - 1`"p \
 498       at-bison-check-warnings > experr
 499   fi
 500   echo ']AT_BISON_WERROR_MSG[' >> experr
 501
 502   # Finish building expected stderr and check.  Unlike warnings,
 503   # complaints cause bison to exit early.  Thus, with -Werror, bison
 504   # does not necessarily report all warnings that it does without
 505   # -Werror, but it at least reports one.
 506   at_bison_check_last=`sed -n '$=' stderr`
 507   : ${at_bison_check_last:=1}
 508   at_bison_check_last=`expr $at_bison_check_last - 1`
 509   sed -n "$at_bison_check_first,$at_bison_check_last"p \
 510     at-bison-check-warnings >> experr
 511   ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 512               stderr 1>&2]], [[0]], [[]], [experr])[
 513
 514   # Now check --warnings=error.
 515   cp stderr experr
 516   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 517
 518   # Now check -Wnone and --warnings=none by making sure that
 519   # -Werror doesn't change the exit status when -Wnone or
 520   # --warnings=none is specified.
 521   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 522   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 523
 524   ]AT_RESTORE_SPECIAL_FILES[
 525 fi]dnl
 526 ])
 527
 528 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 529 # --------------------------------------------------------
 530 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 531 # when a tortured grammar's XML is known to be too large for xsltproc to
 532 # handle.
 533 m4_define([AT_BISON_CHECK_NO_XML],
 534 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison ]]$@)
 535 AT_BISON_CHECK_WARNINGS($@)])
 536
 537 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 538 # -----------------------------------------------------
 539 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 540 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 541 # have a non-zero exit status.
 542 m4_define([AT_BISON_CHECK_XML],
 543 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 544   AT_SAVE_SPECIAL_FILES
 545   [mkdir xml-tests]
 546   m4_pushdef([AT_BISON_ARGS],
 547              [m4_bpatsubsts([[$1]],
 548                             [--report(-file)?=[^][ ]*], [],
 549                             [--graph=[^][ ]*], [],
 550                             [--xml=[^][ ]*], [])])dnl
 551   # Don't combine these Bison invocations since we want to be sure that
 552   # --report=all isn't required to get the full XML file.
 553   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 554                   --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 555                   [[0]], [ignore], [ignore])
 556   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 557                  [[0]], [ignore], [ignore])
 558   m4_popdef([AT_BISON_ARGS])dnl
 559   [cp xml-tests/test.output expout]
 560   AT_CHECK([[$XSLTPROC \
 561              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 562              xml-tests/test.xml]], [[0]], [expout])
 563   [cp xml-tests/test.dot expout]
 564   AT_CHECK([[$XSLTPROC \
 565              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 566              xml-tests/test.xml]], [[0]], [expout])
 567   [rm -rf xml-tests expout]
 568   AT_RESTORE_SPECIAL_FILES
 569 [fi]])
 570
 571 # AT_QUELL_VALGRIND
 572 # -----------------
 573 # Put this before a Bison invocation to keep Valgrind from complaining about
 574 # reachable memory.
 575 #
 576 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 577 # The triple quoting below will cause test cases to fail if you do.  If you do
 578 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 579 # will then fail to shell-escape its contents when attempting to print them.
 580 # The testsuite verbose output, at least, will be incorrect, but nothing may
 581 # fail to make sure you notice.
 582 m4_define([AT_QUELL_VALGRIND],
 583 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 584
 585
 586
 587 ## ------------------------ ##
 588 ## Compiling C, C++ Files.  ##
 589 ## ------------------------ ##
 590
 591
 592 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 593 # ----------------------------------------
 594 # Compile SOURCES into OUTPUT.
 595 #
 596 # If OUTPUT does not contain '.', assume that we are linking too,
 597 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 598 # with trailing .o removed, and ".c" appended.
 599 m4_define([AT_COMPILE],
 600 [AT_CHECK(m4_join([ ],
 601                   [$CC $CFLAGS $CPPFLAGS],
 602                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 603                   [-o $1],
 604                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 605                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 606            0, [ignore], [ignore])])
 607
 608 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 609 # ---------------------------------------------
 610 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 611 # ignore the test.
 612 #
 613 # If OUTPUT does not contain '.', assume that we are linking too,
 614 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 615 # with trailing .o removed, and ".cc" appended.
 616 m4_define([AT_COMPILE_CXX],
 617 [AT_KEYWORDS(c++)
 618 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 619 AT_CHECK(m4_join([ ],
 620                  [$CXX $CXXFLAGS $CPPFLAGS],
 621                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 622                  [-o $1],
 623                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 624                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 625          0, [ignore], [ignore])])
 626
 627 # AT_JAVA_COMPILE(SOURCES)
 628 # ------------------------
 629 # Compile SOURCES into Java class files.  Skip the test if java or javac
 630 # is not installed.
 631 m4_define([AT_JAVA_COMPILE],
 632 [AT_KEYWORDS(java)
 633 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 634 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 635 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 636          [[0]], [ignore], [ignore])])
 637
 638 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 639 # --------------------------------------------
 640 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 641 #
 642 # If OUTPUT does not contain '.', assume that we are linking too,
 643 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 644 # with trailing .o removed, and ".c"/".cc" appended.
 645 m4_define([AT_LANG_COMPILE],
 646 [m4_case(AT_LANG,
 647 [c],    [AT_COMPILE([$1], [$2])],
 648 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 649 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 650         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 651 ])
 652
 653 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 654 # -------------------------------------------
 655 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 656 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 657 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 658 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 659 # AT_SKEL_JAVA_IF.
 660 m4_define([AT_FULL_COMPILE],
 661 [m4_case(AT_LANG,
 662 [java],
 663   [AT_BISON_CHECK([-o $1.java $1.y])
 664    AT_LANG_COMPILE([$1],
 665                    m4_join([ ],
 666                            [$1.java],
 667                            m4_ifval($2, [[$1-$2.java]]),
 668                            m4_ifval($3, [[$1-$3.java]])))],
 669 [c++],
 670   [AT_BISON_CHECK([-o $1.cc $1.y])
 671    AT_LANG_COMPILE([$1],
 672                    m4_join([ ],
 673                            [$1.cc],
 674                            m4_ifval($2, [[$1-$2.cc]]),
 675                            m4_ifval($3, [[$1-$3.cc]])))],
 676 [c],
 677   [AT_BISON_CHECK([-o $1.c $1.y])
 678    AT_LANG_COMPILE([$1],
 679                    m4_join([ ],
 680                            [$1.c],
 681                            m4_ifval($2, [[$1-$2.c]]),
 682                            m4_ifval($3, [[$1-$3.c]])))])
 683 ])
 684
 685
 686
 687 # AT_SKIP_IF_CANNOT_LINK_C_AND_CXX
 688 # --------------------------------
 689 # Check that we can link together C and C++ objects.
 690 m4_define([AT_SKIP_IF_CANNOT_LINK_C_AND_CXX],
 691 [AT_DATA([c-and-cxx.h],
 692 [[#ifdef __cplusplus
 693 extern "C"
 694 {
 695 #endif
 696   int fortytwo (void);
 697 #ifdef __cplusplus
 698 }
 699 #endif
 700 ]])
 701 AT_DATA([c-only.c],
 702 [[#include "c-and-cxx.h"
 703 int
 704 main (void)
 705 {
 706   return fortytwo () == 42 ? 0 : 1;
 707 }
 708 ]])
 709 AT_DATA([cxx-only.cc],
 710 [[#include "c-and-cxx.h"
 711 int fortytwo ()
 712 {
 713   return 42;
 714 }
 715 ]])
 716 AT_COMPILE([c-only.o], [c-only.c])
 717 AT_COMPILE_CXX([cxx-only.o], [cxx-only.cc])
 718 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS $LDFLAGS c-only.o cxx-only.o -o c-and-cxx ||
 719           exit 77], [ignore], [ignore])
 720 AT_CHECK([./c-and-cxx])
 721 ])
 722
 723
 724 ## ---------------------------- ##
 725 ## Running a generated parser.  ##
 726 ## ---------------------------- ##
 727
 728
 729 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 730 # ------------------------------------------------------------
 731 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 732 #
 733 # Get rid of spurious messages when compiled with --coverage:
 734 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 735 m4_define([AT_PARSER_CHECK],
 736 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 737 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 738          [0], [], [$4])
 739 ])
 740
 741
 742 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 743 # -----------------------------------------------------------------
 744 m4_define([AT_JAVA_PARSER_CHECK],
 745 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 746
 747
 748 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 749 #                          DECLS, GRAMMAR, INPUT,
 750 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 751 #                          [OTHER-CHECKS],
 752 #                          [PARSER-EXIT-VALUE],
 753 #                          [PARSER-STDOUT], [PARSER-STDERR])
 754 # -------------------------------------------------------------
 755 # Using TITLE as the test group title, check the generated parser tables
 756 # and parser for a specified grammar file under a condition labeled by
 757 # COND-VALUE.
 758 #
 759 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 760 # recognized attribute is described below where it is relevant.
 761 #
 762 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 763 # the grammar file.  Insert basic yyerror, yylex, and main function
 764 # definitions as well.  Hardcode yylex to return the (possibly empty)
 765 # comma-delimited series of tokens in INPUT followed by token 0.
 766 #
 767 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 768 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 769 # On the bison command-line, specify `--report=all --defines'.  Check
 770 # that Bison exits with value 0, has no stdout, and has stderr
 771 # BISON-STDERR.
 772 #
 773 # If TEST-SPEC contains the attribute `last-state', check that the value
 774 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 775 # the grammar; in other words, check the number of states (minus one).
 776 # Otherwise, check that everything in the `.output' file starting with
 777 # the definition of state 0 is the same as the entire value of
 778 # TABLES-OR-LAST-STATE.
 779 #
 780 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 781 # `.output' file, which is named `input.output', and/or grammar file,
 782 # which is named `input.y'.
 783 #
 784 # Finally, compile the generated parser and then run it using
 785 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 786 # PARSER-STDERR as the 2nd-4th arguments.
 787 #
 788 # As a precondition, you must properly double-quote all arguments that
 789 # are to be interpreted as strings.
 790 #
 791 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 792 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 793 # first argument.  This is useful, for example, when wrapping multiple
 794 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 795 # condition, in another macro.
 796 #
 797 # For example:
 798 #
 799 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 800 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 801 #   # ---------------------------------------------------------------------
 802 #   m4_define([AT_TEST_SYNTAX_ERROR],
 803 #   [
 804 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 805 #                              [[last-state]],
 806 #                              [[%error-verbose ]$2], [$3], [$4],
 807 #                              [[]], [$5], [], [$6], [$7], [$8])
 808 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 809 #                              [[last-state]],
 810 #                              [$2], [$3], [$4],
 811 #                              [[]], [$5], [], [$6], [$7], [$8])
 812 #   ])
 813 #
 814 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 815 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 816 #                        [[3]],
 817 #                        [[1]], [[]],
 818 #                        [AT_COND_CASE([[no verbose]],
 819 #                                      [[syntax error
 820 #   ]],
 821 #                                      [[syntax error, unexpected 'b', expecting $end
 822 #   ]])])
 823 m4_define([AT_TEST_TABLES_AND_PARSE],
 824 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 825
 826 AT_SETUP([$1])
 827 AT_BISON_OPTION_PUSHDEFS([$4])
 828 AT_DATA_GRAMMAR([[input.y]],
 829 [[%code {
 830   #include <stdio.h>
 831   ]AT_YYERROR_DECLARE[
 832   ]AT_YYLEX_DECLARE[
 833 }
 834
 835 ]$4[
 836
 837 %%
 838
 839 ]$5[
 840
 841 %%
 842 ]AT_YYERROR_DEFINE[
 843 static int
 844 yylex (void)
 845 {
 846   static int const input[] = {
 847     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 848   };
 849   static int const *inputp = input;
 850   return *inputp++;
 851 }
 852
 853 int
 854 main (void)
 855 {
 856   return yyparse ();
 857 }
 858 ]])
 859
 860 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 861 # expanding macros, so it corrupts some special characters in the
 862 # macros.  To avoid this, expand now and pass it the result with proper
 863 # string quotation.  Assume args 7 through 12 expand to properly quoted
 864 # strings.
 865
 866 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 867       [AT_BISON_CHECK],
 868       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 869                                [0], [], m4_dquote($7))
 870
 871 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 872       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 873                 m4_dquote($8))],
 874       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 875                 m4_dquote($8)[[
 876 ]])])
 877
 878 $9
 879
 880 # Canonical LR generates very large tables, resulting in very long
 881 # files with #line directives that may overflow what the standards
 882 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 883 # will issue an error.
 884 #
 885 # There is no "" around `wc` since some indent the result.
 886 m4_bmatch([$4], [%define lr.type canonical-lr],
 887 [if test 32767 -lt `wc -l < input.c`; then
 888   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 889   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 890 fi])
 891 AT_COMPILE([[input]])
 892
 893 AT_PARSER_CHECK([[./input]],
 894                 m4_ifval([$10], [m4_dquote($10)]),
 895                 m4_ifval([$11], [m4_dquote($11)]),
 896                 m4_ifval([$12], [m4_dquote($12)]))
 897
 898 AT_BISON_OPTION_POPDEFS
 899 AT_CLEANUP
 900
 901 m4_popdef([AT_COND_CASE])])
 902
 903
 904
 905 ## ----------------------- ##
 906 ## Launch the test suite.  ##
 907 ## ----------------------- ##
 908
 909 AT_INIT
 910
 911 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 912 # options are processed, so we don't know the value of CXX and
 913 # CXXFLAGS yet.
 914 #
 915 # Note that it also means that command line values for CXX and
 916 # CXXFLAGS will not be propagated to CC and CFLAGS.
 917 AT_ARG_OPTION([compile-c-with-cxx],
 918               [compile C parsers with the C++ compiler])
 919
 920 AT_COLOR_TESTS
 921
 922 AT_TESTED([bison])