src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include <strverscmp.h>
  27
  28 #include "complain.h"
  29 #include "conflicts.h"
  30 #include "files.h"
  31 #include "getargs.h"
  32 #include "gram.h"
  33 #include "muscle_tab.h"
  34 #include "quotearg.h"
  35 #include "reader.h"
  36 #include "symlist.h"
  37 #include "scan-gram.h"
  38 #include "scan-code.h"
  39
  40 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  41 static YYLTYPE lloc_default (YYLTYPE const *, int);
  42
  43 #define YY_LOCATION_PRINT(File, Loc) \
  44           location_print (File, Loc)
  45
  46 static void version_check (location const *loc, char const *version);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 static char const *char_name (char);
  56
  57 /** Add a lex-param or a parse-param.
  58  *
  59  * \param type  \a lex_param or \a parse_param
  60  * \param decl  the formal argument
  61  * \param loc   the location in the source.
  62  */
  63 static void add_param (char const *type, char *decl, location loc);
  64
  65
  66 static symbol_class current_class = unknown_sym;
  67 static uniqstr current_type = NULL;
  68 static symbol *current_lhs;
  69 static location current_lhs_location;
  70 static int current_prec = 0;
  71
  72 #define YYTYPE_INT16 int_fast16_t
  73 #define YYTYPE_INT8 int_fast8_t
  74 #define YYTYPE_UINT16 uint_fast16_t
  75 #define YYTYPE_UINT8 uint_fast8_t
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86
  87 %initial-action
  88 {
  89   /* Bison's grammar can initial empty locations, hence a default
  90      location is needed. */
  91   boundary_set (&@$.start, current_file, 1, 1);
  92   boundary_set (&@$.end, current_file, 1, 1);
  93 }
  94
  95 /* Only NUMBERS have a value.  */
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char *chars;
 102   assoc assoc;
 103   uniqstr uniqstr;
 104   unsigned char character;
 105 };
 106
 107 /* Define the tokens together with their human representation.  */
 108 %token GRAM_EOF 0 "end of file"
 109 %token STRING     "string"
 110 %token INT        "integer"
 111
 112 %token PERCENT_TOKEN       "%token"
 113 %token PERCENT_NTERM       "%nterm"
 114
 115 %token PERCENT_TYPE        "%type"
 116 %token PERCENT_DESTRUCTOR  "%destructor"
 117 %token PERCENT_PRINTER     "%printer"
 118
 119 %token PERCENT_LEFT        "%left"
 120 %token PERCENT_RIGHT       "%right"
 121 %token PERCENT_NONASSOC    "%nonassoc"
 122
 123 %token PERCENT_PREC          "%prec"
 124 %token PERCENT_DPREC         "%dprec"
 125 %token PERCENT_MERGE         "%merge"
 126
 127
 128 /*----------------------.
 129 | Global Declarations.  |
 130 `----------------------*/
 131
 132 %token
 133   PERCENT_AFTER_HEADER    "%after-header"
 134   PERCENT_BEFORE_HEADER   "%before-header"
 135   PERCENT_DEBUG           "%debug"
 136   PERCENT_DEFAULT_PREC    "%default-prec"
 137   PERCENT_DEFINE          "%define"
 138   PERCENT_DEFINES         "%defines"
 139   PERCENT_END_HEADER      "%end-header"
 140   PERCENT_ERROR_VERBOSE   "%error-verbose"
 141   PERCENT_EXPECT          "%expect"
 142   PERCENT_EXPECT_RR       "%expect-rr"
 143   PERCENT_FILE_PREFIX     "%file-prefix"
 144   PERCENT_GLR_PARSER      "%glr-parser"
 145   PERCENT_INITIAL_ACTION  "%initial-action"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PURE_PARSER     "%pure-parser"
 156   PERCENT_REQUIRE         "%require"
 157   PERCENT_SKELETON        "%skeleton"
 158   PERCENT_START           "%start"
 159   PERCENT_START_HEADER    "%start-header"
 160   PERCENT_TOKEN_TABLE     "%token-table"
 161   PERCENT_VERBOSE         "%verbose"
 162   PERCENT_YACC            "%yacc"
 163 ;
 164
 165 %token BRACED_CODE     "{...}"
 166 %token CHAR            "char"
 167 %token EPILOGUE        "epilogue"
 168 %token EQUAL           "="
 169 %token ID              "identifier"
 170 %token ID_COLON        "identifier:"
 171 %token PERCENT_PERCENT "%%"
 172 %token PIPE            "|"
 173 %token PROLOGUE        "%{...%}"
 174 %token SEMICOLON       ";"
 175 %token TYPE            "type"
 176
 177 %type <character> CHAR
 178 %printer { fputs (char_name ($$), stderr); } CHAR
 179
 180 /* braceless is not to be used for rule or symbol actions, as it
 181    calls translate_code. */
 182 %type <chars> STRING "{...}" "%{...%}" EPILOGUE braceless content content.opt
 183 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 184          STRING
 185 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 186          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 187
 188 %type <uniqstr> TYPE ID ID_COLON
 189 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 190 %printer { fputs ($$, stderr); } ID
 191 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 192
 193 %type <integer> INT
 194 %printer { fprintf (stderr, "%d", $$); } INT
 195
 196 %type <symbol> id id_colon symbol string_as_id
 197 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 198 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 199
 200 %type <assoc> precedence_declarator
 201 %type <list>  symbols.1
 202 %%
 203
 204 input:
 205   prologue_declarations "%%" grammar epilogue.opt
 206 ;
 207
 208
 209         /*------------------------------------.
 210         | Declarations: before the first %%.  |
 211         `------------------------------------*/
 212
 213 prologue_declarations:
 214   /* Nothing */
 215 | prologue_declarations prologue_declaration
 216 ;
 217
 218 prologue_declaration:
 219   grammar_declaration
 220 | "%{...%}"     { prologue_augment (translate_code ($1, @1), @1, union_seen); }
 221 | "%after-header" braceless        { prologue_augment ($2, @2, true); }
 222 | "%before-header" braceless       { prologue_augment ($2, @2, false); }
 223 | "%debug"                         { debug_flag = true; }
 224 | "%define" STRING content.opt     { muscle_insert ($2, $3); }
 225 | "%defines"                       { defines_flag = true; }
 226 | "%end-header" braceless          { muscle_code_grow ("end_header", $2, @2); }
 227 | "%error-verbose"                 { error_verbose = true; }
 228 | "%expect" INT                    { expected_sr_conflicts = $2; }
 229 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 230 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; }
 231 | "%glr-parser"
 232     {
 233       nondeterministic_parser = true;
 234       glr_parser = true;
 235     }
 236 | "%initial-action" "{...}"
 237     {
 238       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 239     }
 240 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 241 | "%locations"                  { locations_flag = true; }
 242 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; }
 243 | "%no-lines"                   { no_lines_flag = true; }
 244 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 245 | "%output" "=" STRING          { spec_outfile = $3; }
 246 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 247 | "%pure-parser"                { pure_parser = true; }
 248 | "%require" STRING             { version_check (&@2, $2); }
 249 | "%skeleton" STRING            { skeleton = $2; }
 250 | "%start-header" braceless     { muscle_code_grow ("start_header", $2, @2); }
 251 | "%token-table"                { token_table_flag = true; }
 252 | "%verbose"                    { report_flag = report_states; }
 253 | "%yacc"                       { yacc_flag = true; }
 254 | /*FIXME: Err?  What is this horror doing here? */ ";"
 255 ;
 256
 257 grammar_declaration:
 258   precedence_declaration
 259 | symbol_declaration
 260 | "%start" symbol
 261     {
 262       grammar_start_symbol_set ($2, @2);
 263     }
 264 | "%destructor" "{...}" symbols.1
 265     {
 266       symbol_list *list;
 267       const char *action = translate_symbol_action ($2, @2);
 268       for (list = $3; list; list = list->next)
 269         symbol_destructor_set (list->sym, action, @2);
 270       symbol_list_free ($3);
 271     }
 272 | "%printer" "{...}" symbols.1
 273     {
 274       symbol_list *list;
 275       const char *action = translate_symbol_action ($2, @2);
 276       for (list = $3; list; list = list->next)
 277         symbol_printer_set (list->sym, action, @2);
 278       symbol_list_free ($3);
 279     }
 280 | "%default-prec"
 281     {
 282       default_prec = true;
 283     }
 284 | "%no-default-prec"
 285     {
 286       default_prec = false;
 287     }
 288 ;
 289
 290
 291 /*----------*
 292  | %union.  |
 293  *----------*/
 294
 295 %token PERCENT_UNION "%union";
 296
 297 union_name:
 298   /* Nothing. */ {}
 299 | ID             { muscle_code_grow ("union_name", $1, @1); }
 300 ;
 301
 302 grammar_declaration:
 303   "%union" union_name "{...}"
 304     {
 305       char const *body = $3;
 306
 307       /* Concatenate the %union bodies.  If this is the first %union, make sure
 308          the synchronization line appears after the opening '{' so as not to
 309          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 310          into '\n', and omit the new %union's leading '{'.  */
 311       if (!union_seen)
 312         {
 313           muscle_grow ("stype", "{", "");
 314         }
 315       else
 316         {
 317           char *code = muscle_find ("stype");
 318           code[strlen (code) - 1] = '\n';
 319         }
 320       body++;
 321
 322       union_seen = true;
 323       muscle_code_grow ("stype", body, @3);
 324     }
 325 ;
 326
 327
 328
 329
 330 symbol_declaration:
 331   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 332     {
 333       current_class = unknown_sym;
 334       current_type = NULL;
 335     }
 336 | "%token" { current_class = token_sym; } symbol_defs.1
 337     {
 338       current_class = unknown_sym;
 339       current_type = NULL;
 340     }
 341 | "%type" TYPE symbols.1
 342     {
 343       tag_seen = true;
 344       symbol_list *list;
 345       for (list = $3; list; list = list->next)
 346         symbol_type_set (list->sym, $2, @2);
 347       symbol_list_free ($3);
 348     }
 349 ;
 350
 351 precedence_declaration:
 352   precedence_declarator type.opt symbols.1
 353     {
 354       symbol_list *list;
 355       ++current_prec;
 356       for (list = $3; list; list = list->next)
 357         {
 358           symbol_type_set (list->sym, current_type, @2);
 359           symbol_precedence_set (list->sym, current_prec, $1, @1);
 360         }
 361       symbol_list_free ($3);
 362       current_type = NULL;
 363     }
 364 ;
 365
 366 precedence_declarator:
 367   "%left"     { $$ = left_assoc; }
 368 | "%right"    { $$ = right_assoc; }
 369 | "%nonassoc" { $$ = non_assoc; }
 370 ;
 371
 372 type.opt:
 373   /* Nothing. */ { current_type = NULL; }
 374 | TYPE           { current_type = $1; tag_seen = true; }
 375 ;
 376
 377 /* One or more nonterminals to be %typed. */
 378 symbols.1:
 379   symbol            { $$ = symbol_list_new ($1, @1); }
 380 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 381 ;
 382
 383 /* One token definition.  */
 384 symbol_def:
 385   TYPE
 386      {
 387        current_type = $1;
 388        tag_seen = true;
 389      }
 390 | id
 391      {
 392        symbol_class_set ($1, current_class, @1, true);
 393        symbol_type_set ($1, current_type, @1);
 394      }
 395 | id INT
 396     {
 397       symbol_class_set ($1, current_class, @1, true);
 398       symbol_type_set ($1, current_type, @1);
 399       symbol_user_token_number_set ($1, $2, @2);
 400     }
 401 | id string_as_id
 402     {
 403       symbol_class_set ($1, current_class, @1, true);
 404       symbol_type_set ($1, current_type, @1);
 405       symbol_make_alias ($1, $2, @$);
 406     }
 407 | id INT string_as_id
 408     {
 409       symbol_class_set ($1, current_class, @1, true);
 410       symbol_type_set ($1, current_type, @1);
 411       symbol_user_token_number_set ($1, $2, @2);
 412       symbol_make_alias ($1, $3, @$);
 413     }
 414 ;
 415
 416 /* One or more symbol definitions. */
 417 symbol_defs.1:
 418   symbol_def
 419 | symbol_defs.1 symbol_def
 420 ;
 421
 422
 423         /*------------------------------------------.
 424         | The grammar section: between the two %%.  |
 425         `------------------------------------------*/
 426
 427 grammar:
 428   rules_or_grammar_declaration
 429 | grammar rules_or_grammar_declaration
 430 ;
 431
 432 /* As a Bison extension, one can use the grammar declarations in the
 433    body of the grammar.  */
 434 rules_or_grammar_declaration:
 435   rules
 436 | grammar_declaration ";"
 437 | error ";"
 438     {
 439       yyerrok;
 440     }
 441 ;
 442
 443 rules:
 444   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 445 ;
 446
 447 rhses.1:
 448   rhs                { grammar_current_rule_end (@1); }
 449 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 450 | rhses.1 ";"
 451 ;
 452
 453 rhs:
 454   /* Nothing.  */
 455     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 456 | rhs symbol
 457     { grammar_current_rule_symbol_append ($2, @2); }
 458 | rhs "{...}"
 459     { grammar_current_rule_action_append ($2, @2); }
 460 | rhs "%prec" symbol
 461     { grammar_current_rule_prec_set ($3, @3); }
 462 | rhs "%dprec" INT
 463     { grammar_current_rule_dprec_set ($3, @3); }
 464 | rhs "%merge" TYPE
 465     { grammar_current_rule_merge_set ($3, @3); }
 466 ;
 467
 468
 469 /*-----------*
 470  | content.  |
 471  *-----------*/
 472
 473 content:
 474   STRING
 475 | braceless
 476 ;
 477
 478 /* Some content or "1" by default. */
 479 content.opt:
 480   /* Nothing. */
 481     {
 482       static char one[] = "1";
 483       $$ = one;
 484     }
 485 | content
 486 ;
 487
 488
 489 braceless:
 490   "{...}"
 491     {
 492       $1[strlen ($1) - 1] = '\n';
 493       $$ = translate_code ($1 + 1, @1);
 494     }
 495 ;
 496
 497
 498 /*---------------*
 499  | Identifiers.  |
 500  *---------------*/
 501
 502 /* Identifiers are returned as uniqstr values by the scanner.
 503    Depending on their use, we may need to make them genuine symbols.  */
 504
 505 id:
 506   ID
 507     { $$ = symbol_from_uniqstr ($1, @1); }
 508 | CHAR
 509     {
 510       $$ = symbol_get (char_name ($1), @1);
 511       symbol_class_set ($$, token_sym, @1, false);
 512       symbol_user_token_number_set ($$, $1, @1);
 513     }
 514 ;
 515
 516 id_colon:
 517   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 518 ;
 519
 520
 521 symbol:
 522   id
 523 | string_as_id
 524 ;
 525
 526 /* A string used as an ID: quote it.  */
 527 string_as_id:
 528   STRING
 529     {
 530       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 531       symbol_class_set ($$, token_sym, @1, false);
 532     }
 533 ;
 534
 535 epilogue.opt:
 536   /* Nothing.  */
 537 | "%%" EPILOGUE
 538     {
 539       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 540       gram_scanner_last_string_free ();
 541     }
 542 ;
 543
 544 %%
 545
 546
 547 /* Return the location of the left-hand side of a rule whose
 548    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 549    the right-hand side, and return an empty location equal to the end
 550    boundary of RHS[0] if the right-hand side is empty.  */
 551
 552 static YYLTYPE
 553 lloc_default (YYLTYPE const *rhs, int n)
 554 {
 555   int i;
 556   YYLTYPE loc;
 557
 558   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 559      The bug is fixed in 7.4.2m, but play it safe for now.  */
 560   loc.start = rhs[n].end;
 561   loc.end = rhs[n].end;
 562
 563   /* Ignore empty nonterminals the start of the the right-hand side.
 564      Do not bother to ignore them at the end of the right-hand side,
 565      since empty nonterminals have the same end as their predecessors.  */
 566   for (i = 1; i <= n; i++)
 567     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 568       {
 569         loc.start = rhs[i].start;
 570         break;
 571       }
 572
 573   return loc;
 574 }
 575
 576
 577 /* Add a lex-param or a parse-param (depending on TYPE) with
 578    declaration DECL and location LOC.  */
 579
 580 static void
 581 add_param (char const *type, char *decl, location loc)
 582 {
 583   static char const alphanum[26 + 26 + 1 + 10] =
 584     "abcdefghijklmnopqrstuvwxyz"
 585     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 586     "_"
 587     "0123456789";
 588   char const *name_start = NULL;
 589   char *p;
 590
 591   /* Stop on last actual character.  */
 592   for (p = decl; p[1]; p++)
 593     if ((p == decl
 594          || ! memchr (alphanum, p[-1], sizeof alphanum))
 595         && memchr (alphanum, p[0], sizeof alphanum - 10))
 596       name_start = p;
 597
 598   /* Strip the surrounding '{' and '}', and any blanks just inside
 599      the braces.  */
 600   while (*--p == ' ' || *p == '\t')
 601     continue;
 602   p[1] = '\0';
 603   while (*++decl == ' ' || *decl == '\t')
 604     continue;
 605
 606   if (! name_start)
 607     complain_at (loc, _("missing identifier in parameter declaration"));
 608   else
 609     {
 610       char *name;
 611       size_t name_len;
 612
 613       for (name_len = 1;
 614            memchr (alphanum, name_start[name_len], sizeof alphanum);
 615            name_len++)
 616         continue;
 617
 618       name = xmalloc (name_len + 1);
 619       memcpy (name, name_start, name_len);
 620       name[name_len] = '\0';
 621       muscle_pair_list_grow (type, decl, name);
 622       free (name);
 623     }
 624
 625   gram_scanner_last_string_free ();
 626 }
 627
 628
 629 static void
 630 version_check (location const *loc, char const *version)
 631 {
 632   if (strverscmp (version, PACKAGE_VERSION) > 0)
 633     {
 634       complain_at (*loc, "require bison %s, but have %s",
 635                    version, PACKAGE_VERSION);
 636       exit (63);
 637     }
 638 }
 639
 640 static void
 641 gram_error (location const *loc, char const *msg)
 642 {
 643   complain_at (*loc, "%s", msg);
 644 }
 645
 646 char const *
 647 token_name (int type)
 648 {
 649   return yytname[YYTRANSLATE (type)];
 650 }
 651
 652 static char const *
 653 char_name (char c)
 654 {
 655   if (c == '\'')
 656     return "'\\''";
 657   else
 658     {
 659       char buf[4];
 660       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 661       return quotearg_style (escape_quoting_style, buf);
 662     }
 663 }