src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle-tab.h"
  30 #include "quotearg.h"
  31 #include "reader.h"
  32 #include "symlist.h"
  33 #include "scan-gram.h"
  34 #include "scan-code.h"
  35
  36 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  37 static YYLTYPE lloc_default (YYLTYPE const *, int);
  38
  39 #define YY_LOCATION_PRINT(File, Loc) \
  40           location_print (File, Loc)
  41
  42 static void version_check (location const *loc, char const *version);
  43
  44 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  45    FIXME: depends on the undocumented availability of YYLLOC.  */
  46 #undef  yyerror
  47 #define yyerror(Msg) \
  48         gram_error (&yylloc, Msg)
  49 static void gram_error (location const *, char const *);
  50
  51 static char const *char_name (char);
  52
  53 /** Add a lex-param or a parse-param.
  54  *
  55  * \param type  \a lex_param or \a parse_param
  56  * \param decl  the formal argument
  57  * \param loc   the location in the source.
  58  */
  59 static void add_param (char const *type, char *decl, location loc);
  60
  61
  62 static symbol_class current_class = unknown_sym;
  63 static uniqstr current_type = NULL;
  64 static symbol *current_lhs;
  65 static location current_lhs_location;
  66 static int current_prec = 0;
  67
  68 #define YYTYPE_INT16 int_fast16_t
  69 #define YYTYPE_INT8 int_fast8_t
  70 #define YYTYPE_UINT16 uint_fast16_t
  71 #define YYTYPE_UINT8 uint_fast8_t
  72 %}
  73
  74 %debug
  75 %verbose
  76 %defines
  77 %locations
  78 %pure-parser
  79 %error-verbose
  80 %name-prefix="gram_"
  81 %expect 0
  82
  83 %initial-action
  84 {
  85   /* Bison's grammar can initial empty locations, hence a default
  86      location is needed. */
  87   boundary_set (&@$.start, current_file, 1, 1);
  88   boundary_set (&@$.end, current_file, 1, 1);
  89 }
  90
  91 %union
  92 {
  93   symbol *symbol;
  94   symbol_list *list;
  95   int integer;
  96   char const *chars;
  97   char *code;
  98   assoc assoc;
  99   uniqstr uniqstr;
 100   unsigned char character;
 101 };
 102
 103 /* Define the tokens together with their human representation.  */
 104 %token GRAM_EOF 0 "end of file"
 105 %token STRING     "string"
 106 %token INT        "integer"
 107
 108 %token PERCENT_TOKEN       "%token"
 109 %token PERCENT_NTERM       "%nterm"
 110
 111 %token PERCENT_TYPE        "%type"
 112 %token PERCENT_DESTRUCTOR  "%destructor"
 113 %token PERCENT_PRINTER     "%printer"
 114
 115 %token PERCENT_LEFT        "%left"
 116 %token PERCENT_RIGHT       "%right"
 117 %token PERCENT_NONASSOC    "%nonassoc"
 118 %token PERCENT_PRECEDENCE  "%precedence"
 119
 120 %token PERCENT_PREC          "%prec"
 121 %token PERCENT_DPREC         "%dprec"
 122 %token PERCENT_MERGE         "%merge"
 123
 124
 125 /*----------------------.
 126 | Global Declarations.  |
 127 `----------------------*/
 128
 129 %token
 130   PERCENT_CODE            "%code"
 131   PERCENT_DEFAULT_PREC    "%default-prec"
 132   PERCENT_DEFINE          "%define"
 133   PERCENT_DEFINES         "%defines"
 134   PERCENT_EXPECT          "%expect"
 135   PERCENT_EXPECT_RR       "%expect-rr"
 136   PERCENT_FLAG            "%<flag>"
 137   PERCENT_FILE_PREFIX     "%file-prefix"
 138   PERCENT_GLR_PARSER      "%glr-parser"
 139   PERCENT_INITIAL_ACTION  "%initial-action"
 140   PERCENT_LANGUAGE        "%language"
 141   PERCENT_LEX_PARAM       "%lex-param"
 142   PERCENT_NAME_PREFIX     "%name-prefix"
 143   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 144   PERCENT_NO_LINES        "%no-lines"
 145   PERCENT_NONDETERMINISTIC_PARSER
 146                           "%nondeterministic-parser"
 147   PERCENT_OUTPUT          "%output"
 148   PERCENT_PARSE_PARAM     "%parse-param"
 149   PERCENT_REQUIRE         "%require"
 150   PERCENT_SKELETON        "%skeleton"
 151   PERCENT_START           "%start"
 152   PERCENT_TOKEN_TABLE     "%token-table"
 153   PERCENT_VERBOSE         "%verbose"
 154   PERCENT_YACC            "%yacc"
 155 ;
 156
 157 %token BRACED_CODE     "{...}"
 158 %token CHAR            "char"
 159 %token EPILOGUE        "epilogue"
 160 %token EQUAL           "="
 161 %token ID              "identifier"
 162 %token ID_COLON        "identifier:"
 163 %token PERCENT_PERCENT "%%"
 164 %token PIPE            "|"
 165 %token PROLOGUE        "%{...%}"
 166 %token SEMICOLON       ";"
 167 %token TAG             "<tag>"
 168 %token TAG_ANY         "<*>"
 169 %token TAG_NONE        "<>"
 170
 171 %type <character> CHAR
 172 %printer { fputs (char_name ($$), stderr); } CHAR
 173
 174 /* braceless is not to be used for rule or symbol actions, as it
 175    calls code_props_plain_init.  */
 176 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 177 %type <code> "{...}"
 178 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 179          STRING
 180 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 181          braceless content.opt "{...}" "%{...%}" EPILOGUE
 182
 183 %type <uniqstr> TAG ID ID_COLON PERCENT_FLAG variable
 184 %printer { fputs ($$, stderr); } ID variable
 185 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 186 %printer { fprintf (stderr, "%%%s", $$); } PERCENT_FLAG
 187 %printer { fprintf (stderr, "<%s>", $$); } TAG
 188
 189 %type <integer> INT
 190 %printer { fprintf (stderr, "%d", $$); } INT
 191
 192 %type <symbol> id id_colon symbol symbol.prec string_as_id
 193 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 194 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 195
 196 %type <assoc> precedence_declarator
 197 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 198 %%
 199
 200 input:
 201   prologue_declarations "%%" grammar epilogue.opt
 202 ;
 203
 204
 205         /*------------------------------------.
 206         | Declarations: before the first %%.  |
 207         `------------------------------------*/
 208
 209 prologue_declarations:
 210   /* Nothing */
 211 | prologue_declarations prologue_declaration
 212 ;
 213
 214 prologue_declaration:
 215   grammar_declaration
 216 | "%{...%}"
 217     {
 218       code_props plain_code;
 219       code_props_plain_init (&plain_code, $1, @1);
 220       code_props_translate_code (&plain_code);
 221       gram_scanner_last_string_free ();
 222       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 223                         plain_code.code, @1);
 224       code_scanner_last_string_free ();
 225     }
 226 | "%<flag>"
 227     {
 228       muscle_percent_define_ensure ($1, @1, true);
 229     }
 230 | "%define" variable content.opt
 231     {
 232       muscle_percent_define_insert ($2, @2, $3);
 233     }
 234 | "%defines"                       { defines_flag = true; }
 235 | "%defines" STRING
 236     {
 237       defines_flag = true;
 238       spec_defines_file = xstrdup ($2);
 239     }
 240 | "%expect" INT                    { expected_sr_conflicts = $2; }
 241 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 242 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 243 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 244 | "%glr-parser"
 245     {
 246       nondeterministic_parser = true;
 247       glr_parser = true;
 248     }
 249 | "%initial-action" "{...}"
 250     {
 251       code_props action;
 252       code_props_symbol_action_init (&action, $2, @2);
 253       code_props_translate_code (&action);
 254       gram_scanner_last_string_free ();
 255       muscle_code_grow ("initial_action", action.code, @2);
 256       code_scanner_last_string_free ();
 257     }
 258 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 259 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 260 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 261 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 262 | "%no-lines"                   { no_lines_flag = true; }
 263 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 264 | "%output" STRING              { spec_outfile = $2; }
 265 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 266 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 267 | "%require" STRING             { version_check (&@2, $2); }
 268 | "%skeleton" STRING
 269     {
 270       char const *skeleton_user = $2;
 271       if (strchr (skeleton_user, '/'))
 272         {
 273           size_t dir_length = strlen (current_file);
 274           char *skeleton_build;
 275           while (dir_length && current_file[dir_length - 1] != '/')
 276             --dir_length;
 277           while (dir_length && current_file[dir_length - 1] == '/')
 278             --dir_length;
 279           skeleton_build =
 280             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 281           if (dir_length > 0)
 282             {
 283               strncpy (skeleton_build, current_file, dir_length);
 284               skeleton_build[dir_length++] = '/';
 285             }
 286           strcpy (skeleton_build + dir_length, skeleton_user);
 287           skeleton_user = uniqstr_new (skeleton_build);
 288           free (skeleton_build);
 289         }
 290       skeleton_arg (skeleton_user, grammar_prio, @1);
 291     }
 292 | "%token-table"                { token_table_flag = true; }
 293 | "%verbose"                    { report_flag |= report_states; }
 294 | "%yacc"                       { yacc_flag = true; }
 295 | /*FIXME: Err?  What is this horror doing here? */ ";"
 296 ;
 297
 298 grammar_declaration:
 299   precedence_declaration
 300 | symbol_declaration
 301 | "%start" symbol
 302     {
 303       grammar_start_symbol_set ($2, @2);
 304     }
 305 | "%destructor" "{...}" generic_symlist
 306     {
 307       symbol_list *list;
 308       for (list = $3; list; list = list->next)
 309         symbol_list_destructor_set (list, $2, @2);
 310       symbol_list_free ($3);
 311     }
 312 | "%printer" "{...}" generic_symlist
 313     {
 314       symbol_list *list;
 315       for (list = $3; list; list = list->next)
 316         symbol_list_printer_set (list, $2, @2);
 317       symbol_list_free ($3);
 318     }
 319 | "%default-prec"
 320     {
 321       default_prec = true;
 322     }
 323 | "%no-default-prec"
 324     {
 325       default_prec = false;
 326     }
 327 | "%code" braceless
 328     {
 329       /* Do not invoke muscle_percent_code_grow here since it invokes
 330          muscle_user_name_list_grow.  */
 331       muscle_code_grow ("percent_code()", $2, @2);
 332       code_scanner_last_string_free ();
 333     }
 334 | "%code" ID braceless
 335     {
 336       muscle_percent_code_grow ($2, @2, $3, @3);
 337       code_scanner_last_string_free ();
 338     }
 339 ;
 340
 341
 342 /*---------.
 343 | %union.  |
 344 `---------*/
 345
 346 %token PERCENT_UNION "%union";
 347
 348 union_name:
 349   /* Nothing. */ {}
 350 | ID             { muscle_code_grow ("union_name", $1, @1); }
 351 ;
 352
 353 grammar_declaration:
 354   "%union" union_name braceless
 355     {
 356       union_seen = true;
 357       muscle_code_grow ("stype", $3, @3);
 358       code_scanner_last_string_free ();
 359     }
 360 ;
 361
 362
 363
 364
 365 symbol_declaration:
 366   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 367     {
 368       current_class = unknown_sym;
 369       current_type = NULL;
 370     }
 371 | "%token" { current_class = token_sym; } symbol_defs.1
 372     {
 373       current_class = unknown_sym;
 374       current_type = NULL;
 375     }
 376 | "%type" TAG symbols.1
 377     {
 378       symbol_list *list;
 379       tag_seen = true;
 380       for (list = $3; list; list = list->next)
 381         symbol_type_set (list->content.sym, $2, @2);
 382       symbol_list_free ($3);
 383     }
 384 ;
 385
 386 precedence_declaration:
 387   precedence_declarator tag.opt symbols.prec
 388     {
 389       symbol_list *list;
 390       ++current_prec;
 391       for (list = $3; list; list = list->next)
 392         {
 393           symbol_type_set (list->content.sym, current_type, @2);
 394           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 395         }
 396       symbol_list_free ($3);
 397       current_type = NULL;
 398     }
 399 ;
 400
 401 precedence_declarator:
 402   "%left"       { $$ = left_assoc; }
 403 | "%right"      { $$ = right_assoc; }
 404 | "%nonassoc"   { $$ = non_assoc; }
 405 | "%precedence" { $$ = precedence_assoc; }
 406 ;
 407
 408 tag.opt:
 409   /* Nothing. */ { current_type = NULL; }
 410 | TAG            { current_type = $1; tag_seen = true; }
 411 ;
 412
 413 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 414 symbols.prec:
 415   symbol.prec
 416     { $$ = symbol_list_sym_new ($1, @1); }
 417 | symbols.prec symbol.prec
 418     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 419 ;
 420
 421 symbol.prec:
 422     symbol { $$ = $1; }
 423   | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 424   ;
 425
 426 /* One or more symbols to be %typed. */
 427 symbols.1:
 428   symbol
 429     { $$ = symbol_list_sym_new ($1, @1); }
 430 | symbols.1 symbol
 431     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 432 ;
 433
 434 generic_symlist:
 435   generic_symlist_item { $$ = $1; }
 436 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 437 ;
 438
 439 generic_symlist_item:
 440   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 441 | TAG       { $$ = symbol_list_type_new ($1, @1); }
 442 | "<*>"     { $$ = symbol_list_default_tagged_new (@1); }
 443 | "<>"      { $$ = symbol_list_default_tagless_new (@1); }
 444 ;
 445
 446 /* One token definition.  */
 447 symbol_def:
 448   TAG
 449      {
 450        current_type = $1;
 451        tag_seen = true;
 452      }
 453 | id
 454      {
 455        symbol_class_set ($1, current_class, @1, true);
 456        symbol_type_set ($1, current_type, @1);
 457      }
 458 | id INT
 459     {
 460       symbol_class_set ($1, current_class, @1, true);
 461       symbol_type_set ($1, current_type, @1);
 462       symbol_user_token_number_set ($1, $2, @2);
 463     }
 464 | id string_as_id
 465     {
 466       symbol_class_set ($1, current_class, @1, true);
 467       symbol_type_set ($1, current_type, @1);
 468       symbol_make_alias ($1, $2, @$);
 469     }
 470 | id INT string_as_id
 471     {
 472       symbol_class_set ($1, current_class, @1, true);
 473       symbol_type_set ($1, current_type, @1);
 474       symbol_user_token_number_set ($1, $2, @2);
 475       symbol_make_alias ($1, $3, @$);
 476     }
 477 ;
 478
 479 /* One or more symbol definitions. */
 480 symbol_defs.1:
 481   symbol_def
 482 | symbol_defs.1 symbol_def
 483 ;
 484
 485
 486         /*------------------------------------------.
 487         | The grammar section: between the two %%.  |
 488         `------------------------------------------*/
 489
 490 grammar:
 491   rules_or_grammar_declaration
 492 | grammar rules_or_grammar_declaration
 493 ;
 494
 495 /* As a Bison extension, one can use the grammar declarations in the
 496    body of the grammar.  */
 497 rules_or_grammar_declaration:
 498   rules
 499 | grammar_declaration ";"
 500 | error ";"
 501     {
 502       yyerrok;
 503     }
 504 ;
 505
 506 rules:
 507   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 508 ;
 509
 510 rhses.1:
 511   rhs                { grammar_current_rule_end (@1); }
 512 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 513 | rhses.1 ";"
 514 ;
 515
 516 rhs:
 517   /* Nothing.  */
 518     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 519 | rhs symbol
 520     { grammar_current_rule_symbol_append ($2, @2); }
 521 | rhs "{...}"
 522     { grammar_current_rule_action_append ($2, @2); }
 523 | rhs "%prec" symbol
 524     { grammar_current_rule_prec_set ($3, @3); }
 525 | rhs "%dprec" INT
 526     { grammar_current_rule_dprec_set ($3, @3); }
 527 | rhs "%merge" TAG
 528     { grammar_current_rule_merge_set ($3, @3); }
 529 ;
 530
 531
 532 /*---------------------------.
 533 | variable and content.opt.  |
 534 `---------------------------*/
 535
 536 variable:
 537   ID
 538 | STRING { $$ = uniqstr_new ($1); }
 539 ;
 540
 541 /* Some content or empty by default. */
 542 content.opt:
 543   /* Nothing. */   { $$ = ""; }
 544 | STRING
 545 ;
 546
 547
 548 /*------------.
 549 | braceless.  |
 550 `------------*/
 551
 552 braceless:
 553   "{...}"
 554     {
 555       code_props plain_code;
 556       $1[strlen ($1) - 1] = '\n';
 557       code_props_plain_init (&plain_code, $1+1, @1);
 558       code_props_translate_code (&plain_code);
 559       gram_scanner_last_string_free ();
 560       $$ = plain_code.code;
 561     }
 562 ;
 563
 564
 565 /*--------------.
 566 | Identifiers.  |
 567 `--------------*/
 568
 569 /* Identifiers are returned as uniqstr values by the scanner.
 570    Depending on their use, we may need to make them genuine symbols.  */
 571
 572 id:
 573   ID
 574     { $$ = symbol_from_uniqstr ($1, @1); }
 575 | CHAR
 576     {
 577       $$ = symbol_get (char_name ($1), @1);
 578       symbol_class_set ($$, token_sym, @1, false);
 579       symbol_user_token_number_set ($$, $1, @1);
 580     }
 581 ;
 582
 583 id_colon:
 584   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 585 ;
 586
 587
 588 symbol:
 589   id
 590 | string_as_id
 591 ;
 592
 593 /* A string used as an ID: quote it.  */
 594 string_as_id:
 595   STRING
 596     {
 597       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 598       symbol_class_set ($$, token_sym, @1, false);
 599     }
 600 ;
 601
 602 epilogue.opt:
 603   /* Nothing.  */
 604 | "%%" EPILOGUE
 605     {
 606       code_props plain_code;
 607       code_props_plain_init (&plain_code, $2, @2);
 608       code_props_translate_code (&plain_code);
 609       gram_scanner_last_string_free ();
 610       muscle_code_grow ("epilogue", plain_code.code, @2);
 611       code_scanner_last_string_free ();
 612     }
 613 ;
 614
 615 %%
 616
 617
 618 /* Return the location of the left-hand side of a rule whose
 619    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 620    the right-hand side, and return an empty location equal to the end
 621    boundary of RHS[0] if the right-hand side is empty.  */
 622
 623 static YYLTYPE
 624 lloc_default (YYLTYPE const *rhs, int n)
 625 {
 626   int i;
 627   YYLTYPE loc;
 628
 629   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 630      The bug is fixed in 7.4.2m, but play it safe for now.  */
 631   loc.start = rhs[n].end;
 632   loc.end = rhs[n].end;
 633
 634   /* Ignore empty nonterminals the start of the the right-hand side.
 635      Do not bother to ignore them at the end of the right-hand side,
 636      since empty nonterminals have the same end as their predecessors.  */
 637   for (i = 1; i <= n; i++)
 638     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 639       {
 640         loc.start = rhs[i].start;
 641         break;
 642       }
 643
 644   return loc;
 645 }
 646
 647
 648 /* Add a lex-param or a parse-param (depending on TYPE) with
 649    declaration DECL and location LOC.  */
 650
 651 static void
 652 add_param (char const *type, char *decl, location loc)
 653 {
 654   static char const alphanum[26 + 26 + 1 + 10] =
 655     "abcdefghijklmnopqrstuvwxyz"
 656     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 657     "_"
 658     "0123456789";
 659   char const *name_start = NULL;
 660   char *p;
 661
 662   /* Stop on last actual character.  */
 663   for (p = decl; p[1]; p++)
 664     if ((p == decl
 665          || ! memchr (alphanum, p[-1], sizeof alphanum))
 666         && memchr (alphanum, p[0], sizeof alphanum - 10))
 667       name_start = p;
 668
 669   /* Strip the surrounding '{' and '}', and any blanks just inside
 670      the braces.  */
 671   while (*--p == ' ' || *p == '\t')
 672     continue;
 673   p[1] = '\0';
 674   while (*++decl == ' ' || *decl == '\t')
 675     continue;
 676
 677   if (! name_start)
 678     complain_at (loc, _("missing identifier in parameter declaration"));
 679   else
 680     {
 681       char *name;
 682       size_t name_len;
 683
 684       for (name_len = 1;
 685            memchr (alphanum, name_start[name_len], sizeof alphanum);
 686            name_len++)
 687         continue;
 688
 689       name = xmalloc (name_len + 1);
 690       memcpy (name, name_start, name_len);
 691       name[name_len] = '\0';
 692       muscle_pair_list_grow (type, decl, name);
 693       free (name);
 694     }
 695
 696   gram_scanner_last_string_free ();
 697 }
 698
 699
 700 static void
 701 version_check (location const *loc, char const *version)
 702 {
 703   if (strverscmp (version, PACKAGE_VERSION) > 0)
 704     {
 705       complain_at (*loc, "require bison %s, but have %s",
 706                    version, PACKAGE_VERSION);
 707       exit (63);
 708     }
 709 }
 710
 711 static void
 712 gram_error (location const *loc, char const *msg)
 713 {
 714   complain_at (*loc, "%s", msg);
 715 }
 716
 717 char const *
 718 token_name (int type)
 719 {
 720   return yytname[YYTRANSLATE (type)];
 721 }
 722
 723 static char const *
 724 char_name (char c)
 725 {
 726   if (c == '\'')
 727     return "'\\''";
 728   else
 729     {
 730       char buf[4];
 731       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 732       return quotearg_style (escape_quoting_style, buf);
 733     }
 734 }