tests/actions.at

   1 # Executing Actions.                               -*- Autotest -*-
   2 # Copyright 2001 Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2, or (at your option)
   7 # any later version.
   8
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  17 # 02111-1307, USA.
  18
  19 AT_BANNER([[User Actions.]])
  20
  21 ## ------------------ ##
  22 ## Mid-rule actions.  ##
  23 ## ------------------ ##
  24
  25 AT_SETUP([Mid-rule actions])
  26
  27 # Bison once forgot the mid-rule actions.  It was because the action
  28 # was attached to the host rule (the one with the mid-rule action),
  29 # instead of being attached to the empty rule dedicated to this
  30 # action.
  31
  32 AT_DATA_GRAMMAR([[input.y]],
  33 [[%{
  34 # include <stdio.h>
  35 # include <stdlib.h>
  36   static void yyerror (const char *msg);
  37   static int yylex (void);
  38 # define YYDEBUG         1
  39 # define YYERROR_VERBOSE 1
  40 %}
  41 %%
  42 exp:     { putchar ('0'); }
  43      '1' { putchar ('1'); }
  44      '2' { putchar ('2'); }
  45      '3' { putchar ('3'); }
  46      '4' { putchar ('4'); }
  47      '5' { putchar ('5'); }
  48      '6' { putchar ('6'); }
  49      '7' { putchar ('7'); }
  50      '8' { putchar ('8'); }
  51      '9' { putchar ('9'); }
  52          { putchar ('\n'); }
  53    ;
  54 %%
  55 static int
  56 yylex (void)
  57 {
  58   static const char *input = "123456789";
  59   return *input++;
  60 }
  61
  62 static void
  63 yyerror (const char *msg)
  64 {
  65   fprintf (stderr, "%s\n", msg);
  66 }
  67
  68 int
  69 main (void)
  70 {
  71   return yyparse ();
  72 }
  73 ]])
  74
  75 AT_CHECK([bison -d -v -o input.c input.y])
  76 AT_COMPILE([input])
  77 AT_PARSER_CHECK([./input], 0,
  78 [[0123456789
  79 ]])
  80
  81 AT_CLEANUP
  82
  83
  84
  85 ## ---------------------- ##
  86 ## Actions after errors.  ##
  87 ## ---------------------- ##
  88
  89 AT_SETUP([Actions after errors])
  90
  91
  92
  93 AT_DATA_GRAMMAR([[input.y]],
  94 [[%{
  95 #include <stdio.h>
  96 #include <stdlib.h>
  97
  98 static int yylex (void);
  99 static void yyerror (char const *);
 100
 101 #define YYDEBUG 1
 102 %}
 103 %union { int ival; }
 104 %type <ival> 'x' ';' thing line input
 105
 106 %%
 107 input:
 108   /* Nothing. */
 109     {
 110       $$ = 0;
 111       printf ("input(%d): /* Nothing */\n", $$);
 112     }
 113 | line input /* Right recursive to load the stack so that popping at
 114                 EOF can be exercised.  */
 115     {
 116       $$ = 2;
 117       printf ("input(%d): line(%d) input(%d)\n", $$, $1, $2);
 118     }
 119 ;
 120
 121 line:
 122   thing thing thing ';'
 123     {
 124       $$ = $1;
 125       printf ("line(%d): thing(%d) thing(%d) thing(%d) ';'(%d)\n",
 126               $$, $1, $2, $3, $4);
 127     }
 128 | thing thing ';'
 129     {
 130       $$ = $1;
 131       printf ("line(%d): thing(%d) thing(%d) ';'(%d)\n", $$, $1, $2, $3);
 132     }
 133 | thing ';'
 134     {
 135       $$ = $1;
 136       printf ("line(%d): thing(%d) ';'(%d)\n", $$, $1, $2);
 137     }
 138 | error ';'
 139     {
 140       $$ = -1;
 141       printf ("line(%d): error ';'(%d)\n", $$, $2);
 142     }
 143 ;
 144
 145 thing:
 146   'x'
 147     {
 148       $$ = $1;
 149       printf ("thing(%d): 'x'(%d)\n", $$, $1);
 150     }
 151 ;
 152 %%
 153 static size_t counter;
 154
 155 static int
 156 yylex (void)
 157 {
 158   static char const input[] =
 159     {
 160       /* Exericise the discarding of stack top and input until `error'
 161          can be reduced.  */
 162       'x', 'x', 'x', 'x', 'x', 'x', ';',
 163
 164       /* Load the stack and provoke an error that cannot be caught by
 165          the grammar, to check that the stack is cleared. */
 166       'x', 'x', ';',
 167       'x', ';',
 168       'y'
 169     };
 170
 171   if (counter < sizeof input)
 172     {
 173        yylval.ival = counter;
 174        printf ("sending: '%c' (value = %d)\n", input[counter], yylval.ival);
 175        return input[counter++];
 176     }
 177   else
 178     {
 179       printf ("sending: EOF\n");
 180       return EOF;
 181     }
 182 }
 183
 184 static void
 185 yyerror (char const *msg)
 186 {
 187   printf ("%lu: %s\n", (unsigned long int) counter, msg);
 188 }
 189
 190 int
 191 main (void)
 192 {
 193   yydebug = !!getenv ("YYDEBUG");
 194   return yyparse ();
 195 }
 196 ]])
 197
 198 AT_CHECK([bison -o input.c input.y])
 199 AT_COMPILE([input])
 200 AT_PARSER_CHECK([./input], 1,
 201 [[sending: 'x' (value = 0)
 202 thing(0): 'x'(0)
 203 sending: 'x' (value = 1)
 204 thing(1): 'x'(1)
 205 sending: 'x' (value = 2)
 206 thing(2): 'x'(2)
 207 sending: 'x' (value = 3)
 208 4: syntax error
 209 sending: 'x' (value = 4)
 210 sending: 'x' (value = 5)
 211 sending: ';' (value = 6)
 212 line(-1): error ';'(6)
 213 sending: 'x' (value = 7)
 214 thing(7): 'x'(7)
 215 sending: 'x' (value = 8)
 216 thing(8): 'x'(8)
 217 sending: ';' (value = 9)
 218 line(7): thing(7) thing(8) ';'(9)
 219 sending: 'x' (value = 10)
 220 thing(10): 'x'(10)
 221 sending: ';' (value = 11)
 222 line(10): thing(10) ';'(11)
 223 sending: 'y' (value = 12)
 224 13: syntax error
 225 sending: EOF
 226 ]])
 227
 228 AT_CLEANUP
 229
 230
 231
 232 ## ---------------- ##
 233 ## Exotic Dollars.  ##
 234 ## ---------------- ##
 235
 236 AT_SETUP([Exotic Dollars])
 237
 238 AT_DATA_GRAMMAR([[input.y]],
 239 [[%{
 240 # include <stdio.h>
 241 # include <stdlib.h>
 242   static void yyerror (const char *msg);
 243   static int yylex (void);
 244 # define YYDEBUG         1
 245 # define YYERROR_VERBOSE 1
 246 %}
 247
 248 %union
 249 {
 250   int val;
 251 };
 252
 253 %type <val> a_1 a_2 a_5
 254             sum_of_the_five_previous_values
 255
 256 %%
 257 exp: a_1 a_2 { $<val>$ = 3; } { $<val>$ = $<val>3 + 1; } a_5
 258      sum_of_the_five_previous_values
 259     {
 260        printf ("%d\n", $6);
 261     }
 262 ;
 263 a_1: { $$ = 1; };
 264 a_2: { $$ = 2; };
 265 a_5: { $$ = 5; };
 266
 267 sum_of_the_five_previous_values:
 268     {
 269        $$ = $<val>0 + $<val>-1 + $<val>-2 + $<val>-3 + $<val>-4;
 270     }
 271 ;
 272
 273 %%
 274 static int
 275 yylex (void)
 276 {
 277   return EOF;
 278 }
 279
 280 static void
 281 yyerror (const char *msg)
 282 {
 283   fprintf (stderr, "%s\n", msg);
 284 }
 285
 286 int
 287 main (void)
 288 {
 289   return yyparse ();
 290 }
 291 ]])
 292
 293 AT_CHECK([bison -d -v -o input.c input.y])
 294 AT_COMPILE([input])
 295 AT_PARSER_CHECK([./input], 0,
 296 [[15
 297 ]])
 298
 299 AT_CLEANUP
 300
 301
 302
 303 ## -------------------------- ##
 304 ## Printers and Destructors.  ##
 305 ## -------------------------- ##
 306
 307 # _AT_CHECK_PRINTER_AND_DESTRUCTOR($1, $2, $3, BISON-DIRECTIVE)
 308 # -------------------------------------------------------------
 309 m4_define([_AT_CHECK_PRINTER_AND_DESTRUCTOR],
 310 [m4_if([$1$2$3], $[1]$[2]$[3], [],
 311        [m4_fatal([$0: Invalid arguments: $@])])dnl
 312
 313 AT_SETUP([Printers and Destructors: $4])
 314
 315 # Make sure complex $n work.
 316
 317 AT_DATA_GRAMMAR([[input.y]],
 318 [[$4
 319 %{
 320 #include <stdio.h>
 321 #include <stdlib.h>
 322 #include <assert.h>
 323 #define RANGE(Location) (Location).first_line, (Location).last_line
 324 static int yylex (void);
 325 static void yyerror (const char *msg);
 326 %}
 327 %error-verbose
 328 %debug
 329 %verbose
 330 %locations
 331 %union
 332 {
 333   int ival;
 334 }
 335 %type <ival> 'x' thing line input
 336
 337 %printer { fprintf (yyout, "%d@%d-%d", $$, RANGE (@$)); }
 338    input line thing 'x'
 339
 340 %destructor
 341   { printf ("Freeing nterm input (%d@%d-%d)\n", $$, RANGE (@$)); }
 342   input
 343
 344 %destructor
 345   { printf ("Freeing nterm line (%d@%d-%d)\n", $$, RANGE (@$)); }
 346   line
 347
 348 %destructor
 349   { printf ("Freeing nterm thing (%d@%d-%d)\n", $$, RANGE (@$)); }
 350   thing
 351
 352 %destructor
 353   { printf ("Freeing token 'x' (%d@%d-%d)\n", $$, RANGE (@$)); }
 354   'x'
 355
 356 %%
 357 input:
 358   /* Nothing. */
 359     {
 360       $$ = 0;
 361       printf ("input (%d@%d-%d): /* Nothing */';'\n", $$, RANGE (@$));
 362     }
 363 | line input /* Right recursive to load the stack so that popping at
 364                 EOF can be exercised.  */
 365     {
 366       $$ = 2;
 367       printf ("input (%d@%d-%d): line (%d@%d-%d) input (%d@%d-%d)';'\n",
 368               $$, RANGE (@$), $1, RANGE (@1), $2, RANGE (@2));
 369     }
 370 ;
 371
 372 line:
 373   thing thing thing ';'
 374     {
 375       $$ = $1;
 376       printf ("line (%d@%d-%d): thing (%d@%d-%d) thing (%d@%d-%d) thing (%d@%d-%d) ';'\n",
 377               $$, RANGE (@$), $1, RANGE (@1), $2, RANGE (@2),
 378               $3, RANGE (@3));
 379     }
 380 | thing thing ';'
 381     {
 382       $$ = $1;
 383       printf ("line (%d@%d-%d): thing (%d@%d-%d) thing (%d@%d-%d) ';'\n",
 384               $$, RANGE (@$), $1, RANGE (@1), $2, RANGE (@2));
 385     }
 386 | thing ';'
 387     {
 388       $$ = $1;
 389       printf ("line (%d@%d-%d): thing (%d@%d-%d) ';'\n",
 390               $$, RANGE (@$), $1, RANGE (@1));
 391     }
 392 | error ';'
 393     {
 394       $$ = -1;
 395       printf ("line (%d@%d-%d): error (@%d-%d) ';'\n",
 396               $$, RANGE (@$), RANGE (@1));
 397     }
 398 ;
 399
 400 thing:
 401   'x'
 402     {
 403       $$ = $1;
 404       printf ("thing (%d@%d-%d): 'x' (%d@%d-%d)\n",
 405               $$, RANGE (@$), $1, RANGE (@1));
 406     }
 407 ;
 408 %%
 409 static int
 410 yylex (void)
 411 {
 412   static const unsigned int input[] =
 413     {
 414       /* Exercise the discarding of stack top and input until `error'
 415          can be reduced.  */
 416       'x', 'x', 'x', 'x', 'x', 'x', ';',
 417
 418       /* Load the stack and provoke an error that cannot be caught by
 419          the grammar, to check that the stack is cleared. */
 420       'x', 'x', ';',
 421       'x', ';',
 422       'y'
 423     };
 424   static unsigned int counter = 0;
 425
 426   if (counter < (sizeof(input) / sizeof (input[0])))
 427     {
 428        yylval.ival = counter;
 429        /* As in BASIC, line numbers go from 10 to 10.  */
 430        yylloc.first_line = yylloc.first_column = 10 * counter;
 431        yylloc.last_line = yylloc.last_column = yylloc.first_line + 9;
 432        printf ("sending: '%c' (%d@%d-%d)\n",
 433                input[counter], yylval.ival, RANGE (yylloc));
 434        return (int) input[counter++];
 435     }
 436   else
 437     {
 438       printf ("sending: EOF\n");
 439       return EOF;
 440     }
 441 }
 442
 443 static void
 444 yyerror (const char *msg)
 445 {
 446   printf ("%d-%d: %s\n", RANGE (yylloc), msg);
 447 }
 448
 449 int
 450 main (void)
 451 {
 452   yydebug = !!getenv ("YYDEBUG");
 453   if (yyparse ())
 454     {
 455       printf ("Parsing FAILED.\n");
 456       exit (1);
 457     }
 458   printf ("Successful parse.\n");
 459   return 0;
 460 }
 461 ]])
 462
 463 AT_CHECK([bison -o input.c input.y])
 464 AT_COMPILE([input])
 465 AT_PARSER_CHECK([./input], 1,
 466 [[sending: 'x' (0@0-9)
 467 thing (0@0-9): 'x' (0@0-9)
 468 sending: 'x' (1@10-19)
 469 thing (1@10-19): 'x' (1@10-19)
 470 sending: 'x' (2@20-29)
 471 thing (2@20-29): 'x' (2@20-29)
 472 sending: 'x' (3@30-39)
 473 30-39: syntax error, unexpected 'x', expecting ';'
 474 Freeing nterm thing (2@20-29)
 475 Freeing nterm thing (1@10-19)
 476 Freeing nterm thing (0@0-9)
 477 Freeing token 'x' (3@30-39)
 478 sending: 'x' (4@40-49)
 479 Freeing token 'x' (4@40-49)
 480 sending: 'x' (5@50-59)
 481 Freeing token 'x' (5@50-59)
 482 sending: ';' (6@60-69)
 483 line (-1@50-69): error (@50-59) ';'
 484 sending: 'x' (7@70-79)
 485 thing (7@70-79): 'x' (7@70-79)
 486 sending: 'x' (8@80-89)
 487 thing (8@80-89): 'x' (8@80-89)
 488 sending: ';' (9@90-99)
 489 line (7@70-99): thing (7@70-79) thing (8@80-89) ';'
 490 sending: 'x' (10@100-109)
 491 thing (10@100-109): 'x' (10@100-109)
 492 sending: ';' (11@110-119)
 493 line (10@100-119): thing (10@100-109) ';'
 494 sending: 'y' (12@120-129)
 495 120-129: syntax error, unexpected $undefined, expecting $end or 'x'
 496 sending: EOF
 497 Freeing nterm line (10@100-119)
 498 Freeing nterm line (7@70-99)
 499 Freeing nterm line (-1@50-69)
 500 Parsing FAILED.
 501 ]])
 502
 503 AT_CLEANUP
 504 ])
 505
 506
 507 # AT_CHECK_PRINTER_AND_DESTRUCTOR([BISON-OPTIONS])
 508 # ------------------------------------------------
 509 # Produce `calc.y'.
 510 m4_define([AT_CHECK_PRINTER_AND_DESTRUCTOR],
 511 [_AT_CHECK_PRINTER_AND_DESTRUCTOR($[1], $[2], $[3], [$1])
 512 ])
 513
 514
 515 AT_CHECK_PRINTER_AND_DESTRUCTOR()
 516 AT_CHECK_PRINTER_AND_DESTRUCTOR([%glr-parser])