configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2013 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2013])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz nostdinc
  49                  color-tests parallel-tests
  50                  silent-rules]
  51                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  52                            [gnu], [gnits]))
  53 AM_SILENT_RULES([yes])
  54 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  55
  56 # Checks for the compiler.
  57 AC_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 # Gnulib (early checks).
  61 gl_EARLY
  62
  63 # Gnulib uses '#pragma GCC diagnostic push' to silence some
  64 # warnings, but older gcc doesn't support this.
  65 AC_CACHE_CHECK([whether pragma GCC diagnostic push works],
  66   [lv_cv_gcc_pragma_push_works], [
  67   save_CFLAGS=$CFLAGS
  68   CFLAGS='-Wunknown-pragmas -Werror'
  69   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  70     #pragma GCC diagnostic push
  71     #pragma GCC diagnostic pop
  72   ]])],
  73   [lv_cv_gcc_pragma_push_works=yes],
  74   [lv_cv_gcc_pragma_push_works=no])
  75   CFLAGS=$save_CFLAGS])
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  79 [case $enable_gcc_warnings in
  80    yes|no) ;;
  81    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  82  esac],
  83               [enable_gcc_warnings=no])
  84 if test "$enable_gcc_warnings" = yes; then
  85   warn_common='-Wall -Wextra -Wno-sign-compare -Wcast-align
  86     -Wformat -Wpointer-arith -Wwrite-strings'
  87   warn_c='-Wbad-function-cast -Wshadow -Wstrict-prototypes'
  88   warn_cxx='-Wnoexcept'
  89
  90   AC_LANG_PUSH([C])
  91   # Clang supports many of GCC's -W options, but only issues warnings
  92   # on the ones it does not recognize.  In that case, gl_WARN_ADD
  93   # thinks the option is supported, and unknown options are then added
  94   # to CFLAGS.  But then, when -Werror is added in the test suite for
  95   # instance, the warning about the unknown option turns into an
  96   # error.
  97   #
  98   # This should be addressed by gnulib's gl_WARN_ADD, but in the
  99   # meanwhile, turn warnings about unknown options into errors in
 100   # CFLAGS, and restore CFLAGS after the tests.
 101   save_CFLAGS=$CFLAGS
 102   gl_WARN_ADD([-Werror=unknown-warning-option], [CFLAGS])
 103   for i in $warn_common $warn_c;
 104   do
 105     gl_WARN_ADD([$i], [WARN_CFLAGS])
 106   done
 107   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 108
 109   # Warnings for the test suite, and maybe for bison if GCC is modern
 110   # enough.
 111   gl_WARN_ADD([-Wmissing-declarations], [WARN_CFLAGS_TEST])
 112   gl_WARN_ADD([-Wmissing-prototypes], [WARN_CFLAGS_TEST])
 113   test $lv_cv_gcc_pragma_push_works = yes &&
 114     AS_VAR_APPEND([WARN_CFLAGS], [" $WARN_CFLAGS_TEST"])
 115
 116   # Warnings for the test suite only.
 117   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
 118   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
 119   CFLAGS=$save_CFLAGS
 120   AC_LANG_POP([C])
 121
 122
 123   AC_LANG_PUSH([C++])
 124   save_CXXFLAGS=$CXXFLAGS
 125   gl_WARN_ADD([-Werror=unknown-warning-option], [CXXFLAGS])
 126   for i in $warn_common $warn_cxx;
 127   do
 128     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
 129   done
 130   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
 131               [AC_LANG_PROGRAM([], [nullptr])])
 132   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
 133   # Warnings for the test suite only.
 134   gl_WARN_ADD([-Wundef], [WARN_CXXFLAGS_TEST])
 135   gl_WARN_ADD([-pedantic], [WARN_CXXFLAGS_TEST])
 136   # Variants break strict aliasing analysis.
 137   gl_WARN_ADD([-fno-strict-aliasing], [NO_STRICT_ALIAS_CXXFLAGS])
 138   CXXFLAGS=$save_CXXFLAGS
 139   AC_LANG_POP([C++])
 140 fi
 141
 142 BISON_TEST_FOR_WORKING_C_COMPILER
 143 BISON_C_COMPILER_POSIXLY_CORRECT
 144 BISON_TEST_FOR_WORKING_CXX_COMPILER
 145 BISON_CXX_COMPILER_POSIXLY_CORRECT
 146
 147 AC_ARG_ENABLE([yacc],
 148   [AC_HELP_STRING([--disable-yacc],
 149      [do not build a yacc command or an -ly library])],
 150   , [enable_yacc=yes])
 151 case $enable_yacc in
 152 yes)
 153   YACC_SCRIPT=src/yacc
 154   YACC_LIBRARY=lib/liby.a;;
 155 *)
 156   YACC_SCRIPT=
 157   YACC_LIBRARY=;;
 158 esac
 159 AC_SUBST([YACC_SCRIPT])
 160 AC_SUBST([YACC_LIBRARY])
 161
 162 # Checks for programs.
 163 AM_MISSING_PROG([DOT], [dot])
 164 AC_PROG_LEX
 165 $LEX_IS_FLEX || AC_MSG_ERROR([Flex is required])
 166 AC_PROG_YACC
 167 AC_PROG_RANLIB
 168 AC_PROG_GNU_M4
 169 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 170 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 171 supports -g, otherwise to "".])
 172 AC_PATH_PROG([PERL], [perl])
 173 if test -z "$PERL"; then
 174    AC_MSG_ERROR([perl not found])
 175 fi
 176 AM_MISSING_PROG([HELP2MAN], [help2man])
 177 AC_PATH_PROG([XSLTPROC], [xsltproc])
 178 AC_SUBST([XSLTPROC])
 179
 180 # Checks for header files.
 181 AC_CHECK_HEADERS_ONCE([locale.h])
 182
 183 # Checks for compiler characteristics.
 184 AC_C_INLINE
 185
 186 # Gnulib (later checks).  Putting them here rather than right after
 187 # gl_EARLY avoids some redundant checks.
 188 gl_INIT
 189
 190 # Checks for library functions.
 191 AC_CHECK_FUNCS_ONCE([setlocale])
 192 AM_WITH_DMALLOC
 193 BISON_PREREQ_TIMEVAR
 194
 195 # Gettext.
 196 # We use gnulib, which is only guaranteed to work properly with the
 197 # latest Gettext.
 198 AM_GNU_GETTEXT([external], [need-ngettext])
 199 AM_GNU_GETTEXT_VERSION([0.18])
 200 BISON_I18N
 201
 202 # Internationalized parsers.
 203 AC_CONFIG_FILES([runtime-po/Makefile.in])
 204 # Autoconf macros for packages using internationalized parsers.
 205 aclocaldir='${datadir}/aclocal'
 206 AC_SUBST([aclocaldir])
 207
 208 # Create the benchmark script.
 209 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 210
 211 # Initialize the test suite.
 212 AC_CONFIG_TESTDIR(tests)
 213 AC_CONFIG_FILES([tests/atlocal])
 214 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 215 AC_CHECK_PROGS([VALGRIND], [valgrind])
 216 case $VALGRIND:$host_os in
 217   '':*) ;;
 218   *:darwin*)
 219     # See README-hacking.
 220     # VALGRIND+=' --suppressions=$(abs_top_srcdir)/build-aux/darwin11.4.0.valgrind'
 221     VALGRIND=;;
 222   *:*)
 223     AC_SUBST([VALGRIND_PREBISON], ["$VALGRIND -q"]);;
 224 esac
 225
 226 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 227 # Needed by tests/atlocal.in.
 228 AC_SUBST([GCC])
 229
 230 gt_JAVACOMP([1.3], [1.4])
 231 gt_JAVAEXEC
 232
 233 AC_CONFIG_FILES([Makefile
 234                  po/Makefile.in
 235                  doc/yacc.1])
 236 AC_OUTPUT