tests/actions.at

   1 # Executing Actions.                               -*- Autotest -*-
   2 # Copyright 2001 Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2, or (at your option)
   7 # any later version.
   8
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  17 # 02111-1307, USA.
  18
  19 AT_BANNER([[User Actions.]])
  20
  21 ## ------------------ ##
  22 ## Mid-rule actions.  ##
  23 ## ------------------ ##
  24
  25 AT_SETUP([Mid-rule actions])
  26
  27 # Bison once forgot the mid-rule actions.  It was because the action
  28 # was attached to the host rule (the one with the mid-rule action),
  29 # instead of being attached to the empty rule dedicated to this
  30 # action.
  31
  32 AT_DATA([[input.y]],
  33 [[%{
  34 # include <stdio.h>
  35 # include <stdlib.h>
  36   static void yyerror (const char *msg);
  37   static int yylex (void);
  38 # define YYDEBUG         1
  39 # define YYERROR_VERBOSE 1
  40 %}
  41 %%
  42 exp:     { putchar ('0'); }
  43      '1' { putchar ('1'); }
  44      '2' { putchar ('2'); }
  45      '3' { putchar ('3'); }
  46      '4' { putchar ('4'); }
  47      '5' { putchar ('5'); }
  48      '6' { putchar ('6'); }
  49      '7' { putchar ('7'); }
  50      '8' { putchar ('8'); }
  51      '9' { putchar ('9'); }
  52          { putchar ('\n'); }
  53    ;
  54 %%
  55 static int
  56 yylex (void)
  57 {
  58   static const char *input = "123456789";
  59   return *input++;
  60 }
  61
  62 static void
  63 yyerror (const char *msg)
  64 {
  65   fprintf (stderr, "%s\n", msg);
  66 }
  67
  68 int
  69 main (void)
  70 {
  71   return yyparse ();
  72 }
  73 ]])
  74
  75 AT_CHECK([bison -d -v -o input.c input.y])
  76 AT_COMPILE([input])
  77 AT_PARSER_CHECK([./input], 0,
  78 [[0123456789
  79 ]])
  80
  81 AT_CLEANUP
  82
  83
  84
  85 ## ---------------- ##
  86 ## Exotic Dollars.  ##
  87 ## ---------------- ##
  88
  89 AT_SETUP([Exotic Dollars])
  90
  91 AT_DATA([[input.y]],
  92 [[%{
  93 # include <stdio.h>
  94 # include <stdlib.h>
  95   static void yyerror (const char *msg);
  96   static int yylex (void);
  97 # define YYDEBUG         1
  98 # define YYERROR_VERBOSE 1
  99 %}
 100
 101 %union
 102 {
 103   int val;
 104 };
 105
 106 %type <val> a_1 a_2 a_5
 107             sum_of_the_five_previous_values
 108
 109 %%
 110 exp: a_1 a_2 { $<val>$ = 3; } { $<val>$ = $<val>3 + 1; } a_5
 111      sum_of_the_five_previous_values
 112     {
 113        printf ("%d\n", $6);
 114     }
 115 ;
 116 a_1: { $$ = 1; };
 117 a_2: { $$ = 2; };
 118 a_5: { $$ = 5; };
 119
 120 sum_of_the_five_previous_values:
 121     {
 122        $$ = $<val>0 + $<val>-1 + $<val>-2 + $<val>-3 + $<val>-4;
 123     }
 124 ;
 125
 126 %%
 127 static int
 128 yylex (void)
 129 {
 130   return EOF;
 131 }
 132
 133 static void
 134 yyerror (const char *msg)
 135 {
 136   fprintf (stderr, "%s\n", msg);
 137 }
 138
 139 int
 140 main (void)
 141 {
 142   return yyparse ();
 143 }
 144 ]])
 145
 146 AT_CHECK([bison -d -v -o input.c input.y])
 147 AT_COMPILE([input])
 148 AT_PARSER_CHECK([./input], 0,
 149 [[15
 150 ]])
 151
 152 AT_CLEANUP
 153
 154
 155
 156 ## -------------------------- ##
 157 ## Printers and Destructors.  ##
 158 ## -------------------------- ##
 159
 160 # _AT_CHECK_PRINTER_AND_DESTRUCTOR($1, $2, $3, BISON-DIRECTIVE)
 161 # -------------------------------------------------------------
 162 m4_define([_AT_CHECK_PRINTER_AND_DESTRUCTOR],
 163 [m4_if([$1$2$3], $[1]$[2]$[3], [],
 164        [m4_fatal([$0: Invalid arguments: $@])])dnl
 165
 166 AT_SETUP([Printers and Destructors: $4])
 167
 168 # Make sure complex $n work.
 169
 170 AT_DATA([[input.y]],
 171 [[$4
 172 %{
 173 #include <stdio.h>
 174 #include <stdlib.h>
 175 #include <assert.h>
 176
 177 static int yylex (void);
 178 static void yyerror (const char *msg);
 179 %}
 180 %error-verbose
 181 %debug
 182 %verbose
 183 %locations
 184 %union
 185 {
 186   int ival;
 187 }
 188 %type <ival> 'x' thing line input
 189
 190 %printer { fprintf (yyout, "%d from %d", $$, @$.first_line); }
 191    input line thing 'x'
 192
 193 %destructor
 194   { fprintf (stdout, "Freeing nterm input (%d from %d)\n", $$, @$.first_line); }
 195   input
 196
 197 %destructor
 198   { fprintf (stdout, "Freeing nterm line (%d from %d)\n", $$, @$.first_line); }
 199   line
 200
 201 %destructor
 202   { fprintf (stdout, "Freeing nterm thing (%d from %d)\n", $$, @$.first_line); }
 203   thing
 204
 205 %destructor
 206   { fprintf (stdout, "Freeing token 'x' (%d from %d)\n", $$, @$.first_line); }
 207   'x'
 208
 209 %%
 210 input:
 211   /* Nothing. */
 212     {
 213       $$ = 0;
 214       printf ("input(%d): /* Nothing */';'\n", $$);
 215     }
 216 | line input /* Right recursive to load the stack so that popping at
 217                 EOF can be exercised.  */
 218     {
 219       $$ = 2;
 220       printf ("input(%d): line(%d) input(%d)';'\n", $$, $1, $2);
 221     }
 222 ;
 223
 224 line:
 225   thing thing thing ';'
 226     {
 227       $$ = $1;
 228       printf ("line(%d): thing(%d) thing(%d) thing(%d) ';'\n", $$, $1, $2, $3);
 229     }
 230 | thing thing ';'
 231     {
 232       $$ = $1;
 233       printf ("line(%d): thing(%d) thing(%d) ';'\n", $$, $1, $2);
 234     }
 235 | thing ';'
 236     {
 237       $$ = $1;
 238       printf ("line(%d): thing(%d) ';'\n", $$, $1);
 239     }
 240 | error ';'
 241     {
 242       $$ = -1;
 243       printf ("line(%d): error ';'\n", $$);
 244     }
 245 ;
 246
 247 thing:
 248   'x'
 249     {
 250       $$ = $1;
 251       printf ("thing(%d): 'x'(%d)\n", $$, $1);
 252     }
 253 ;
 254 %%
 255 static int
 256 yylex (void)
 257 {
 258   static const unsigned int input[] =
 259     {
 260       /* Exericise the discarding of stack top and input until `error'
 261          can be reduced.  */
 262       'x', 'x', 'x', 'x', 'x', 'x', ';',
 263
 264       /* Load the stack and provoke an error that cannot be caught by
 265          the grammar, to check that the stack is cleared. */
 266       'x', 'x', ';',
 267       'x', ';',
 268       'y'
 269     };
 270   static unsigned int counter = 0;
 271
 272   if (counter < (sizeof(input) / sizeof (input[0])))
 273     {
 274        yylval.ival = counter;
 275        /* As in BASIC, line numbers go from 10 to 10.  */
 276        yylloc.first_line = 10 * counter;
 277        printf ("sending: '%c' (value = %d, line %d)\n",
 278                input[counter], yylval.ival, yylloc.first_line);
 279        return (int) input[counter++];
 280     }
 281   else
 282     {
 283       printf ("sending: EOF\n");
 284       return EOF;
 285     }
 286 }
 287
 288 static void
 289 yyerror (const char *msg)
 290 {
 291   fprintf (stdout, "%d: %s\n", yylloc.first_line, msg);
 292 }
 293
 294 int
 295 main (void)
 296 {
 297   yydebug = !!getenv ("YYDEBUG");
 298   if (yyparse ())
 299     {
 300       fprintf (stdout, "Parsing FAILED.\n");
 301       exit (1);
 302     }
 303   fprintf (stdout, "Successful parse.\n");
 304   return 0;
 305 }
 306 ]])
 307
 308 AT_CHECK([bison -o input.c input.y])
 309 AT_COMPILE([input])
 310 AT_PARSER_CHECK([./input], 1,
 311 [[sending: 'x' (value = 0, line 0)
 312 thing(0): 'x'(0)
 313 sending: 'x' (value = 1, line 10)
 314 thing(1): 'x'(1)
 315 sending: 'x' (value = 2, line 20)
 316 thing(2): 'x'(2)
 317 sending: 'x' (value = 3, line 30)
 318 30: parse error, unexpected 'x', expecting ';'
 319 Freeing nterm thing (2 from 20)
 320 Freeing nterm thing (1 from 10)
 321 Freeing nterm thing (0 from 0)
 322 Freeing token 'x' (3 from 30)
 323 sending: 'x' (value = 4, line 40)
 324 Freeing token 'x' (4 from 40)
 325 sending: 'x' (value = 5, line 50)
 326 Freeing token 'x' (5 from 50)
 327 sending: ';' (value = 6, line 60)
 328 line(-1): error ';'
 329 sending: 'x' (value = 7, line 70)
 330 thing(7): 'x'(7)
 331 sending: 'x' (value = 8, line 80)
 332 thing(8): 'x'(8)
 333 sending: ';' (value = 9, line 90)
 334 line(7): thing(7) thing(8) ';'
 335 sending: 'x' (value = 10, line 100)
 336 thing(10): 'x'(10)
 337 sending: ';' (value = 11, line 110)
 338 line(10): thing(10) ';'
 339 sending: 'y' (value = 12, line 120)
 340 120: parse error, unexpected $undefined, expecting $end or 'x'
 341 sending: EOF
 342 Freeing nterm line (10 from 100)
 343 Freeing nterm line (7 from 70)
 344 Freeing nterm line (-1 from 50)
 345 Parsing FAILED.
 346 ]])
 347
 348 AT_CLEANUP
 349 ])
 350
 351
 352 # AT_CHECK_PRINTER_AND_DESTRUCTOR([BISON-OPTIONS])
 353 # ------------------------------------------------
 354 # Produce `calc.y'.
 355 m4_define([AT_CHECK_PRINTER_AND_DESTRUCTOR],
 356 [_AT_CHECK_PRINTER_AND_DESTRUCTOR($[1], $[2], $[3], [$1])
 357 ])
 358
 359
 360 AT_CHECK_PRINTER_AND_DESTRUCTOR()
 361 AT_CHECK_PRINTER_AND_DESTRUCTOR([%glr-parser])