tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 ## ------------- ##
  33 ## Basic tests.  ##
  34 ## ------------- ##
  35
  36 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  37 # ------------------------------------------
  38 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  39 # taken in "slurp" mode, i.e., one can match end-of-lines.
  40 m4_define([AT_MATCHES_CHECK],
  41 [AT_CHECK([$PERL -0777 -ne '
  42 my $count = 0;
  43 s{$2}{ ++$count; "" }gem;
  44 printf "$count\n";' $1], [0], [$3
  45 ])])
  46
  47
  48 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  49 # ------------------------------------------------
  50 # Don't interfere with caller's files.
  51 m4_divert_text([PREPARE_TESTS],
  52 [at_save_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       as_fn_error 1 "fatal error: back-up on top of a back-up"
  58     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  59   done
  60 }
  61
  62 at_restore_special_files ()
  63 {
  64   for at_save_file in stderr experr expout
  65   do
  66     test ! -f at-bison-check-$at_save_file.bak ||
  67       mv at-bison-check-$at_save_file.bak $at_save_file
  68   done
  69 }
  70 ])
  71
  72 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  73 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  74
  75
  76
  77 ## ------------------------------- ##
  78 ## Macros decoding Bison options.  ##
  79 ## ------------------------------- ##
  80
  81 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  82 # ----------------------------------------------------------------
  83 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  84 m4_define([AT_LOC_PUSHDEF],
  85 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  86 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  87 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  88 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  89
  90 # AT_LOC_POPDEF
  91 # -------------
  92 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  93 m4_define([AT_LOC_POPDEF],
  94 [m4_popdef([AT_LOC_FIRST_LINE])
  95 m4_popdef([AT_LOC_FIRST_COLUMN])
  96 m4_popdef([AT_LOC_LAST_LINE])
  97 m4_popdef([AT_LOC_LAST_COLUMN])])
  98
  99
 100
 101 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 102 # -----------------------------------------
 103 m4_define([AT_BISON_OPTION_PUSHDEFS],
 104 [m4_divert_text([KILL],
 105                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 106
 107
 108 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 109 # --------------------------------------------------
 110 # This macro works around the impossibility to define macros
 111 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 112 # This sucks hard, GNU M4 should really provide M5-like $$1.
 113 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 114 [m4_if([$1$2], $[1]$[2], [],
 115        [m4_fatal([$0: Invalid arguments: $@])])dnl
 116 m4_pushdef([AT_DEFINES_IF],
 117 [m4_bmatch([$3], [%defines], [$1], [$2])])
 118 m4_pushdef([AT_SKEL_CC_IF],
 119 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 120 m4_pushdef([AT_SKEL_JAVA_IF],
 121 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 122 # The target language: "c", "c++", or "java".
 123 m4_pushdef([AT_LANG],
 124 [AT_SKEL_JAVA_IF([java],
 125                  [AT_SKEL_CC_IF([c++],
 126                                 [c])])])
 127 m4_pushdef([AT_GLR_IF],
 128 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 129 m4_pushdef([AT_LALR1_CC_IF],
 130 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 131 m4_pushdef([AT_GLR_CC_IF],
 132 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 133 # Using yacc.c?
 134 m4_pushdef([AT_YACC_IF],
 135 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 136 m4_pushdef([AT_LEXPARAM_IF],
 137 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 138 m4_pushdef([AT_LOCATION_IF],
 139 [m4_bmatch([$3], [%locations], [$1], [$2])])
 140 m4_pushdef([AT_LOCATION_TYPE_IF],
 141 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 142 m4_pushdef([AT_PARAM_IF],
 143 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 144 # Comma-terminated list of formals parse-parameters.
 145 # E.g., %parse-param { int x } %parse-param {int y} -> "int x, int y, ".
 146 # FIXME: Support grouped parse-param.
 147 m4_pushdef([AT_PARSE_PARAMS])
 148 m4_bpatsubst([$3], [%parse-param { *\([^{}]*[^{} ]\) *}],
 149              [m4_append([AT_PARSE_PARAMS], [\1, ])])
 150
 151 m4_pushdef([AT_PURE_IF],
 152 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 153            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 154            [$2])])
 155 m4_pushdef([AT_NAME_PREFIX],
 156 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 157            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 158            [yy])])
 159 m4_pushdef([AT_TOKEN_CTOR_IF],
 160 [m4_bmatch([$3], [%define api.token.constructor], [$1], [$2])])
 161 m4_pushdef([AT_TOKEN_PREFIX],
 162 [m4_bmatch([$3], [%define api.token.prefix ".*"],
 163            [m4_bregexp([$3], [%define api.token.prefix "\(.*\)"], [\1])])])
 164 m4_pushdef([AT_API_prefix],
 165 [m4_bmatch([$3], [%define api\.prefix ".*"],
 166            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 167            [yy])])
 168 m4_pushdef([AT_API_PREFIX],
 169 [m4_toupper(AT_API_prefix)])
 170 # yyerror receives the location if %location, and if the parser is pure. For
 171 # historical reasons, with the "yacc.c" skeleton, the location is not passed
 172 # unless an additional "%parse-param" is present, or if the purity is defined
 173 # as "full".
 174 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 175 [AT_LOCATION_IF([AT_PURE_IF([m4_bmatch([$3],
 176                                        m4_quote(m4_join([\|],
 177                                                         [%define api.pure "?full"?],
 178                                                         [%glr-parser],
 179                                                         [%parse-param],
 180                                                         [%skeleton "?glr.c"?])),
 181                                        [$1], [$2])],
 182                             [$2])],
 183                     [$2])])
 184
 185 # yyerror always sees the locations (when activated) if the parser is impure.
 186 # When the parser is pure, yyerror sees the location if it is received as an
 187 # argument.
 188 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 189 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_YYERROR_ARG_LOC_IF([$1], [$2])],
 190                                         [$1])],
 191                             [$1])],
 192                 [$2])])
 193
 194 # The interface is pure: either because %define api.pure, or because we
 195 # are using the C++ parsers.
 196 m4_pushdef([AT_PURE_LEX_IF],
 197 [AT_PURE_IF([$1],
 198             [AT_SKEL_CC_IF([$1], [$2])])])
 199
 200 m4_pushdef([AT_YYSTYPE],
 201 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 202                [AT_API_PREFIX[STYPE]])])
 203 m4_pushdef([AT_YYLTYPE],
 204 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 205                [AT_API_PREFIX[LTYPE]])])
 206
 207
 208 AT_PURE_LEX_IF(
 209 [m4_pushdef([AT_LOC], [(*llocp)])
 210  m4_pushdef([AT_VAL], [(*lvalp)])
 211  m4_pushdef([AT_YYLEX_FORMALS],
 212             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 213  m4_pushdef([AT_YYLEX_ARGS],
 214             [lvalp[]AT_LOCATION_IF([, llocp])])
 215  m4_pushdef([AT_USE_LEX_ARGS],
 216             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 217  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 218             [AT_YYLEX_FORMALS, ])
 219  m4_pushdef([AT_YYLEX_PRE_ARGS],
 220             [AT_YYLEX_ARGS, ])
 221 ],
 222 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 223  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 224  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 225  m4_pushdef([AT_YYLEX_ARGS],        [])
 226  m4_pushdef([AT_USE_LEX_ARGS],    [])
 227  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 228  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 229 ])
 230
 231 # Handle the different types of location components.
 232
 233 AT_SKEL_CC_IF(
 234   [AT_LOCATION_TYPE_IF(
 235     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 236     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 237   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 238
 239
 240 AT_GLR_IF([AT_KEYWORDS([glr])])
 241 ])# _AT_BISON_OPTION_PUSHDEFS
 242
 243
 244 # AT_BISON_OPTION_POPDEFS
 245 # -----------------------
 246 m4_define([AT_BISON_OPTION_POPDEFS],
 247 [m4_divert_text([KILL],
 248 [m4_popdef([AT_YYLEX_PRE_ARGS])
 249 m4_popdef([AT_YYLEX_PRE_FORMALS])
 250 m4_popdef([AT_USE_LEX_ARGS])
 251 m4_popdef([AT_YYLEX_ARGS])
 252 m4_popdef([AT_YYLEX_FORMALS])
 253 m4_popdef([AT_YYLTYPE])
 254 m4_popdef([AT_YYSTYPE])
 255 m4_popdef([AT_VAL])
 256 m4_popdef([AT_LOC])
 257 m4_popdef([AT_PURE_LEX_IF])
 258 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 259 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 260 m4_popdef([AT_API_PREFIX])
 261 m4_popdef([AT_API_prefix])
 262 m4_popdef([AT_TOKEN_PREFIX])
 263 m4_popdef([AT_TOKEN_CTOR_IF])
 264 m4_popdef([AT_NAME_PREFIX])
 265 m4_popdef([AT_LOCATION_TYPE_IF])
 266 m4_popdef([AT_LOCATION_IF])
 267 m4_popdef([AT_PARSE_PARAMS])
 268 m4_popdef([AT_PARAM_IF])
 269 m4_popdef([AT_LEXPARAM_IF])
 270 m4_popdef([AT_YACC_IF])
 271 m4_popdef([AT_GLR_IF])
 272 m4_popdef([AT_SKEL_CC_IF])
 273 m4_popdef([AT_LANG])
 274 m4_popdef([AT_SKEL_JAVA_IF])
 275 m4_popdef([AT_GLR_CC_IF])
 276 m4_popdef([AT_LALR1_CC_IF])
 277 m4_popdef([AT_DEFINES_IF])
 278 AT_LOC_POPDEF])dnl
 279 ])# AT_BISON_OPTION_POPDEFS
 280
 281
 282
 283 ## -------------------------- ##
 284 ## Generating Grammar Files.  ##
 285 ## -------------------------- ##
 286
 287 # AT_DATA_SOURCE_PROLOGUE
 288 # ------------------------
 289 # The prologue that should be included in any source code that is
 290 # meant to be compiled.
 291 m4_define([AT_DATA_SOURCE_PROLOGUE],
 292 [[#include <config.h>
 293 /* We don't need perfect functions for these tests. */
 294 #undef malloc
 295 #undef memcmp
 296 #undef realloc
 297 ]])
 298
 299 # AT_DATA_GRAMMAR_PROLOGUE
 300 # ------------------------
 301 # The prologue that should be included in any grammar which parser is
 302 # meant to be compiled.
 303 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 304 [[%code top {
 305 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 306 [}
 307 ]])
 308
 309 # AT_DATA_SOURCE(NAME, CONTENT)
 310 # -----------------------------
 311 # Generate the file NAME, which CONTENT is preceded by
 312 # AT_DATA_SOURCE_PROLOGUE.
 313 m4_define([AT_DATA_SOURCE],
 314 [AT_DATA([$1],
 315 [AT_DATA_SOURCE_PROLOGUE
 316 $2])
 317 ])
 318
 319 # AT_DATA_GRAMMAR(NAME, CONTENT)
 320 # ------------------------------
 321 # Generate the file NAME, which CONTENT is preceded by
 322 # AT_DATA_GRAMMAR_PROLOGUE.
 323 m4_define([AT_DATA_GRAMMAR],
 324 [AT_DATA([$1],
 325 [AT_DATA_GRAMMAR_PROLOGUE
 326 $2])
 327 ])
 328
 329 # AT_YYLEX_PROTOTYPE
 330 # AT_YYLEX_DECLARE_EXTERN
 331 # AT_YYLEX_DECLARE
 332 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 333 # ----------------------------------
 334 # INPUT can be empty, or in double quotes, or a list (in braces).
 335 # ACTION may compute yylval for instance, using "res" as token type,
 336 # and "toknum" as the number of calls to yylex (starting at 0).
 337 m4_define([AT_YYLEX_PROTOTYPE],
 338 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 339 ])
 340
 341 m4_define([AT_YYLEX_DECLARE_EXTERN],
 342 [AT_YYLEX_PROTOTYPE;dnl
 343 ])
 344
 345 m4_define([AT_YYLEX_DECLARE],
 346 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 347 ])
 348
 349 m4_define([AT_YYLEX_DEFINE],
 350 [[#include <assert.h>
 351 static
 352 ]AT_YYLEX_PROTOTYPE[
 353 {
 354   ]m4_bmatch([$1], [^\(".*"\)?$],
 355              [[static char const input[] = ]m4_default([$1], [""])],
 356              [[static int const input[] = ]$1])[;
 357   static size_t toknum = 0;
 358   int res;
 359   ]AT_USE_LEX_ARGS[;
 360   assert (toknum < sizeof input / sizeof input[0]);
 361   res = input[toknum++];
 362   ]$2[;]AT_LOCATION_IF([[
 363   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 364   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 365   return res;
 366 }]dnl
 367 ])
 368
 369 # AT_YYERROR_FORMALS
 370 # AT_YYERROR_PROTOTYPE
 371 # AT_YYERROR_DECLARE_EXTERN
 372 # AT_YYERROR_DECLARE
 373 # AT_YYERROR_DEFINE
 374 # -------------------------
 375 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 376 m4_define([AT_YYERROR_FORMALS],
 377 [m4_case(AT_LANG,
 378 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE const * const llocp, ])AT_PARSE_PARAMS [const char *msg]])[]dnl
 379 ])
 380
 381 m4_define([AT_YYERROR_PROTOTYPE],
 382 [m4_case(AT_LANG,
 383 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 384 ])
 385
 386 m4_define([AT_YYERROR_DECLARE_EXTERN],
 387 [m4_case(AT_LANG,
 388 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 389 ])
 390
 391 m4_define([AT_YYERROR_DECLARE],
 392 [m4_case(AT_LANG,
 393 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 394 ])
 395
 396 m4_define([AT_YYERROR_DEFINE],
 397 [m4_case(AT_LANG,
 398 [c], [[#include <stdio.h>
 399 /* A C error reporting function.  */
 400 static
 401 ]AT_YYERROR_PROTOTYPE[
 402 {]m4_bpatsubst(m4_defn([AT_PARSE_PARAMS]),
 403               [[^,]+[^A-Za-z_0-9]\([A-Za-z_][A-Za-z_0-9]*\), *], [
 404   YYUSE(\1);])dnl
 405 AT_YYERROR_SEES_LOC_IF([[
 406   YY_LOCATION_PRINT (stderr, ]AT_LOC[);
 407   fprintf (stderr, ": ");]])[
 408   fprintf (stderr, "%s\n", msg);
 409 }]],
 410 [c++], [[/* A C++ error reporting function.  */
 411 void
 412 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 413 {  std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 414 }]],
 415 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 416 {
 417     if (l == null)
 418       System.err.println (s);
 419     else
 420       System.err.println (l + ": " + s);
 421   }
 422 ]], [[
 423   public void yyerror (String s)
 424   {
 425     System.err.println (s);
 426   }]])],
 427 [m4_fatal([$0: invalid language: ]AT_LANG)])dnl
 428 ])
 429
 430
 431 ## --------------- ##
 432 ## Running Bison.  ##
 433 ## --------------- ##
 434
 435 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 436 # -------------------------------------------------
 437 # High-level routine that may call bison several times, under different
 438 # conditions.
 439 #
 440 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 441 # shell constructs (such as redirection or pipes) that would prevent
 442 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 443 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 444 #
 445 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 446 # Bison in the test suite.  For now it ensures that:
 447 #
 448 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 449 #      a non-zero exit status since Bison doesn't always try to free all memory
 450 #      in that case.
 451 #
 452 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 453 #      --graph and --report=all output for every working grammar.
 454 #
 455 #   3. If stderr contains a warning, -Werror and --warnings=error
 456 #      convert the warning to an error.
 457 #
 458 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 459 m4_define([AT_BISON_CHECK],
 460 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 461 AT_BISON_CHECK_NO_XML($@)])
 462
 463 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 464 # --------------------------------------------------
 465 # Low-level macro to run bison once.
 466 m4_define([AT_BISON_CHECK_],
 467 [AT_CHECK(AT_QUELL_VALGRIND[[ bison ]]$@)])
 468
 469
 470 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 471 # ----------------------------------------------------------
 472 # Check that warnings (if some are expected) are correctly
 473 # turned into errors with -Werror, etc.
 474 m4_define([AT_BISON_CHECK_WARNINGS],
 475 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 476       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 477
 478 m4_define([AT_BISON_CHECK_WARNINGS_],
 479 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 480 # added after the grammar file name, so skip these checks in that
 481 # case.
 482 if test "$POSIXLY_CORRECT_IS_EXPORTED" = false; then
 483           ]AT_SAVE_SPECIAL_FILES[
 484
 485   # To avoid expanding it repeatedly, store specified stdout.
 486   ]AT_DATA([expout], [$3])[
 487
 488   # Run with -Werror.
 489   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 490
 491   # Build expected stderr up to and including the "warnings being
 492   # treated as errors" message.
 493   ]AT_DATA([[experr]], [$4])[
 494   $PERL -pi -e 's{(.*): warning: (.*)\[-W(.*)\]$}
 495                  {$][1: error: $][2\@<:@-Werror=$][3@:>@}' experr
 496   ]AT_CHECK([[sed 's,.*/$,,' stderr 1>&2]], [[0]], [[]], [experr])[
 497
 498   # Now check --warnings=error.
 499   cp stderr experr
 500   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 501
 502   # Now check -Wnone and --warnings=none by making sure that
 503   # -Werror doesn't change the exit status when -Wnone or
 504   # --warnings=none is specified.
 505   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 506   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 507
 508   ]AT_RESTORE_SPECIAL_FILES[
 509 fi]dnl
 510 ])
 511
 512 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 513 # --------------------------------------------------------
 514 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 515 # when a tortured grammar's XML is known to be too large for xsltproc to
 516 # handle.
 517 m4_define([AT_BISON_CHECK_NO_XML],
 518 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison ]]$@)
 519 AT_BISON_CHECK_WARNINGS($@)])
 520
 521 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 522 # -----------------------------------------------------
 523 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 524 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 525 # have a non-zero exit status.
 526 m4_define([AT_BISON_CHECK_XML],
 527 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 528   AT_SAVE_SPECIAL_FILES
 529   [mkdir xml-tests]
 530   m4_pushdef([AT_BISON_ARGS],
 531              [m4_bpatsubsts([[$1]],
 532                             [--report(-file)?=[^][ ]*], [],
 533                             [--graph=[^][ ]*], [],
 534                             [--xml=[^][ ]*], [])])dnl
 535   # Don't combine these Bison invocations since we want to be sure that
 536   # --report=all isn't required to get the full XML file.
 537   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 538              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 539            [[0]], [ignore], [ignore])
 540   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 541            [[0]], [ignore], [ignore])
 542   m4_popdef([AT_BISON_ARGS])dnl
 543   [cp xml-tests/test.output expout]
 544   AT_CHECK([[$XSLTPROC \
 545              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 546              xml-tests/test.xml]], [[0]], [expout])
 547   [sort xml-tests/test.dot > expout]
 548   AT_CHECK([[$XSLTPROC \
 549              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 550              xml-tests/test.xml | sort]], [[0]], [expout])
 551   [rm -rf xml-tests expout]
 552   AT_RESTORE_SPECIAL_FILES
 553 [fi]])
 554
 555 # AT_QUELL_VALGRIND
 556 # -----------------
 557 # Put this before a Bison invocation to keep Valgrind from complaining about
 558 # reachable memory.
 559 #
 560 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 561 # The triple quoting below will cause test cases to fail if you do.  If you do
 562 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 563 # will then fail to shell-escape its contents when attempting to print them.
 564 # The testsuite verbose output, at least, will be incorrect, but nothing may
 565 # fail to make sure you notice.
 566 m4_define([AT_QUELL_VALGRIND],
 567 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 568
 569
 570
 571 ## ------------------------ ##
 572 ## Compiling C, C++ Files.  ##
 573 ## ------------------------ ##
 574
 575
 576 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 577 # ----------------------------------------
 578 # Compile SOURCES into OUTPUT.
 579 #
 580 # If OUTPUT does not contain '.', assume that we are linking too,
 581 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 582 # with trailing .o removed, and ".c" appended.
 583 m4_define([AT_COMPILE],
 584 [AT_CHECK([$BISON_C_WORKS], 0, ignore, ignore)
 585 AT_CHECK(m4_join([ ],
 586                   [$CC $CFLAGS $CPPFLAGS],
 587                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 588                   [-o $1],
 589                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 590                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 591            0, [ignore], [ignore])])
 592
 593 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 594 # ---------------------------------------------
 595 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 596 # ignore the test.
 597 #
 598 # If OUTPUT does not contain '.', assume that we are linking too,
 599 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 600 # with trailing .o removed, and ".cc" appended.
 601 m4_define([AT_COMPILE_CXX],
 602 [AT_KEYWORDS(c++)
 603 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 604 AT_CHECK(m4_join([ ],
 605                  [$CXX $CXXFLAGS $CPPFLAGS],
 606                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 607                  [-o $1],
 608                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 609                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 610          0, [ignore], [ignore])])
 611
 612 # AT_JAVA_COMPILE(SOURCES)
 613 # ------------------------
 614 # Compile SOURCES into Java class files.  Skip the test if java or javac
 615 # is not installed.
 616 m4_define([AT_JAVA_COMPILE],
 617 [AT_KEYWORDS(java)
 618 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 619 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 620 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 621          [[0]], [ignore], [ignore])])
 622
 623 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 624 # --------------------------------------------
 625 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 626 #
 627 # If OUTPUT does not contain '.', assume that we are linking too,
 628 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 629 # with trailing .o removed, and ".c"/".cc" appended.
 630 m4_define([AT_LANG_COMPILE],
 631 [m4_case(AT_LANG,
 632 [c],    [AT_COMPILE([$1], [$2])],
 633 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 634 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 635         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 636 ])
 637
 638 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 639 # -------------------------------------------
 640 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 641 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 642 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 643 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 644 # AT_SKEL_JAVA_IF.
 645 m4_define([AT_FULL_COMPILE],
 646 [m4_case(AT_LANG,
 647 [java],
 648   [AT_BISON_CHECK([-o $1.java $1.y])
 649    AT_LANG_COMPILE([$1],
 650                     m4_join([ ],
 651                             [$1.java],
 652                             m4_ifval($2, [[$1-$2.java]]),
 653                            m4_ifval($3, [[$1-$3.java]])))],
 654 [c++],
 655   [AT_BISON_CHECK([-o $1.cc $1.y])
 656    AT_LANG_COMPILE([$1],
 657                      m4_join([ ],
 658                              [$1.cc],
 659                              m4_ifval($2, [[$1-$2.cc]]),
 660                            m4_ifval($3, [[$1-$3.cc]])))],
 661 [c],
 662   [AT_BISON_CHECK([-o $1.c $1.y])
 663    AT_LANG_COMPILE([$1],
 664                   m4_join([ ],
 665                           [$1.c],
 666                           m4_ifval($2, [[$1-$2.c]]),
 667                            m4_ifval($3, [[$1-$3.c]])))])
 668 ])
 669
 670
 671
 672 # AT_SKIP_IF_CANNOT_LINK_C_AND_CXX
 673 # --------------------------------
 674 # Check that we can link together C and C++ objects.
 675 m4_define([AT_SKIP_IF_CANNOT_LINK_C_AND_CXX],
 676 [AT_DATA([c-and-cxx.h],
 677 [[#ifdef __cplusplus
 678 extern "C"
 679 {
 680 #endif
 681   int fortytwo (void);
 682 #ifdef __cplusplus
 683 }
 684 #endif
 685 ]])
 686 AT_DATA([c-only.c],
 687 [[#include "c-and-cxx.h"
 688 int
 689 main (void)
 690 {
 691   return fortytwo () == 42 ? 0 : 1;
 692 }
 693 ]])
 694 AT_DATA([cxx-only.cc],
 695 [[#include "c-and-cxx.h"
 696 int fortytwo ()
 697 {
 698   return 42;
 699 }
 700 ]])
 701 AT_COMPILE([c-only.o], [c-only.c])
 702 AT_COMPILE_CXX([cxx-only.o], [cxx-only.cc])
 703 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS $LDFLAGS c-only.o cxx-only.o -o c-and-cxx ||
 704           exit 77], [ignore], [ignore])
 705 AT_PARSER_CHECK([./c-and-cxx])
 706 ])
 707
 708
 709 ## ---------------------------- ##
 710 ## Running a generated parser.  ##
 711 ## ---------------------------- ##
 712
 713
 714 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 715 # ------------------------------------------------------------
 716 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 717 #
 718 # Get rid of spurious messages when compiled with --coverage:
 719 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 720 m4_define([AT_PARSER_CHECK],
 721 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 722 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 723          [0], [], [$4])
 724 ])
 725
 726
 727 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 728 # -----------------------------------------------------------------
 729 m4_define([AT_JAVA_PARSER_CHECK],
 730 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 731
 732
 733 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 734 #                          DECLS, GRAMMAR, INPUT,
 735 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 736 #                          [OTHER-CHECKS],
 737 #                          [PARSER-EXIT-VALUE],
 738 #                          [PARSER-STDOUT], [PARSER-STDERR])
 739 # -------------------------------------------------------------
 740 # Using TITLE as the test group title, check the generated parser tables
 741 # and parser for a specified grammar file under a condition labeled by
 742 # COND-VALUE.
 743 #
 744 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 745 # recognized attribute is described below where it is relevant.
 746 #
 747 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 748 # the grammar file.  Insert basic yyerror, yylex, and main function
 749 # definitions as well.  Hardcode yylex to return the (possibly empty)
 750 # comma-delimited series of tokens in INPUT followed by token 0.
 751 #
 752 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 753 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 754 # On the bison command-line, specify `--report=all --defines'.  Check
 755 # that Bison exits with value 0, has no stdout, and has stderr
 756 # BISON-STDERR.
 757 #
 758 # If TEST-SPEC contains the attribute `last-state', check that the value
 759 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 760 # the grammar; in other words, check the number of states (minus one).
 761 # Otherwise, check that everything in the `.output' file starting with
 762 # the definition of state 0 is the same as the entire value of
 763 # TABLES-OR-LAST-STATE.
 764 #
 765 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 766 # `.output' file, which is named `input.output', and/or grammar file,
 767 # which is named `input.y'.
 768 #
 769 # Finally, compile the generated parser and then run it using
 770 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 771 # PARSER-STDERR as the 2nd-4th arguments.
 772 #
 773 # As a precondition, you must properly double-quote all arguments that
 774 # are to be interpreted as strings.
 775 #
 776 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 777 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 778 # first argument.  This is useful, for example, when wrapping multiple
 779 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 780 # condition, in another macro.
 781 #
 782 # For example:
 783 #
 784 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 785 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 786 #   # ---------------------------------------------------------------------
 787 #   m4_define([AT_TEST_SYNTAX_ERROR],
 788 #   [
 789 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 790 #                              [[last-state]],
 791 #                              [[%error-verbose ]$2], [$3], [$4],
 792 #                              [[]], [$5], [], [$6], [$7], [$8])
 793 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 794 #                              [[last-state]],
 795 #                              [$2], [$3], [$4],
 796 #                              [[]], [$5], [], [$6], [$7], [$8])
 797 #   ])
 798 #
 799 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 800 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 801 #                        [[3]],
 802 #                        [[1]], [[]],
 803 #                        [AT_COND_CASE([[no verbose]],
 804 #                                      [[syntax error
 805 #   ]],
 806 #                                      [[syntax error, unexpected 'b', expecting $end
 807 #   ]])])
 808 m4_define([AT_TEST_TABLES_AND_PARSE],
 809 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 810
 811 AT_SETUP([$1])
 812 AT_BISON_OPTION_PUSHDEFS([$4])
 813 AT_DATA_GRAMMAR([[input.y]],
 814 [[%code {
 815   #include <stdio.h>
 816   ]AT_YYERROR_DECLARE[
 817   ]AT_YYLEX_DECLARE[
 818 }
 819
 820 ]$4[
 821
 822 %%
 823
 824 ]$5[
 825
 826 %%
 827 ]AT_YYERROR_DEFINE[
 828 static int
 829 yylex (void)
 830 {
 831   static int const input[] = {
 832     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 833   };
 834   static int const *inputp = input;
 835   return *inputp++;
 836 }
 837
 838 int
 839 main (void)
 840 {
 841   return yyparse ();
 842 }
 843 ]])
 844
 845 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 846 # expanding macros, so it corrupts some special characters in the
 847 # macros.  To avoid this, expand now and pass it the result with proper
 848 # string quotation.  Assume args 7 through 12 expand to properly quoted
 849 # strings.
 850
 851 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 852       [AT_BISON_CHECK],
 853       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 854                                [0], [], m4_dquote($7))
 855
 856 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 857       [AT_CHECK([[sed -n '/^State 0$/,$p' input.output]], [[0]],
 858                 m4_dquote($8))],
 859       [AT_CHECK([[sed -n 's/^State //p' input.output | tail -1]], [[0]],
 860                 m4_dquote($8)[[
 861 ]])])
 862
 863 $9
 864
 865 # Canonical LR generates very large tables, resulting in very long
 866 # files with #line directives that may overflow what the standards
 867 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 868 # will issue an error.
 869 #
 870 # There is no "" around `wc` since some indent the result.
 871 m4_bmatch([$4], [%define lr.type canonical-lr],
 872 [if test 32767 -lt `wc -l < input.c`; then
 873   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 874   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 875 fi])
 876 AT_COMPILE([[input]])
 877
 878 AT_PARSER_CHECK([[./input]],
 879                 m4_ifval([$10], [m4_dquote($10)]),
 880                 m4_ifval([$11], [m4_dquote($11)]),
 881                 m4_ifval([$12], [m4_dquote($12)]))
 882
 883 AT_BISON_OPTION_POPDEFS
 884 AT_CLEANUP
 885
 886 m4_popdef([AT_COND_CASE])])
 887
 888
 889
 890 ## ----------------------- ##
 891 ## Launch the test suite.  ##
 892 ## ----------------------- ##
 893
 894 AT_INIT
 895
 896 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 897 # options are processed, so we don't know the value of CXX and
 898 # CXXFLAGS yet.
 899 #
 900 # Note that it also means that command line values for CXX and
 901 # CXXFLAGS will not be propagated to CC and CFLAGS.
 902 AT_ARG_OPTION([compile-c-with-cxx],
 903               [compile C parsers with the C++ compiler])
 904
 905 AT_COLOR_TESTS
 906
 907 AT_TESTED([bison])