configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2012])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz nostdinc
  49                  color-tests parallel-tests
  50                  silent-rules]
  51                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  52                            [gnu], [gnits]))
  53 AM_SILENT_RULES([yes])
  54 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  55
  56 # Checks for the compiler.
  57 AC_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 # Gnulib (early checks).
  61 gl_EARLY
  62
  63 AC_ARG_ENABLE([gcc-warnings],
  64 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  65 [case $enable_gcc_warnings in
  66    yes|no) ;;
  67    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  68  esac],
  69               [enable_gcc_warnings=no])
  70 if test "$enable_gcc_warnings" = yes; then
  71   warn_common='-Wall -Wextra -Wno-sign-compare -Wcast-align
  72     -Wcast-qual -Wformat -Wpointer-arith -Wwrite-strings'
  73   warn_c='-Wbad-function-cast -Wmissing-declarations -Wmissing-prototypes
  74     -Wshadow -Wstrict-prototypes'
  75   warn_cxx='-Wnoexcept'
  76   AC_LANG_PUSH([C])
  77   for i in $warn_common $warn_c;
  78   do
  79     gl_WARN_ADD([$i], [WARN_CFLAGS])
  80   done
  81   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  82   # Warnings for the test suite only.
  83   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  84   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
  85   AC_LANG_POP([C])
  86
  87   AC_LANG_PUSH([C++])
  88   for i in $warn_common $warn_cxx;
  89   do
  90     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
  91   done
  92   gl_WARN_ADD([ -Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
  93               [AC_LANG_PROGRAM([], [nullptr])])
  94   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
  95   # Warnings for the test suite only.
  96   gl_WARN_ADD([-Wundef], [WARN_CXXFLAGS_TEST])
  97   gl_WARN_ADD([-pedantic], [WARN_CXXFLAGS_TEST])
  98   AC_LANG_POP([C++])
  99 fi
 100
 101 BISON_TEST_FOR_WORKING_C_COMPILER
 102 BISON_TEST_FOR_WORKING_CXX_COMPILER
 103
 104 AC_ARG_ENABLE([yacc],
 105   [AC_HELP_STRING([--disable-yacc],
 106      [do not build a yacc command or an -ly library])],
 107   , [enable_yacc=yes])
 108 case $enable_yacc in
 109 yes)
 110   YACC_SCRIPT=src/yacc
 111   YACC_LIBRARY=lib/liby.a;;
 112 *)
 113   YACC_SCRIPT=
 114   YACC_LIBRARY=;;
 115 esac
 116 AC_SUBST([YACC_SCRIPT])
 117 AC_SUBST([YACC_LIBRARY])
 118
 119 # Checks for programs.
 120 AC_PROG_LEX
 121 $LEX_IS_FLEX || AC_MSG_ERROR([Flex is required])
 122 AC_PROG_YACC
 123 AC_PROG_RANLIB
 124 AC_PROG_GNU_M4
 125 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 126 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 127 supports -g, otherwise to "".])
 128 AC_PATH_PROG([PERL], [perl])
 129 if test -z "$PERL"; then
 130    AC_MSG_ERROR([perl not found])
 131 fi
 132 AM_MISSING_PROG([HELP2MAN], [help2man])
 133 AC_PATH_PROG([XSLTPROC], [xsltproc])
 134 AC_SUBST([XSLTPROC])
 135
 136 # Checks for header files.
 137 AC_CHECK_HEADERS_ONCE([locale.h])
 138
 139 # Checks for compiler characteristics.
 140 AC_C_INLINE
 141
 142 # Gnulib (later checks).  Putting them here rather than right after
 143 # gl_EARLY avoids some redundant checks.
 144 gl_INIT
 145
 146 # Checks for library functions.
 147 AC_CHECK_FUNCS_ONCE([setlocale])
 148 AM_WITH_DMALLOC
 149 BISON_PREREQ_TIMEVAR
 150
 151 # Gettext.
 152 # We use gnulib, which is only guaranteed to work properly with the
 153 # latest Gettext.
 154 AM_GNU_GETTEXT([external], [need-ngettext])
 155 AM_GNU_GETTEXT_VERSION([0.18])
 156 BISON_I18N
 157
 158 # Internationalized parsers.
 159 AC_CONFIG_FILES([runtime-po/Makefile.in])
 160 # Autoconf macros for packages using internationalized parsers.
 161 aclocaldir='${datadir}/aclocal'
 162 AC_SUBST([aclocaldir])
 163
 164 # Create the benchmark script.
 165 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 166
 167 # Initialize the test suite.
 168 AC_CONFIG_TESTDIR(tests)
 169 AC_CONFIG_FILES([tests/atlocal])
 170 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 171 AC_CHECK_PROGS([VALGRIND], [valgrind])
 172 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 173 # Needed by tests/atlocal.in.
 174 AC_SUBST([GCC])
 175
 176 gt_JAVACOMP([1.3], [1.4])
 177 gt_JAVAEXEC
 178
 179 # We use gnulib, but from lib/local.mk instead of lib/Makefile.am.
 180 # So prefix paths with lib/.  See also etc/prefix-gnulib-mk.
 181 gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, , lib/,g'`
 182 # Listing the names of the variables to prefix is error-prone.
 183 # Rather, adjust all the AC_SUBST variables whose name ends in '_H',
 184 # and whose content ends in '.h'.
 185 for ac_var in $ac_subst_vars
 186 do
 187   eval "ac_val=\$$ac_var"
 188   case $ac_var=$ac_val in
 189     (*_H=*.h) eval "$ac_var=lib/\$$ac_var";;
 190   esac
 191 done
 192 AC_CONFIG_FILES([Makefile
 193                  po/Makefile.in
 194                  doc/yacc.1])
 195 AC_OUTPUT