configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software
   4 # Foundation, Inc.
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We have strange test case titles, so we need Autoconf 2.61 or better.
  20 AC_PREREQ(2.61)
  21
  22 AC_INIT([GNU Bison],
  23         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  24         [bug-bison@gnu.org])
  25 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2008],
  26           [The copyright year for this package])
  27 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2008])
  28
  29 AC_CONFIG_AUX_DIR([build-aux])
  30 AC_CONFIG_MACRO_DIR([m4])
  31
  32 # We don't have a file m4/Makefile.am, so we need Automake 1.8 or later.
  33 AM_INIT_AUTOMAKE([1.8 check-news readme-alpha dist-bzip2])
  34 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  35
  36 # Checks for the compiler.
  37 AC_PROG_CC_STDC
  38
  39 # Gnulib (early checks).
  40 gl_EARLY
  41
  42 AC_ARG_ENABLE(gcc-warnings,
  43 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  44 [case "${enableval}" in
  45    yes|no) ;;
  46    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  47  esac],
  48               [enableval=no])
  49 if test "${enableval}" = yes; then
  50   gl_WARNING_CFLAGS([-Werror])
  51   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  52   WARNING_CFLAGS=
  53   gl_WARNING_CFLAGS([-Wall])
  54   gl_WARNING_CFLAGS([-Wextra -Wno-sign-compare])
  55   gl_WARNING_CFLAGS([-Wcast-align])
  56   gl_WARNING_CFLAGS([-Wcast-qual])
  57   gl_WARNING_CFLAGS([-Wformat])
  58   gl_WARNING_CFLAGS([-Wpointer-arith])
  59   gl_WARNING_CFLAGS([-Wwrite-strings])
  60   AC_SUBST([WARNING_CXXFLAGS], [$WARNING_CFLAGS])
  61   # The following warnings are not suitable for C++.
  62   gl_WARNING_CFLAGS([-Wbad-function-cast])
  63   gl_WARNING_CFLAGS([-Wmissing-declarations])
  64   gl_WARNING_CFLAGS([-Wmissing-prototypes])
  65   gl_WARNING_CFLAGS([-Wshadow])
  66   gl_WARNING_CFLAGS([-Wstrict-prototypes])
  67   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  68 fi
  69
  70 BISON_TEST_FOR_WORKING_C_COMPILER
  71
  72 AC_ARG_ENABLE([yacc],
  73   [AC_HELP_STRING([--disable-yacc],
  74      [do not build a yacc command or an -ly library])],
  75   , [enable_yacc=yes])
  76 case $enable_yacc in
  77 yes)
  78   YACC_SCRIPT=yacc
  79   YACC_LIBRARY=liby.a;;
  80 *)
  81   YACC_SCRIPT=
  82   YACC_LIBRARY=;;
  83 esac
  84 AC_SUBST([YACC_SCRIPT])
  85 AC_SUBST([YACC_LIBRARY])
  86
  87 # Checks for programs.
  88 AC_PROG_LEX
  89 AC_PROG_YACC
  90 AC_PROG_RANLIB
  91 BISON_PROG_GNU_M4
  92 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  93   AC_MSG_ERROR([GNU M4 1.4 is required])
  94 fi
  95 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  96 AM_MISSING_PROG([HELP2MAN], [help2man])
  97 AC_PATH_PROG([XSLTPROC], [xsltproc])
  98 AC_SUBST([XSLTPROC])
  99
 100 # Checks for header files.
 101 AC_CHECK_HEADERS_ONCE([locale.h])
 102
 103 # Checks for compiler characteristics.
 104 AC_C_INLINE
 105
 106 # Gnulib (later checks).  Putting them here rather than right after
 107 # gl_EARLY avoids some redundant checks.
 108 gl_INIT
 109
 110 # Checks for library functions.
 111 AC_CHECK_FUNCS_ONCE([setlocale])
 112 AM_WITH_DMALLOC
 113 BISON_PREREQ_SUBPIPE
 114 BISON_PREREQ_TIMEVAR
 115
 116 # Gettext.
 117 # We've never tested with gettext versions before 0.15, so play it safe.
 118 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 119 AM_GNU_GETTEXT_VERSION([0.15])
 120 BISON_I18N
 121
 122 # Internationalized parsers.
 123 AC_CONFIG_FILES([runtime-po/Makefile.in])
 124 # Autoconf macros for packages using internationalized parsers.
 125 aclocaldir='${datadir}/aclocal'
 126 AC_SUBST([aclocaldir])
 127
 128 # Create the benchmark script.
 129 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 130
 131 # Initialize the test suite.
 132 AC_CONFIG_TESTDIR(tests)
 133 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 134 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 135 AC_CHECK_PROGS([VALGRIND], [valgrind])
 136 AC_PROG_CXX
 137 BISON_TEST_FOR_WORKING_CXX_COMPILER
 138 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 139 # Needed by tests/atlocal.in.
 140 AC_SUBST([GCC])
 141 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 142 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 143
 144 gt_JAVACOMP([1.3])
 145 gt_JAVAEXEC
 146
 147 AC_CONFIG_FILES([Makefile
 148                  build-aux/Makefile
 149                  po/Makefile.in
 150                  data/Makefile
 151                  etc/Makefile
 152                  examples/Makefile
 153                     examples/calc++/Makefile
 154                  lib/Makefile src/Makefile
 155                  doc/Makefile
 156                    doc/yacc.1])
 157 AC_OUTPUT