src/scan-gram.l

   1 /* Bison Grammar Scanner                             -*- C -*-
   2
   3    Copyright (C) 2002-2013 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software: you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation, either version 3 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  19
  20 %option debug nodefault noinput noyywrap never-interactive
  21 %option prefix="gram_" outfile="lex.yy.c"
  22
  23 %{
  24 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  25    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  26 #undef gram_wrap
  27 #define gram_wrap() 1
  28
  29 #define FLEX_PREFIX(Id) gram_ ## Id
  30 #include <src/flex-scanner.h>
  31
  32 #include <src/complain.h>
  33 #include <src/files.h>
  34 #include <src/getargs.h>
  35 #include <src/gram.h>
  36 #include <quotearg.h>
  37 #include <src/reader.h>
  38 #include <src/uniqstr.h>
  39
  40 #include <c-ctype.h>
  41 #include <mbswidth.h>
  42 #include <quote.h>
  43
  44 #include <src/scan-gram.h>
  45
  46 #define YY_DECL GRAM_LEX_DECL
  47
  48 #define YY_USER_INIT                                    \
  49    code_start = scanner_cursor = loc->start;            \
  50
  51 /* Location of scanner cursor.  */
  52 static boundary scanner_cursor;
  53
  54 #define YY_USER_ACTION  location_compute (loc, &scanner_cursor, yytext, yyleng);
  55
  56 static size_t no_cr_read (FILE *, char *, size_t);
  57 #define YY_INPUT(buf, result, size) ((result) = no_cr_read (yyin, buf, size))
  58
  59 #define RETURN_PERCENT_PARAM(Value)                     \
  60   RETURN_VALUE(PERCENT_PARAM, param, param_ ## Value)
  61
  62 #define RETURN_PERCENT_FLAG(Value)                              \
  63   RETURN_VALUE(PERCENT_FLAG, uniqstr, uniqstr_new (Value))
  64
  65 #define RETURN_VALUE(Token, Field, Value)       \
  66   do {                                          \
  67     val->Field = Value;                         \
  68     return Token;                               \
  69   } while (0)
  70
  71 #define ROLLBACK_CURRENT_TOKEN                                  \
  72   do {                                                          \
  73     scanner_cursor.column -= mbsnwidth (yytext, yyleng, 0);     \
  74     yyless (0);                                                 \
  75   } while (0)
  76
  77 #define DEPRECATED(Msg)                                         \
  78   do {                                                          \
  79     size_t i;                                                   \
  80     deprecated_directive (loc, yytext, Msg);                    \
  81     scanner_cursor.column -= mbsnwidth (Msg, strlen (Msg), 0);  \
  82     for (i = strlen (Msg); i != 0; --i)                         \
  83       unput (Msg[i - 1]);                                       \
  84   } while (0)
  85
  86 /* A string representing the most recently saved token.  */
  87 static char *last_string;
  88
  89 /* Bracketed identifier. */
  90 static uniqstr bracketed_id_str = 0;
  91 static location bracketed_id_loc;
  92 static boundary bracketed_id_start;
  93 static int bracketed_id_context_state = 0;
  94
  95 void
  96 gram_scanner_last_string_free (void)
  97 {
  98   STRING_FREE;
  99 }
 100
 101 static void handle_syncline (char *, location);
 102 static unsigned long int scan_integer (char const *p, int base, location loc);
 103 static int convert_ucn_to_byte (char const *hex_text);
 104 static void unexpected_eof (boundary, char const *);
 105 static void unexpected_newline (boundary, char const *);
 106
 107 %}
 108  /* A C-like comment in directives/rules. */
 109 %x SC_YACC_COMMENT
 110  /* Strings and characters in directives/rules. */
 111 %x SC_ESCAPED_STRING SC_ESCAPED_CHARACTER
 112  /* A identifier was just read in directives/rules.  Special state
 113     to capture the sequence 'identifier :'. */
 114 %x SC_AFTER_IDENTIFIER
 115  /* A complex tag, with nested angles brackets. */
 116 %x SC_TAG
 117
 118  /* Four types of user code:
 119     - prologue (code between '%{' '%}' in the first section, before %%);
 120     - actions, printers, union, etc, (between braced in the middle section);
 121     - epilogue (everything after the second %%).
 122     - predicate (code between '%?{' and '{' in middle section); */
 123 %x SC_PROLOGUE SC_BRACED_CODE SC_EPILOGUE SC_PREDICATE
 124  /* C and C++ comments in code. */
 125 %x SC_COMMENT SC_LINE_COMMENT
 126  /* Strings and characters in code. */
 127 %x SC_STRING SC_CHARACTER
 128  /* Bracketed identifiers support. */
 129 %x SC_BRACKETED_ID SC_RETURN_BRACKETED_ID
 130
 131 letter    [.abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_]
 132 notletter [^.abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_]{-}[%\{]
 133 id        {letter}({letter}|[-0-9])*
 134 int       [0-9]+
 135
 136 /* POSIX says that a tag must be both an id and a C union member, but
 137    historically almost any character is allowed in a tag.  We disallow
 138    NUL, as this simplifies our implementation.  We disallow angle
 139    bracket to match them in nested pairs: several languages use them
 140    for generics/template types.  */
 141 tag      [^\0<>]+
 142
 143 /* Zero or more instances of backslash-newline.  Following GCC, allow
 144    white space between the backslash and the newline.  */
 145 splice   (\\[ \f\t\v]*\n)*
 146
 147 /* An equal sign, with optional leading whitespaces. This is used in some
 148    deprecated constructs. */
 149 eqopt    ([[:space:]]*=)?
 150
 151 %%
 152 %{
 153   /* Nesting level.  Either for nested braces, or nested angle brackets
 154      (but not mixed).  */
 155   int nesting PACIFY_CC (= 0);
 156
 157   /* Parent context state, when applicable.  */
 158   int context_state PACIFY_CC (= 0);
 159
 160   /* Location of most recent identifier, when applicable.  */
 161   location id_loc PACIFY_CC (= empty_location);
 162
 163   /* Where containing code started, when applicable.  Its initial
 164      value is relevant only when yylex is invoked in the SC_EPILOGUE
 165      start condition.  */
 166   boundary code_start = scanner_cursor;
 167
 168   /* Where containing comment or string or character literal started,
 169      when applicable.  */
 170   boundary token_start PACIFY_CC (= scanner_cursor);
 171 %}
 172
 173
 174   /*-----------------------.
 175   | Scanning white space.  |
 176   `-----------------------*/
 177
 178 <INITIAL,SC_AFTER_IDENTIFIER,SC_BRACKETED_ID,SC_RETURN_BRACKETED_ID>
 179 {
 180   /* Comments and white space.  */
 181   "," {
 182      complain (loc, Wother, _("stray ',' treated as white space"));
 183   }
 184   [ \f\n\t\v]  |
 185   "//".*       continue;
 186   "/*" {
 187     token_start = loc->start;
 188     context_state = YY_START;
 189     BEGIN SC_YACC_COMMENT;
 190   }
 191
 192   /* #line directives are not documented, and may be withdrawn or
 193      modified in future versions of Bison.  */
 194   ^"#line "{int}(" \"".*"\"")?"\n" {
 195     handle_syncline (yytext + sizeof "#line " - 1, *loc);
 196   }
 197 }
 198
 199
 200   /*----------------------------.
 201   | Scanning Bison directives.  |
 202   `----------------------------*/
 203
 204   /* For directives that are also command line options, the regex must be
 205         "%..."
 206      after "[-_]"s are removed, and the directive must match the --long
 207      option name, with a single string argument.  Otherwise, add exceptions
 208      to ../build-aux/cross-options.pl.  */
 209
 210 <INITIAL>
 211 {
 212   "%binary"                         return PERCENT_NONASSOC;
 213   "%code"                           return PERCENT_CODE;
 214   "%debug"                          RETURN_PERCENT_FLAG("parse.trace");
 215   "%default-prec"                   return PERCENT_DEFAULT_PREC;
 216   "%define"                         return PERCENT_DEFINE;
 217   "%defines"                        return PERCENT_DEFINES;
 218   "%destructor"                     return PERCENT_DESTRUCTOR;
 219   "%dprec"                          return PERCENT_DPREC;
 220   "%empty"                          return PERCENT_EMPTY;
 221   "%error-verbose"                  return PERCENT_ERROR_VERBOSE;
 222   "%expect"                         return PERCENT_EXPECT;
 223   "%expect-rr"                      return PERCENT_EXPECT_RR;
 224   "%file-prefix"                    return PERCENT_FILE_PREFIX;
 225   "%fixed-output-files"             return PERCENT_YACC;
 226   "%initial-action"                 return PERCENT_INITIAL_ACTION;
 227   "%glr-parser"                     return PERCENT_GLR_PARSER;
 228   "%language"                       return PERCENT_LANGUAGE;
 229   "%left"                           return PERCENT_LEFT;
 230   "%lex-param"                      RETURN_PERCENT_PARAM(lex);
 231   "%locations"                      RETURN_PERCENT_FLAG("locations");
 232   "%merge"                          return PERCENT_MERGE;
 233   "%name-prefix"                    return PERCENT_NAME_PREFIX;
 234   "%no-default-prec"                return PERCENT_NO_DEFAULT_PREC;
 235   "%no-lines"                       return PERCENT_NO_LINES;
 236   "%nonassoc"                       return PERCENT_NONASSOC;
 237   "%nondeterministic-parser"        return PERCENT_NONDETERMINISTIC_PARSER;
 238   "%nterm"                          return PERCENT_NTERM;
 239   "%output"                         return PERCENT_OUTPUT;
 240   "%param"                          RETURN_PERCENT_PARAM(both);
 241   "%parse-param"                    RETURN_PERCENT_PARAM(parse);
 242   "%prec"                           return PERCENT_PREC;
 243   "%precedence"                     return PERCENT_PRECEDENCE;
 244   "%printer"                        return PERCENT_PRINTER;
 245   "%pure-parser"                    RETURN_PERCENT_FLAG("api.pure");
 246   "%require"                        return PERCENT_REQUIRE;
 247   "%right"                          return PERCENT_RIGHT;
 248   "%skeleton"                       return PERCENT_SKELETON;
 249   "%start"                          return PERCENT_START;
 250   "%term"                           return PERCENT_TOKEN;
 251   "%token"                          return PERCENT_TOKEN;
 252   "%token-table"                    return PERCENT_TOKEN_TABLE;
 253   "%type"                           return PERCENT_TYPE;
 254   "%union"                          return PERCENT_UNION;
 255   "%verbose"                        return PERCENT_VERBOSE;
 256   "%yacc"                           return PERCENT_YACC;
 257
 258   /* deprecated */
 259   "%default"[-_]"prec"              DEPRECATED("%default-prec");
 260   "%error"[-_]"verbose"             DEPRECATED("%define parse.error verbose");
 261   "%expect"[-_]"rr"                 DEPRECATED("%expect-rr");
 262   "%file-prefix"{eqopt}             DEPRECATED("%file-prefix");
 263   "%fixed"[-_]"output"[-_]"files"   DEPRECATED("%fixed-output-files");
 264   "%name"[-_]"prefix"{eqopt}        DEPRECATED("%name-prefix");
 265   "%no"[-_]"default"[-_]"prec"      DEPRECATED("%no-default-prec");
 266   "%no"[-_]"lines"                  DEPRECATED("%no-lines");
 267   "%output"{eqopt}                  DEPRECATED("%output");
 268   "%pure"[-_]"parser"               DEPRECATED("%pure-parser");
 269   "%token"[-_]"table"               DEPRECATED("%token-table");
 270
 271   "%"{id}|"%"{notletter}([[:graph:]])+ {
 272     complain (loc, complaint, _("invalid directive: %s"), quote (yytext));
 273   }
 274
 275   "="                     return EQUAL;
 276   "|"                     return PIPE;
 277   ";"                     return SEMICOLON;
 278
 279   {id} {
 280     val->uniqstr = uniqstr_new (yytext);
 281     id_loc = *loc;
 282     bracketed_id_str = NULL;
 283     BEGIN SC_AFTER_IDENTIFIER;
 284   }
 285
 286   {int} {
 287     val->integer = scan_integer (yytext, 10, *loc);
 288     return INT;
 289   }
 290   0[xX][0-9abcdefABCDEF]+ {
 291     val->integer = scan_integer (yytext, 16, *loc);
 292     return INT;
 293   }
 294
 295   /* Identifiers may not start with a digit.  Yet, don't silently
 296      accept "1FOO" as "1 FOO".  */
 297   {int}{id} {
 298     complain (loc, complaint, _("invalid identifier: %s"), quote (yytext));
 299   }
 300
 301   /* Characters.  */
 302   "'"         token_start = loc->start; BEGIN SC_ESCAPED_CHARACTER;
 303
 304   /* Strings. */
 305   "\""        token_start = loc->start; BEGIN SC_ESCAPED_STRING;
 306
 307   /* Prologue. */
 308   "%{"        code_start = loc->start; BEGIN SC_PROLOGUE;
 309
 310   /* Code in between braces.  */
 311   "{" {
 312     STRING_GROW;
 313     nesting = 0;
 314     code_start = loc->start;
 315     BEGIN SC_BRACED_CODE;
 316   }
 317
 318   /* Semantic predicate. */
 319   "%?"[ \f\n\t\v]*"{" {
 320     nesting = 0;
 321     code_start = loc->start;
 322     BEGIN SC_PREDICATE;
 323   }
 324
 325   /* A type. */
 326   "<*>"       return TAG_ANY;
 327   "<>"        return TAG_NONE;
 328   "<"{tag}">" {
 329     obstack_grow (&obstack_for_string, yytext + 1, yyleng - 2);
 330     STRING_FINISH;
 331     val->uniqstr = uniqstr_new (last_string);
 332     STRING_FREE;
 333     return TAG;
 334   }
 335   "<"         {
 336     nesting = 0;
 337     token_start = loc->start;
 338     BEGIN SC_TAG;
 339   }
 340
 341   "%%" {
 342     static int percent_percent_count;
 343     if (++percent_percent_count == 2)
 344       BEGIN SC_EPILOGUE;
 345     return PERCENT_PERCENT;
 346   }
 347
 348   "[" {
 349     bracketed_id_str = NULL;
 350     bracketed_id_start = loc->start;
 351     bracketed_id_context_state = YY_START;
 352     BEGIN SC_BRACKETED_ID;
 353   }
 354
 355   [^\[%A-Za-z0-9_<>{}\"\'*;|=/, \f\n\t\v]+|. {
 356     complain (loc, complaint, "%s: %s",
 357               ngettext ("invalid character", "invalid characters", yyleng),
 358               quote_mem (yytext, yyleng));
 359   }
 360
 361   <<EOF>> {
 362     loc->start = loc->end = scanner_cursor;
 363     yyterminate ();
 364   }
 365 }
 366
 367
 368   /*--------------------------------------------------------------.
 369   | Supporting \0 complexifies our implementation for no expected |
 370   | added value.                                                  |
 371   `--------------------------------------------------------------*/
 372
 373 <SC_ESCAPED_CHARACTER,SC_ESCAPED_STRING,SC_TAG>
 374 {
 375   \0        complain (loc, complaint, _("invalid null character"));
 376 }
 377
 378
 379   /*-----------------------------------------------------------------.
 380   | Scanning after an identifier, checking whether a colon is next.  |
 381   `-----------------------------------------------------------------*/
 382
 383 <SC_AFTER_IDENTIFIER>
 384 {
 385   "[" {
 386     if (bracketed_id_str)
 387       {
 388         ROLLBACK_CURRENT_TOKEN;
 389         BEGIN SC_RETURN_BRACKETED_ID;
 390         *loc = id_loc;
 391         return ID;
 392       }
 393     else
 394       {
 395         bracketed_id_start = loc->start;
 396         bracketed_id_context_state = YY_START;
 397         BEGIN SC_BRACKETED_ID;
 398       }
 399   }
 400   ":" {
 401     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 402     *loc = id_loc;
 403     return ID_COLON;
 404   }
 405   . {
 406     ROLLBACK_CURRENT_TOKEN;
 407     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 408     *loc = id_loc;
 409     return ID;
 410   }
 411   <<EOF>> {
 412     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 413     *loc = id_loc;
 414     return ID;
 415   }
 416 }
 417
 418   /*--------------------------------.
 419   | Scanning bracketed identifiers. |
 420   `--------------------------------*/
 421
 422 <SC_BRACKETED_ID>
 423 {
 424   {id} {
 425     if (bracketed_id_str)
 426       {
 427         complain (loc, complaint,
 428                   _("unexpected identifier in bracketed name: %s"),
 429                   quote (yytext));
 430       }
 431     else
 432       {
 433         bracketed_id_str = uniqstr_new (yytext);
 434         bracketed_id_loc = *loc;
 435       }
 436   }
 437   "]" {
 438     BEGIN bracketed_id_context_state;
 439     if (bracketed_id_str)
 440       {
 441         if (INITIAL == bracketed_id_context_state)
 442           {
 443             val->uniqstr = bracketed_id_str;
 444             bracketed_id_str = 0;
 445             *loc = bracketed_id_loc;
 446             return BRACKETED_ID;
 447           }
 448       }
 449     else
 450       complain (loc, complaint, _("an identifier expected"));
 451   }
 452
 453   [^\].A-Za-z0-9_/ \f\n\t\v]+|. {
 454     complain (loc, complaint, "%s: %s",
 455               ngettext ("invalid character in bracketed name",
 456                         "invalid characters in bracketed name", yyleng),
 457               quote_mem (yytext, yyleng));
 458   }
 459
 460   <<EOF>> {
 461     BEGIN bracketed_id_context_state;
 462     unexpected_eof (bracketed_id_start, "]");
 463   }
 464 }
 465
 466 <SC_RETURN_BRACKETED_ID>
 467 {
 468   . {
 469     ROLLBACK_CURRENT_TOKEN;
 470     val->uniqstr = bracketed_id_str;
 471     bracketed_id_str = 0;
 472     *loc = bracketed_id_loc;
 473     BEGIN INITIAL;
 474     return BRACKETED_ID;
 475   }
 476 }
 477
 478
 479   /*---------------------------------------------------------------.
 480   | Scanning a Yacc comment.  The initial '/ *' is already eaten.  |
 481   `---------------------------------------------------------------*/
 482
 483 <SC_YACC_COMMENT>
 484 {
 485   "*/"     BEGIN context_state;
 486   .|\n     continue;
 487   <<EOF>>  unexpected_eof (token_start, "*/"); BEGIN context_state;
 488 }
 489
 490
 491   /*------------------------------------------------------------.
 492   | Scanning a C comment.  The initial '/ *' is already eaten.  |
 493   `------------------------------------------------------------*/
 494
 495 <SC_COMMENT>
 496 {
 497   "*"{splice}"/"  STRING_GROW; BEGIN context_state;
 498   <<EOF>>         unexpected_eof (token_start, "*/"); BEGIN context_state;
 499 }
 500
 501
 502   /*--------------------------------------------------------------.
 503   | Scanning a line comment.  The initial '//' is already eaten.  |
 504   `--------------------------------------------------------------*/
 505
 506 <SC_LINE_COMMENT>
 507 {
 508   "\n"           STRING_GROW; BEGIN context_state;
 509   {splice}       STRING_GROW;
 510   <<EOF>>        BEGIN context_state;
 511 }
 512
 513
 514   /*------------------------------------------------.
 515   | Scanning a Bison string, including its escapes. |
 516   | The initial quote is already eaten.             |
 517   `------------------------------------------------*/
 518
 519 <SC_ESCAPED_STRING>
 520 {
 521   "\"" {
 522     STRING_FINISH;
 523     loc->start = token_start;
 524     val->chars = last_string;
 525     BEGIN INITIAL;
 526     return STRING;
 527   }
 528   <<EOF>>   unexpected_eof (token_start, "\"");
 529   "\n"      unexpected_newline (token_start, "\"");
 530 }
 531
 532   /*----------------------------------------------------------.
 533   | Scanning a Bison character literal, decoding its escapes. |
 534   | The initial quote is already eaten.                       |
 535   `----------------------------------------------------------*/
 536
 537 <SC_ESCAPED_CHARACTER>
 538 {
 539   "'" {
 540     STRING_FINISH;
 541     loc->start = token_start;
 542     val->character = last_string[0];
 543
 544     /* FIXME: Eventually, make these errors.  */
 545     if (last_string[0] == '\0')
 546     {
 547       complain (loc, Wother, _("empty character literal"));
 548       /* '\0' seems dangerous even if we are about to complain.  */
 549       val->character = '\'';
 550     }
 551     else if (last_string[1] != '\0')
 552       complain (loc, Wother,
 553                 _("extra characters in character literal"));
 554     STRING_FREE;
 555     BEGIN INITIAL;
 556     return CHAR;
 557   }
 558   "\n"      unexpected_newline (token_start, "'");
 559   <<EOF>>   unexpected_eof (token_start, "'");
 560 }
 561
 562   /*-----------------------------------------------------------.
 563   | Scanning a Bison nested tag.  The initial angle bracket is |
 564   | already eaten.                                             |
 565   `-----------------------------------------------------------*/
 566
 567 <SC_TAG>
 568 {
 569   ">" {
 570     --nesting;
 571     if (nesting < 0)
 572       {
 573         STRING_FINISH;
 574         loc->start = token_start;
 575         val->uniqstr = uniqstr_new (last_string);
 576         STRING_FREE;
 577         BEGIN INITIAL;
 578         return TAG;
 579       }
 580     STRING_GROW;
 581   }
 582
 583   [^<>]+ STRING_GROW;
 584   "<"+   STRING_GROW; nesting += yyleng;
 585
 586   <<EOF>>   unexpected_eof (token_start, ">");
 587 }
 588
 589   /*----------------------------.
 590   | Decode escaped characters.  |
 591   `----------------------------*/
 592
 593 <SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>
 594 {
 595   \\[0-7]{1,3} {
 596     unsigned long int c = strtoul (yytext + 1, NULL, 8);
 597     if (!c || UCHAR_MAX < c)
 598       complain (loc, complaint, _("invalid number after \\-escape: %s"),
 599                    yytext+1);
 600     else
 601       obstack_1grow (&obstack_for_string, c);
 602   }
 603
 604   \\x[0-9abcdefABCDEF]+ {
 605     verify (UCHAR_MAX < ULONG_MAX);
 606     unsigned long int c = strtoul (yytext + 2, NULL, 16);
 607     if (!c || UCHAR_MAX < c)
 608       complain (loc, complaint, _("invalid number after \\-escape: %s"),
 609                    yytext+1);
 610     else
 611       obstack_1grow (&obstack_for_string, c);
 612   }
 613
 614   \\a   obstack_1grow (&obstack_for_string, '\a');
 615   \\b   obstack_1grow (&obstack_for_string, '\b');
 616   \\f   obstack_1grow (&obstack_for_string, '\f');
 617   \\n   obstack_1grow (&obstack_for_string, '\n');
 618   \\r   obstack_1grow (&obstack_for_string, '\r');
 619   \\t   obstack_1grow (&obstack_for_string, '\t');
 620   \\v   obstack_1grow (&obstack_for_string, '\v');
 621
 622   /* \\[\"\'?\\] would be shorter, but it confuses xgettext.  */
 623   \\("\""|"'"|"?"|"\\")  obstack_1grow (&obstack_for_string, yytext[1]);
 624
 625   \\(u|U[0-9abcdefABCDEF]{4})[0-9abcdefABCDEF]{4} {
 626     int c = convert_ucn_to_byte (yytext);
 627     if (c <= 0)
 628       complain (loc, complaint, _("invalid number after \\-escape: %s"),
 629                    yytext+1);
 630     else
 631       obstack_1grow (&obstack_for_string, c);
 632   }
 633   \\(.|\n)      {
 634     char const *p = yytext + 1;
 635     /* Quote only if escaping won't make the character visible.  */
 636     if (c_isspace ((unsigned char) *p) && c_isprint ((unsigned char) *p))
 637       p = quote (p);
 638     else
 639       p = quotearg_style_mem (escape_quoting_style, p, 1);
 640     complain (loc, complaint, _("invalid character after \\-escape: %s"),
 641                  p);
 642   }
 643 }
 644
 645   /*--------------------------------------------.
 646   | Scanning user-code characters and strings.  |
 647   `--------------------------------------------*/
 648
 649 <SC_CHARACTER,SC_STRING>
 650 {
 651   {splice}|\\{splice}[^\n\[\]]  STRING_GROW;
 652 }
 653
 654 <SC_CHARACTER>
 655 {
 656   "'"           STRING_GROW; BEGIN context_state;
 657   \n            unexpected_newline (token_start, "'");
 658   <<EOF>>       unexpected_eof (token_start, "'");
 659 }
 660
 661 <SC_STRING>
 662 {
 663   "\""          STRING_GROW; BEGIN context_state;
 664   \n            unexpected_newline (token_start, "\"");
 665   <<EOF>>       unexpected_eof (token_start, "\"");
 666 }
 667
 668
 669   /*---------------------------------------------------.
 670   | Strings, comments etc. can be found in user code.  |
 671   `---------------------------------------------------*/
 672
 673 <SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE,SC_PREDICATE>
 674 {
 675   "'" {
 676     STRING_GROW;
 677     context_state = YY_START;
 678     token_start = loc->start;
 679     BEGIN SC_CHARACTER;
 680   }
 681   "\"" {
 682     STRING_GROW;
 683     context_state = YY_START;
 684     token_start = loc->start;
 685     BEGIN SC_STRING;
 686   }
 687   "/"{splice}"*" {
 688     STRING_GROW;
 689     context_state = YY_START;
 690     token_start = loc->start;
 691     BEGIN SC_COMMENT;
 692   }
 693   "/"{splice}"/" {
 694     STRING_GROW;
 695     context_state = YY_START;
 696     BEGIN SC_LINE_COMMENT;
 697   }
 698 }
 699
 700
 701
 702   /*-----------------------------------------------------------.
 703   | Scanning some code in braces (actions, predicates). The    |
 704   | initial "{" is already eaten.                              |
 705   `-----------------------------------------------------------*/
 706
 707 <SC_BRACED_CODE,SC_PREDICATE>
 708 {
 709   "{"|"<"{splice}"%"  STRING_GROW; nesting++;
 710   "%"{splice}">"      STRING_GROW; nesting--;
 711
 712   /* Tokenize '<<%' correctly (as '<<' '%') rather than incorrrectly
 713      (as '<' '<%').  */
 714   "<"{splice}"<"  STRING_GROW;
 715
 716   <<EOF>>   unexpected_eof (code_start, "}");
 717 }
 718
 719 <SC_BRACED_CODE>
 720 {
 721   "}" {
 722     obstack_1grow (&obstack_for_string, '}');
 723
 724     --nesting;
 725     if (nesting < 0)
 726       {
 727         STRING_FINISH;
 728         loc->start = code_start;
 729         val->code = last_string;
 730         BEGIN INITIAL;
 731         return BRACED_CODE;
 732       }
 733   }
 734 }
 735
 736 <SC_PREDICATE>
 737 {
 738   "}" {
 739     --nesting;
 740     if (nesting < 0)
 741       {
 742         STRING_FINISH;
 743         loc->start = code_start;
 744         val->code = last_string;
 745         BEGIN INITIAL;
 746         return BRACED_PREDICATE;
 747       }
 748     else
 749       obstack_1grow (&obstack_for_string, '}');
 750   }
 751 }
 752
 753   /*--------------------------------------------------------------.
 754   | Scanning some prologue: from "%{" (already scanned) to "%}".  |
 755   `--------------------------------------------------------------*/
 756
 757 <SC_PROLOGUE>
 758 {
 759   "%}" {
 760     STRING_FINISH;
 761     loc->start = code_start;
 762     val->chars = last_string;
 763     BEGIN INITIAL;
 764     return PROLOGUE;
 765   }
 766
 767   <<EOF>>   unexpected_eof (code_start, "%}");
 768 }
 769
 770
 771   /*---------------------------------------------------------------.
 772   | Scanning the epilogue (everything after the second "%%", which |
 773   | has already been eaten).                                       |
 774   `---------------------------------------------------------------*/
 775
 776 <SC_EPILOGUE>
 777 {
 778   <<EOF>> {
 779     STRING_FINISH;
 780     loc->start = code_start;
 781     val->chars = last_string;
 782     BEGIN INITIAL;
 783     return EPILOGUE;
 784   }
 785 }
 786
 787
 788   /*-----------------------------------------------------.
 789   | By default, grow the string obstack with the input.  |
 790   `-----------------------------------------------------*/
 791
 792 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PREDICATE,SC_PROLOGUE,SC_EPILOGUE,SC_STRING,SC_CHARACTER,SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>. |
 793   <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PREDICATE,SC_PROLOGUE,SC_EPILOGUE>\n    STRING_GROW;
 794
 795 %%
 796
 797 /* Read bytes from FP into buffer BUF of size SIZE.  Return the
 798    number of bytes read.  Remove '\r' from input, treating \r\n
 799    and isolated \r as \n.  */
 800
 801 static size_t
 802 no_cr_read (FILE *fp, char *buf, size_t size)
 803 {
 804   size_t bytes_read = fread (buf, 1, size, fp);
 805   if (bytes_read)
 806     {
 807       char *w = memchr (buf, '\r', bytes_read);
 808       if (w)
 809         {
 810           char const *r = ++w;
 811           char const *lim = buf + bytes_read;
 812
 813           for (;;)
 814             {
 815               /* Found an '\r'.  Treat it like '\n', but ignore any
 816                  '\n' that immediately follows.  */
 817               w[-1] = '\n';
 818               if (r == lim)
 819                 {
 820                   int ch = getc (fp);
 821                   if (ch != '\n' && ungetc (ch, fp) != ch)
 822                     break;
 823                 }
 824               else if (*r == '\n')
 825                 r++;
 826
 827               /* Copy until the next '\r'.  */
 828               do
 829                 {
 830                   if (r == lim)
 831                     return w - buf;
 832                 }
 833               while ((*w++ = *r++) != '\r');
 834             }
 835
 836           return w - buf;
 837         }
 838     }
 839
 840   return bytes_read;
 841 }
 842
 843
 844
 845 /*------------------------------------------------------.
 846 | Scan NUMBER for a base-BASE integer at location LOC.  |
 847 `------------------------------------------------------*/
 848
 849 static unsigned long int
 850 scan_integer (char const *number, int base, location loc)
 851 {
 852   verify (INT_MAX < ULONG_MAX);
 853   unsigned long int num = strtoul (number, NULL, base);
 854
 855   if (INT_MAX < num)
 856     {
 857       complain (&loc, complaint, _("integer out of range: %s"),
 858                    quote (number));
 859       num = INT_MAX;
 860     }
 861
 862   return num;
 863 }
 864
 865
 866 /*------------------------------------------------------------------.
 867 | Convert universal character name UCN to a single-byte character,  |
 868 | and return that character.  Return -1 if UCN does not correspond  |
 869 | to a single-byte character.                                       |
 870 `------------------------------------------------------------------*/
 871
 872 static int
 873 convert_ucn_to_byte (char const *ucn)
 874 {
 875   verify (UCHAR_MAX <= INT_MAX);
 876   unsigned long int code = strtoul (ucn + 2, NULL, 16);
 877
 878   /* FIXME: Currently we assume Unicode-compatible unibyte characters
 879      on ASCII hosts (i.e., Latin-1 on hosts with 8-bit bytes).  On
 880      non-ASCII hosts we support only the portable C character set.
 881      These limitations should be removed once we add support for
 882      multibyte characters.  */
 883
 884   if (UCHAR_MAX < code)
 885     return -1;
 886
 887 #if ! ('$' == 0x24 && '@' == 0x40 && '`' == 0x60 && '~' == 0x7e)
 888   {
 889     /* A non-ASCII host.  Use CODE to index into a table of the C
 890        basic execution character set, which is guaranteed to exist on
 891        all Standard C platforms.  This table also includes '$', '@',
 892        and '`', which are not in the basic execution character set but
 893        which are unibyte characters on all the platforms that we know
 894        about.  */
 895     static signed char const table[] =
 896       {
 897         '\0',   -1,   -1,   -1,   -1,   -1,   -1, '\a',
 898         '\b', '\t', '\n', '\v', '\f', '\r',   -1,   -1,
 899           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 900           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 901          ' ',  '!',  '"',  '#',  '$',  '%',  '&', '\'',
 902          '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
 903          '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
 904          '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
 905          '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
 906          'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
 907          'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
 908          'X',  'Y',  'Z',  '[', '\\',  ']',  '^',  '_',
 909          '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
 910          'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
 911          'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
 912          'x',  'y',  'z',  '{',  '|',  '}',  '~'
 913       };
 914
 915     code = code < sizeof table ? table[code] : -1;
 916   }
 917 #endif
 918
 919   return code;
 920 }
 921
 922
 923 /*---------------------------------------------------------------------.
 924 | Handle '#line INT( "FILE")?\n'.  ARGS has already skipped '#line '.  |
 925 `---------------------------------------------------------------------*/
 926
 927 static void
 928 handle_syncline (char *args, location loc)
 929 {
 930   char *file;
 931   unsigned long int lineno = strtoul (args, &file, 10);
 932   if (INT_MAX <= lineno)
 933     {
 934       complain (&loc, Wother, _("line number overflow"));
 935       lineno = INT_MAX;
 936     }
 937
 938   file = strchr (file, '"');
 939   if (file)
 940     {
 941       *strchr (file + 1, '"') = '\0';
 942       current_file = uniqstr_new (file + 1);
 943     }
 944   boundary_set (&scanner_cursor, current_file, lineno, 1);
 945 }
 946
 947
 948 /*----------------------------------------------------------------.
 949 | For a token or comment starting at START, report message MSGID, |
 950 | which should say that an end marker was found before the        |
 951 | expected TOKEN_END. Then, pretend that TOKEN_END was found.     |
 952 `----------------------------------------------------------------*/
 953
 954 static void
 955 unexpected_end (boundary start, char const *msgid, char const *token_end)
 956 {
 957   location loc;
 958   loc.start = start;
 959   loc.end = scanner_cursor;
 960   size_t i = strlen (token_end);
 961
 962 /* Adjust scanner cursor so that any later message does not count
 963      the characters about to be inserted.  */
 964   scanner_cursor.column -= i;
 965
 966   while (i != 0)
 967     unput (token_end[--i]);
 968
 969   token_end = quote (token_end);
 970   /* Instead of '\'', display "'".  */
 971   if (STREQ (token_end, "'\\''"))
 972     token_end = "\"'\"";
 973   complain (&loc, complaint, _(msgid), token_end);
 974 }
 975
 976
 977 /*------------------------------------------------------------------------.
 978 | Report an unexpected EOF in a token or comment starting at START.       |
 979 | An end of file was encountered and the expected TOKEN_END was missing.  |
 980 | After reporting the problem, pretend that TOKEN_END was found.          |
 981 `------------------------------------------------------------------------*/
 982
 983 static void
 984 unexpected_eof (boundary start, char const *token_end)
 985 {
 986   unexpected_end (start, N_("missing %s at end of file"), token_end);
 987 }
 988
 989
 990 /*----------------------------------------.
 991 | Likewise, but for unexpected newlines.  |
 992 `----------------------------------------*/
 993
 994 static void
 995 unexpected_newline (boundary start, char const *token_end)
 996 {
 997   unexpected_end (start, N_("missing %s at end of line"), token_end);
 998 }
 999
1000
1001 /*-------------------------.
1002 | Initialize the scanner.  |
1003 `-------------------------*/
1004
1005 void
1006 gram_scanner_initialize (void)
1007 {
1008   obstack_init (&obstack_for_string);
1009 }
1010
1011
1012 /*-----------------------------------------------.
1013 | Free all the memory allocated to the scanner.  |
1014 `-----------------------------------------------*/
1015
1016 void
1017 gram_scanner_free (void)
1018 {
1019   obstack_free (&obstack_for_string, 0);
1020   /* Reclaim Flex's buffers.  */
1021   yylex_destroy ();
1022 }