configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2012])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz nostdinc
  49                  color-tests parallel-tests
  50                  silent-rules]
  51                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  52                            [gnu], [gnits]))
  53 AM_SILENT_RULES([yes])
  54 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  55
  56 # Checks for the compiler.
  57 AC_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 # Gnulib (early checks).
  61 gl_EARLY
  62
  63 AC_ARG_ENABLE([gcc-warnings],
  64 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  65 [case $enable_gcc_warnings in
  66    yes|no) ;;
  67    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  68  esac],
  69               [enable_gcc_warnings=no])
  70 if test "$enable_gcc_warnings" = yes; then
  71   warn_common='-Wall -Wextra -Wno-sign-compare -Wcast-align
  72     -Wcast-qual -Wformat -Wpointer-arith -Wwrite-strings'
  73   warn_c='-Wbad-function-cast -Wmissing-declarations -Wmissing-prototypes
  74     -Wshadow -Wstrict-prototypes'
  75   warn_cxx='-Wnoexcept'
  76
  77   AC_LANG_PUSH([C])
  78   for i in $warn_common $warn_c;
  79   do
  80     gl_WARN_ADD([$i], [WARN_CFLAGS])
  81   done
  82   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  83   # Warnings for the test suite only.
  84   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  85   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
  86   AC_LANG_POP([C])
  87
  88   AC_LANG_PUSH([C++])
  89   for i in $warn_common $warn_cxx;
  90   do
  91     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
  92   done
  93   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
  94               [AC_LANG_PROGRAM([], [nullptr])])
  95   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
  96   # Warnings for the test suite only.
  97   gl_WARN_ADD([-Wundef], [WARN_CXXFLAGS_TEST])
  98   gl_WARN_ADD([-pedantic], [WARN_CXXFLAGS_TEST])
  99   AC_LANG_POP([C++])
 100 fi
 101
 102 BISON_TEST_FOR_WORKING_C_COMPILER
 103 BISON_TEST_FOR_WORKING_CXX_COMPILER
 104
 105 AC_ARG_ENABLE([yacc],
 106   [AC_HELP_STRING([--disable-yacc],
 107      [do not build a yacc command or an -ly library])],
 108   , [enable_yacc=yes])
 109 case $enable_yacc in
 110 yes)
 111   YACC_SCRIPT=src/yacc
 112   YACC_LIBRARY=lib/liby.a;;
 113 *)
 114   YACC_SCRIPT=
 115   YACC_LIBRARY=;;
 116 esac
 117 AC_SUBST([YACC_SCRIPT])
 118 AC_SUBST([YACC_LIBRARY])
 119
 120 # Checks for programs.
 121 AC_PROG_LEX
 122 $LEX_IS_FLEX || AC_MSG_ERROR([Flex is required])
 123 AC_PROG_YACC
 124 AC_PROG_RANLIB
 125 AC_PROG_GNU_M4
 126 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 127 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 128 supports -g, otherwise to "".])
 129 AC_PATH_PROG([PERL], [perl])
 130 if test -z "$PERL"; then
 131    AC_MSG_ERROR([perl not found])
 132 fi
 133 AM_MISSING_PROG([HELP2MAN], [help2man])
 134 AC_PATH_PROG([XSLTPROC], [xsltproc])
 135 AC_SUBST([XSLTPROC])
 136
 137 # Checks for header files.
 138 AC_CHECK_HEADERS_ONCE([locale.h])
 139
 140 # Checks for compiler characteristics.
 141 AC_C_INLINE
 142
 143 # Gnulib (later checks).  Putting them here rather than right after
 144 # gl_EARLY avoids some redundant checks.
 145 gl_INIT
 146
 147 # Checks for library functions.
 148 AC_CHECK_FUNCS_ONCE([setlocale])
 149 AM_WITH_DMALLOC
 150 BISON_PREREQ_TIMEVAR
 151
 152 # Gettext.
 153 # We use gnulib, which is only guaranteed to work properly with the
 154 # latest Gettext.
 155 AM_GNU_GETTEXT([external], [need-ngettext])
 156 AM_GNU_GETTEXT_VERSION([0.18])
 157 BISON_I18N
 158
 159 # Internationalized parsers.
 160 AC_CONFIG_FILES([runtime-po/Makefile.in])
 161 # Autoconf macros for packages using internationalized parsers.
 162 aclocaldir='${datadir}/aclocal'
 163 AC_SUBST([aclocaldir])
 164
 165 # Create the benchmark script.
 166 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 167
 168 # Initialize the test suite.
 169 AC_CONFIG_TESTDIR(tests)
 170 AC_CONFIG_FILES([tests/atlocal])
 171 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 172 AC_CHECK_PROGS([VALGRIND], [valgrind])
 173 case $VALGRIND:$host_os in
 174   '':*) ;;
 175   *:darwin*)
 176     # See README-hacking.
 177     # VALGRIND+=' --suppressions=$(abs_top_srcdir)/build-aux/darwin11.4.0.valgrind'
 178     VALGRIND=;;
 179   *:*)
 180     AC_SUBST([VALGRIND_PREBISON], [$VALGRIND -q]);;
 181 esac
 182
 183 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 184 # Needed by tests/atlocal.in.
 185 AC_SUBST([GCC])
 186
 187 gt_JAVACOMP([1.3], [1.4])
 188 gt_JAVAEXEC
 189
 190 # We use gnulib, but from lib/local.mk instead of lib/Makefile.am.
 191 # So prefix paths with lib/.  See also etc/prefix-gnulib-mk.
 192 gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, , lib/,g'`
 193 # Listing the names of the variables to prefix is error-prone.
 194 # Rather, adjust all the AC_SUBST variables whose name ends in '_H',
 195 # and whose content ends in '.h'.
 196 for ac_var in $ac_subst_vars
 197 do
 198   eval "ac_val=\$$ac_var"
 199   case $ac_var=$ac_val in
 200     (*_H=*.h) eval "$ac_var=lib/\$$ac_var";;
 201   esac
 202 done
 203 AC_CONFIG_FILES([Makefile
 204                  po/Makefile.in
 205                  doc/yacc.1])
 206 AC_OUTPUT