m4/realloc.m4

   1 #serial 6
   2
   3 dnl From Jim Meyering.
   4 dnl Determine whether realloc works when both arguments are 0.
   5 dnl If it doesn't, arrange to use the replacement function.
   6 dnl
   7
   8 AC_DEFUN([jm_FUNC_REALLOC],
   9 [
  10  dnl xmalloc.c requires that this symbol be defined so it doesn't
  11  dnl mistakenly use a broken realloc -- as it might if this test were omitted.
  12  AC_DEFINE(HAVE_DONE_WORKING_REALLOC_CHECK, 1,
  13            [Define if the realloc check has been performed. ])
  14
  15  AC_CACHE_CHECK([whether realloc(0,0) returns a non-NULL pointer],
  16                 jm_cv_func_working_realloc,
  17   [AC_TRY_RUN([
  18     char *realloc ();
  19     int
  20     main ()
  21     {
  22       exit (realloc (0, 0) ? 0 : 1);
  23     }
  24           ],
  25          jm_cv_func_working_realloc=yes,
  26          jm_cv_func_working_realloc=no,
  27          dnl When crosscompiling, assume realloc(0,0) returns NULL.
  28          jm_cv_func_working_realloc=no)
  29   ])
  30   if test $jm_cv_func_working_realloc = yes; then
  31     AC_DEFINE([HAVE_REALLOC], 1,
  32               [Define to 1 if your system has a working `realloc' function,
  33                and to 0 otherwise.])
  34   else
  35     AC_DEFINE([HAVE_REALLOC], 0)
  36     AC_LIBOBJ(realloc)
  37     AC_DEFINE(realloc, rpl_realloc,
  38       [Define to rpl_realloc if the replacement function should be used.])
  39   fi
  40 ])