configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2012])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz silent-rules]
  49                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  50                            [gnu], [gnits]))
  51 AM_SILENT_RULES([yes])
  52 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  53
  54 # Checks for the compiler.
  55 AC_PROG_CC_STDC
  56 AC_PROG_CXX
  57
  58 # Gnulib (early checks).
  59 gl_EARLY
  60
  61 AC_ARG_ENABLE([gcc-warnings],
  62 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  63 [case $enable_gcc_warnings in
  64    yes|no) ;;
  65    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  66  esac],
  67               [enable_gcc_warnings=no])
  68 if test "$enable_gcc_warnings" = yes; then
  69   warn_common='-Wall -Wextra -Wno-sign-compare -Wcast-align
  70     -Wcast-qual -Wformat -Wpointer-arith -Wwrite-strings'
  71   warn_c='-Wbad-function-cast -Wmissing-declarations -Wmissing-prototypes
  72     -Wshadow -Wstrict-prototypes'
  73   warn_cxx='-Wnoexcept'
  74   AC_LANG_PUSH([C])
  75   # Clang supports many of GCC's -W options, but only issues warnings
  76   # on the ones it does not recognize.  In that case, gl_WARN_ADD
  77   # thinks the option is supported, and unknown options are then added
  78   # to CFLAGS.  But then, when -Werror is added in the test suite for
  79   # instance, the warning about the unknown option turns into an
  80   # error.
  81   #
  82   # This should be addressed by gnulib's gl_WARN_ADD, but in the
  83   # meanwhile, turn warnings about unknown options into errors in
  84   # CFLAGS, and restore CFLAGS after the tests.
  85   save_CFLAGS=$CFLAGS
  86   gl_WARN_ADD([-Werror=unknown-warning-option], [CFLAGS])
  87   for i in $warn_common $warn_c;
  88   do
  89     gl_WARN_ADD([$i], [WARN_CFLAGS])
  90   done
  91   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  92   # Warnings for the test suite only.
  93   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  94   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
  95   CFLAGS=$save_CFLAGS
  96   AC_LANG_POP([C])
  97
  98   AC_LANG_PUSH([C++])
  99   save_CXXFLAGS=$CXXFLAGS
 100   gl_WARN_ADD([-Werror=unknown-warning-option], [CXXFLAGS])
 101   for i in $warn_common $warn_cxx;
 102   do
 103     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
 104   done
 105   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
 106               [AC_LANG_PROGRAM([], [nullptr])])
 107   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
 108   # Warnings for the test suite only.
 109   gl_WARN_ADD([-Wundef], [WARN_CXXFLAGS_TEST])
 110   gl_WARN_ADD([-pedantic], [WARN_CXXFLAGS_TEST])
 111   CXXFLAGS=$save_CXXFLAGS
 112   AC_LANG_POP([C++])
 113 fi
 114
 115 BISON_TEST_FOR_WORKING_C_COMPILER
 116 BISON_TEST_FOR_WORKING_CXX_COMPILER
 117 BISON_C_COMPILER_POSIXLY_CORRECT
 118
 119 AC_ARG_ENABLE([yacc],
 120   [AC_HELP_STRING([--disable-yacc],
 121      [do not build a yacc command or an -ly library])],
 122   , [enable_yacc=yes])
 123 case $enable_yacc in
 124 yes)
 125   YACC_SCRIPT=yacc
 126   YACC_LIBRARY=liby.a;;
 127 *)
 128   YACC_SCRIPT=
 129   YACC_LIBRARY=;;
 130 esac
 131 AC_SUBST([YACC_SCRIPT])
 132 AC_SUBST([YACC_LIBRARY])
 133
 134 # Checks for programs.
 135 AC_PROG_LEX
 136 $LEX_IS_FLEX || AC_MSG_ERROR([Flex is required])
 137 AC_PROG_YACC
 138 AC_PROG_RANLIB
 139 AC_PROG_GNU_M4
 140 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 141 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 142 supports -g, otherwise to "".])
 143 AC_PATH_PROG([PERL], [perl])
 144 if test -z "$PERL"; then
 145    AC_MSG_ERROR([perl not found])
 146 fi
 147 AM_MISSING_PROG([HELP2MAN], [help2man])
 148 AC_PATH_PROG([XSLTPROC], [xsltproc])
 149 AC_SUBST([XSLTPROC])
 150
 151 # Checks for header files.
 152 AC_CHECK_HEADERS_ONCE([locale.h])
 153
 154 # Checks for compiler characteristics.
 155 AC_C_INLINE
 156
 157 # Gnulib (later checks).  Putting them here rather than right after
 158 # gl_EARLY avoids some redundant checks.
 159 gl_INIT
 160
 161 # Checks for library functions.
 162 AC_CHECK_FUNCS_ONCE([setlocale])
 163 AM_WITH_DMALLOC
 164 BISON_PREREQ_TIMEVAR
 165
 166 # Gettext.
 167 # We use gnulib, which is only guaranteed to work properly with the
 168 # latest Gettext.
 169 AM_GNU_GETTEXT([external], [need-ngettext])
 170 AM_GNU_GETTEXT_VERSION([0.18])
 171 BISON_I18N
 172
 173 # Internationalized parsers.
 174 AC_CONFIG_FILES([runtime-po/Makefile.in])
 175 # Autoconf macros for packages using internationalized parsers.
 176 aclocaldir='${datadir}/aclocal'
 177 AC_SUBST([aclocaldir])
 178
 179 # Create the benchmark script.
 180 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 181
 182 # Initialize the test suite.
 183 AC_CONFIG_TESTDIR(tests)
 184 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 185 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 186 AC_CHECK_PROGS([VALGRIND], [valgrind])
 187 case $VALGRIND:$host_os in
 188   '':*) ;;
 189   *:darwin*)
 190     # See README-hacking.
 191     # VALGRIND+=' --suppressions=$(abs_top_srcdir)/build-aux/darwin11.4.0.valgrind'
 192     VALGRIND=;;
 193   *:*)
 194     AC_SUBST([VALGRIND_PREBISON], ["$VALGRIND -q"]);;
 195 esac
 196
 197 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 198 # Needed by tests/atlocal.in.
 199 AC_SUBST([GCC])
 200
 201 gt_JAVACOMP([1.3])
 202 gt_JAVAEXEC
 203
 204 AC_CONFIG_FILES([Makefile
 205                  build-aux/Makefile
 206                  po/Makefile.in
 207                  data/Makefile
 208                  etc/Makefile
 209                  examples/Makefile
 210                     examples/calc++/Makefile
 211                  lib/Makefile src/Makefile
 212                  doc/Makefile
 213                    doc/yacc.1])
 214 AC_OUTPUT