m4/malloc.m4

   1 #serial 7
   2
   3 dnl From Jim Meyering.
   4 dnl Determine whether malloc accepts 0 as its argument.
   5 dnl If it doesn't, arrange to use the replacement function.
   6 dnl
   7
   8 AC_DEFUN([jm_FUNC_MALLOC],
   9 [
  10  dnl xmalloc.c requires that this symbol be defined so it doesn't
  11  dnl mistakenly use a broken malloc -- as it might if this test were omitted.
  12  AC_DEFINE(HAVE_DONE_WORKING_MALLOC_CHECK, 1,
  13            [Define if the malloc check has been performed. ])
  14
  15  AC_CACHE_CHECK([whether malloc(0) returns a non-NULL pointer],
  16                 jm_cv_func_working_malloc,
  17   [AC_TRY_RUN([
  18     char *malloc ();
  19     int
  20     main ()
  21     {
  22       exit (malloc (0) ? 0 : 1);
  23     }
  24           ],
  25          jm_cv_func_working_malloc=yes,
  26          jm_cv_func_working_malloc=no,
  27          dnl When crosscompiling, assume malloc(0) returns NULL.
  28          jm_cv_func_working_malloc=no)
  29   ])
  30   if test $jm_cv_func_working_malloc = yes; then
  31     AC_DEFINE([HAVE_MALLOC], 1,
  32               [Define to 1 if your system has a working `malloc' function,
  33                and to 0 otherwise.])
  34   else
  35     AC_DEFINE([HAVE_MALLOC], 0)
  36     AC_LIBOBJ(malloc)
  37     AC_DEFINE(malloc, rpl_malloc,
  38       [Define to rpl_malloc if the replacement function should be used.])
  39   fi
  40 ])