configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2012])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz nostdinc
  49                  color-tests parallel-tests
  50                  silent-rules]
  51                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  52                            [gnu], [gnits]))
  53 AM_SILENT_RULES([yes])
  54 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  55
  56 # Checks for the compiler.
  57 AC_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 # Gnulib (early checks).
  61 gl_EARLY
  62
  63 AC_ARG_ENABLE([gcc-warnings],
  64 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  65 [case $enable_gcc_warnings in
  66    yes|no) ;;
  67    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  68  esac],
  69               [enable_gcc_warnings=no])
  70 if test "$enable_gcc_warnings" = yes; then
  71   warn_common='-Wall -Wextra -Wno-sign-compare -Wcast-align
  72     -Wcast-qual -Wformat -Wpointer-arith -Wwrite-strings'
  73   warn_c='-Wbad-function-cast -Wmissing-declarations -Wmissing-prototypes
  74     -Wshadow -Wstrict-prototypes'
  75   warn_cxx='-Wnoexcept -Wzero-as-null-pointer-constant'
  76   AC_LANG_PUSH([C])
  77   for i in $warn_common $warn_c;
  78   do
  79     gl_WARN_ADD([$i], [WARN_CFLAGS])
  80   done
  81   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  82   # Warnings for the test suite only.
  83   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  84   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
  85   AC_LANG_POP([C])
  86
  87   AC_LANG_PUSH([C++])
  88   for i in $warn_common $warn_cxx;
  89   do
  90     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
  91   done
  92   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
  93   # Warnings for the test suite only.
  94   gl_WARN_ADD([-Wundef], [WARN_CXXFLAGS_TEST])
  95   gl_WARN_ADD([-pedantic], [WARN_CXXFLAGS_TEST])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 BISON_TEST_FOR_WORKING_C_COMPILER
 100 BISON_TEST_FOR_WORKING_CXX_COMPILER
 101
 102 AC_ARG_ENABLE([yacc],
 103   [AC_HELP_STRING([--disable-yacc],
 104      [do not build a yacc command or an -ly library])],
 105   , [enable_yacc=yes])
 106 case $enable_yacc in
 107 yes)
 108   YACC_SCRIPT=src/yacc
 109   YACC_LIBRARY=lib/liby.a;;
 110 *)
 111   YACC_SCRIPT=
 112   YACC_LIBRARY=;;
 113 esac
 114 AC_SUBST([YACC_SCRIPT])
 115 AC_SUBST([YACC_LIBRARY])
 116
 117 # Checks for programs.
 118 AC_PROG_LEX
 119 AC_PROG_YACC
 120 AC_PROG_RANLIB
 121 AC_PROG_GNU_M4
 122 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 123 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 124 supports -g, otherwise to "".])
 125 AM_MISSING_PROG([HELP2MAN], [help2man])
 126 AC_PATH_PROG([XSLTPROC], [xsltproc])
 127 AC_SUBST([XSLTPROC])
 128
 129 # Checks for header files.
 130 AC_CHECK_HEADERS_ONCE([locale.h])
 131
 132 # Checks for compiler characteristics.
 133 AC_C_INLINE
 134
 135 # Gnulib (later checks).  Putting them here rather than right after
 136 # gl_EARLY avoids some redundant checks.
 137 gl_INIT
 138
 139 # Checks for library functions.
 140 AC_CHECK_FUNCS_ONCE([setlocale])
 141 AM_WITH_DMALLOC
 142 BISON_PREREQ_TIMEVAR
 143
 144 # Gettext.
 145 # We use gnulib, which is only guaranteed to work properly with the
 146 # latest Gettext.
 147 AM_GNU_GETTEXT([external], [need-ngettext])
 148 AM_GNU_GETTEXT_VERSION([0.18])
 149 BISON_I18N
 150
 151 # Internationalized parsers.
 152 AC_CONFIG_FILES([runtime-po/Makefile.in])
 153 # Autoconf macros for packages using internationalized parsers.
 154 aclocaldir='${datadir}/aclocal'
 155 AC_SUBST([aclocaldir])
 156
 157 # Create the benchmark script.
 158 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 159
 160 # Initialize the test suite.
 161 AC_CONFIG_TESTDIR(tests)
 162 AC_CONFIG_FILES([tests/atlocal])
 163 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 164 AC_CHECK_PROGS([VALGRIND], [valgrind])
 165 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 166 # Needed by tests/atlocal.in.
 167 AC_SUBST([GCC])
 168
 169 gt_JAVACOMP([1.3], [1.4])
 170 gt_JAVAEXEC
 171
 172 # We use gnulib, but from lib/local.mk instead of lib/Makefile.am.
 173 # So prefix paths with lib/.  See also etc/prefix-gnulib-mk.
 174 gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, , lib/,g'`
 175 # Listing the names of the variables to prefix is error-prone.
 176 # Rather, adjust all the AC_SUBST variables whose name ends in '_H',
 177 # and whose content ends in '.h'.
 178 for ac_var in $ac_subst_vars
 179 do
 180   eval "ac_val=\$$ac_var"
 181   case $ac_var=$ac_val in
 182     (*_H=*.h) eval "$ac_var=lib/\$$ac_var";;
 183   esac
 184 done
 185 AC_CONFIG_FILES([Makefile
 186                  po/Makefile.in
 187                  doc/yacc.1])
 188 AC_OUTPUT