tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2013 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 # AT_SETUP_STRIP(TITLE)
  33 # ---------------------
  34 # Abbreviate the TITLE to be passed to AT_SETUP.  Remove new-lines
  35 # that completely break AT_SETUP.
  36 m4_define([AT_SETUP_STRIP],
  37 [m4_bpatsubsts([$1],
  38       [%\(language\|skeleton\) "?\([^\" ]*\)"?],
  39         [\2],
  40       [%define "?\([-A-Za-z0-9_.]+\)"? \({[^\}]+}\|"[^\"]+"\|[-A-Za-z0-9_.]+\)],
  41         [\1=\2],
  42       [%define "?\([-A-Za-z0-9_.]+\)"?],
  43         [\1],
  44       [ *
  45 + *],    [ ])dnl
  46 ])
  47
  48
  49 ## ------------- ##
  50 ## Basic tests.  ##
  51 ## ------------- ##
  52
  53 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  54 # ------------------------------------------
  55 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  56 # taken in "slurp" mode, i.e., one can match end-of-lines.
  57 m4_define([AT_MATCHES_CHECK],
  58 [AT_CHECK([$PERL -0777 -ne '
  59 my $count = 0;
  60 s{$2}{ ++$count; "" }gem;
  61 printf "$count\n";' $1], [0], [$3
  62 ])])
  63
  64
  65 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  66 # ------------------------------------------------
  67 # Don't interfere with caller's files.
  68 m4_divert_text([PREPARE_TESTS],
  69 [at_save_special_files ()
  70 {
  71   for at_save_file in stderr experr expout
  72   do
  73     test ! -f at-bison-check-$at_save_file.bak ||
  74       as_fn_error 1 "fatal error: back-up on top of a back-up"
  75     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  76   done
  77 }
  78
  79 at_restore_special_files ()
  80 {
  81   for at_save_file in stderr experr expout
  82   do
  83     test ! -f at-bison-check-$at_save_file.bak ||
  84       mv at-bison-check-$at_save_file.bak $at_save_file
  85   done
  86 }
  87 ])
  88
  89 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  90 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  91
  92
  93
  94 ## ------------------------------- ##
  95 ## Macros decoding Bison options.  ##
  96 ## ------------------------------- ##
  97
  98 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  99 # ----------------------------------------------------------------
 100 # Pushdef AT(_LOC)?_(FIRST|LAST)_(LINE|COLUMN).
 101 m4_define([AT_LOC_PUSHDEF],
 102 [m4_pushdef([AT_FIRST_LINE],  [$1])
 103 m4_pushdef([AT_FIRST_COLUMN], [$2])
 104 m4_pushdef([AT_LAST_LINE],    [$3])
 105 m4_pushdef([AT_LAST_COLUMN],  [$4])
 106 m4_pushdef([AT_LOC_FIRST_LINE],   [AT_LOC.AT_FIRST_LINE])
 107 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.AT_FIRST_COLUMN])
 108 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.AT_LAST_LINE])
 109 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.AT_LAST_COLUMN])])
 110
 111 # AT_LOC_POPDEF
 112 # -------------
 113 # Popdef AT(_LOC)?_(FIRST|LAST)_(LINE|COLUMN).
 114 m4_define([AT_LOC_POPDEF],
 115 [m4_popdef([AT_LOC_FIRST_LINE])
 116 m4_popdef([AT_LOC_FIRST_COLUMN])
 117 m4_popdef([AT_LOC_LAST_LINE])
 118 m4_popdef([AT_LOC_LAST_COLUMN])
 119 m4_popdef([AT_FIRST_LINE])
 120 m4_popdef([AT_FIRST_COLUMN])
 121 m4_popdef([AT_LAST_LINE])
 122 m4_popdef([AT_LAST_COLUMN])
 123 ])
 124
 125
 126
 127 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 128 # -----------------------------------------
 129 m4_define([AT_BISON_OPTION_PUSHDEFS],
 130 [m4_divert_text([KILL],
 131                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 132
 133
 134 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 135 # --------------------------------------------------
 136 # This macro works around the impossibility to define macros
 137 # inside macros, because issuing '[$1]' is not possible in M4 :(.
 138 # This sucks hard, GNU M4 should really provide M5-like $$1.
 139 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 140 [m4_if([$1$2], $[1]$[2], [],
 141        [m4_fatal([$0: Invalid arguments: $@])])dnl
 142 m4_pushdef([AT_DEFINES_IF],
 143 [m4_bmatch([$3], [%defines], [$1], [$2])])
 144 m4_pushdef([AT_DEBUG_IF],
 145 [m4_bmatch([$3], [%debug\|%define parse.trace], [$1], [$2])])
 146 m4_pushdef([AT_SKEL_CC_IF],
 147 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 148 m4_pushdef([AT_SKEL_JAVA_IF],
 149 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 150 # The target language: "c", "c++", or "java".
 151 m4_pushdef([AT_LANG],
 152 [AT_SKEL_JAVA_IF([java],
 153                  [AT_SKEL_CC_IF([c++],
 154                                 [c])])])
 155 m4_pushdef([AT_GLR_IF],
 156 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 157 m4_pushdef([AT_LALR1_CC_IF],
 158 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 159 m4_pushdef([AT_GLR_CC_IF],
 160 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 161 # Using yacc.c?
 162 m4_pushdef([AT_YACC_IF],
 163 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 164 m4_pushdef([AT_LEXPARAM_IF],
 165 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 166 m4_pushdef([AT_LOCATION_IF],
 167 [m4_bmatch([$3], [%locations], [$1], [$2])])
 168 m4_pushdef([AT_LOCATION_TYPE_IF],
 169 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 170 m4_pushdef([AT_PARAM_IF],
 171 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 172 # Comma-terminated list of formals parse-parameters.
 173 # E.g., %parse-param { int x } %parse-param {int y} -> "int x, int y, ".
 174 # FIXME: Support grouped parse-param.
 175 m4_pushdef([AT_PARSE_PARAMS])
 176 m4_bpatsubst([$3], [%parse-param { *\([^{}]*[^{} ]\) *}],
 177              [m4_append([AT_PARSE_PARAMS], [\1, ])])
 178
 179 m4_pushdef([AT_PURE_IF],
 180 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 181            [m4_bmatch([$3], [%define  *api\.pure *false], [$2], [$1])],
 182            [$2])])
 183 # AT_NAME_PREFIX: also consider api.namespace.
 184 m4_pushdef([AT_NAME_PREFIX],
 185 [m4_bmatch([$3], [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) .*],
 186    [m4_bregexp([$3],
 187      [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) [\{\"]\([^\"\}]*\)[\"\}]],
 188      [\3])],
 189    [yy])])
 190 m4_pushdef([AT_TOKEN_CTOR_IF],
 191 [m4_bmatch([$3], [%define api\.token\.constructor], [$1], [$2])])
 192 m4_pushdef([AT_TOKEN_PREFIX],
 193 [m4_bmatch([$3], [%define api\.token\.prefix {.*}],
 194            [m4_bregexp([$3], [%define api\.token\.prefix {\(.*\)}], [\1])])])
 195 m4_pushdef([AT_VARIANT_IF],
 196 [m4_bmatch([$3], [%define api\.value\.type variant], [$1], [$2])])
 197 m4_pushdef([AT_API_prefix],
 198 [m4_bmatch([$3], [%define api\.prefix {.*}],
 199            [m4_bregexp([$3], [%define api\.prefix {\([^\}]*\)}], [\1])],
 200            [yy])])
 201 m4_pushdef([AT_API_PREFIX],
 202 [m4_toupper(AT_API_prefix)])
 203 # yyerror receives the location if %location, and if the parser is pure. For
 204 # historical reasons, with the "yacc.c" skeleton, the location is not passed
 205 # unless an additional "%parse-param" is present, or if the purity is defined
 206 # as "full".
 207 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 208 [AT_LOCATION_IF([AT_PURE_IF([m4_bmatch([$3],
 209                                        m4_quote(m4_join([\|],
 210                                                         [%define api\.pure full],
 211                                                         [%glr-parser],
 212                                                         [%parse-param],
 213                                                         [%skeleton "?glr.c"?])),
 214                                        [$1], [$2])],
 215                             [$2])],
 216                     [$2])])
 217
 218 # yyerror always sees the locations (when activated) if the parser is impure.
 219 # When the parser is pure, yyerror sees the location if it is received as an
 220 # argument.
 221 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 222 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_YYERROR_ARG_LOC_IF([$1], [$2])],
 223                                         [$1])],
 224                             [$1])],
 225                 [$2])])
 226
 227 # The interface is pure: either because %define api.pure, or because we
 228 # are using the C++ parsers.
 229 m4_pushdef([AT_PURE_LEX_IF],
 230 [AT_PURE_IF([$1],
 231             [AT_SKEL_CC_IF([$1], [$2])])])
 232
 233 m4_pushdef([AT_YYSTYPE],
 234 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 235                [AT_API_PREFIX[STYPE]])])
 236 m4_pushdef([AT_YYLTYPE],
 237 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 238                [AT_API_PREFIX[LTYPE]])])
 239
 240
 241 AT_PURE_LEX_IF(
 242 [m4_pushdef([AT_LOC], [(*llocp)])
 243  m4_pushdef([AT_VAL], [(*lvalp)])
 244  m4_pushdef([AT_YYLEX_FORMALS],
 245             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 246  m4_pushdef([AT_YYLEX_ARGS],
 247             [lvalp[]AT_LOCATION_IF([, llocp])])
 248  m4_pushdef([AT_USE_LEX_ARGS],
 249             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 250  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 251             [AT_YYLEX_FORMALS, ])
 252  m4_pushdef([AT_YYLEX_PRE_ARGS],
 253             [AT_YYLEX_ARGS, ])
 254 ],
 255 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 256  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 257  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 258  m4_pushdef([AT_YYLEX_ARGS],        [])
 259  m4_pushdef([AT_USE_LEX_ARGS],    [])
 260  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 261  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 262 ])
 263
 264 # Handle the different types of location components.
 265
 266 AT_SKEL_CC_IF(
 267   [AT_LOCATION_TYPE_IF(
 268     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 269     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 270   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 271
 272
 273 AT_GLR_IF([AT_KEYWORDS([glr])])
 274 ])# _AT_BISON_OPTION_PUSHDEFS
 275
 276
 277 # AT_BISON_OPTION_POPDEFS
 278 # -----------------------
 279 m4_define([AT_BISON_OPTION_POPDEFS],
 280 [m4_divert_text([KILL],
 281 [m4_popdef([AT_YYLEX_PRE_ARGS])
 282 m4_popdef([AT_YYLEX_PRE_FORMALS])
 283 m4_popdef([AT_USE_LEX_ARGS])
 284 m4_popdef([AT_YYLEX_ARGS])
 285 m4_popdef([AT_YYLEX_FORMALS])
 286 m4_popdef([AT_YYLTYPE])
 287 m4_popdef([AT_YYSTYPE])
 288 m4_popdef([AT_VAL])
 289 m4_popdef([AT_LOC])
 290 m4_popdef([AT_PURE_LEX_IF])
 291 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 292 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 293 m4_popdef([AT_API_PREFIX])
 294 m4_popdef([AT_API_prefix])
 295 m4_popdef([AT_VARIANT_IF])
 296 m4_popdef([AT_TOKEN_PREFIX])
 297 m4_popdef([AT_TOKEN_CTOR_IF])
 298 m4_popdef([AT_NAME_PREFIX])
 299 m4_popdef([AT_LOCATION_TYPE_IF])
 300 m4_popdef([AT_LOCATION_IF])
 301 m4_popdef([AT_PARSE_PARAMS])
 302 m4_popdef([AT_PARAM_IF])
 303 m4_popdef([AT_LEXPARAM_IF])
 304 m4_popdef([AT_YACC_IF])
 305 m4_popdef([AT_GLR_IF])
 306 m4_popdef([AT_SKEL_CC_IF])
 307 m4_popdef([AT_LANG])
 308 m4_popdef([AT_SKEL_JAVA_IF])
 309 m4_popdef([AT_GLR_CC_IF])
 310 m4_popdef([AT_LALR1_CC_IF])
 311 m4_popdef([AT_DEFINES_IF])
 312 m4_popdef([AT_DEBUG_IF])
 313 AT_LOC_POPDEF])dnl
 314 ])# AT_BISON_OPTION_POPDEFS
 315
 316
 317
 318 ## -------------------------- ##
 319 ## Generating Grammar Files.  ##
 320 ## -------------------------- ##
 321
 322 # _AT_LANG_DISPATCH(LANG, MACRO, ARGS)
 323 # ------------------------------------
 324 # Call the specialization of MACRO for LANG with ARGS.  Complain if
 325 # unavailable.
 326 m4_define([_AT_LANG_DISPATCH],
 327 [m4_ifdef([$2($1)],
 328        [m4_indir([$2($1)], m4_shift2($@))],
 329        [m4_fatal([$2: unknown language: $1])])])
 330
 331
 332 # AT_LANG_DISPATCH(MACRO, ARGS)
 333 # -----------------------------
 334 # Call the specialization of MACRO for AT_LANG with ARGS.  Complain if
 335 # unavailable.
 336 m4_define([AT_LANG_DISPATCH],
 337 [_AT_LANG_DISPATCH(AT_LANG, $@)])
 338
 339
 340
 341 # AT_DATA_SOURCE_PROLOGUE
 342 # -----------------------
 343 # The prologue that should be included in any source code that is
 344 # meant to be compiled.  Keep atlocal.in sync (BISON_CXX_WORKS).
 345 m4_define([AT_DATA_SOURCE_PROLOGUE],
 346 [[#include <config.h>
 347 /* We don't need perfect functions for these tests. */
 348 #undef malloc
 349 #undef memcmp
 350 #undef realloc
 351 ]])
 352
 353 # AT_DATA_GRAMMAR_PROLOGUE
 354 # ------------------------
 355 # The prologue that should be included in any grammar which parser is
 356 # meant to be compiled.
 357 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 358 [[%code top {
 359 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 360 [}
 361 ]])
 362
 363 # AT_DATA_SOURCE(NAME, CONTENT)
 364 # -----------------------------
 365 # Generate the file NAME, which CONTENT is preceded by
 366 # AT_DATA_SOURCE_PROLOGUE.
 367 m4_define([AT_DATA_SOURCE],
 368 [AT_DATA([$1],
 369 [AT_DATA_SOURCE_PROLOGUE
 370 $2])
 371 ])
 372
 373 # AT_DATA_GRAMMAR(NAME, CONTENT)
 374 # ------------------------------
 375 # Generate the file NAME, which CONTENT is preceded by
 376 # AT_DATA_GRAMMAR_PROLOGUE.
 377 m4_define([AT_DATA_GRAMMAR],
 378 [AT_DATA([$1],
 379 [AT_DATA_GRAMMAR_PROLOGUE
 380 $2])
 381 ])
 382
 383 # AT_YYLEX_PROTOTYPE
 384 # AT_YYLEX_DECLARE_EXTERN
 385 # AT_YYLEX_DECLARE
 386 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 387 # ----------------------------------
 388 # INPUT can be empty, or in double quotes, or a list (in braces).
 389 # ACTION may compute yylval for instance, using "res" as token type,
 390 # and "toknum" as the number of calls to yylex (starting at 0).
 391 m4_define([AT_YYLEX_PROTOTYPE],
 392 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 393 ])
 394
 395 m4_define([AT_YYLEX_DECLARE_EXTERN],
 396 [AT_YYLEX_PROTOTYPE;dnl
 397 ])
 398
 399 m4_define([AT_YYLEX_DECLARE],
 400 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 401 ])
 402
 403 m4_define([AT_YYLEX_DEFINE],
 404 [[#include <assert.h>
 405 static
 406 ]AT_YYLEX_PROTOTYPE[
 407 {
 408   ]m4_bmatch([$1], [^\(".*"\)?$],
 409              [[static char const input[] = ]m4_default([$1], [""])],
 410              [[static int const input[] = ]$1])[;
 411   static size_t toknum = 0;
 412   int res;
 413   ]AT_USE_LEX_ARGS[;
 414   assert (toknum < sizeof input / sizeof input[0]);
 415   res = input[toknum++];
 416   ]$2[;]AT_LOCATION_IF([[
 417   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 418   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 419   return res;
 420 }]dnl
 421 ])
 422
 423 # AT_YYERROR_FORMALS
 424 # AT_YYERROR_PROTOTYPE
 425 # AT_YYERROR_DECLARE_EXTERN
 426 # AT_YYERROR_DECLARE
 427 # AT_YYERROR_DEFINE
 428 # -------------------------
 429 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 430 m4_define([AT_YYERROR_FORMALS],  [AT_LANG_DISPATCH([$0], $@)])
 431 m4_define([AT_YYERROR_PROTOTYPE],[AT_LANG_DISPATCH([$0], $@)])
 432 m4_define([AT_YYERROR_DECLARE_EXTERN], [AT_LANG_DISPATCH([$0], $@)])
 433 m4_define([AT_YYERROR_DECLARE],  [AT_LANG_DISPATCH([$0], $@)])
 434 m4_define([AT_YYERROR_DEFINE],   [AT_LANG_DISPATCH([$0], $@)])
 435
 436 # AT_MAIN_DEFINE
 437 # --------------
 438 m4_define([AT_MAIN_DEFINE],   [AT_LANG_DISPATCH([$0], $@)])
 439
 440
 441
 442 ## --- ##
 443 ## C.  ##
 444 ## --- ##
 445
 446 m4_define([AT_YYERROR_FORMALS(c)],
 447 [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE const * const llocp, ])AT_PARSE_PARAMS[const char *msg]])
 448
 449 m4_define([AT_YYERROR_PROTOTYPE(c)],
 450 [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])
 451
 452 m4_define([AT_YYERROR_DECLARE_EXTERN(c)],
 453 [AT_YYERROR_PROTOTYPE;])
 454
 455 m4_define([AT_YYERROR_DECLARE(c)],
 456 [#include <stdio.h>
 457 ]AT_LOCATION_IF([[
 458 #if defined ]AT_YYLTYPE[_IS_TRIVIAL && ]AT_YYLTYPE[_IS_TRIVIAL
 459 static unsigned location_print (FILE *yyo, ]AT_YYLTYPE[ const * const yylocp);
 460 # ifndef LOCATION_PRINT
 461 #  define LOCATION_PRINT(File, Loc) location_print (File, &(Loc))
 462 # endif
 463 #endif
 464 ]])[
 465 static AT_YYERROR_DECLARE_EXTERN])
 466
 467
 468 m4_define([AT_YYERROR_DEFINE(c)],
 469 [[
 470 ]AT_LOCATION_IF([[
 471 # if defined ]AT_YYLTYPE[_IS_TRIVIAL && ]AT_YYLTYPE[_IS_TRIVIAL
 472 /* Print *YYLOCP on YYO. */
 473 __attribute__((__unused__))
 474 static unsigned
 475 location_print (FILE *yyo, ]AT_YYLTYPE[ const * const yylocp)
 476 {
 477   unsigned res = 0;
 478   int end_col = 0 != yylocp->last_column ? yylocp->last_column - 1 : 0;
 479   if (0 <= yylocp->first_line)
 480     {
 481       res += fprintf (yyo, "%d", yylocp->first_line);
 482       if (0 <= yylocp->first_column)
 483         res += fprintf (yyo, ".%d", yylocp->first_column);
 484     }
 485   if (0 <= yylocp->last_line)
 486     {
 487       if (yylocp->first_line < yylocp->last_line)
 488         {
 489           res += fprintf (yyo, "-%d", yylocp->last_line);
 490           if (0 <= end_col)
 491             res += fprintf (yyo, ".%d", end_col);
 492         }
 493       else if (0 <= end_col && yylocp->first_column < end_col)
 494         res += fprintf (yyo, "-%d", end_col);
 495     }
 496   return res;
 497 }
 498 #endif
 499 ]])[
 500 /* A C error reporting function.  */
 501 static
 502 ]AT_YYERROR_PROTOTYPE[
 503 {]m4_bpatsubst(m4_defn([AT_PARSE_PARAMS]),
 504               [[^,]+[^A-Za-z_0-9]\([A-Za-z_][A-Za-z_0-9]*\), *], [
 505   YYUSE(\1);])dnl
 506 AT_YYERROR_SEES_LOC_IF([[
 507   LOCATION_PRINT (stderr, ]AT_LOC[);
 508   fprintf (stderr, ": ");]])[
 509   fprintf (stderr, "%s\n", msg);
 510 }]])
 511
 512
 513 m4_define([AT_MAIN_DEFINE(c)],
 514 [[#include <stdlib.h> /* getenv. */
 515 #include <string.h> /* strcmp. */
 516 int
 517 main (int argc, char const* argv[])
 518 {]AT_DEBUG_IF([[
 519   if (getenv("YYDEBUG")
 520       || (argc == 2
 521           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 522     yydebug |= 1;]], [[
 523   (void) argc;
 524   (void) argv;]])[
 525   return ]AT_NAME_PREFIX[parse ();
 526 }]])
 527
 528
 529 ## ----- ##
 530 ## C++.  ##
 531 ## ----- ##
 532
 533 # No need to declare, it's part of the class interface.
 534 m4_define([AT_YYERROR_DECLARE(c++)],        [])
 535 m4_define([AT_YYERROR_DECLARE_EXTERN(c++)], [])
 536
 537 m4_define([AT_YYERROR_DEFINE(c++)],
 538 [[/* A C++ error reporting function.  */
 539 void
 540 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 541 {
 542   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 543 }]])
 544
 545
 546 m4_define([AT_MAIN_DEFINE(c++)],
 547 [[#include <cstdlib> // getenv.
 548 #include <cstring> // strcmp.
 549 int
 550 main (int argc, char const* argv[])
 551 {
 552   ]AT_NAME_PREFIX[::parser p;]AT_DEBUG_IF([[
 553   if (getenv("YYDEBUG")
 554       || (argc == 2
 555           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 556     p.set_debug_level (true);]], [[
 557   (void) argc;
 558   (void) argv;]])[
 559   return p.parse ();
 560 }]])
 561
 562
 563
 564 ## ------ ##
 565 ## Java.  ##
 566 ## ------ ##
 567
 568 m4_define([AT_YYERROR_DEFINE(java)],
 569 [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 570 {
 571     if (l == null)
 572       System.err.println (s);
 573     else
 574       System.err.println (l + ": " + s);
 575   }
 576 ]], [[
 577   public void yyerror (String s)
 578   {
 579     System.err.println (s);
 580   }
 581 ]])])
 582
 583 m4_define([AT_MAIN_DEFINE(java)],
 584 [[class input
 585 {
 586   public static void main (String args[]) throws IOException
 587   {
 588     YYParser p = new YYParser ();
 589     p.parse ();
 590   }
 591 }]])
 592
 593
 594
 595 ## --------------- ##
 596 ## Running Bison.  ##
 597 ## --------------- ##
 598
 599 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 600 # -------------------------------------------------
 601 # High-level routine that may call bison several times, under different
 602 # conditions.
 603 #
 604 # Check Bison by invoking 'bison BISON_ARGS'.  BISON_ARGS should not contain
 605 # shell constructs (such as redirection or pipes) that would prevent
 606 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 607 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 608 #
 609 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 610 # Bison in the test suite.  For now it ensures that:
 611 #
 612 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 613 #      a non-zero exit status since Bison doesn't always try to free all memory
 614 #      in that case.
 615 #
 616 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 617 #      --graph and --report=all output for every working grammar.
 618 #
 619 #   3. If stderr contains a warning, -Werror and --warnings=error
 620 #      convert the warning to an error.
 621 #
 622 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 623 m4_define([AT_BISON_CHECK],
 624 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 625 AT_BISON_CHECK_NO_XML($@)])
 626
 627 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 628 # --------------------------------------------------
 629 # Low-level macro to run bison once.
 630 m4_define([AT_BISON_CHECK_],
 631 [AT_CHECK(AT_QUELL_VALGRIND[[ bison -fno-caret ]]$@)])
 632
 633
 634 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 635 # ----------------------------------------------------------
 636 # Check that warnings (if some are expected) are correctly
 637 # turned into errors with -Werror, etc.
 638 #
 639 # When -Wno-error is used, the rules are really different, don't try.
 640 m4_define([AT_BISON_CHECK_WARNINGS],
 641 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 642        m4_bregexp([$1], [-Wno-error=]), [-1],
 643                   [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 644
 645 m4_define([AT_BISON_CHECK_WARNINGS_],
 646 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 647 # added after the grammar file name, so skip these checks in that
 648 # case.
 649 if test "$POSIXLY_CORRECT_IS_EXPORTED" = false; then
 650           ]AT_SAVE_SPECIAL_FILES[
 651
 652   # To avoid expanding it repeatedly, store specified stdout.
 653   ]AT_DATA([expout], [$3])[
 654
 655   # Run with -Werror.
 656   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 657
 658   # Build expected stderr up to and including the "warnings being
 659   # treated as errors" message.
 660   ]AT_DATA([[experr]], [$4])[
 661   $PERL -pi -e 's{(.*): warning: (.*)\[-W(.*)\]$}
 662                  {$][1: error: $][2\@<:@-Werror=$][3@:>@}' experr
 663   ]AT_CHECK([[sed 's,.*/$,,' stderr 1>&2]], [[0]], [[]], [experr])[
 664
 665   # Now check --warnings=error.
 666   cp stderr experr
 667   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 668
 669   # Now check -Wnone and --warnings=none by making sure that
 670   # -Werror doesn't change the exit status when -Wnone or
 671   # --warnings=none is specified.
 672   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 673   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 674
 675   ]AT_RESTORE_SPECIAL_FILES[
 676 fi]dnl
 677 ])
 678
 679 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 680 # --------------------------------------------------------
 681 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 682 # when a tortured grammar's XML is known to be too large for xsltproc to
 683 # handle.
 684 m4_define([AT_BISON_CHECK_NO_XML],
 685 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison -fno-caret ]]$@)
 686 AT_BISON_CHECK_WARNINGS($@)])
 687
 688 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 689 # -----------------------------------------------------
 690 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 691 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 692 # have a non-zero exit status.
 693 m4_define([AT_BISON_CHECK_XML],
 694 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 695   AT_SAVE_SPECIAL_FILES
 696   [mkdir xml-tests]
 697   m4_pushdef([AT_BISON_ARGS],
 698              [m4_bpatsubsts([[$1]],
 699                             [--report(-file)?=[^][ ]*], [],
 700                             [--graph=[^][ ]*], [],
 701                             [--xml=[^][ ]*], [])])dnl
 702   # Don't combine these Bison invocations since we want to be sure that
 703   # --report=all isn't required to get the full XML file.
 704   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 705              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 706            [[0]], [ignore], [ignore])
 707   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 708            [[0]], [ignore], [ignore])
 709   m4_popdef([AT_BISON_ARGS])dnl
 710   [cp xml-tests/test.output expout]
 711   AT_CHECK([[$XSLTPROC \
 712              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 713              xml-tests/test.xml]], [[0]], [expout])
 714   [sort xml-tests/test.dot > expout]
 715   AT_CHECK([[$XSLTPROC \
 716              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 717              xml-tests/test.xml | sort]], [[0]], [expout])
 718   [rm -rf xml-tests expout]
 719   AT_RESTORE_SPECIAL_FILES
 720 [fi]])
 721
 722 # AT_QUELL_VALGRIND
 723 # -----------------
 724 # Put this before a Bison invocation to keep Valgrind from complaining about
 725 # reachable memory.
 726 #
 727 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 728 # The triple quoting below will cause test cases to fail if you do.  If you do
 729 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 730 # will then fail to shell-escape its contents when attempting to print them.
 731 # The testsuite verbose output, at least, will be incorrect, but nothing may
 732 # fail to make sure you notice.
 733 m4_define([AT_QUELL_VALGRIND],
 734 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 735
 736
 737
 738 ## ------------------------ ##
 739 ## Compiling C, C++ Files.  ##
 740 ## ------------------------ ##
 741
 742
 743 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 744 # ----------------------------------------
 745 # Compile SOURCES into OUTPUT.
 746 #
 747 # If OUTPUT does not contain '.', assume that we are linking too,
 748 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 749 # with trailing .o removed, and ".c" appended.
 750 m4_define([AT_COMPILE],
 751 [AT_CHECK([$BISON_C_WORKS], 0, ignore, ignore)
 752 AT_CHECK(m4_join([ ],
 753                   [$CC $CFLAGS $CPPFLAGS],
 754                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 755                   [-o $1],
 756                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 757                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 758            0, [ignore], [ignore])])
 759
 760
 761 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 762 # ---------------------------------------------
 763 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 764 # ignore the test.
 765 #
 766 # If OUTPUT does not contain '.', assume that we are linking too,
 767 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 768 # with trailing ".o" removed, and ".cc" appended.
 769 m4_define([AT_COMPILE_CXX],
 770 [AT_KEYWORDS(c++)
 771 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 772 AT_CHECK(m4_join([ ],
 773                  [$CXX $CXXFLAGS $CPPFLAGS],
 774                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 775                  [-o $1],
 776                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 777                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 778          0, [ignore], [ignore])])
 779
 780
 781 # AT_JAVA_COMPILE(SOURCES)
 782 # ------------------------
 783 # Compile SOURCES into Java class files.  Skip the test if java or javac
 784 # is not installed.
 785 m4_define([AT_JAVA_COMPILE],
 786 [AT_KEYWORDS(java)
 787 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 788 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 789 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 790          [[0]], [ignore], [ignore])])
 791
 792
 793 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 794 # --------------------------------------------
 795 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 796 #
 797 # If OUTPUT does not contain '.', assume that we are linking too,
 798 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 799 # with trailing .o removed, and ".c"/".cc" appended.
 800 m4_define([AT_LANG_COMPILE],  [AT_LANG_DISPATCH([$0], $@)])
 801 m4_define([AT_LANG_COMPILE(c)],    [AT_COMPILE([$1], [$2])])
 802 m4_define([AT_LANG_COMPILE(c++)],  [AT_COMPILE_CXX([$1], [$2])])
 803 m4_define([AT_LANG_COMPILE(java)], [AT_JAVA_COMPILE([$1.java], [$2])])
 804
 805
 806 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 807 # -------------------------------------------
 808 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 809 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 810 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 811 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 812 # AT_SKEL_JAVA_IF.
 813 m4_define([AT_FULL_COMPILE],  [AT_LANG_DISPATCH([$0], $@)])
 814 m4_define([AT_FULL_COMPILE(c)],
 815 [AT_BISON_CHECK([-o $1.c $1.y])
 816  AT_LANG_COMPILE([$1],
 817                  m4_join([ ],
 818                          [$1.c],
 819                          m4_ifval($2, [[$1-$2.c]]),
 820                          m4_ifval($3, [[$1-$3.c]])))])
 821
 822 m4_define([AT_FULL_COMPILE(c++)],
 823 [AT_BISON_CHECK([-o $1.cc $1.y])
 824  AT_LANG_COMPILE([$1],
 825                  m4_join([ ],
 826                          [$1.cc],
 827                          m4_ifval($2, [[$1-$2.cc]]),
 828                          m4_ifval($3, [[$1-$3.cc]])))])
 829
 830 m4_define([AT_FULL_COMPILE(java)],
 831 [AT_BISON_CHECK([-o $1.java $1.y])
 832  AT_LANG_COMPILE([$1],
 833                  m4_join([ ],
 834                          [$1.java],
 835                          m4_ifval($2, [[$1-$2.java]]),
 836                          m4_ifval($3, [[$1-$3.java]])))])
 837
 838
 839
 840
 841 # AT_SKIP_IF_CANNOT_LINK_C_AND_CXX
 842 # --------------------------------
 843 # Check that we can link together C and C++ objects.
 844 m4_define([AT_SKIP_IF_CANNOT_LINK_C_AND_CXX],
 845 [AT_DATA([c-and-cxx.h],
 846 [[#ifdef __cplusplus
 847 extern "C"
 848 {
 849 #endif
 850   int fortytwo (void);
 851 #ifdef __cplusplus
 852 }
 853 #endif
 854 ]])
 855 AT_DATA([c-only.c],
 856 [[#include "c-and-cxx.h"
 857 int
 858 main (void)
 859 {
 860   return fortytwo () == 42 ? 0 : 1;
 861 }
 862 ]])
 863 AT_DATA([cxx-only.cc],
 864 [[#include "c-and-cxx.h"
 865 int fortytwo ()
 866 {
 867   return 42;
 868 }
 869 ]])
 870 AT_COMPILE([c-only.o], [c-only.c])
 871 AT_COMPILE_CXX([cxx-only.o], [cxx-only.cc])
 872 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS $LDFLAGS c-only.o cxx-only.o -o c-and-cxx ||
 873           exit 77], [ignore], [ignore])
 874 AT_PARSER_CHECK([./c-and-cxx])
 875 ])
 876
 877
 878 # AT_SKIP_IF_EXCEPTION_SUPPORT_IS_POOR
 879 # ------------------------------------
 880 # Check that we can expect exceptions to be handled properly.
 881 # GCC 4.3 and 4.4 fail https://trac.macports.org/ticket/40853.
 882 m4_define([AT_SKIP_IF_EXCEPTION_SUPPORT_IS_POOR],
 883 [AT_DATA_SOURCE([exception.cc],
 884 [[#include <iostream>
 885 #include <stdexcept>
 886
 887 void foo()
 888 {
 889   try
 890     {
 891       throw std::runtime_error("foo");
 892     }
 893   catch (...)
 894     {
 895       std::cerr << "Inner caught" << std::endl;
 896       throw;
 897     }
 898 }
 899
 900 int main()
 901 {
 902   try
 903     {
 904       foo();
 905     }
 906   catch (...)
 907     {
 908       std::cerr << "Outer caught" << std::endl;
 909       return 0;
 910     }
 911   return 1;
 912 }
 913 ]])
 914 AT_COMPILE_CXX([exception])
 915 # The "empty" quadrigraph is to protect from cfg.mk's
 916 # sc_at_parser_check.
 917 AT_CHECK([@&t@./exception || exit 77], [0], [], [ignore])
 918 ])
 919
 920
 921 ## ---------------------------- ##
 922 ## Running a generated parser.  ##
 923 ## ---------------------------- ##
 924
 925
 926 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 927 # ------------------------------------------------------------
 928 # So that we can run './testsuite PREPARSER='valgrind -q' for instance.
 929 #
 930 # Get rid of spurious messages when compiled with --coverage:
 931 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 932 m4_define([AT_PARSER_CHECK],
 933 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 934 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 935          [0], [], [$4])
 936 ])
 937
 938
 939 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 940 # -----------------------------------------------------------------
 941 m4_define([AT_JAVA_PARSER_CHECK],
 942 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 943
 944
 945 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 946 #                          DECLS, GRAMMAR, INPUT,
 947 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 948 #                          [OTHER-CHECKS],
 949 #                          [PARSER-EXIT-VALUE],
 950 #                          [PARSER-STDOUT], [PARSER-STDERR])
 951 # -------------------------------------------------------------
 952 # Using TITLE as the test group title, check the generated parser tables
 953 # and parser for a specified grammar file under a condition labeled by
 954 # COND-VALUE.
 955 #
 956 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 957 # recognized attribute is described below where it is relevant.
 958 #
 959 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 960 # the grammar file.  Insert basic yyerror, yylex, and main function
 961 # definitions as well.  Hardcode yylex to return the (possibly empty)
 962 # comma-delimited series of tokens in INPUT followed by token 0.
 963 #
 964 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 965 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 966 # On the bison command-line, specify `--report=all --defines'.  Check
 967 # that Bison exits with value 0, has no stdout, and has stderr
 968 # BISON-STDERR.
 969 #
 970 # If TEST-SPEC contains the attribute 'last-state', check that the value
 971 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 972 # the grammar; in other words, check the number of states (minus one).
 973 # Otherwise, check that everything in the '.output' file starting with
 974 # the definition of state 0 is the same as the entire value of
 975 # TABLES-OR-LAST-STATE.
 976 #
 977 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 978 # '.output' file, which is named 'input.output', and/or grammar file,
 979 # which is named 'input.y'.
 980 #
 981 # Finally, compile the generated parser and then run it using
 982 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 983 # PARSER-STDERR as the 2nd-4th arguments.
 984 #
 985 # As a precondition, you must properly double-quote all arguments that
 986 # are to be interpreted as strings.
 987 #
 988 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 989 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 990 # first argument.  This is useful, for example, when wrapping multiple
 991 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 992 # condition, in another macro.
 993 #
 994 # For example:
 995 #
 996 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 997 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 998 #   # ---------------------------------------------------------------------
 999 #   m4_define([AT_TEST_SYNTAX_ERROR],
1000 #   [
1001 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
1002 #                              [[last-state]],
1003 #                              [[%error-verbose ]$2], [$3], [$4],
1004 #                              [[]], [$5], [], [$6], [$7], [$8])
1005 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
1006 #                              [[last-state]],
1007 #                              [$2], [$3], [$4],
1008 #                              [[]], [$5], [], [$6], [$7], [$8])
1009 #   ])
1010 #
1011 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
1012 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
1013 #                        [[3]],
1014 #                        [[1]], [[]],
1015 #                        [AT_COND_CASE([[no verbose]],
1016 #                                      [[syntax error
1017 #   ]],
1018 #                                      [[syntax error, unexpected 'b', expecting $end
1019 #   ]])])
1020 m4_define([AT_TEST_TABLES_AND_PARSE],
1021 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
1022
1023 AT_SETUP([$1])
1024 AT_BISON_OPTION_PUSHDEFS([$4])
1025 AT_DATA_GRAMMAR([[input.y]],
1026 [[%code {
1027   ]AT_YYERROR_DECLARE[
1028   ]AT_YYLEX_DECLARE[
1029 }
1030
1031 ]$4[
1032
1033 %%
1034
1035 ]$5[
1036
1037 %%
1038 ]AT_YYERROR_DEFINE[
1039 static int
1040 yylex (void)
1041 {
1042   static int const input[] = {
1043     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
1044   };
1045   static int const *inputp = input;
1046   return *inputp++;
1047 }
1048
1049 ]AT_MAIN_DEFINE[
1050 ]])
1051
1052 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
1053 # expanding macros, so it corrupts some special characters in the
1054 # macros.  To avoid this, expand now and pass it the result with proper
1055 # string quotation.  Assume args 7 through 12 expand to properly quoted
1056 # strings.
1057
1058 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
1059       [AT_BISON_CHECK],
1060       [AT_BISON_CHECK_NO_XML])([[-Wall --report=all --defines -o input.c input.y]],
1061                                [0], [], m4_dquote($7))
1062
1063 m4_if(m4_index(m4_quote($3), [last-state]), -1,
1064       [AT_CHECK([[sed -n '/^State 0$/,$p' input.output]], [[0]],
1065                 m4_dquote($8))],
1066       [AT_CHECK([[sed -n 's/^State //p' input.output | tail -1]], [[0]],
1067                 m4_dquote($8)[[
1068 ]])])
1069
1070 $9
1071
1072 # Canonical LR generates very large tables, resulting in very long
1073 # files with #line directives that may overflow what the standards
1074 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
1075 # will issue an error.
1076 #
1077 # There is no "" around `wc` since some indent the result.
1078 m4_bmatch([$4], [%define lr.type canonical-lr],
1079 [if test 32767 -lt `wc -l < input.c`; then
1080   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic / /'`
1081   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic / /'`
1082 fi])
1083 AT_COMPILE([[input]])
1084
1085 AT_PARSER_CHECK([[./input]],
1086                 m4_ifval([$10], [m4_dquote($10)]),
1087                 m4_ifval([$11], [m4_dquote($11)]),
1088                 m4_ifval([$12], [m4_dquote($12)]))
1089
1090 AT_BISON_OPTION_POPDEFS
1091 AT_CLEANUP
1092
1093 m4_popdef([AT_COND_CASE])])
1094
1095
1096
1097
1098 ## ----------------------- ##
1099 ## Launch the test suite.  ##
1100 ## ----------------------- ##
1101
1102 AT_INIT
1103
1104 # AT_SETUP([TITLE])
1105 # -----------------
1106 # Redefine AT_SETUP to be more concise.  Must be done after AT_INIT.
1107 m4_copy_force([AT_SETUP], [B4_SETUP])
1108 m4_define([AT_SETUP],
1109 [B4_SETUP(m4_expand([AT_SETUP_STRIP([[$1]])]))])
1110
1111 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
1112 # options are processed, so we don't know the value of CXX and
1113 # CXXFLAGS yet.
1114 #
1115 # Note that it also means that command line values for CXX and
1116 # CXXFLAGS will not be propagated to CC and CFLAGS.
1117 AT_ARG_OPTION([compile-c-with-cxx],
1118               [compile C parsers with the C++ compiler])
1119
1120 AT_COLOR_TESTS
1121
1122 AT_TESTED([bison])