data/c.m4

   1                                                             -*- Autoconf -*-
   2
   3 # C M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_include(b4_pkgdatadir/[c-like.m4])
  21
  22 # b4_tocpp(STRING)
  23 # ----------------
  24 # Convert STRING into a valid C macro name.
  25 m4_define([b4_tocpp],
  26 [m4_toupper(m4_bpatsubst(m4_quote($1), [[^a-zA-Z0-9]+], [_]))])
  27
  28
  29 # b4_cpp_guard(FILE)
  30 # ------------------
  31 # A valid C macro name to use as a CPP header guard for FILE.
  32 m4_define([b4_cpp_guard],
  33 [[YY_]b4_tocpp(m4_defn([b4_prefix])/[$1])[_INCLUDED]])
  34
  35
  36 # b4_cpp_guard_open(FILE)
  37 # b4_cpp_guard_close(FILE)
  38 # ------------------------
  39 # If FILE does not expand to nothing, open/close CPP inclusion guards for FILE.
  40 m4_define([b4_cpp_guard_open],
  41 [m4_ifval(m4_quote($1),
  42 [#ifndef b4_cpp_guard([$1])
  43 # define b4_cpp_guard([$1])])])
  44
  45 m4_define([b4_cpp_guard_close],
  46 [m4_ifval(m4_quote($1),
  47 [#endif b4_comment([!b4_cpp_guard([$1])])])])
  48
  49
  50 ## ---------------- ##
  51 ## Identification.  ##
  52 ## ---------------- ##
  53
  54 # b4_comment_(TEXT, OPEN, CONTINUE, END)
  55 # --------------------------------------
  56 # Put TEXT in comment.  Avoid trailing spaces: don't indent empty lines.
  57 # Avoid adding indentation to the first line, as the indentation comes
  58 # from OPEN.  That's why we don't patsubst([$1], [^\(.\)], [   \1]).
  59 #
  60 # Prefix all the output lines with PREFIX.
  61 m4_define([b4_comment_],
  62 [$2[]m4_bpatsubst(m4_expand([$1]), [
  63 \(.\)], [
  64 $3\1])$4])
  65
  66
  67 # b4_comment(TEXT, [PREFIX])
  68 # --------------------------
  69 # Put TEXT in comment.  Prefix all the output lines with PREFIX.
  70 m4_define([b4_comment],
  71 [b4_comment_([$1], [$2/* ], [$2   ], [  */])])
  72
  73
  74 # b4_identification
  75 # -----------------
  76 # Depends on individual skeletons to define b4_pure_flag, b4_push_flag, or
  77 # b4_pull_flag if they use the values of the %define variables api.pure or
  78 # api.push-pull.
  79 m4_define([b4_identification],
  80 [[/* Identify Bison output.  */
  81 #define YYBISON 1
  82
  83 /* Bison version.  */
  84 #define YYBISON_VERSION "]b4_version["
  85
  86 /* Skeleton name.  */
  87 #define YYSKELETON_NAME ]b4_skeleton[]m4_ifdef([b4_pure_flag], [[
  88
  89 /* Pure parsers.  */
  90 #define YYPURE ]b4_pure_flag])[]m4_ifdef([b4_push_flag], [[
  91
  92 /* Push parsers.  */
  93 #define YYPUSH ]b4_push_flag])[]m4_ifdef([b4_pull_flag], [[
  94
  95 /* Pull parsers.  */
  96 #define YYPULL ]b4_pull_flag])[
  97 ]])
  98
  99
 100 ## ---------------- ##
 101 ## Default values.  ##
 102 ## ---------------- ##
 103
 104 # b4_api_prefix, b4_api_PREFIX
 105 # ----------------------------
 106 # Corresponds to %define api.prefix
 107 b4_percent_define_default([[api.prefix]], [[yy]])
 108 m4_define([b4_api_prefix],
 109 [b4_percent_define_get([[api.prefix]])])
 110 m4_define([b4_api_PREFIX],
 111 [m4_toupper(b4_api_prefix)])
 112
 113
 114 # b4_prefix
 115 # ---------
 116 # If the %name-prefix is not given, it is api.prefix.
 117 m4_define_default([b4_prefix], [b4_api_prefix])
 118
 119 # If the %union is not named, its name is YYSTYPE.
 120 m4_define_default([b4_union_name], [b4_api_PREFIX[]STYPE])
 121
 122
 123 ## ------------------------ ##
 124 ## Pure/impure interfaces.  ##
 125 ## ------------------------ ##
 126
 127 # b4_user_args
 128 # ------------
 129 m4_define([b4_user_args],
 130 [m4_ifset([b4_parse_param], [, b4_args(b4_parse_param)])])
 131
 132
 133 # b4_parse_param
 134 # --------------
 135 # If defined, b4_parse_param arrives double quoted, but below we prefer
 136 # it to be single quoted.
 137 m4_define([b4_parse_param],
 138 b4_parse_param)
 139
 140
 141 # b4_parse_param_for(DECL, FORMAL, BODY)
 142 # ---------------------------------------
 143 # Iterate over the user parameters, binding the declaration to DECL,
 144 # the formal name to FORMAL, and evaluating the BODY.
 145 m4_define([b4_parse_param_for],
 146 [m4_foreach([$1_$2], m4_defn([b4_parse_param]),
 147 [m4_pushdef([$1], m4_unquote(m4_car($1_$2)))dnl
 148 m4_pushdef([$2], m4_shift($1_$2))dnl
 149 $3[]dnl
 150 m4_popdef([$2])dnl
 151 m4_popdef([$1])dnl
 152 ])])
 153
 154 # b4_parse_param_use([VAL], [LOC])
 155 # --------------------------------
 156 # `YYUSE' VAL, LOC if locations are enabled, and all the parse-params.
 157 m4_define([b4_parse_param_use],
 158 [m4_ifvaln([$1], [  YYUSE([$1]);])dnl
 159 b4_locations_if([m4_ifvaln([$2], [  YYUSE ([$2]);])])dnl
 160 b4_parse_param_for([Decl], [Formal], [  YYUSE (Formal);
 161 ])dnl
 162 ])
 163
 164
 165 ## ------------ ##
 166 ## Data Types.  ##
 167 ## ------------ ##
 168
 169 # b4_int_type(MIN, MAX)
 170 # ---------------------
 171 # Return the smallest int type able to handle numbers ranging from
 172 # MIN to MAX (included).
 173 m4_define([b4_int_type],
 174 [m4_if(b4_ints_in($@,      [0],   [255]), [1], [unsigned char],
 175        b4_ints_in($@,   [-128],   [127]), [1], [signed char],
 176
 177        b4_ints_in($@,      [0], [65535]), [1], [unsigned short int],
 178        b4_ints_in($@, [-32768], [32767]), [1], [short int],
 179
 180        m4_eval([0 <= $1]),                [1], [unsigned int],
 181
 182                                                [int])])
 183
 184
 185 # b4_int_type_for(NAME)
 186 # ---------------------
 187 # Return the smallest int type able to handle numbers ranging from
 188 # `NAME_min' to `NAME_max' (included).
 189 m4_define([b4_int_type_for],
 190 [b4_int_type($1_min, $1_max)])
 191
 192
 193 # b4_table_value_equals(TABLE, VALUE, LITERAL)
 194 # --------------------------------------------
 195 # Without inducing a comparison warning from the compiler, check if the
 196 # literal value LITERAL equals VALUE from table TABLE, which must have
 197 # TABLE_min and TABLE_max defined.
 198 m4_define([b4_table_value_equals],
 199 [m4_if(m4_eval($3 < m4_indir([b4_]$1[_min])
 200                || m4_indir([b4_]$1[_max]) < $3), [1],
 201        [[0]],
 202        [(!!(($2) == ($3)))])])
 203
 204
 205 ## ---------##
 206 ## Values.  ##
 207 ## ---------##
 208
 209
 210 # b4_null_define
 211 # --------------
 212 # Portability issues: define a YY_NULL appropriate for the current
 213 # language (C, C++98, or C++11).
 214 m4_define([b4_null_define],
 215 [# ifndef YY_NULL
 216 #  if defined __cplusplus && 201103L <= __cplusplus
 217 #   define YY_NULL nullptr
 218 #  else
 219 #   define YY_NULL 0
 220 #  endif
 221 # endif[]dnl
 222 ])
 223
 224
 225 # b4_null
 226 # -------
 227 # Return a null pointer constant.
 228 m4_define([b4_null], [YY_NULL])
 229
 230 # b4_integral_parser_table_define(TABLE-NAME, CONTENT, COMMENT)
 231 # -------------------------------------------------------------
 232 # Define "yy<TABLE-NAME>" which contents is CONTENT.
 233 m4_define([b4_integral_parser_table_define],
 234 [m4_ifvaln([$3], [b4_comment([$3], [  ])])dnl
 235 static const b4_int_type_for([$2]) yy$1[[]] =
 236 {
 237   $2
 238 };dnl
 239 ])
 240
 241
 242 ## ------------------------- ##
 243 ## Assigning token numbers.  ##
 244 ## ------------------------- ##
 245
 246 # b4_token_define(TOKEN-NUM)
 247 # --------------------------
 248 # Output the definition of this token as #define.
 249 m4_define([b4_token_define],
 250 [b4_token_format([#define %s %s], [$1])])
 251
 252 # b4_token_defines
 253 # ----------------
 254 # Output the definition of the tokens.
 255 m4_define([b4_token_defines],
 256 [b4_any_token_visible_if([/* Tokens.  */
 257 m4_join([
 258 ], b4_symbol_map([b4_token_define]))
 259 ])])
 260
 261
 262 # b4_token_enum(TOKEN-NUM)
 263 # ------------------------
 264 # Output the definition of this token as an enum.
 265 m4_define([b4_token_enum],
 266 [b4_token_format([%s = %s], [$1])])
 267
 268
 269 # b4_token_enums
 270 # --------------
 271 # Output the definition of the tokens (if there are) as enums.
 272 m4_define([b4_token_enums],
 273 [b4_any_token_visible_if([[/* Token type.  */
 274 #ifndef ]b4_api_PREFIX[TOKENTYPE
 275 # define ]b4_api_PREFIX[TOKENTYPE
 276   enum ]b4_api_prefix[tokentype
 277   {
 278     ]m4_join([,
 279     ],
 280              b4_symbol_map([b4_token_enum]))[
 281   };
 282 #endif
 283 ]])])
 284
 285
 286 # b4_token_enums_defines
 287 # ----------------------
 288 # Output the definition of the tokens (if there are any) as enums and,
 289 # if POSIX Yacc is enabled, as #defines.
 290 m4_define([b4_token_enums_defines],
 291 [b4_token_enums[]b4_yacc_if([b4_token_defines])])
 292
 293
 294 ## ----------------- ##
 295 ## Semantic Values.  ##
 296 ## ----------------- ##
 297
 298
 299 # b4_symbol_value(VAL, [TYPE])
 300 # ----------------------------
 301 # Given a semantic value VAL ($$, $1 etc.), extract its value of type
 302 # TYPE if TYPE is given, otherwise just return VAL.  The result can be
 303 # used safetly, it is put in parens to avoid nasty precedence issues.
 304 # TYPE is *not* put in braces, provide some if needed.
 305 m4_define([b4_symbol_value],
 306 [($1[]m4_ifval([$2], [.$2]))])
 307
 308
 309
 310 ## ---------------------- ##
 311 ## Defining C functions.  ##
 312 ## ---------------------- ##
 313
 314
 315 # b4_function_define(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 316 # -----------------------------------------------------------
 317 # Declare the function NAME in C.
 318 m4_define([b4_function_define],
 319 [$2
 320 $1 (b4_formals(m4_shift2($@)))[]dnl
 321 ])
 322
 323
 324 # b4_formals([DECL1, NAME1], ...)
 325 # -------------------------------
 326 # The formal arguments of a C function definition.
 327 m4_define([b4_formals],
 328 [m4_if([$#], [0], [void],
 329        [$#$1], [1], [void],
 330                [m4_map_sep([b4_formal], [, ], [$@])])])
 331
 332 m4_define([b4_formal],
 333 [$1])
 334
 335
 336
 337 ## ----------------------- ##
 338 ## Declaring C functions.  ##
 339 ## ----------------------- ##
 340
 341
 342 # b4_function_declare(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 343 # ------------------------------------------------------------
 344 # Declare the function NAME.
 345 m4_define([b4_function_declare],
 346 [$2 $1 (b4_formals(m4_shift2($@)));[]dnl
 347 ])
 348
 349
 350
 351
 352 ## --------------------- ##
 353 ## Calling C functions.  ##
 354 ## --------------------- ##
 355
 356
 357 # b4_function_call(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 358 # -----------------------------------------------------------
 359 # Call the function NAME with arguments NAME1, NAME2 etc.
 360 m4_define([b4_function_call],
 361 [$1 (b4_args(m4_shift2($@)))[]dnl
 362 ])
 363
 364
 365 # b4_args([DECL1, NAME1], ...)
 366 # ----------------------------
 367 # Output the arguments NAME1, NAME2...
 368 m4_define([b4_args],
 369 [m4_map_sep([b4_arg], [, ], [$@])])
 370
 371 m4_define([b4_arg],
 372 [$2])
 373
 374
 375 ## ----------- ##
 376 ## Synclines.  ##
 377 ## ----------- ##
 378
 379 # b4_sync_start(LINE, FILE)
 380 # -------------------------
 381 m4_define([b4_sync_start], [[#]line $1 $2])
 382
 383
 384 ## -------------- ##
 385 ## User actions.  ##
 386 ## -------------- ##
 387
 388 # b4_case(LABEL, STATEMENTS)
 389 # --------------------------
 390 m4_define([b4_case],
 391 [  case $1:
 392 $2
 393 b4_syncline([@oline@], [@ofile@])
 394     break;])
 395
 396
 397 # b4_predicate_case(LABEL, CONDITIONS)
 398 # ------------------------------------
 399 m4_define([b4_predicate_case],
 400 [  case $1:
 401     if (! ($2)) YYERROR;
 402 b4_syncline([@oline@], [@ofile@])
 403     break;])
 404
 405
 406 # b4_yydestruct_define
 407 # --------------------
 408 # Define the "yydestruct" function.
 409 m4_define_default([b4_yydestruct_define],
 410 [[/*-----------------------------------------------.
 411 | Release the memory associated to this symbol.  |
 412 `-----------------------------------------------*/
 413
 414 ]b4_function_define([yydestruct],
 415     [static void],
 416     [[const char *yymsg],    [yymsg]],
 417     [[int yytype],           [yytype]],
 418     [[YYSTYPE *yyvaluep],    [yyvaluep]][]dnl
 419 b4_locations_if(            [, [[YYLTYPE *yylocationp], [yylocationp]]])[]dnl
 420 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 421 {
 422 ]b4_parse_param_use([yyvaluep], [yylocationp])dnl
 423 [  if (!yymsg)
 424     yymsg = "Deleting";
 425   YY_SYMBOL_PRINT (yymsg, yytype, yyvaluep, yylocationp);
 426
 427   switch (yytype)
 428     {
 429 ]b4_symbol_foreach([b4_symbol_destructor])dnl
 430 [      default:
 431         break;
 432     }
 433 }]dnl
 434 ])
 435
 436
 437 # b4_yy_symbol_print_define
 438 # -------------------------
 439 # Define the "yy_symbol_print" function.
 440 m4_define_default([b4_yy_symbol_print_define],
 441 [[
 442 /*--------------------------------.
 443 | Print this symbol on YYOUTPUT.  |
 444 `--------------------------------*/
 445
 446 ]b4_function_define([yy_symbol_value_print],
 447     [static void],
 448                [[FILE *yyoutput],                       [yyoutput]],
 449                [[int yytype],                           [yytype]],
 450                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 451 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 452 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 453 {
 454   FILE *yyo = yyoutput;
 455 ]b4_parse_param_use([yyo], [yylocationp])dnl
 456 [  if (!yyvaluep)
 457     return;]
 458 dnl glr.c does not feature yytoknum.
 459 m4_if(b4_skeleton, ["yacc.c"],
 460 [[# ifdef YYPRINT
 461   if (yytype < YYNTOKENS)
 462     YYPRINT (yyoutput, yytoknum[yytype], *yyvaluep);
 463 # endif
 464 ]])dnl
 465 [  switch (yytype)
 466     {
 467 ]b4_symbol_foreach([b4_symbol_printer])dnl
 468 [      default:
 469         break;
 470     }
 471 }
 472
 473
 474 /*--------------------------------.
 475 | Print this symbol on YYOUTPUT.  |
 476 `--------------------------------*/
 477
 478 ]b4_function_define([yy_symbol_print],
 479     [static void],
 480                [[FILE *yyoutput],                       [yyoutput]],
 481                [[int yytype],                           [yytype]],
 482                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 483 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 484 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 485 {
 486   if (yytype < YYNTOKENS)
 487     YYFPRINTF (yyoutput, "token %s (", yytname[yytype]);
 488   else
 489     YYFPRINTF (yyoutput, "nterm %s (", yytname[yytype]);
 490
 491 ]b4_locations_if([  YY_LOCATION_PRINT (yyoutput, *yylocationp);
 492   YYFPRINTF (yyoutput, ": ");
 493 ])dnl
 494 [  yy_symbol_value_print (yyoutput, yytype, yyvaluep]dnl
 495 b4_locations_if([, yylocationp])[]b4_user_args[);
 496   YYFPRINTF (yyoutput, ")");
 497 }]dnl
 498 ])
 499
 500 ## -------------- ##
 501 ## Declarations.  ##
 502 ## -------------- ##
 503
 504 # b4_value_type_define
 505 # --------------------
 506 m4_define([b4_value_type_define],
 507 [[/* Value type.  */
 508 #if ! defined ]b4_api_PREFIX[STYPE && ! defined ]b4_api_PREFIX[STYPE_IS_DECLARED
 509 ]m4_ifdef([b4_stype],
 510 [[typedef union ]b4_union_name[ ]b4_api_PREFIX[STYPE;
 511 union ]b4_union_name[
 512 {
 513 ]b4_user_stype[
 514 };
 515 # define ]b4_api_PREFIX[STYPE_IS_TRIVIAL 1]],
 516 [m4_if(b4_tag_seen_flag, 0,
 517 [[typedef int ]b4_api_PREFIX[STYPE;
 518 # define ]b4_api_PREFIX[STYPE_IS_TRIVIAL 1]])])[
 519 # define ]b4_api_PREFIX[STYPE_IS_DECLARED 1
 520 #endif
 521 ]])
 522
 523
 524 # b4_location_type_define
 525 # -----------------------
 526 m4_define([b4_location_type_define],
 527 [[/* Location type.  */
 528 #if ! defined ]b4_api_PREFIX[LTYPE && ! defined ]b4_api_PREFIX[LTYPE_IS_DECLARED
 529 typedef struct ]b4_api_PREFIX[LTYPE ]b4_api_PREFIX[LTYPE;
 530 struct ]b4_api_PREFIX[LTYPE
 531 {
 532   int first_line;
 533   int first_column;
 534   int last_line;
 535   int last_column;
 536 };
 537 # define ]b4_api_PREFIX[LTYPE_IS_DECLARED 1
 538 # define ]b4_api_PREFIX[LTYPE_IS_TRIVIAL 1
 539 #endif
 540 ]])
 541
 542
 543 # b4_declare_yylstype
 544 # -------------------
 545 # Declarations that might either go into the header (if --defines) or
 546 # in the parser body.  Declare YYSTYPE/YYLTYPE, and yylval/yylloc.
 547 m4_define([b4_declare_yylstype],
 548 [b4_value_type_define[]b4_locations_if([
 549 b4_location_type_define])
 550
 551 b4_pure_if([], [[extern ]b4_api_PREFIX[STYPE ]b4_prefix[lval;
 552 ]b4_locations_if([[extern ]b4_api_PREFIX[LTYPE ]b4_prefix[lloc;]])])[]dnl
 553 ])
 554
 555
 556 # b4_YYDEBUG_define
 557 # ------------------
 558 m4_define([b4_YYDEBUG_define],
 559 [[/* Debug traces.  */
 560 ]m4_if(b4_api_prefix, [yy],
 561 [[#ifndef YYDEBUG
 562 # define YYDEBUG ]b4_parse_trace_if([1], [0])[
 563 #endif]],
 564 [[#ifndef ]b4_api_PREFIX[DEBUG
 565 # if defined YYDEBUG
 566 #if YYDEBUG
 567 #   define ]b4_api_PREFIX[DEBUG 1
 568 #  else
 569 #   define ]b4_api_PREFIX[DEBUG 0
 570 #  endif
 571 # else /* ! defined YYDEBUG */
 572 #  define ]b4_api_PREFIX[DEBUG ]b4_parse_trace_if([1], [0])[
 573 # endif /* ! defined YYDEBUG */
 574 #endif  /* ! defined ]b4_api_PREFIX[DEBUG */]])[]dnl
 575 ])
 576
 577 # b4_declare_yydebug
 578 # ------------------
 579 m4_define([b4_declare_yydebug],
 580 [b4_YYDEBUG_define[
 581 #if ]b4_api_PREFIX[DEBUG
 582 extern int ]b4_prefix[debug;
 583 #endif][]dnl
 584 ])
 585
 586 # b4_yylloc_default_define
 587 # ------------------------
 588 # Define YYLLOC_DEFAULT.
 589 m4_define([b4_yylloc_default_define],
 590 [[/* YYLLOC_DEFAULT -- Set CURRENT to span from RHS[1] to RHS[N].
 591    If N is 0, then set CURRENT to the empty location which ends
 592    the previous symbol: RHS[0] (always defined).  */
 593
 594 #ifndef YYLLOC_DEFAULT
 595 # define YYLLOC_DEFAULT(Current, Rhs, N)                                \
 596     do                                                                  \
 597       if (N)                                                            \
 598         {                                                               \
 599           (Current).first_line   = YYRHSLOC (Rhs, 1).first_line;        \
 600           (Current).first_column = YYRHSLOC (Rhs, 1).first_column;      \
 601           (Current).last_line    = YYRHSLOC (Rhs, N).last_line;         \
 602           (Current).last_column  = YYRHSLOC (Rhs, N).last_column;       \
 603         }                                                               \
 604       else                                                              \
 605         {                                                               \
 606           (Current).first_line   = (Current).last_line   =              \
 607             YYRHSLOC (Rhs, 0).last_line;                                \
 608           (Current).first_column = (Current).last_column =              \
 609             YYRHSLOC (Rhs, 0).last_column;                              \
 610         }                                                               \
 611     while (0)
 612 #endif
 613 ]])
 614
 615 # b4_yy_location_print_define
 616 # ---------------------------
 617 # Define YY_LOCATION_PRINT.
 618 m4_define([b4_yy_location_print_define],
 619 [b4_locations_if([[
 620 /* YY_LOCATION_PRINT -- Print the location on the stream.
 621    This macro was not mandated originally: define only if we know
 622    we won't break user code: when these are the locations we know.  */
 623
 624 #ifndef YY_LOCATION_PRINT
 625 # if defined ]b4_api_PREFIX[LTYPE_IS_TRIVIAL && ]b4_api_PREFIX[LTYPE_IS_TRIVIAL
 626
 627 /* Print *YYLOCP on YYO.  Private, do not rely on its existence. */
 628
 629 __attribute__((__unused__))
 630 ]b4_function_define([yy_location_print_],
 631     [static unsigned],
 632                [[FILE *yyo],                    [yyo]],
 633                [[YYLTYPE const * const yylocp], [yylocp]])[
 634 {
 635   unsigned res = 0;
 636   int end_col = 0 != yylocp->last_column ? yylocp->last_column - 1 : 0;
 637   if (0 <= yylocp->first_line)
 638     {
 639       res += fprintf (yyo, "%d", yylocp->first_line);
 640       if (0 <= yylocp->first_column)
 641         res += fprintf (yyo, ".%d", yylocp->first_column);
 642     }
 643   if (0 <= yylocp->last_line)
 644     {
 645       if (yylocp->first_line < yylocp->last_line)
 646         {
 647           res += fprintf (yyo, "-%d", yylocp->last_line);
 648           if (0 <= end_col)
 649             res += fprintf (yyo, ".%d", end_col);
 650         }
 651       else if (0 <= end_col && yylocp->first_column < end_col)
 652         res += fprintf (yyo, "-%d", end_col);
 653     }
 654   return res;
 655  }
 656
 657 #  define YY_LOCATION_PRINT(File, Loc)                                   \
 658   yy_location_print_ (File, &(Loc))
 659
 660 # else
 661 #  define YY_LOCATION_PRINT(File, Loc) ((void) 0)
 662 # endif
 663 #endif]],
 664 [[/* This macro is provided for backward compatibility. */
 665 #ifndef YY_LOCATION_PRINT
 666 # define YY_LOCATION_PRINT(File, Loc) ((void) 0)
 667 #endif]])
 668 ])
 669
 670 # b4_yyloc_default
 671 # ----------------
 672 # Expand to a possible default value for yylloc.
 673 m4_define([b4_yyloc_default],
 674 [[
 675 # if defined ]b4_api_PREFIX[LTYPE_IS_TRIVIAL && ]b4_api_PREFIX[LTYPE_IS_TRIVIAL
 676   = { ]m4_join([, ],
 677                m4_defn([b4_location_initial_line]),
 678                m4_defn([b4_location_initial_column]),
 679                m4_defn([b4_location_initial_line]),
 680                m4_defn([b4_location_initial_column]))[ }
 681 # endif
 682 ]])