configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19
  20 # We need a recent Autoconf to run a recent Autotest.
  21 AC_PREREQ(2.57)
  22
  23 AC_INIT([GNU Bison], [1.875e], [bug-bison@gnu.org])
  24 AC_CONFIG_AUX_DIR([config])
  25 AC_CONFIG_MACRO_DIR([m4])
  26
  27 AM_INIT_AUTOMAKE([1.7 check-news readme-alpha dist-bzip2])
  28 AC_CONFIG_HEADERS([config.h:config.hin])
  29
  30 gl_USE_SYSTEM_EXTENSIONS
  31
  32 # Checks for the compiler.
  33 AC_PROG_CC
  34 AM_PROG_CC_STDC
  35 AC_ARG_ENABLE(gcc-warnings,
  36 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  37 [case "${enableval}" in
  38    yes|no) ;;
  39    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  40  esac],
  41               [enableval=no])
  42 if test "${enableval}" = yes; then
  43   BISON_WARNING(-Werror)
  44   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  45   WARNING_CFLAGS=
  46   BISON_WARNING(-W)
  47   BISON_WARNING(-Wall)
  48   BISON_WARNING(-Wcast-align)
  49   BISON_WARNING(-Wcast-qual)
  50   BISON_WARNING(-Wformat)
  51   BISON_WARNING(-Wwrite-strings)
  52   AC_SUBST([WARNING_CXXFLAGS], [$WARNING_CFLAGS])
  53   # The following warnings are not suitable for C++.
  54   BISON_WARNING(-Wbad-function-cast)
  55   BISON_WARNING(-Wmissing-declarations)
  56   BISON_WARNING(-Wmissing-prototypes)
  57   BISON_WARNING(-Wnested-externs)
  58   BISON_WARNING(-Wshadow)
  59   BISON_WARNING(-Wstrict-prototypes)
  60   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  61 fi
  62
  63 AC_ARG_ENABLE([yacc],
  64   [AC_HELP_STRING([--disable-yacc],
  65      [do not build a yacc command or an -ly library])],
  66   , [enable_yacc=yes])
  67 case $enable_yacc in
  68 yes)
  69   YACC_SCRIPT=yacc
  70   YACC_LIBRARY=liby.a;;
  71 *)
  72   YACC_SCRIPT=
  73   YACC_LIBRARY=;;
  74 esac
  75 AC_SUBST([YACC_SCRIPT])
  76 AC_SUBST([YACC_LIBRARY])
  77
  78 # Checks for programs.
  79 AC_PROG_LEX
  80 AC_PROG_YACC
  81 AC_PROG_RANLIB
  82 BISON_PROG_GNU_M4
  83 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  84   AC_MSG_ERROR([GNU M4 1.4 is required])
  85 fi
  86 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  87
  88 # Checks for header files.
  89 AC_CHECK_HEADERS_ONCE([locale.h])
  90 AM_STDBOOL_H
  91
  92 # Checks for compiler characteristics.
  93 AC_C_INLINE
  94
  95 # Checks for types.
  96 AC_CHECK_TYPES([uintptr_t])
  97
  98 # Checks for library functions.
  99 AC_CHECK_FUNCS_ONCE([setlocale])
 100 AM_WITH_DMALLOC
 101 BISON_PREREQ_SUBPIPE
 102 BISON_PREREQ_TIMEVAR
 103
 104 # gnulib and gettext.
 105 GNULIB_AUTOCONF_SNIPPET
 106 AM_GNU_GETTEXT_VERSION([0.14.1])
 107
 108 # Initialize the test suite.
 109 AC_CONFIG_TESTDIR(tests)
 110 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 111 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 112 AC_CHECK_PROGS([VALGRIND], [valgrind])
 113 AC_PROG_CXX
 114 BISON_TEST_FOR_WORKING_CXX_COMPILER
 115 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 116 # Needed by tests/atlocal.in.
 117 AC_SUBST([GCC])
 118 O0CFLAGS=`echo $CFLAGS | sed 's/-O[0-9] *//'`
 119 AC_SUBST([O0CFLAGS])
 120
 121 AC_CONFIG_FILES([Makefile
 122                  config/Makefile
 123                  po/Makefile.in
 124                  data/Makefile
 125                  lib/Makefile src/Makefile doc/Makefile])
 126 AC_OUTPUT