src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 %option nodefault noyywrap nounput never-interactive debug
  22 %option prefix="skel_" outfile="lex.yy.c"
  23
  24 %{
  25 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  26    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  27 #undef skel_wrap
  28 #define skel_wrap() 1
  29
  30 #define FLEX_PREFIX(Id) skel_ ## Id
  31 #include "flex-scanner.h"
  32
  33 #include <dirname.h>
  34 #include <error.h>
  35 #include <quotearg.h>
  36
  37 #include "complain.h"
  38 #include "getargs.h"
  39 #include "files.h"
  40 #include "scan-skel.h"
  41
  42 #define YY_DECL static int skel_lex (void)
  43 YY_DECL;
  44
  45 #define QPUTS(String) \
  46    fputs (quotearg_style (c_quoting_style, String), yyout)
  47
  48 static void at_directive_perform (int at_directive_argc,
  49                                   char *at_directive_argv[],
  50                                   char **outnamep, int *out_linenop);
  51 static void fail_for_at_directive_too_many_args (char const *at_directive_name);
  52 static void fail_for_at_directive_too_few_args (char const *at_directive_name);
  53 static void fail_for_invalid_at (char const *at);
  54 %}
  55
  56 %x SC_AT_DIRECTIVE_ARGS
  57 %x SC_AT_DIRECTIVE_SKIP_WS
  58
  59 %%
  60
  61 %{
  62   int out_lineno IF_LINT (= 0);
  63   char *outname = NULL;
  64
  65   /* Currently, only the @warn, @complain, @fatal, @warn_at, @complain_at, and
  66      @fatal_at directives take multiple arguments, and the last three already
  67      can't take more than 7.  at_directive_argv[0] is the directive name.  */
  68   #define AT_DIRECTIVE_ARGC_MAX 8
  69   int at_directive_argc = 0;
  70   char *at_directive_argv[AT_DIRECTIVE_ARGC_MAX];
  71 %}
  72
  73 "@@"       fputc ('@', yyout);
  74 "@{"       fputc ('[', yyout);
  75 "@}"       fputc (']', yyout);
  76
  77 "@oline@"  fprintf (yyout, "%d", out_lineno + 1);
  78 "@ofile@"  QPUTS (outname);
  79 "@dir_prefix@" QPUTS (dir_prefix);
  80
  81 @[a-z_]+"(" {
  82   yytext[yyleng-1] = '\0';
  83   obstack_grow (&obstack_for_string, yytext, yyleng);
  84   at_directive_argv[at_directive_argc++] =
  85     obstack_finish (&obstack_for_string);
  86   BEGIN SC_AT_DIRECTIVE_ARGS;
  87 }
  88
  89   /* This pattern must not match more than the previous @ patterns. */
  90 @[^@{}(\n]* fail_for_invalid_at (yytext);
  91 \n         out_lineno++; ECHO;
  92 [^@\n]+    ECHO;
  93
  94 <INITIAL><<EOF>> {
  95   if (outname)
  96     {
  97       free (outname);
  98       xfclose (yyout);
  99     }
 100   return EOF;
 101 }
 102
 103 <SC_AT_DIRECTIVE_ARGS>{
 104   [^@]+ { STRING_GROW; }
 105
 106   "@@" { obstack_1grow (&obstack_for_string, '@'); }
 107   "@{" { obstack_1grow (&obstack_for_string, '['); }
 108   "@}" { obstack_1grow (&obstack_for_string, ']'); }
 109   "@`" /* Emtpy.  Useful for starting an argument
 110           that begins with whitespace. */
 111
 112   @[,)] {
 113     if (at_directive_argc >= AT_DIRECTIVE_ARGC_MAX)
 114       fail_for_at_directive_too_many_args (at_directive_argv[0]);
 115
 116     obstack_1grow (&obstack_for_string, '\0');
 117     at_directive_argv[at_directive_argc++] =
 118       obstack_finish (&obstack_for_string);
 119
 120     /* Like M4, skip whitespace after a comma.  */
 121     if (yytext[1] == ',')
 122       BEGIN SC_AT_DIRECTIVE_SKIP_WS;
 123     else
 124       {
 125         at_directive_perform (at_directive_argc, at_directive_argv,
 126                               &outname, &out_lineno);
 127         obstack_free (&obstack_for_string, at_directive_argv[0]);
 128         at_directive_argc = 0;
 129         BEGIN INITIAL;
 130       }
 131   }
 132
 133   @.? { fail_for_invalid_at (yytext); }
 134 }
 135
 136 <SC_AT_DIRECTIVE_SKIP_WS>{
 137   [ \t\r\n]
 138   . { yyless (0); BEGIN SC_AT_DIRECTIVE_ARGS; }
 139 }
 140
 141 <SC_AT_DIRECTIVE_ARGS,SC_AT_DIRECTIVE_SKIP_WS>{
 142   <<EOF>> {
 143     fatal (_("unclosed %s directive in skeleton"), at_directive_argv[0]);
 144   }
 145 }
 146
 147 %%
 148
 149 /*------------------------.
 150 | Scan a Bison skeleton.  |
 151 `------------------------*/
 152
 153 void
 154 scan_skel (FILE *in)
 155 {
 156   static bool initialized = false;
 157   if (!initialized)
 158     {
 159       initialized = true;
 160       obstack_init (&obstack_for_string);
 161     }
 162   skel_in = in;
 163   skel__flex_debug = trace_flag & trace_skeleton;
 164   skel_lex ();
 165 }
 166
 167 void
 168 skel_scanner_free (void)
 169 {
 170   obstack_free (&obstack_for_string, 0);
 171   /* Reclaim Flex's buffers.  */
 172   yylex_destroy ();
 173 }
 174
 175 static
 176 void at_directive_perform (int at_directive_argc,
 177                            char *at_directive_argv[],
 178                            char **outnamep, int *out_linenop)
 179 {
 180   if (0 == strcmp (at_directive_argv[0], "@basename"))
 181     {
 182       if (at_directive_argc > 2)
 183         fail_for_at_directive_too_many_args (at_directive_argv[0]);
 184       fputs (last_component (at_directive_argv[1]), yyout);
 185     }
 186   else if (0 == strcmp (at_directive_argv[0], "@warn")
 187            || 0 == strcmp (at_directive_argv[0], "@complain")
 188            || 0 == strcmp (at_directive_argv[0], "@fatal"))
 189     {
 190       void (*func)(char const *, ...);
 191       switch (at_directive_argv[0][1])
 192         {
 193           case 'w': func = warn; break;
 194           case 'c': func = complain; break;
 195           case 'f': func = fatal; break;
 196           default: aver (false); break;
 197         }
 198       switch (at_directive_argc)
 199         {
 200           case 2:
 201             func (_(at_directive_argv[1]));
 202             break;
 203           case 3:
 204             func (_(at_directive_argv[1]), at_directive_argv[2]);
 205             break;
 206           case 4:
 207             func (_(at_directive_argv[1]), at_directive_argv[2],
 208                   at_directive_argv[3]);
 209             break;
 210           case 5:
 211             func (_(at_directive_argv[1]), at_directive_argv[2],
 212                   at_directive_argv[3], at_directive_argv[4]);
 213             break;
 214           case 6:
 215             func (_(at_directive_argv[1]), at_directive_argv[2],
 216                   at_directive_argv[3], at_directive_argv[4],
 217                   at_directive_argv[5]);
 218             break;
 219           default:
 220             fail_for_at_directive_too_many_args (at_directive_argv[0]);
 221             break;
 222         }
 223     }
 224   else if (0 == strcmp (at_directive_argv[0], "@warn_at")
 225            || 0 == strcmp (at_directive_argv[0], "@complain_at")
 226            || 0 == strcmp (at_directive_argv[0], "@fatal_at"))
 227     {
 228       void (*func)(location, char const *, ...);
 229       location loc;
 230       if (at_directive_argc < 4)
 231         fail_for_at_directive_too_few_args (at_directive_argv[0]);
 232       switch (at_directive_argv[0][1])
 233         {
 234           case 'w': func = warn_at; break;
 235           case 'c': func = complain_at; break;
 236           case 'f': func = fatal_at; break;
 237           default: aver (false); break;
 238         }
 239       boundary_set_from_string (&loc.start, at_directive_argv[1]);
 240       boundary_set_from_string (&loc.end, at_directive_argv[2]);
 241       switch (at_directive_argc)
 242         {
 243           case 4:
 244             func (loc, _(at_directive_argv[3]));
 245             break;
 246           case 5:
 247             func (loc, _(at_directive_argv[3]), at_directive_argv[4]);
 248             break;
 249           case 6:
 250             func (loc, _(at_directive_argv[3]), at_directive_argv[4],
 251                   at_directive_argv[5]);
 252             break;
 253           case 7:
 254             func (loc, _(at_directive_argv[3]), at_directive_argv[4],
 255                   at_directive_argv[5], at_directive_argv[6]);
 256             break;
 257           case 8:
 258             func (loc, _(at_directive_argv[3]), at_directive_argv[4],
 259                   at_directive_argv[5], at_directive_argv[6],
 260                   at_directive_argv[7]);
 261             break;
 262           default:
 263             fail_for_at_directive_too_many_args (at_directive_argv[0]);
 264             break;
 265         }
 266     }
 267   else if (0 == strcmp (at_directive_argv[0], "@output"))
 268     {
 269       if (at_directive_argc > 2)
 270         fail_for_at_directive_too_many_args (at_directive_argv[0]);
 271       if (*outnamep)
 272         {
 273           free (*outnamep);
 274           xfclose (yyout);
 275         }
 276       *outnamep = xstrdup (at_directive_argv[1]);
 277       output_file_name_check (*outnamep);
 278       yyout = xfopen (*outnamep, "w");
 279       *out_linenop = 1;
 280     }
 281   else
 282     fail_for_invalid_at (at_directive_argv[0]);
 283 }
 284
 285 static void
 286 fail_for_at_directive_too_few_args (char const *at_directive_name)
 287 {
 288   fatal (_("too few arguments for %s directive in skeleton"),
 289          at_directive_name);
 290 }
 291
 292 static void
 293 fail_for_at_directive_too_many_args (char const *at_directive_name)
 294 {
 295   fatal (_("too many arguments for %s directive in skeleton"),
 296          at_directive_name);
 297 }
 298
 299 static void
 300 fail_for_invalid_at (char const *at)
 301 {
 302   fatal ("invalid @ in skeleton: %s", at);
 303 }