configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007 Free Software
   4 # Foundation, Inc.
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We have strange test case titles, so we need Autoconf 2.61 or better.
  20 AC_PREREQ(2.61)
  21
  22 AC_INIT([GNU Bison], [2.3a+], [bug-bison@gnu.org])
  23 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2007],
  24           [The copyright year for this package])
  25 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2007])
  26
  27 AC_CONFIG_AUX_DIR([build-aux])
  28 AC_CONFIG_MACRO_DIR([m4])
  29
  30 # We don't have a file m4/Makefile.am, so we need Automake 1.8 or later.
  31 AM_INIT_AUTOMAKE([1.8 check-news readme-alpha dist-bzip2])
  32 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  33
  34 # Checks for the compiler.
  35 AC_PROG_CC_STDC
  36
  37 # Gnulib (early checks).
  38 gl_EARLY
  39
  40 AC_ARG_ENABLE(gcc-warnings,
  41 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  42 [case "${enableval}" in
  43    yes|no) ;;
  44    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  45  esac],
  46               [enableval=no])
  47 if test "${enableval}" = yes; then
  48   gl_WARNING_CFLAGS([-Werror])
  49   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  50   WARNING_CFLAGS=
  51   gl_WARNING_CFLAGS([-Wall])
  52   gl_WARNING_CFLAGS([-Wextra -Wno-sign-compare])
  53   gl_WARNING_CFLAGS([-Wcast-align])
  54   gl_WARNING_CFLAGS([-Wcast-qual])
  55   gl_WARNING_CFLAGS([-Wformat])
  56   gl_WARNING_CFLAGS([-Wpointer-arith])
  57   gl_WARNING_CFLAGS([-Wwrite-strings])
  58   AC_SUBST([WARNING_CXXFLAGS], [$WARNING_CFLAGS])
  59   # The following warnings are not suitable for C++.
  60   gl_WARNING_CFLAGS([-Wbad-function-cast])
  61   gl_WARNING_CFLAGS([-Wmissing-declarations])
  62   gl_WARNING_CFLAGS([-Wmissing-prototypes])
  63   gl_WARNING_CFLAGS([-Wshadow])
  64   gl_WARNING_CFLAGS([-Wstrict-prototypes])
  65   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  66 fi
  67
  68 BISON_TEST_FOR_WORKING_C_COMPILER
  69
  70 AC_ARG_ENABLE([yacc],
  71   [AC_HELP_STRING([--disable-yacc],
  72      [do not build a yacc command or an -ly library])],
  73   , [enable_yacc=yes])
  74 case $enable_yacc in
  75 yes)
  76   YACC_SCRIPT=yacc
  77   YACC_LIBRARY=liby.a;;
  78 *)
  79   YACC_SCRIPT=
  80   YACC_LIBRARY=;;
  81 esac
  82 AC_SUBST([YACC_SCRIPT])
  83 AC_SUBST([YACC_LIBRARY])
  84
  85 # Checks for programs.
  86 AC_PROG_LEX
  87 AC_PROG_YACC
  88 AC_PROG_RANLIB
  89 BISON_PROG_GNU_M4
  90 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  91   AC_MSG_ERROR([GNU M4 1.4 is required])
  92 fi
  93 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  94 AM_MISSING_PROG([HELP2MAN], [help2man])
  95
  96 # Checks for header files.
  97 AC_CHECK_HEADERS_ONCE([locale.h])
  98
  99 # Checks for compiler characteristics.
 100 AC_C_INLINE
 101
 102 # Gnulib (later checks).  Putting them here rather than right after
 103 # gl_EARLY avoids some redundant checks.
 104 gl_INIT
 105
 106 # Checks for library functions.
 107 AC_CHECK_FUNCS_ONCE([setlocale])
 108 AM_WITH_DMALLOC
 109 BISON_PREREQ_SUBPIPE
 110 BISON_PREREQ_TIMEVAR
 111
 112 # Gettext.
 113 # We've never tested with gettext versions before 0.15, so play it safe.
 114 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 115 AM_GNU_GETTEXT_VERSION([0.15])
 116 BISON_I18N
 117
 118 # Internationalized parsers.
 119 AC_CONFIG_FILES([runtime-po/Makefile.in])
 120 # Autoconf macros for packages using internationalized parsers.
 121 aclocaldir='${datadir}/aclocal'
 122 AC_SUBST([aclocaldir])
 123
 124 # Create the benchmark script.
 125 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 126
 127 # Initialize the test suite.
 128 AC_CONFIG_TESTDIR(tests)
 129 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 130 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 131 AC_CHECK_PROGS([VALGRIND], [valgrind])
 132 AC_PROG_CXX
 133 BISON_TEST_FOR_WORKING_CXX_COMPILER
 134 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 135 # Needed by tests/atlocal.in.
 136 AC_SUBST([GCC])
 137 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 138 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 139
 140 gt_JAVACOMP([1.3])
 141 gt_JAVAEXEC
 142
 143 AC_CONFIG_FILES([Makefile
 144                  build-aux/Makefile
 145                  po/Makefile.in
 146                  data/Makefile
 147                  etc/Makefile
 148                  examples/Makefile
 149                     examples/calc++/Makefile
 150                  lib/Makefile src/Makefile
 151                  doc/Makefile
 152                    doc/yacc.1])
 153 AC_OUTPUT