data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, [YEARS])
  26 # ----------------------------
  27 # If YEARS are not defined, use b4_copyright_years.
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 ]m4_dquote(m4_text_wrap([Copyright (C)
  34 ]m4_ifval([$2], [[$2]], [m4_defn([b4_copyright_years])])[
  35 Free Software Foundation, Inc.]))[
  36
  37 This program is free software: you can redistribute it and/or modify
  38 it under the terms of the GNU General Public License as published by
  39 the Free Software Foundation, either version 3 of the License, or
  40 (at your option) any later version.
  41
  42 This program is distributed in the hope that it will be useful,
  43 but WITHOUT ANY WARRANTY; without even the implied warranty of
  44 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  45 GNU General Public License for more details.
  46
  47 You should have received a copy of the GNU General Public License
  48 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## ---------------- ##
  65 ## Error handling.  ##
  66 ## ---------------- ##
  67
  68 # The following error handling macros print error directives that should not
  69 # become arguments of other macro invocations since they would likely then be
  70 # mangled.  Thus, they print to stdout directly.
  71
  72 # b4_cat(TEXT)
  73 # ------------
  74 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  75 # escaped.  For example:
  76 #
  77 #   b4_cat([[@complain(invalid input@)]])
  78 m4_define([b4_cat],
  79 [m4_syscmd([cat <<'_m4eof'
  80 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  81 _m4eof
  82 ])dnl
  83 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  84
  85 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  86 # -------------------------------------------
  87 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  88 #
  89 # For example:
  90 #
  91 #   b4_error([[warn]], [[invalid value for '%s': %s]], [[foo]], [[3]])
  92 m4_define([b4_error],
  93 [b4_cat([[@]$1[(]$2[]]dnl
  94 [m4_if([$#], [2], [],
  95        [m4_foreach([b4_arg],
  96                    m4_dquote(m4_shift(m4_shift($@))),
  97                    [[@,]b4_arg])])[@)]])])
  98
  99 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
 100 # ----------------------------------------------------------
 101 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 102 #
 103 # For example:
 104 #
 105 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 106 #               [[invalid %s]], [[foo]])
 107 m4_define([b4_error_at],
 108 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 109 [m4_if([$#], [4], [],
 110        [m4_foreach([b4_arg],
 111                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 112                    [[@,]b4_arg])])[@)]])])
 113
 114 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 115 # ------------------------------------
 116 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 117 #
 118 # For example:
 119 #
 120 #   b4_warn([[invalid value for '%s': %s]], [[foo]], [[3]])
 121 #
 122 # As a simple test suite, this:
 123 #
 124 #   m4_divert(-1)
 125 #   m4_define([asdf], [ASDF])
 126 #   m4_define([fsa], [FSA])
 127 #   m4_define([fdsa], [FDSA])
 128 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 129 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 130 #   b4_warn()
 131 #   b4_warn(1)
 132 #   b4_warn(1, 2)
 133 #
 134 # Should produce this without newlines:
 135 #
 136 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 137 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 138 #   @warn(@)
 139 #   @warn(1@)
 140 #   @warn(1@,2@)
 141 m4_define([b4_warn],
 142 [b4_error([[warn]], $@)])
 143
 144 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 145 # ---------------------------------------------------
 146 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 147 #
 148 # For example:
 149 #
 150 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 151 m4_define([b4_warn_at],
 152 [b4_error_at([[warn]], $@)])
 153
 154 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 155 # ----------------------------------------
 156 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 157 #
 158 # See b4_warn example.
 159 m4_define([b4_complain],
 160 [b4_error([[complain]], $@)])
 161
 162 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 163 # -------------------------------------------------------
 164 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 165 #
 166 # See b4_warn_at example.
 167 m4_define([b4_complain_at],
 168 [b4_error_at([[complain]], $@)])
 169
 170 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 171 # -------------------------------------
 172 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 173 #
 174 # See b4_warn example.
 175 m4_define([b4_fatal],
 176 [b4_error([[fatal]], $@)dnl
 177 m4_exit(1)])
 178
 179 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 180 # ----------------------------------------------------
 181 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 182 #
 183 # See b4_warn_at example.
 184 m4_define([b4_fatal_at],
 185 [b4_error_at([[fatal]], $@)dnl
 186 m4_exit(1)])
 187
 188
 189 ## ------------ ##
 190 ## Data Types.  ##
 191 ## ------------ ##
 192
 193 # b4_ints_in(INT1, INT2, LOW, HIGH)
 194 # ---------------------------------
 195 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 196 m4_define([b4_ints_in],
 197 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 198
 199
 200 # b4_subtract(LHS, RHS)
 201 # ---------------------
 202 # Evaluate LHS - RHS if they are integer literals, otherwise expand
 203 # to (LHS) - (RHS).
 204 m4_define([b4_subtract],
 205 [m4_bmatch([$1$2], [^[0123456789]*$],
 206            [m4_eval([$1 - $2])],
 207            [($1) - ($2)])])
 208
 209 # b4_args(ARG1, ...)
 210 # _b4_args(ARG1, ...)
 211 # -------------------
 212 # Join with comma, skipping empty arguments.
 213 # b4_args calls itself recursively until it sees the first non-empty
 214 # argument, then calls _b4_args which prepends each non-empty argument
 215 # with a comma.
 216 m4_define([b4_args],
 217 [m4_if([$#$1],
 218        [1], [],
 219        [m4_ifval([$1],
 220                  [$1[]_$0(m4_shift($@))],
 221                  [$0(m4_shift($@))])])])
 222
 223 # _b4_args(ARGS1, ...)
 224 # --------------------
 225 m4_define([_b4_args],
 226 [m4_if([$#$1],
 227        [1], [],
 228        [m4_ifval([$1], [, $1])[]$0(m4_shift($@))])])
 229
 230
 231
 232
 233 # b4_integral_parser_tables_map(MACRO)
 234 # -------------------------------------
 235 # Map MACRO on all the integral tables.  MACRO is expected to have
 236 # the signature MACRO(TABLE-NAME, CONTENT, COMMENT).
 237 m4_define([b4_integral_parser_tables_map],
 238 [$1([pact], [b4_pact],
 239     [[YYPACT[STATE-NUM] -- Index in YYTABLE of the portion describing
 240 STATE-NUM.]])
 241
 242 $1([defact], [b4_defact],
 243    [[YYDEFACT[S] -- default reduction number in state S.  Performed when
 244 YYTABLE does not specify something else to do.  Zero means the default
 245 is an error.]])
 246
 247 $1([pgoto], [b4_pgoto], [[YYPGOTO[NTERM-NUM].]])
 248
 249 $1([defgoto], [b4_defgoto], [[YYDEFGOTO[NTERM-NUM].]])
 250
 251 $1([table], [b4_table],
 252    [[YYTABLE[YYPACT[STATE-NUM]].  What to do in state STATE-NUM.  If
 253 positive, shift that token.  If negative, reduce the rule which
 254 number is the opposite.  If YYTABLE_NINF, syntax error.]])
 255
 256 $1([check], [b4_check])
 257
 258 $1([stos], [b4_stos],
 259    [[STOS_[STATE-NUM] -- The (internal number of the) accessing
 260 symbol of state STATE-NUM.]])
 261
 262 $1([r1], [b4_r1],
 263    [[YYR1[YYN] -- Symbol number of symbol that rule YYN derives.]])
 264
 265 $1([r2], [b4_r2],
 266    [[YYR2[YYN] -- Number of symbols composing right hand side of rule YYN.]])
 267 ])
 268
 269
 270 # b4_parser_tables_declare
 271 # b4_parser_tables_define
 272 # ------------------------
 273 # Define/declare the (deterministic) parser tables.
 274 m4_define([b4_parser_tables_declare],
 275 [b4_integral_parser_tables_map([b4_integral_parser_table_declare])])
 276
 277 m4_define([b4_parser_tables_define],
 278 [b4_integral_parser_tables_map([b4_integral_parser_table_define])])
 279
 280
 281
 282 ## ------------------ ##
 283 ## Decoding options.  ##
 284 ## ------------------ ##
 285
 286 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 287 # -----------------------------------
 288 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 289 m4_define([b4_flag_if],
 290 [m4_case(b4_$1_flag,
 291          [0], [$3],
 292          [1], [$2],
 293          [m4_fatal([invalid $1 value: ]$1)])])
 294
 295
 296 # b4_define_flag_if(FLAG)
 297 # -----------------------
 298 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 299 # value of the Boolean FLAG.
 300 m4_define([b4_define_flag_if],
 301 [_b4_define_flag_if($[1], $[2], [$1])])
 302
 303 # _b4_define_flag_if($1, $2, FLAG)
 304 # --------------------------------
 305 # Work around the impossibility to define macros inside macros,
 306 # because issuing `[$1]' is not possible in M4.  GNU M4 should provide
 307 # $$1 a la M5/TeX.
 308 m4_define([_b4_define_flag_if],
 309 [m4_if([$1$2], $[1]$[2], [],
 310        [m4_fatal([$0: Invalid arguments: $@])])dnl
 311 m4_define([b4_$3_if],
 312           [b4_flag_if([$3], [$1], [$2])])])
 313
 314
 315 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 316 # -----------------------------
 317 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 318 b4_define_flag_if([defines])            # Whether headers are requested.
 319 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 320 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 321 b4_define_flag_if([token_table])        # Whether yytoken_table is demanded.
 322 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 323
 324
 325 ## --------- ##
 326 ## Symbols.  ##
 327 ## --------- ##
 328
 329 # In order to unify the handling of the various aspects of symbols
 330 # (tag, type_name, whether terminal, etc.), bison.exe defines one
 331 # macro per (token, field), where field can has_id, id, etc.: see
 332 # src/output.c:prepare_symbols_definitions().
 333 #
 334 # The following macros provide access to these values.
 335
 336 # b4_symbol_(NUM, FIELD)
 337 # ----------------------
 338 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 339 # undefined.
 340 m4_define([b4_symbol_],
 341 [m4_indir([b4_symbol($1, $2)])])
 342
 343
 344 # b4_symbol(NUM, FIELD)
 345 # ---------------------
 346 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 347 # undefined.  If FIELD = id, prepend the prefix.
 348 m4_define([b4_symbol],
 349 [m4_case([$2],
 350          [id],    [m4_do([b4_percent_define_get([api.tokens.prefix])],
 351                          [b4_symbol_([$1], [id])])],
 352          [b4_symbol_($@)])])
 353
 354
 355 # b4_symbol_if(NUM, FIELD, IF-TRUE, IF-FALSE)
 356 # -------------------------------------------
 357 # If FIELD about symbol #NUM is 1 expand IF-TRUE, if is 0, expand IF-FALSE.
 358 # Otherwise an error.
 359 m4_define([b4_symbol_if],
 360 [m4_case(b4_symbol([$1], [$2]),
 361          [1], [$3],
 362          [0], [$4],
 363          [m4_fatal([$0: field $2 of $1 is not a Boolean:] b4_symbol([$1], [$2]))])])
 364
 365
 366 # b4_symbol_action_location(SYMBOL-NUM, KIND)
 367 # -------------------------------------------
 368 # Report the location of the KIND action as FILE:LINE.
 369 m4_define([b4_symbol_action_location],
 370 [b4_symbol([$1], [$2_file]):b4_syncline([b4_symbol([$1], [$2_line])])])
 371
 372
 373 # b4_symbol_action(SYMBOL-NUM, KIND)
 374 # ----------------------------------
 375 # Run the action KIND (destructor or printer) for SYMBOL-NUM.
 376 # Same as in C, but using references instead of pointers.
 377 m4_define([b4_symbol_action],
 378 [b4_symbol_if([$1], [has_$2],
 379 [m4_pushdef([b4_dollar_dollar],
 380     [b4_symbol_value([(*yyvaluep)],
 381                      b4_symbol_if([$1], [has_type],
 382                                   [b4_symbol([$1], [type])]))])dnl
 383 m4_pushdef([b4_at_dollar], [(*yylocationp)])dnl
 384       b4_symbol_case_([$1])[]dnl
 385 b4_syncline([b4_symbol([$1], [$2_line])], ["b4_symbol([$1], [$2_file])"])
 386         b4_symbol([$1], [$2])
 387 b4_syncline([@oline@], [@ofile@])
 388         break;
 389
 390 m4_popdef([b4_at_dollar])dnl
 391 m4_popdef([b4_dollar_dollar])dnl
 392 ])])
 393
 394
 395 # b4_symbol_destructor(SYMBOL-NUM)
 396 # b4_symbol_printer(SYMBOL-NUM)
 397 # --------------------------------
 398 m4_define([b4_symbol_destructor], [b4_symbol_action([$1], [destructor])])
 399 m4_define([b4_symbol_printer],    [b4_symbol_action([$1], [printer])])
 400
 401
 402 # b4_symbol_case_(SYMBOL-NUM)
 403 # ---------------------------
 404 # Issue a "case NUM" for SYMBOL-NUM.
 405 m4_define([b4_symbol_case_],
 406 [      case b4_symbol([$1], [number]): // b4_symbol([$1], [tag])
 407 ])
 408
 409
 410 # b4_symbol_foreach(MACRO)
 411 # ------------------------
 412 # Invoke MACRO(SYMBOL-NUM) for each SYMBOL-NUM.
 413 m4_define([b4_symbol_foreach],
 414           [m4_map([$1], m4_defn([b4_symbol_numbers]))])
 415
 416 # b4_symbol_map(MACRO)
 417 # --------------------
 418 # Return a list (possibly empty elements) of MACRO invoked for each
 419 # SYMBOL-NUM.
 420 m4_define([b4_symbol_map],
 421 [m4_map_args_sep([$1(], [)], [,], b4_symbol_numbers)])
 422
 423
 424 # b4_token_visible_if(NUM, IF-TRUE, IF-FALSE)
 425 # -------------------------------------------
 426 # Whether NUM denotes a token that has an exported definition (i.e.,
 427 # shows in enum yytokentype).
 428 m4_define([b4_token_visible_if],
 429 [b4_symbol_if([$1], [is_token],
 430               [b4_symbol_if([$1], [has_id], [$2], [$3])],
 431               [$3])])
 432
 433 # b4_token_has_definition(NUM)
 434 # ----------------------------
 435 # 1 if NUM is visible, nothing otherwise.
 436 m4_define([b4_token_has_definition],
 437 [b4_token_visible_if([$1], [1])])
 438
 439 # b4_any_token_visible_if([IF-TRUE], [IF-FALSE])
 440 # ----------------------------------------------
 441 # Whether there is a token that needs to be defined.
 442 m4_define([b4_any_token_visible_if],
 443 [m4_ifval(b4_symbol_foreach([b4_token_has_definition]),
 444           [$1], [$2])])
 445
 446
 447 # b4_token_format(FORMAT, NUM)
 448 # ----------------------------
 449 m4_define([b4_token_format],
 450 [b4_token_visible_if([$2],
 451 [m4_quote(m4_format([$1],
 452                      [b4_symbol([$2], [id])],
 453                      [b4_symbol([$2], [user_number])]))])])
 454
 455
 456 ## ------- ##
 457 ## Types.  ##
 458 ## ------- ##
 459
 460 # b4_type_action_(NUMS)
 461 # ---------------------
 462 # Run actions for the symbol NUMS that all have the same type-name.
 463 # Skip NUMS that have no type-name.
 464 m4_define([b4_type_action_],
 465 [b4_symbol_if([$1], [has_type],
 466 [m4_map([b4_symbol_case_], [$@])[]dnl
 467         b4_dollar_dollar([b4_symbol([$1], [number])],
 468                          [b4_symbol([$1], [tag])],
 469                          [b4_symbol([$1], [type])]);
 470         break;
 471
 472 ])])
 473
 474 # b4_type_foreach(MACRO)
 475 # ----------------------
 476 # Invoke MACRO(SYMBOL-NUMS) for each set of SYMBOL-NUMS for each type set.
 477 m4_define([b4_type_foreach],
 478           [m4_map([$1], m4_defn([b4_type_names]))])
 479
 480
 481
 482 ## ----------- ##
 483 ## Synclines.  ##
 484 ## ----------- ##
 485
 486 # b4_basename(NAME)
 487 # -----------------
 488 # Similar to POSIX basename; the differences don't matter here.
 489 # Beware that NAME is not evaluated.
 490 m4_define([b4_basename],
 491 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 492
 493
 494 # b4_syncline(LINE, FILE)
 495 # -----------------------
 496 m4_define([b4_syncline],
 497 [b4_flag_if([synclines],
 498 [b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 499 b4_sync_start([$1], [$2])])])
 500
 501 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 502 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 503
 504 # b4_user_code(USER-CODE)
 505 # -----------------------
 506 # Emit code from the user, ending it with synclines.
 507 m4_define([b4_user_code],
 508 [$1
 509 b4_syncline([@oline@], [@ofile@])])
 510
 511
 512 # b4_define_user_code(MACRO)
 513 # --------------------------
 514 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 515 m4_define([b4_define_user_code],
 516 [m4_define([b4_user_$1],
 517 [b4_user_code([b4_$1])])])
 518
 519
 520 # b4_user_actions
 521 # b4_user_initial_action
 522 # b4_user_post_prologue
 523 # b4_user_pre_prologue
 524 # b4_user_stype
 525 # ----------------------
 526 # Macros that issue user code, ending with synclines.
 527 b4_define_user_code([actions])
 528 b4_define_user_code([initial_action])
 529 b4_define_user_code([post_prologue])
 530 b4_define_user_code([pre_prologue])
 531 b4_define_user_code([stype])
 532
 533
 534 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 535 # -----------------------------------------------------
 536 # Complain if any name of type WHAT is used by the user (as recorded in
 537 # USER-LIST) but is not used by Bison (as recorded by macros in the
 538 # namespace BISON-NAMESPACE).
 539 #
 540 # USER-LIST must expand to a list specifying all user occurrences of all names
 541 # of type WHAT.   Each item in the list must be a triplet specifying one
 542 # occurrence: name, start boundary, and end boundary.  Empty string names are
 543 # fine.  An empty list is fine.
 544 #
 545 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 546 # name occurrences and with correct quoting:
 547 #
 548 #   m4_define([b4_foo_user_names],
 549 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 550 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 551 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 552 #
 553 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 554 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 555 # are fine, but it would be ugly for Bison to actually use one.
 556 #
 557 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 558 # the names bar and baz are used by Bison:
 559 #
 560 #   m4_define([b4_foo_bison_names(bar)])
 561 #   m4_define([b4_foo_bison_names(baz)])
 562 #
 563 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 564 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 565 # quoting:
 566 #
 567 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 568 #                       [[b4_foo_bison_names]])
 569 m4_define([b4_check_user_names],
 570 [m4_foreach([b4_occurrence], $2,
 571 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 572 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 573 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 574 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 575 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 576           [b4_complain_at([b4_start], [b4_end],
 577                           [[%s '%s' is not used]],
 578                           [$1], [b4_user_name])])[]dnl
 579 m4_popdef([b4_occurrence])dnl
 580 m4_popdef([b4_user_name])dnl
 581 m4_popdef([b4_start])dnl
 582 m4_popdef([b4_end])dnl
 583 ])])
 584
 585
 586
 587 ## --------------------- ##
 588 ## b4_percent_define_*.  ##
 589 ## --------------------- ##
 590
 591
 592 # b4_percent_define_use(VARIABLE)
 593 # -------------------------------
 594 # Declare that VARIABLE was used.
 595 m4_define([b4_percent_define_use],
 596 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 597 ])
 598
 599 # b4_percent_define_get(VARIABLE, [DEFAULT])
 600 # ------------------------------------------
 601 # Mimic muscle_percent_define_get in ../src/muscle-tab.h.  That is, if
 602 # the %define variable VARIABLE is defined, emit its value.  Contrary
 603 # to its C counterpart, return DEFAULT otherwise.  Also, record
 604 # Bison's usage of VARIABLE by defining
 605 # b4_percent_define_bison_variables(VARIABLE).
 606 #
 607 # For example:
 608 #
 609 #   b4_percent_define_get([[foo]])
 610 m4_define([b4_percent_define_get],
 611 [b4_percent_define_use([$1])dnl
 612 m4_ifdef([b4_percent_define(]$1[)],
 613          [m4_indir([b4_percent_define(]$1[)])],
 614          [$2])])
 615
 616 # b4_percent_define_get_loc(VARIABLE)
 617 # -----------------------------------
 618 # Mimic muscle_percent_define_get_loc in ../src/muscle-tab.h exactly.  That is,
 619 # if the %define variable VARIABLE is undefined, complain fatally since that's
 620 # a Bison or skeleton error.  Otherwise, return its definition location in a
 621 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 622 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 623 # reason to suspect that the user-supplied value has yet influenced the output.
 624 #
 625 # For example:
 626 #
 627 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 628 m4_define([b4_percent_define_get_loc],
 629 [m4_ifdef([b4_percent_define_loc(]$1[)],
 630           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 631 b4_loc[]dnl
 632 m4_popdef([b4_loc])],
 633           [b4_fatal([[b4_percent_define_get_loc: undefined %%define variable '%s']], [$1])])])
 634
 635 # b4_percent_define_get_syncline(VARIABLE)
 636 # ----------------------------------------
 637 # Mimic muscle_percent_define_get_syncline in ../src/muscle-tab.h exactly.
 638 # That is, if the %define variable VARIABLE is undefined, complain fatally
 639 # since that's a Bison or skeleton error.  Otherwise, return its definition
 640 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 641 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 642 # influenced the output.
 643 #
 644 # For example:
 645 #
 646 #   b4_percent_define_get_syncline([[foo]])
 647 m4_define([b4_percent_define_get_syncline],
 648 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 649           [m4_indir([b4_percent_define_syncline(]$1[)])],
 650           [b4_fatal([[b4_percent_define_get_syncline: undefined %%define variable '%s']], [$1])])])
 651
 652 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 653 # ------------------------------------------------------
 654 # Mimic muscle_percent_define_ifdef in ../src/muscle-tab.h exactly.  That is,
 655 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 656 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 657 # b4_percent_define_bison_variables(VARIABLE).
 658 #
 659 # For example:
 660 #
 661 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 662 m4_define([b4_percent_define_ifdef],
 663 [m4_ifdef([b4_percent_define(]$1[)],
 664           [b4_percent_define_use([$1])$2],
 665           [$3])])
 666
 667
 668 ## --------- ##
 669 ## Options.  ##
 670 ## --------- ##
 671
 672
 673 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 674 # --------------------------------------------------------
 675 # Mimic muscle_percent_define_flag_if in ../src/muscle-tab.h exactly.  That is,
 676 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 677 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 678 # (a Bison or skeleton error since the default value should have been set
 679 # already) or defined to any other value (possibly a user error).  Also, record
 680 # Bison's usage of VARIABLE by defining
 681 # b4_percent_define_bison_variables(VARIABLE).
 682 #
 683 # For example:
 684 #
 685 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 686 m4_define([b4_percent_define_flag_if],
 687 [b4_percent_define_ifdef([$1],
 688   [m4_case(b4_percent_define_get([$1]),
 689            [], [$2], [true], [$2], [false], [$3],
 690            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 691                                            [[invalid value for %%define Boolean variable '%s']],
 692                                            [$1])],
 693                            [[b4_percent_define_flag_if($1)]])])],
 694   [b4_fatal([[b4_percent_define_flag_if: undefined %%define variable '%s']], [$1])])])
 695
 696
 697 # b4_percent_define_default(VARIABLE, DEFAULT)
 698 # --------------------------------------------
 699 # Mimic muscle_percent_define_default in ../src/muscle-tab.h exactly.  That is,
 700 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 701 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 702 # suspect that the value has yet influenced the output.
 703 #
 704 # For example:
 705 #
 706 #   b4_percent_define_default([[foo]], [[default value]])
 707 m4_define([b4_percent_define_default],
 708 [m4_ifndef([b4_percent_define(]$1[)],
 709            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 710             m4_define([b4_percent_define_loc(]$1[)],
 711                       [[[[<skeleton default value>:-1.-1]],
 712                         [[<skeleton default value>:-1.-1]]]])dnl
 713             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 714
 715
 716 # b4_percent_define_if_define(VARIABLE)
 717 # -------------------------------------
 718 # Define b4_VARIABLE_if that executes its $1 or $2 depending whether
 719 # VARIABLE was %defined.  The characters `.' and `-' in VARIABLE are mapped
 720 # to `_'.
 721 m4_define([b4_percent_define_if_define_],
 722 [m4_define(m4_bpatsubst([b4_$1_if], [[-.]], [_]),
 723            [b4_percent_define_flag_if([$1], [$2], [$3])])])
 724 m4_define([b4_percent_define_if_define],
 725 [b4_percent_define_default([[$1]], [[false]])
 726 b4_percent_define_if_define_([$1], $[1], $[2])])
 727
 728
 729 # b4_percent_define_check_values(VALUES)
 730 # --------------------------------------
 731 # Mimic muscle_percent_define_check_values in ../src/muscle-tab.h exactly
 732 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 733 # is a list of sublists of strings.  For each sublist, the first string is the
 734 # name of a %define variable, and all remaining strings in that sublist are the
 735 # valid values for that variable.  Complain if such a variable is undefined (a
 736 # Bison error since the default value should have been set already) or defined
 737 # to any other value (possibly a user error).  Don't record this as a Bison
 738 # usage of the variable as there's no reason to suspect that the value has yet
 739 # influenced the output.
 740 #
 741 # For example:
 742 #
 743 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 744 #                                  [[[[bar]], [[bar-value1]]]])
 745 m4_define([b4_percent_define_check_values],
 746 [m4_foreach([b4_sublist], m4_quote($@),
 747             [_b4_percent_define_check_values(b4_sublist)])])
 748
 749 m4_define([_b4_percent_define_check_values],
 750 [m4_ifdef([b4_percent_define(]$1[)],
 751   [m4_pushdef([b4_good_value], [0])dnl
 752    m4_if($#, 1, [],
 753          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 754                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 755                             [m4_define([b4_good_value], [1])])])])dnl
 756    m4_if(b4_good_value, [0],
 757          [b4_complain_at(b4_percent_define_get_loc([$1]),
 758                          [[invalid value for %%define variable '%s': '%s']],
 759                          [$1],
 760                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))
 761           m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 762                      [b4_complain_at(b4_percent_define_get_loc([$1]),
 763                                      [[accepted value: '%s']],
 764                                      m4_dquote(b4_value))])])dnl
 765    m4_popdef([b4_good_value])],
 766   [b4_fatal([[b4_percent_define_check_values: undefined %%define variable '%s']], [$1])])])
 767
 768 # b4_percent_code_get([QUALIFIER])
 769 # --------------------------------
 770 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 771 # comment and ending with synclines and a newline.  If QUALIFIER is not
 772 # specified or empty, do this for the unqualified %code blocks.  Also, record
 773 # Bison's usage of QUALIFIER (if specified) by defining
 774 # b4_percent_code_bison_qualifiers(QUALIFIER).
 775 #
 776 # For example, to emit any unqualified %code blocks followed by any %code
 777 # blocks for the qualifier foo:
 778 #
 779 #   b4_percent_code_get
 780 #   b4_percent_code_get([[foo]])
 781 m4_define([b4_percent_code_get],
 782 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 783 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 784 m4_ifdef(b4_macro_name,
 785 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 786                    [["%code ]$1["]])[ blocks.]])
 787 b4_user_code([m4_indir(b4_macro_name)])
 788 ])dnl
 789 m4_popdef([b4_macro_name])])
 790
 791 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 792 # -----------------------------------------------------
 793 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 794 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 795 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 796 # b4_percent_code_bison_qualifiers(QUALIFIER).
 797 m4_define([b4_percent_code_ifdef],
 798 [m4_ifdef([b4_percent_code(]$1[)],
 799           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 800           [$3])])
 801
 802
 803 ## ------------------ ##
 804 ## Common variables.  ##
 805 ## ------------------ ##
 806
 807 # Default values for %define.
 808 # ---------------------------
 809 # If the api.tokens.prefix, it is empty.
 810 m4_percent_define_default([[api.tokens.prefix]], [[]])
 811
 812 # b4_parse_assert_if([IF-ASSERTIONS-ARE-USED], [IF-NOT])
 813 # b4_parse_trace_if([IF-DEBUG-TRACES-ARE-ENABLED], [IF-NOT])
 814 # b4_lex_symbol_if([IF-YYLEX-RETURNS-A-COMPLETE-SYMBOL], [IF-NOT])
 815 # b4_variant_if([IF-VARIANT-ARE-USED], [IF-NOT])
 816 # ----------------------------------------------
 817 b4_percent_define_if_define([lex_symbol])
 818 b4_percent_define_if_define([locations])     # Whether locations are tracked.
 819 b4_percent_define_if_define([parse.assert])
 820 b4_percent_define_if_define([parse.trace])
 821 b4_percent_define_if_define([variant])
 822
 823
 824 # b4_error_verbose_if([IF-ERRORS-ARE-VERBOSE], [IF-NOT])
 825 # ------------------------------------------------------
 826 # Map %define parse.error "(simple|verbose)" to b4_error_verbose_if and
 827 # b4_error_verbose_flag.
 828 b4_percent_define_default([[parse.error]], [[simple]])
 829 b4_percent_define_check_values([[[[parse.error]],
 830                                  [[simple]], [[verbose]]]])
 831 m4_define([b4_error_verbose_flag],
 832           [m4_case(b4_percent_define_get([[parse.error]]),
 833                    [simple],  [[0]],
 834                    [verbose], [[1]])])
 835 b4_define_flag_if([error_verbose])
 836
 837 # yytoken_table is needed to support verbose errors.
 838 b4_error_verbose_if([m4_define([b4_token_table_flag], [1])])
 839
 840
 841 ## ----------------------------------------------------------- ##
 842 ## After processing the skeletons, check that all the user's   ##
 843 ## %define variables and %code qualifiers were used by Bison.  ##
 844 ## ----------------------------------------------------------- ##
 845
 846 m4_define([b4_check_user_names_wrap],
 847 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 848           [b4_check_user_names([[%]$1 $2],
 849                                [b4_percent_]$1[_user_]$2[s],
 850                                [[b4_percent_]$1[_bison_]$2[s]])])])
 851
 852 m4_wrap_lifo([
 853 b4_check_user_names_wrap([[define]], [[variable]])
 854 b4_check_user_names_wrap([[code]], [[qualifier]])
 855 ])
 856
 857
 858 ## ---------------- ##
 859 ## Default values.  ##
 860 ## ---------------- ##
 861
 862 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 863 m4_define_default([b4_pre_prologue], [])
 864 m4_define_default([b4_post_prologue], [])
 865 m4_define_default([b4_epilogue], [])
 866 m4_define_default([b4_parse_param], [])
 867
 868 # The initial column and line.
 869 m4_define_default([b4_location_initial_column], [1])
 870 m4_define_default([b4_location_initial_line],   [1])
 871
 872 # Sanity checks.
 873 b4_percent_define_ifdef([api.prefix],
 874 [m4_ifdef([b4_prefix],
 875 [b4_complain_at(b4_percent_define_get_loc([api.prefix]),
 876                 [['%s' and '%s' cannot be used together]],
 877                 [%name-prefix],
 878                 [%define api.prefix])])])