djgpp/config.sed

   1 # DJGPP specific configuration file.
   2 # Sed script for additional DJGPP specific editing
   3 # of the configure script generated by autoconf 2.61.
   4
   5
   6 # Copyright (C) 2005, 2006 Free Software Foundation, Inc.
   7
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 # Additional editing of Makefiles
  23 /^".*ac_file_inputs.*tmp\/out$/ a\
  24 cat > "$tmp/subs-djgpp.sed" << eof_djgpp\
  25 # DJGPP specific Makefile changes.\
  26 s,\\.deps,_deps,g\
  27 s,\\.libs,_libs,g\
  28 s,\\.new\\.,_new.,g\
  29 s,\\.old\\.,_old.,g\
  30 s,\\.tab\\.,_tab.,g\
  31 s,c++\\.at,cxx.at,g\
  32 s,c++\\.m4,cxx.m4,g\
  33 s,c++-skel\\.m4,cxx-skel.m4,g\
  34 s,calc++,calcxx,g\
  35 s,scan-gram-c,c-scan-gram,g\
  36 s,scan-skel-c,c-scan-skel,g\
  37 s,inttypes_,_inttypes,g\
  38 s,Makefile\\.am\\.in,Makefile.am-in,g\
  39 s,Makefile\\.in\\.in,Makefile.in-in,g\
  40 /^\\.y\\.c:/,/^$/ {\
  41   /\\\$(YACCCOMPILE)/ {\
  42     a\\\\\
  43         -@test -f y.tab.c && mv -f y.tab.c y_tab.c\\\\\
  44         -@test -f y.tab.h && mv -f y.tab.h y_tab.h\
  45   }\
  46 }\
  47 /^libbison.a:/ i\\\\\
  48 \\$(top_srcdir)/djgpp/subpipe.c: \\$(top_srcdir)/djgpp/subpipe.h\\\\\
  49 subpipe.o: \\$(top_srcdir)/djgpp/subpipe.c \\$(top_srcdir)/djgpp/subpipe.h\\\\\
  50         \\$(COMPILE) -c \\$<\
  51 /^yacc:/ i\\\\\
  52 yacc.bat:\\\\\
  53         echo "bison\\$(EXEEXT) -y %1 %2 %3 %4 %5 %6 %7 %8 %9" >\\$@\
  54 /^bin_SCRIPTS =/s/$/ yacc.bat/\
  55 /^MOSTLYCLEANFILES = yacc/s/$/ yacc.bat/\
  56 eof_djgpp\
  57 sed -f "\$tmp/subs-djgpp.sed" \$tmp/out > \$tmp/out.djgpp\
  58 mv -f \$tmp/out.djgpp \$tmp/out
  59
  60
  61 # Makefile.in.in is renamed to Makefile.in-in.
  62 /ac_config_files=/ {
  63   /runtime-po/!s|po/Makefile\.in|&:po/Makefile.in-in|
  64   s|runtime-po/Makefile\.in|&:runtime-po/Makefile.in-in|
  65 }
  66
  67 /CONFIG_FILES=/ {
  68   /runtime-po/!s|po/Makefile\.in|&:po/Makefile.in-in|2
  69   s|runtime-po/Makefile\.in|&:runtime-po/Makefile.in-in|2
  70 }
  71
  72 # We always use _deps and _libs instead of .deps and .libs, because
  73 # the latter is an invalid name on 8+3 MS-DOS file system.  This makes
  74 # the generated Makefiles good for every DJGPP installation, not only
  75 # the one where the package was configured (which could happen to be
  76 # a Windows box, where leading dots in file names are allowed).
  77 /^rmdir[         ]*\.tst/ i\
  78 am__leading_dot=_
  79
  80 # Replace (command) > /dev/null with `command > /dev/null`, since
  81 # parenthesized commands always return zero status in the ported Bash,
  82 # even if the named command doesn't exist
  83 /if ([^|;`]*null/{
  84   s,(,`,
  85   s,),,
  86   /null[         ]*2>&1/ s,2>&1,&`,
  87   /null.*null/ s,null.*null,&`,
  88   /null.*null/ !{
  89     /null[       ]*2>&1/ !s,null,&`,
  90   }
  91 }
  92
  93 # DOS-style absolute file names should be supported as well
  94 /\*) top_srcdir=/s,/\*,[\\\\/]* | ?:[\\\\/]*,
  95
  96 # The following two items are changes needed for configuring
  97 # and compiling across partitions.
  98 # 1) The given srcdir value is always translated from the
  99 #    "x:" syntax into "/dev/x" syntax while we run configure.
 100 /^[      ]*-srcdir=\*.*$/ a\
 101     ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
 102 /set X `ls -Lt \$srcdir/ i\
 103    if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
 104      srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
 105    fi
 106
 107 # Autoconf 2.52e generated configure scripts
 108 # write absolute paths into Makefiles and bison.in
 109 # making them useless for DJGPP installations for
 110 # which the package has not been configured for.
 111 /MISSING=/,/^$/ {
 112   /^fi$/ a\
 113 am_missing_run=`echo "$am_missing_run" | sed 's%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%'`
 114 }
 115 /^install_sh=/a\
 116 install_sh=`echo "$install_sh" | sed 's%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%'`
 117
 118 # This will only work if the assumption that the
 119 # testsuite is ran from the following path:
 120 #   ${top_srcdir}/tests/testsuite.dir
 121 # holds. The explicit names are of no importance.
 122 #   ../../. == ${top_srcdir}
 123 #/^esac$/,/^ac_abs_srcdir=/ {
 124 /^ac_abs_srcdir=/ i\
 125 ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`\
 126 ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%"`\
 127 ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%"`
 128 #ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`
 129 /^ac_abs_srcdir=/ a\
 130 for dj_dir in $ac_abs_builddir $ac_abs_top_builddir $ac_abs_top_srcdir $ac_abs_srcdir\
 131 do\
 132   ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%//%/%g"`\
 133   ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%//%/%g"`\
 134   ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%//%/%g"`\
 135   ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%//%/%g"`\
 136 done
 137
 138 # Add DJGPP version information.
 139 /^#define VERSION/ s/\$VERSION/&  (DJGPP port (r1))/
 140
 141 # We need makeinfo to make the html formated docs.
 142 /\$am_missing_run[       ]*makeinfo/ s,\$am_missing_run,,
 143
 144 # The path to the FORTRAN compiler and libraries
 145 # shall contain no absolute path reference so it
 146 # will be good for all djgpp installations.
 147 /^FLIBS="\$ac_cv_flibs"/ i\
 148 ac_djgpp_path=`echo "$DJDIR" | sed 's%\\\\\\%/%g' | tr $as_cr_LETTERS $as_cr_letters`\
 149 ac_cv_flibs=`echo "$ac_cv_flibs" | sed "s%-L$ac_djgpp_path%-L/dev/env/DJDIR%g"`
 150
 151 # Autoconf generated configure scripts write absolute
 152 # paths of certain header files into Makefiles making
 153 # them useless for DJGPP installations for which the
 154 # package has not been configured for.
 155 /^.*echo "\$as_me:\$LINENO: result: \$gl_cv_absolute_.*$/ {
 156 h
 157 s,^.*\(gl_cv_absolute_\)\([a-z0-9_]*\)\(_h\).*$,\1\2\3=`echo $\1\2\3 | sed "s%[^:]:.*/include/%/dev/env/DJDIR/include/%"`,
 158 G
 159 }
 160 /^.*echo "\$as_me:\$LINENO: result: \$gl_cv_full_.*$/ {
 161 h
 162 s,^.*\(gl_cv_full_\)\([a-z0-9_]*\)\(_h\).*$,\1\2\3=`echo $\1\2\3 | sed "s%[^:]:.*/include/%/dev/env/DJDIR/include/%"`,
 163 G
 164 }
 165
 166 # The following is not a valid DOS file name
 167 s/calc++/calcxx/g