configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19
  20 # We need a recent Autoconf to run a recent Autotest.
  21 AC_PREREQ(2.54)
  22
  23 AC_INIT([GNU Bison], [1.75b], [bug-bison@gnu.org])
  24 AC_CONFIG_AUX_DIR(config)
  25
  26 AM_INIT_AUTOMAKE([1.7 check-news readme-alpha dist-bzip2])
  27 AC_CONFIG_HEADERS([config.h:config.hin])
  28
  29 # Checks for the compiler.
  30 AC_PROG_CC
  31 # Remove with Automake 1.8.
  32 AC_ISC_POSIX
  33 AC_GNU_SOURCE
  34 AC_MINIX
  35 AM_PROG_CC_STDC
  36 AC_ARG_ENABLE(gcc-warnings,
  37 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  38 [case "${enableval}" in
  39    yes|no) ;;
  40    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  41  esac],
  42               [enableval=no])
  43 if test "${enableval}" = yes; then
  44   BISON_WARNING(-Werror)
  45   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  46   WARNING_CFLAGS=
  47   BISON_WARNING(-Wall)
  48   BISON_WARNING(-W)
  49   BISON_WARNING(-Wbad-function-cast)
  50   BISON_WARNING(-Wcast-align)
  51   BISON_WARNING(-Wcast-qual)
  52   BISON_WARNING(-Wformat)
  53   BISON_WARNING(-Wmissing-declarations)
  54   BISON_WARNING(-Wmissing-prototypes)
  55   BISON_WARNING(-Wnested-externs)
  56   BISON_WARNING(-Wshadow)
  57   BISON_WARNING(-Wstrict-prototypes)
  58   BISON_WARNING(-Wwrite-strings)
  59 fi
  60
  61 # Checks for programs.
  62 AC_PROG_LEX
  63 AC_PROG_YACC
  64 AC_PROG_RANLIB
  65 BISON_PROG_GNU_M4
  66 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  67   AC_MSG_ERROR([GNU M4 1.4 is required])
  68 fi
  69 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  70
  71 # Checks for header files.
  72 AC_HEADER_STDC
  73 AC_CHECK_HEADERS([ctype.h locale.h memory.h stdlib.h string.h unistd.h])
  74 AC_HEADER_STDBOOL
  75
  76 # Checks for compiler characteristics.
  77 AC_C_INLINE
  78
  79 # Checks for library functions.
  80 AC_FUNC_ALLOCA
  81 AC_FUNC_OBSTACK
  82 AC_FUNC_ERROR_AT_LINE
  83 AC_FUNC_STRNLEN
  84 AC_CHECK_FUNCS(setlocale)
  85 AC_CHECK_DECLS([free, getenv, getopt,
  86                 stpcpy, strchr, strspn, strnlen,
  87                 malloc, memchr, memrchr])
  88 AC_REPLACE_FUNCS(memchr memrchr \
  89                  strchr stpcpy strrchr strspn strtol)
  90 AC_FUNC_MALLOC
  91 AC_FUNC_REALLOC
  92 jm_PREREQ_MBSWIDTH
  93 jm_PREREQ_QUOTEARG
  94 jm_FUNC_ARGMATCH
  95 jm_PREREQ_ERROR
  96 AM_WITH_DMALLOC
  97 BISON_PREREQ_SUBPIPE
  98 BISON_PREREQ_TIMEVAR
  99
 100 # Gettext.
 101 AM_GNU_GETTEXT(external, need-ngettext)
 102 AM_GNU_GETTEXT_VERSION(0.11.5)
 103
 104 # Initialize the test suite.
 105 AC_CONFIG_TESTDIR(tests)
 106 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 107 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 108 AC_CHECK_PROGS([VALGRIND], [valgrind])
 109 AC_CHECK_PROGS([GXX], [g++])
 110 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 111 # Needed by tests/atlocal.in.
 112 AC_SUBST([GCC])
 113 O0CFLAGS=`echo $CFLAGS | sed 's/-O[0-9] *//'`
 114 AC_SUBST([O0CFLAGS])
 115
 116 AC_CONFIG_FILES([Makefile
 117                  config/Makefile
 118                  po/Makefile.in
 119                  data/Makefile
 120                  lib/Makefile src/Makefile doc/Makefile
 121                  m4/Makefile])
 122 AC_OUTPUT