tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2013 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 # AT_SETUP_STRIP(TITLE)
  33 # ---------------------
  34 # Abbreviate the TITLE to be passed to AT_SETUP.
  35 m4_define([AT_SETUP_STRIP],
  36 [m4_bpatsubsts([$1],
  37       [%\(language\|skeleton\) "?\([^\" ]*\)"?],
  38         [\2],
  39       [%define "?\([-A-Za-z0-9_.]+\)"? \("\([^\" ]+\)"\|\([-A-Za-z0-9_.]+\)\)],
  40         [\1=\3\4],
  41       [%define "?\([-A-Za-z0-9_.]+\)"?],
  42         [\1])dnl
  43 ])
  44
  45
  46 ## ------------- ##
  47 ## Basic tests.  ##
  48 ## ------------- ##
  49
  50 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  51 # ------------------------------------------
  52 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  53 # taken in "slurp" mode, i.e., one can match end-of-lines.
  54 m4_define([AT_MATCHES_CHECK],
  55 [AT_CHECK([$PERL -0777 -ne '
  56 my $count = 0;
  57 s{$2}{ ++$count; "" }gem;
  58 printf "$count\n";' $1], [0], [$3
  59 ])])
  60
  61
  62 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  63 # ------------------------------------------------
  64 # Don't interfere with caller's files.
  65 m4_divert_text([PREPARE_TESTS],
  66 [at_save_special_files ()
  67 {
  68   for at_save_file in stderr experr expout
  69   do
  70     test ! -f at-bison-check-$at_save_file.bak ||
  71       as_fn_error 1 "fatal error: back-up on top of a back-up"
  72     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  73   done
  74 }
  75
  76 at_restore_special_files ()
  77 {
  78   for at_save_file in stderr experr expout
  79   do
  80     test ! -f at-bison-check-$at_save_file.bak ||
  81       mv at-bison-check-$at_save_file.bak $at_save_file
  82   done
  83 }
  84 ])
  85
  86 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  87 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  88
  89
  90
  91 ## ------------------------------- ##
  92 ## Macros decoding Bison options.  ##
  93 ## ------------------------------- ##
  94
  95 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  96 # ----------------------------------------------------------------
  97 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  98 m4_define([AT_LOC_PUSHDEF],
  99 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
 100 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
 101 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
 102 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
 103
 104 # AT_LOC_POPDEF
 105 # -------------
 106 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
 107 m4_define([AT_LOC_POPDEF],
 108 [m4_popdef([AT_LOC_FIRST_LINE])
 109 m4_popdef([AT_LOC_FIRST_COLUMN])
 110 m4_popdef([AT_LOC_LAST_LINE])
 111 m4_popdef([AT_LOC_LAST_COLUMN])])
 112
 113
 114
 115 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 116 # -----------------------------------------
 117 m4_define([AT_BISON_OPTION_PUSHDEFS],
 118 [m4_divert_text([KILL],
 119                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 120
 121
 122 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 123 # --------------------------------------------------
 124 # This macro works around the impossibility to define macros
 125 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 126 # This sucks hard, GNU M4 should really provide M5-like $$1.
 127 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 128 [m4_if([$1$2], $[1]$[2], [],
 129        [m4_fatal([$0: Invalid arguments: $@])])dnl
 130 m4_pushdef([AT_DEFINES_IF],
 131 [m4_bmatch([$3], [%defines], [$1], [$2])])
 132 m4_pushdef([AT_DEBUG_IF],
 133 [m4_bmatch([$3], [%debug\|%define parse.trace], [$1], [$2])])
 134 m4_pushdef([AT_SKEL_CC_IF],
 135 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 136 m4_pushdef([AT_SKEL_JAVA_IF],
 137 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 138 # The target language: "c", "c++", or "java".
 139 m4_pushdef([AT_LANG],
 140 [AT_SKEL_JAVA_IF([java],
 141                  [AT_SKEL_CC_IF([c++],
 142                                 [c])])])
 143 m4_pushdef([AT_GLR_IF],
 144 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 145 m4_pushdef([AT_LALR1_CC_IF],
 146 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 147 m4_pushdef([AT_GLR_CC_IF],
 148 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 149 # Using yacc.c?
 150 m4_pushdef([AT_YACC_IF],
 151 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 152 m4_pushdef([AT_LEXPARAM_IF],
 153 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 154 m4_pushdef([AT_LOCATION_IF],
 155 [m4_bmatch([$3], [%locations], [$1], [$2])])
 156 m4_pushdef([AT_LOCATION_TYPE_IF],
 157 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 158 m4_pushdef([AT_PARAM_IF],
 159 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 160 # Comma-terminated list of formals parse-parameters.
 161 # E.g., %parse-param { int x } %parse-param {int y} -> "int x, int y, ".
 162 # FIXME: Support grouped parse-param.
 163 m4_pushdef([AT_PARSE_PARAMS])
 164 m4_bpatsubst([$3], [%parse-param { *\([^{}]*[^{} ]\) *}],
 165              [m4_append([AT_PARSE_PARAMS], [\1, ])])
 166
 167 m4_pushdef([AT_PURE_IF],
 168 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 169            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 170            [$2])])
 171 # AT_NAME_PREFIX: also consider api.namespace.
 172 m4_pushdef([AT_NAME_PREFIX],
 173 [m4_bmatch([$3], [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) ".*"],
 174            [m4_bregexp([$3], [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) "\([^""]*\)"], [\3])],
 175            [yy])])
 176 m4_pushdef([AT_TOKEN_CTOR_IF],
 177 [m4_bmatch([$3], [%define api.token.constructor], [$1], [$2])])
 178 m4_pushdef([AT_TOKEN_PREFIX],
 179 [m4_bmatch([$3], [%define api.token.prefix ".*"],
 180            [m4_bregexp([$3], [%define api.token.prefix "\(.*\)"], [\1])])])
 181 m4_pushdef([AT_API_prefix],
 182 [m4_bmatch([$3], [%define api\.prefix ".*"],
 183            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 184            [yy])])
 185 m4_pushdef([AT_API_PREFIX],
 186 [m4_toupper(AT_API_prefix)])
 187 # yyerror receives the location if %location, and if the parser is pure. For
 188 # historical reasons, with the "yacc.c" skeleton, the location is not passed
 189 # unless an additional "%parse-param" is present, or if the purity is defined
 190 # as "full".
 191 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 192 [AT_LOCATION_IF([AT_PURE_IF([m4_bmatch([$3],
 193                                        m4_quote(m4_join([\|],
 194                                                         [%define api.pure "?full"?],
 195                                                         [%glr-parser],
 196                                                         [%parse-param],
 197                                                         [%skeleton "?glr.c"?])),
 198                                        [$1], [$2])],
 199                             [$2])],
 200                     [$2])])
 201
 202 # yyerror always sees the locations (when activated) if the parser is impure.
 203 # When the parser is pure, yyerror sees the location if it is received as an
 204 # argument.
 205 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 206 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_YYERROR_ARG_LOC_IF([$1], [$2])],
 207                                         [$1])],
 208                             [$1])],
 209                 [$2])])
 210
 211 # The interface is pure: either because %define api.pure, or because we
 212 # are using the C++ parsers.
 213 m4_pushdef([AT_PURE_LEX_IF],
 214 [AT_PURE_IF([$1],
 215             [AT_SKEL_CC_IF([$1], [$2])])])
 216
 217 m4_pushdef([AT_YYSTYPE],
 218 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 219                [AT_API_PREFIX[STYPE]])])
 220 m4_pushdef([AT_YYLTYPE],
 221 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 222                [AT_API_PREFIX[LTYPE]])])
 223
 224
 225 AT_PURE_LEX_IF(
 226 [m4_pushdef([AT_LOC], [(*llocp)])
 227  m4_pushdef([AT_VAL], [(*lvalp)])
 228  m4_pushdef([AT_YYLEX_FORMALS],
 229             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 230  m4_pushdef([AT_YYLEX_ARGS],
 231             [lvalp[]AT_LOCATION_IF([, llocp])])
 232  m4_pushdef([AT_USE_LEX_ARGS],
 233             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 234  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 235             [AT_YYLEX_FORMALS, ])
 236  m4_pushdef([AT_YYLEX_PRE_ARGS],
 237             [AT_YYLEX_ARGS, ])
 238 ],
 239 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 240  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 241  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 242  m4_pushdef([AT_YYLEX_ARGS],        [])
 243  m4_pushdef([AT_USE_LEX_ARGS],    [])
 244  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 245  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 246 ])
 247
 248 # Handle the different types of location components.
 249
 250 AT_SKEL_CC_IF(
 251   [AT_LOCATION_TYPE_IF(
 252     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 253     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 254   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 255
 256
 257 AT_GLR_IF([AT_KEYWORDS([glr])])
 258 ])# _AT_BISON_OPTION_PUSHDEFS
 259
 260
 261 # AT_BISON_OPTION_POPDEFS
 262 # -----------------------
 263 m4_define([AT_BISON_OPTION_POPDEFS],
 264 [m4_divert_text([KILL],
 265 [m4_popdef([AT_YYLEX_PRE_ARGS])
 266 m4_popdef([AT_YYLEX_PRE_FORMALS])
 267 m4_popdef([AT_USE_LEX_ARGS])
 268 m4_popdef([AT_YYLEX_ARGS])
 269 m4_popdef([AT_YYLEX_FORMALS])
 270 m4_popdef([AT_YYLTYPE])
 271 m4_popdef([AT_YYSTYPE])
 272 m4_popdef([AT_VAL])
 273 m4_popdef([AT_LOC])
 274 m4_popdef([AT_PURE_LEX_IF])
 275 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 276 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 277 m4_popdef([AT_API_PREFIX])
 278 m4_popdef([AT_API_prefix])
 279 m4_popdef([AT_TOKEN_PREFIX])
 280 m4_popdef([AT_TOKEN_CTOR_IF])
 281 m4_popdef([AT_NAME_PREFIX])
 282 m4_popdef([AT_LOCATION_TYPE_IF])
 283 m4_popdef([AT_LOCATION_IF])
 284 m4_popdef([AT_PARSE_PARAMS])
 285 m4_popdef([AT_PARAM_IF])
 286 m4_popdef([AT_LEXPARAM_IF])
 287 m4_popdef([AT_YACC_IF])
 288 m4_popdef([AT_GLR_IF])
 289 m4_popdef([AT_SKEL_CC_IF])
 290 m4_popdef([AT_LANG])
 291 m4_popdef([AT_SKEL_JAVA_IF])
 292 m4_popdef([AT_GLR_CC_IF])
 293 m4_popdef([AT_LALR1_CC_IF])
 294 m4_popdef([AT_DEFINES_IF])
 295 m4_popdef([AT_DEBUG_IF])
 296 AT_LOC_POPDEF])dnl
 297 ])# AT_BISON_OPTION_POPDEFS
 298
 299
 300
 301 ## -------------------------- ##
 302 ## Generating Grammar Files.  ##
 303 ## -------------------------- ##
 304
 305 # AT_DATA_SOURCE_PROLOGUE
 306 # ------------------------
 307 # The prologue that should be included in any source code that is
 308 # meant to be compiled.
 309 m4_define([AT_DATA_SOURCE_PROLOGUE],
 310 [[#include <config.h>
 311 /* We don't need perfect functions for these tests. */
 312 #undef malloc
 313 #undef memcmp
 314 #undef realloc
 315 ]])
 316
 317 # AT_DATA_GRAMMAR_PROLOGUE
 318 # ------------------------
 319 # The prologue that should be included in any grammar which parser is
 320 # meant to be compiled.
 321 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 322 [[%code top {
 323 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 324 [}
 325 ]])
 326
 327 # AT_DATA_SOURCE(NAME, CONTENT)
 328 # -----------------------------
 329 # Generate the file NAME, which CONTENT is preceded by
 330 # AT_DATA_SOURCE_PROLOGUE.
 331 m4_define([AT_DATA_SOURCE],
 332 [AT_DATA([$1],
 333 [AT_DATA_SOURCE_PROLOGUE
 334 $2])
 335 ])
 336
 337 # AT_DATA_GRAMMAR(NAME, CONTENT)
 338 # ------------------------------
 339 # Generate the file NAME, which CONTENT is preceded by
 340 # AT_DATA_GRAMMAR_PROLOGUE.
 341 m4_define([AT_DATA_GRAMMAR],
 342 [AT_DATA([$1],
 343 [AT_DATA_GRAMMAR_PROLOGUE
 344 $2])
 345 ])
 346
 347 # AT_YYLEX_PROTOTYPE
 348 # AT_YYLEX_DECLARE_EXTERN
 349 # AT_YYLEX_DECLARE
 350 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 351 # ----------------------------------
 352 # INPUT can be empty, or in double quotes, or a list (in braces).
 353 # ACTION may compute yylval for instance, using "res" as token type,
 354 # and "toknum" as the number of calls to yylex (starting at 0).
 355 m4_define([AT_YYLEX_PROTOTYPE],
 356 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 357 ])
 358
 359 m4_define([AT_YYLEX_DECLARE_EXTERN],
 360 [AT_YYLEX_PROTOTYPE;dnl
 361 ])
 362
 363 m4_define([AT_YYLEX_DECLARE],
 364 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 365 ])
 366
 367 m4_define([AT_YYLEX_DEFINE],
 368 [[#include <assert.h>
 369 static
 370 ]AT_YYLEX_PROTOTYPE[
 371 {
 372   ]m4_bmatch([$1], [^\(".*"\)?$],
 373              [[static char const input[] = ]m4_default([$1], [""])],
 374              [[static int const input[] = ]$1])[;
 375   static size_t toknum = 0;
 376   int res;
 377   ]AT_USE_LEX_ARGS[;
 378   assert (toknum < sizeof input / sizeof input[0]);
 379   res = input[toknum++];
 380   ]$2[;]AT_LOCATION_IF([[
 381   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 382   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 383   return res;
 384 }]dnl
 385 ])
 386
 387 # AT_YYERROR_FORMALS
 388 # AT_YYERROR_PROTOTYPE
 389 # AT_YYERROR_DECLARE_EXTERN
 390 # AT_YYERROR_DECLARE
 391 # AT_YYERROR_DEFINE
 392 # -------------------------
 393 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 394 m4_define([AT_YYERROR_FORMALS],
 395 [m4_case(AT_LANG,
 396 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE const * const llocp, ])AT_PARSE_PARAMS [const char *msg]])[]dnl
 397 ])
 398
 399 m4_define([AT_YYERROR_PROTOTYPE],
 400 [m4_case(AT_LANG,
 401 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 402 ])
 403
 404 m4_define([AT_YYERROR_DECLARE_EXTERN],
 405 [m4_case(AT_LANG,
 406 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 407 ])
 408
 409 m4_define([AT_YYERROR_DECLARE],
 410 [m4_case(AT_LANG,
 411 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 412 ])
 413
 414 m4_define([AT_YYERROR_DEFINE],
 415 [m4_case(AT_LANG,
 416 [c], [[#include <stdio.h>
 417 /* A C error reporting function.  */
 418 static
 419 ]AT_YYERROR_PROTOTYPE[
 420 {]m4_bpatsubst(m4_defn([AT_PARSE_PARAMS]),
 421               [[^,]+[^A-Za-z_0-9]\([A-Za-z_][A-Za-z_0-9]*\), *], [
 422   YYUSE(\1);])dnl
 423 AT_YYERROR_SEES_LOC_IF([[
 424   YY_LOCATION_PRINT (stderr, ]AT_LOC[);
 425   fprintf (stderr, ": ");]])[
 426   fprintf (stderr, "%s\n", msg);
 427 }]],
 428 [c++], [[/* A C++ error reporting function.  */
 429 void
 430 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 431 {
 432   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 433 }]],
 434 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 435 {
 436     if (l == null)
 437       System.err.println (s);
 438     else
 439       System.err.println (l + ": " + s);
 440   }
 441 ]], [[
 442   public void yyerror (String s)
 443   {
 444     System.err.println (s);
 445   }]])],
 446 [m4_fatal([$0: invalid language: ]AT_LANG)])dnl
 447 ])
 448
 449
 450 # AT_MAIN_DEFINE
 451 # --------------
 452 m4_define([AT_MAIN_DEFINE],
 453 [m4_case(AT_LANG,
 454 [c],
 455 [[#include <stdlib.h> /* getenv. */
 456 #include <string.h> /* strcmp. */
 457 int
 458 main (int argc, char const* argv[])
 459 {]AT_DEBUG_IF([[
 460   if (getenv("YYDEBUG")
 461       || (argc == 2
 462           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 463     yydebug |= 1;]], [[
 464   (void) argc;
 465   (void) argv;]])[
 466   return ]AT_NAME_PREFIX[parse ();
 467 }]],
 468 [c++],
 469 [[#include <cstdlib> // getenv.
 470 #include <cstring> // strcmp.
 471 int
 472 main (int argc, char const* argv[])
 473 {
 474   ]AT_NAME_PREFIX[::parser p;]AT_DEBUG_IF([[
 475   if (getenv("YYDEBUG")
 476       || (argc == 2
 477           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 478     p.set_debug_level (true);]], [[
 479   (void) argc;
 480   (void) argv;]])[
 481   return p.parse ();
 482 }]],
 483 [java],
 484 [[class input
 485 {
 486   public static void main (String args[]) throws IOException
 487   {
 488     YYParser p = new YYParser ();
 489     p.parse ();
 490   }
 491 }]])])
 492
 493
 494 ## --------------- ##
 495 ## Running Bison.  ##
 496 ## --------------- ##
 497
 498 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 499 # -------------------------------------------------
 500 # High-level routine that may call bison several times, under different
 501 # conditions.
 502 #
 503 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 504 # shell constructs (such as redirection or pipes) that would prevent
 505 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 506 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 507 #
 508 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 509 # Bison in the test suite.  For now it ensures that:
 510 #
 511 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 512 #      a non-zero exit status since Bison doesn't always try to free all memory
 513 #      in that case.
 514 #
 515 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 516 #      --graph and --report=all output for every working grammar.
 517 #
 518 #   3. If stderr contains a warning, -Werror and --warnings=error
 519 #      convert the warning to an error.
 520 #
 521 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 522 m4_define([AT_BISON_CHECK],
 523 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 524 AT_BISON_CHECK_NO_XML($@)])
 525
 526 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 527 # --------------------------------------------------
 528 # Low-level macro to run bison once.
 529 m4_define([AT_BISON_CHECK_],
 530 [AT_CHECK(AT_QUELL_VALGRIND[[ bison -fno-caret ]]$@)])
 531
 532
 533 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 534 # ----------------------------------------------------------
 535 # Check that warnings (if some are expected) are correctly
 536 # turned into errors with -Werror, etc.
 537 m4_define([AT_BISON_CHECK_WARNINGS],
 538 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 539       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 540
 541 m4_define([AT_BISON_CHECK_WARNINGS_],
 542 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 543 # added after the grammar file name, so skip these checks in that
 544 # case.
 545 if test "$POSIXLY_CORRECT_IS_EXPORTED" = false; then
 546           ]AT_SAVE_SPECIAL_FILES[
 547
 548   # To avoid expanding it repeatedly, store specified stdout.
 549   ]AT_DATA([expout], [$3])[
 550
 551   # Run with -Werror.
 552   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 553
 554   # Build expected stderr up to and including the "warnings being
 555   # treated as errors" message.
 556   ]AT_DATA([[experr]], [$4])[
 557   $PERL -pi -e 's{(.*): warning: (.*)\[-W(.*)\]$}
 558                  {$][1: error: $][2\@<:@-Werror=$][3@:>@}' experr
 559   ]AT_CHECK([[sed 's,.*/$,,' stderr 1>&2]], [[0]], [[]], [experr])[
 560
 561   # Now check --warnings=error.
 562   cp stderr experr
 563   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 564
 565   # Now check -Wnone and --warnings=none by making sure that
 566   # -Werror doesn't change the exit status when -Wnone or
 567   # --warnings=none is specified.
 568   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 569   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 570
 571   ]AT_RESTORE_SPECIAL_FILES[
 572 fi]dnl
 573 ])
 574
 575 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 576 # --------------------------------------------------------
 577 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 578 # when a tortured grammar's XML is known to be too large for xsltproc to
 579 # handle.
 580 m4_define([AT_BISON_CHECK_NO_XML],
 581 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison -fno-caret ]]$@)
 582 AT_BISON_CHECK_WARNINGS($@)])
 583
 584 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 585 # -----------------------------------------------------
 586 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 587 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 588 # have a non-zero exit status.
 589 m4_define([AT_BISON_CHECK_XML],
 590 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 591   AT_SAVE_SPECIAL_FILES
 592   [mkdir xml-tests]
 593   m4_pushdef([AT_BISON_ARGS],
 594              [m4_bpatsubsts([[$1]],
 595                             [--report(-file)?=[^][ ]*], [],
 596                             [--graph=[^][ ]*], [],
 597                             [--xml=[^][ ]*], [])])dnl
 598   # Don't combine these Bison invocations since we want to be sure that
 599   # --report=all isn't required to get the full XML file.
 600   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 601              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 602            [[0]], [ignore], [ignore])
 603   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 604            [[0]], [ignore], [ignore])
 605   m4_popdef([AT_BISON_ARGS])dnl
 606   [cp xml-tests/test.output expout]
 607   AT_CHECK([[$XSLTPROC \
 608              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 609              xml-tests/test.xml]], [[0]], [expout])
 610   [sort xml-tests/test.dot > expout]
 611   AT_CHECK([[$XSLTPROC \
 612              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 613              xml-tests/test.xml | sort]], [[0]], [expout])
 614   [rm -rf xml-tests expout]
 615   AT_RESTORE_SPECIAL_FILES
 616 [fi]])
 617
 618 # AT_QUELL_VALGRIND
 619 # -----------------
 620 # Put this before a Bison invocation to keep Valgrind from complaining about
 621 # reachable memory.
 622 #
 623 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 624 # The triple quoting below will cause test cases to fail if you do.  If you do
 625 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 626 # will then fail to shell-escape its contents when attempting to print them.
 627 # The testsuite verbose output, at least, will be incorrect, but nothing may
 628 # fail to make sure you notice.
 629 m4_define([AT_QUELL_VALGRIND],
 630 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 631
 632
 633
 634 ## ------------------------ ##
 635 ## Compiling C, C++ Files.  ##
 636 ## ------------------------ ##
 637
 638
 639 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 640 # ----------------------------------------
 641 # Compile SOURCES into OUTPUT.
 642 #
 643 # If OUTPUT does not contain '.', assume that we are linking too,
 644 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 645 # with trailing .o removed, and ".c" appended.
 646 m4_define([AT_COMPILE],
 647 [AT_CHECK([$BISON_C_WORKS], 0, ignore, ignore)
 648 AT_CHECK(m4_join([ ],
 649                   [$CC $CFLAGS $CPPFLAGS],
 650                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 651                   [-o $1],
 652                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 653                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 654            0, [ignore], [ignore])])
 655
 656 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 657 # ---------------------------------------------
 658 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 659 # ignore the test.
 660 #
 661 # If OUTPUT does not contain '.', assume that we are linking too,
 662 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 663 # with trailing .o removed, and ".cc" appended.
 664 m4_define([AT_COMPILE_CXX],
 665 [AT_KEYWORDS(c++)
 666 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 667 AT_CHECK(m4_join([ ],
 668                  [$CXX $CXXFLAGS $CPPFLAGS],
 669                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 670                  [-o $1],
 671                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 672                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 673          0, [ignore], [ignore])])
 674
 675 # AT_JAVA_COMPILE(SOURCES)
 676 # ------------------------
 677 # Compile SOURCES into Java class files.  Skip the test if java or javac
 678 # is not installed.
 679 m4_define([AT_JAVA_COMPILE],
 680 [AT_KEYWORDS(java)
 681 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 682 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 683 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 684          [[0]], [ignore], [ignore])])
 685
 686 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 687 # --------------------------------------------
 688 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 689 #
 690 # If OUTPUT does not contain '.', assume that we are linking too,
 691 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 692 # with trailing .o removed, and ".c"/".cc" appended.
 693 m4_define([AT_LANG_COMPILE],
 694 [m4_case(AT_LANG,
 695 [c],    [AT_COMPILE([$1], [$2])],
 696 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 697 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 698         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 699 ])
 700
 701 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 702 # -------------------------------------------
 703 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 704 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 705 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 706 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 707 # AT_SKEL_JAVA_IF.
 708 m4_define([AT_FULL_COMPILE],
 709 [m4_case(AT_LANG,
 710 [java],
 711   [AT_BISON_CHECK([-o $1.java $1.y])
 712    AT_LANG_COMPILE([$1],
 713                     m4_join([ ],
 714                             [$1.java],
 715                             m4_ifval($2, [[$1-$2.java]]),
 716                            m4_ifval($3, [[$1-$3.java]])))],
 717 [c++],
 718   [AT_BISON_CHECK([-o $1.cc $1.y])
 719    AT_LANG_COMPILE([$1],
 720                      m4_join([ ],
 721                              [$1.cc],
 722                              m4_ifval($2, [[$1-$2.cc]]),
 723                            m4_ifval($3, [[$1-$3.cc]])))],
 724 [c],
 725   [AT_BISON_CHECK([-o $1.c $1.y])
 726    AT_LANG_COMPILE([$1],
 727                   m4_join([ ],
 728                           [$1.c],
 729                           m4_ifval($2, [[$1-$2.c]]),
 730                            m4_ifval($3, [[$1-$3.c]])))])
 731 ])
 732
 733
 734
 735 # AT_SKIP_IF_CANNOT_LINK_C_AND_CXX
 736 # --------------------------------
 737 # Check that we can link together C and C++ objects.
 738 m4_define([AT_SKIP_IF_CANNOT_LINK_C_AND_CXX],
 739 [AT_DATA([c-and-cxx.h],
 740 [[#ifdef __cplusplus
 741 extern "C"
 742 {
 743 #endif
 744   int fortytwo (void);
 745 #ifdef __cplusplus
 746 }
 747 #endif
 748 ]])
 749 AT_DATA([c-only.c],
 750 [[#include "c-and-cxx.h"
 751 int
 752 main (void)
 753 {
 754   return fortytwo () == 42 ? 0 : 1;
 755 }
 756 ]])
 757 AT_DATA([cxx-only.cc],
 758 [[#include "c-and-cxx.h"
 759 int fortytwo ()
 760 {
 761   return 42;
 762 }
 763 ]])
 764 AT_COMPILE([c-only.o], [c-only.c])
 765 AT_COMPILE_CXX([cxx-only.o], [cxx-only.cc])
 766 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS $LDFLAGS c-only.o cxx-only.o -o c-and-cxx ||
 767           exit 77], [ignore], [ignore])
 768 AT_PARSER_CHECK([./c-and-cxx])
 769 ])
 770
 771
 772 ## ---------------------------- ##
 773 ## Running a generated parser.  ##
 774 ## ---------------------------- ##
 775
 776
 777 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 778 # ------------------------------------------------------------
 779 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 780 #
 781 # Get rid of spurious messages when compiled with --coverage:
 782 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 783 m4_define([AT_PARSER_CHECK],
 784 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 785 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 786          [0], [], [$4])
 787 ])
 788
 789
 790 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 791 # -----------------------------------------------------------------
 792 m4_define([AT_JAVA_PARSER_CHECK],
 793 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 794
 795
 796 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 797 #                          DECLS, GRAMMAR, INPUT,
 798 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 799 #                          [OTHER-CHECKS],
 800 #                          [PARSER-EXIT-VALUE],
 801 #                          [PARSER-STDOUT], [PARSER-STDERR])
 802 # -------------------------------------------------------------
 803 # Using TITLE as the test group title, check the generated parser tables
 804 # and parser for a specified grammar file under a condition labeled by
 805 # COND-VALUE.
 806 #
 807 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 808 # recognized attribute is described below where it is relevant.
 809 #
 810 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 811 # the grammar file.  Insert basic yyerror, yylex, and main function
 812 # definitions as well.  Hardcode yylex to return the (possibly empty)
 813 # comma-delimited series of tokens in INPUT followed by token 0.
 814 #
 815 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 816 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 817 # On the bison command-line, specify `--report=all --defines'.  Check
 818 # that Bison exits with value 0, has no stdout, and has stderr
 819 # BISON-STDERR.
 820 #
 821 # If TEST-SPEC contains the attribute `last-state', check that the value
 822 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 823 # the grammar; in other words, check the number of states (minus one).
 824 # Otherwise, check that everything in the `.output' file starting with
 825 # the definition of state 0 is the same as the entire value of
 826 # TABLES-OR-LAST-STATE.
 827 #
 828 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 829 # `.output' file, which is named `input.output', and/or grammar file,
 830 # which is named `input.y'.
 831 #
 832 # Finally, compile the generated parser and then run it using
 833 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 834 # PARSER-STDERR as the 2nd-4th arguments.
 835 #
 836 # As a precondition, you must properly double-quote all arguments that
 837 # are to be interpreted as strings.
 838 #
 839 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 840 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 841 # first argument.  This is useful, for example, when wrapping multiple
 842 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 843 # condition, in another macro.
 844 #
 845 # For example:
 846 #
 847 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 848 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 849 #   # ---------------------------------------------------------------------
 850 #   m4_define([AT_TEST_SYNTAX_ERROR],
 851 #   [
 852 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 853 #                              [[last-state]],
 854 #                              [[%error-verbose ]$2], [$3], [$4],
 855 #                              [[]], [$5], [], [$6], [$7], [$8])
 856 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 857 #                              [[last-state]],
 858 #                              [$2], [$3], [$4],
 859 #                              [[]], [$5], [], [$6], [$7], [$8])
 860 #   ])
 861 #
 862 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 863 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 864 #                        [[3]],
 865 #                        [[1]], [[]],
 866 #                        [AT_COND_CASE([[no verbose]],
 867 #                                      [[syntax error
 868 #   ]],
 869 #                                      [[syntax error, unexpected 'b', expecting $end
 870 #   ]])])
 871 m4_define([AT_TEST_TABLES_AND_PARSE],
 872 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 873
 874 AT_SETUP([$1])
 875 AT_BISON_OPTION_PUSHDEFS([$4])
 876 AT_DATA_GRAMMAR([[input.y]],
 877 [[%code {
 878   #include <stdio.h>
 879   ]AT_YYERROR_DECLARE[
 880   ]AT_YYLEX_DECLARE[
 881 }
 882
 883 ]$4[
 884
 885 %%
 886
 887 ]$5[
 888
 889 %%
 890 ]AT_YYERROR_DEFINE[
 891 static int
 892 yylex (void)
 893 {
 894   static int const input[] = {
 895     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 896   };
 897   static int const *inputp = input;
 898   return *inputp++;
 899 }
 900
 901 int
 902 main (void)
 903 {
 904   return yyparse ();
 905 }
 906 ]])
 907
 908 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 909 # expanding macros, so it corrupts some special characters in the
 910 # macros.  To avoid this, expand now and pass it the result with proper
 911 # string quotation.  Assume args 7 through 12 expand to properly quoted
 912 # strings.
 913
 914 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 915       [AT_BISON_CHECK],
 916       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 917                                [0], [], m4_dquote($7))
 918
 919 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 920       [AT_CHECK([[sed -n '/^State 0$/,$p' input.output]], [[0]],
 921                 m4_dquote($8))],
 922       [AT_CHECK([[sed -n 's/^State //p' input.output | tail -1]], [[0]],
 923                 m4_dquote($8)[[
 924 ]])])
 925
 926 $9
 927
 928 # Canonical LR generates very large tables, resulting in very long
 929 # files with #line directives that may overflow what the standards
 930 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 931 # will issue an error.
 932 #
 933 # There is no "" around `wc` since some indent the result.
 934 m4_bmatch([$4], [%define lr.type canonical-lr],
 935 [if test 32767 -lt `wc -l < input.c`; then
 936   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 937   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 938 fi])
 939 AT_COMPILE([[input]])
 940
 941 AT_PARSER_CHECK([[./input]],
 942                 m4_ifval([$10], [m4_dquote($10)]),
 943                 m4_ifval([$11], [m4_dquote($11)]),
 944                 m4_ifval([$12], [m4_dquote($12)]))
 945
 946 AT_BISON_OPTION_POPDEFS
 947 AT_CLEANUP
 948
 949 m4_popdef([AT_COND_CASE])])
 950
 951
 952
 953
 954 ## ----------------------- ##
 955 ## Launch the test suite.  ##
 956 ## ----------------------- ##
 957
 958 AT_INIT
 959
 960 # AT_SETUP([TITLE])
 961 # -----------------
 962 # Redefine AT_SETUP to be more concise.  Must be done after AT_INIT.
 963 m4_copy_force([AT_SETUP], [B4_SETUP])
 964 m4_define([AT_SETUP],
 965 [B4_SETUP(m4_expand([AT_SETUP_STRIP([[$1]])]))])
 966
 967 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 968 # options are processed, so we don't know the value of CXX and
 969 # CXXFLAGS yet.
 970 #
 971 # Note that it also means that command line values for CXX and
 972 # CXXFLAGS will not be propagated to CC and CFLAGS.
 973 AT_ARG_OPTION([compile-c-with-cxx],
 974               [compile C parsers with the C++ compiler])
 975
 976 AT_COLOR_TESTS
 977
 978 AT_TESTED([bison])