src/scan-gram.l

   1 /* Bison Grammar Scanner                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 %option debug nodefault nounput noyywrap never-interactive
  22 %option prefix="gram_" outfile="lex.yy.c"
  23
  24 %{
  25 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  26    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  27 #undef gram_wrap
  28 #define gram_wrap() 1
  29
  30 #define FLEX_PREFIX(Id) gram_ ## Id
  31 #include "flex-scanner.h"
  32
  33 #include "complain.h"
  34 #include "files.h"
  35 #include "gram.h"
  36 #include "quotearg.h"
  37 #include "reader.h"
  38 #include "uniqstr.h"
  39
  40 #include <mbswidth.h>
  41 #include <quote.h>
  42
  43 #include "scan-gram.h"
  44
  45 #define YY_DECL GRAM_LEX_DECL
  46
  47 #define YY_USER_INIT                                    \
  48    code_start = scanner_cursor = loc->start;            \
  49
  50 /* Location of scanner cursor.  */
  51 static boundary scanner_cursor;
  52
  53 #define YY_USER_ACTION  location_compute (loc, &scanner_cursor, yytext, yyleng);
  54
  55 static size_t no_cr_read (FILE *, char *, size_t);
  56 #define YY_INPUT(buf, result, size) ((result) = no_cr_read (yyin, buf, size))
  57
  58 /* A string representing the most recently saved token.  */
  59 static char *last_string;
  60
  61 void
  62 gram_scanner_last_string_free (void)
  63 {
  64   STRING_FREE;
  65 }
  66
  67 static void handle_syncline (char *, location);
  68 static unsigned long int scan_integer (char const *p, int base, location loc);
  69 static int convert_ucn_to_byte (char const *hex_text);
  70 static void unexpected_eof (boundary, char const *);
  71 static void unexpected_newline (boundary, char const *);
  72
  73 %}
  74  /* A C-like comment in directives/rules. */
  75 %x SC_YACC_COMMENT
  76  /* Strings and characters in directives/rules. */
  77 %x SC_ESCAPED_STRING SC_ESCAPED_CHARACTER
  78  /* A identifier was just read in directives/rules.  Special state
  79     to capture the sequence `identifier :'. */
  80 %x SC_AFTER_IDENTIFIER
  81
  82  /* Three types of user code:
  83     - prologue (code between `%{' `%}' in the first section, before %%);
  84     - actions, printers, union, etc, (between braced in the middle section);
  85     - epilogue (everything after the second %%). */
  86 %x SC_PROLOGUE SC_BRACED_CODE SC_EPILOGUE
  87  /* C and C++ comments in code. */
  88 %x SC_COMMENT SC_LINE_COMMENT
  89  /* Strings and characters in code. */
  90 %x SC_STRING SC_CHARACTER
  91
  92 letter    [.abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_]
  93 id        {letter}({letter}|[0-9])*
  94 directive %{letter}({letter}|[0-9]|-)*
  95 int       [0-9]+
  96
  97 /* POSIX says that a tag must be both an id and a C union member, but
  98    historically almost any character is allowed in a tag.  We disallow
  99    NUL and newline, as this simplifies our implementation.  */
 100 tag      [^\0\n>]+
 101
 102 /* Zero or more instances of backslash-newline.  Following GCC, allow
 103    white space between the backslash and the newline.  */
 104 splice   (\\[ \f\t\v]*\n)*
 105
 106 %%
 107 %{
 108   /* Nesting level of the current code in braces.  */
 109   int braces_level IF_LINT (= 0);
 110
 111   /* Parent context state, when applicable.  */
 112   int context_state IF_LINT (= 0);
 113
 114   /* Location of most recent identifier, when applicable.  */
 115   location id_loc IF_LINT (= empty_location);
 116
 117   /* Where containing code started, when applicable.  Its initial
 118      value is relevant only when yylex is invoked in the SC_EPILOGUE
 119      start condition.  */
 120   boundary code_start = scanner_cursor;
 121
 122   /* Where containing comment or string or character literal started,
 123      when applicable.  */
 124   boundary token_start IF_LINT (= scanner_cursor);
 125 %}
 126
 127
 128   /*-----------------------.
 129   | Scanning white space.  |
 130   `-----------------------*/
 131
 132 <INITIAL,SC_AFTER_IDENTIFIER>
 133 {
 134   /* Comments and white space.  */
 135   ","          warn_at (*loc, _("stray `,' treated as white space"));
 136   [ \f\n\t\v]  |
 137   "//".*       ;
 138   "/*" {
 139     token_start = loc->start;
 140     context_state = YY_START;
 141     BEGIN SC_YACC_COMMENT;
 142   }
 143
 144   /* #line directives are not documented, and may be withdrawn or
 145      modified in future versions of Bison.  */
 146   ^"#line "{int}" \"".*"\"\n" {
 147     handle_syncline (yytext + sizeof "#line " - 1, *loc);
 148   }
 149 }
 150
 151
 152   /*----------------------------.
 153   | Scanning Bison directives.  |
 154   `----------------------------*/
 155
 156   /* For directives that are also command line options, the regex must be
 157         "%..."
 158      after "[-_]"s are removed, and the directive must match the --long
 159      option name, with a single string argument.  Otherwise, add exceptions
 160      to ../build-aux/cross-options.pl.  */
 161
 162 <INITIAL>
 163 {
 164   "%binary"                         return PERCENT_NONASSOC;
 165   "%code"                           return PERCENT_CODE;
 166   "%debug"                          return PERCENT_DEBUG;
 167   "%default"[-_]"prec"              return PERCENT_DEFAULT_PREC;
 168   "%define"                         return PERCENT_DEFINE;
 169   "%defines"                        return PERCENT_DEFINES;
 170   "%destructor"                     return PERCENT_DESTRUCTOR;
 171   "%dprec"                          return PERCENT_DPREC;
 172   "%error"[-_]"verbose"             return PERCENT_ERROR_VERBOSE;
 173   "%expect"                         return PERCENT_EXPECT;
 174   "%expect"[-_]"rr"                 return PERCENT_EXPECT_RR;
 175   "%file-prefix"                    return PERCENT_FILE_PREFIX;
 176   "%fixed"[-_]"output"[-_]"files"   return PERCENT_YACC;
 177   "%initial-action"                 return PERCENT_INITIAL_ACTION;
 178   "%glr-parser"                     return PERCENT_GLR_PARSER;
 179   "%language"                       return PERCENT_LANGUAGE;
 180   "%left"                           return PERCENT_LEFT;
 181   "%lex-param"                      return PERCENT_LEX_PARAM;
 182   "%locations"                      return PERCENT_LOCATIONS;
 183   "%merge"                          return PERCENT_MERGE;
 184   "%name"[-_]"prefix"               return PERCENT_NAME_PREFIX;
 185   "%no"[-_]"default"[-_]"prec"      return PERCENT_NO_DEFAULT_PREC;
 186   "%no"[-_]"lines"                  return PERCENT_NO_LINES;
 187   "%nonassoc"                       return PERCENT_NONASSOC;
 188   "%nondeterministic-parser"        return PERCENT_NONDETERMINISTIC_PARSER;
 189   "%nterm"                          return PERCENT_NTERM;
 190   "%output"                         return PERCENT_OUTPUT;
 191   "%parse-param"                    return PERCENT_PARSE_PARAM;
 192   "%prec"                           return PERCENT_PREC;
 193   "%printer"                        return PERCENT_PRINTER;
 194   "%pure"[-_]"parser"               return PERCENT_PURE_PARSER;
 195   "%require"                        return PERCENT_REQUIRE;
 196   "%right"                          return PERCENT_RIGHT;
 197   "%skeleton"                       return PERCENT_SKELETON;
 198   "%start"                          return PERCENT_START;
 199   "%term"                           return PERCENT_TOKEN;
 200   "%token"                          return PERCENT_TOKEN;
 201   "%token"[-_]"table"               return PERCENT_TOKEN_TABLE;
 202   "%type"                           return PERCENT_TYPE;
 203   "%union"                          return PERCENT_UNION;
 204   "%verbose"                        return PERCENT_VERBOSE;
 205   "%yacc"                           return PERCENT_YACC;
 206
 207   {directive} {
 208     complain_at (*loc, _("invalid directive: %s"), quote (yytext));
 209   }
 210
 211   "="                     return EQUAL;
 212   "|"                     return PIPE;
 213   ";"                     return SEMICOLON;
 214   "<*>"                   return TYPE_TAG_ANY;
 215   "<>"                    return TYPE_TAG_NONE;
 216
 217   {id} {
 218     val->uniqstr = uniqstr_new (yytext);
 219     id_loc = *loc;
 220     BEGIN SC_AFTER_IDENTIFIER;
 221   }
 222
 223   {int} {
 224     val->integer = scan_integer (yytext, 10, *loc);
 225     return INT;
 226   }
 227   0[xX][0-9abcdefABCDEF]+ {
 228     val->integer = scan_integer (yytext, 16, *loc);
 229     return INT;
 230   }
 231
 232   /* Characters.  We don't check there is only one.  */
 233   "'"         STRING_GROW; token_start = loc->start; BEGIN SC_ESCAPED_CHARACTER;
 234
 235   /* Strings. */
 236   "\""        token_start = loc->start; BEGIN SC_ESCAPED_STRING;
 237
 238   /* Prologue. */
 239   "%{"        code_start = loc->start; BEGIN SC_PROLOGUE;
 240
 241   /* Code in between braces.  */
 242   "{" {
 243     STRING_GROW;
 244     braces_level = 0;
 245     code_start = loc->start;
 246     BEGIN SC_BRACED_CODE;
 247   }
 248
 249   /* A type. */
 250   "<"{tag}">" {
 251     obstack_grow (&obstack_for_string, yytext + 1, yyleng - 2);
 252     STRING_FINISH;
 253     val->uniqstr = uniqstr_new (last_string);
 254     STRING_FREE;
 255     return TYPE;
 256   }
 257
 258   "%%" {
 259     static int percent_percent_count;
 260     if (++percent_percent_count == 2)
 261       BEGIN SC_EPILOGUE;
 262     return PERCENT_PERCENT;
 263   }
 264
 265   . {
 266     complain_at (*loc, _("invalid character: %s"), quote (yytext));
 267   }
 268
 269   <<EOF>> {
 270     loc->start = loc->end = scanner_cursor;
 271     yyterminate ();
 272   }
 273 }
 274
 275
 276   /*-----------------------------------------------------------------.
 277   | Scanning after an identifier, checking whether a colon is next.  |
 278   `-----------------------------------------------------------------*/
 279
 280 <SC_AFTER_IDENTIFIER>
 281 {
 282   ":" {
 283     *loc = id_loc;
 284     BEGIN INITIAL;
 285     return ID_COLON;
 286   }
 287   . {
 288     scanner_cursor.column -= mbsnwidth (yytext, yyleng, 0);
 289     yyless (0);
 290     *loc = id_loc;
 291     BEGIN INITIAL;
 292     return ID;
 293   }
 294   <<EOF>> {
 295     *loc = id_loc;
 296     BEGIN INITIAL;
 297     return ID;
 298   }
 299 }
 300
 301
 302   /*---------------------------------------------------------------.
 303   | Scanning a Yacc comment.  The initial `/ *' is already eaten.  |
 304   `---------------------------------------------------------------*/
 305
 306 <SC_YACC_COMMENT>
 307 {
 308   "*/"     BEGIN context_state;
 309   .|\n     ;
 310   <<EOF>>  unexpected_eof (token_start, "*/"); BEGIN context_state;
 311 }
 312
 313
 314   /*------------------------------------------------------------.
 315   | Scanning a C comment.  The initial `/ *' is already eaten.  |
 316   `------------------------------------------------------------*/
 317
 318 <SC_COMMENT>
 319 {
 320   "*"{splice}"/"  STRING_GROW; BEGIN context_state;
 321   <<EOF>>         unexpected_eof (token_start, "*/"); BEGIN context_state;
 322 }
 323
 324
 325   /*--------------------------------------------------------------.
 326   | Scanning a line comment.  The initial `//' is already eaten.  |
 327   `--------------------------------------------------------------*/
 328
 329 <SC_LINE_COMMENT>
 330 {
 331   "\n"           STRING_GROW; BEGIN context_state;
 332   {splice}       STRING_GROW;
 333   <<EOF>>        BEGIN context_state;
 334 }
 335
 336
 337   /*------------------------------------------------.
 338   | Scanning a Bison string, including its escapes. |
 339   | The initial quote is already eaten.             |
 340   `------------------------------------------------*/
 341
 342 <SC_ESCAPED_STRING>
 343 {
 344   "\""|"\n" {
 345     if (yytext[0] == '\n')
 346       unexpected_newline (token_start, "\"");
 347     STRING_FINISH;
 348     loc->start = token_start;
 349     val->chars = last_string;
 350     BEGIN INITIAL;
 351     return STRING;
 352   }
 353   <<EOF>> {
 354     unexpected_eof (token_start, "\"");
 355     STRING_FINISH;
 356     loc->start = token_start;
 357     val->chars = last_string;
 358     BEGIN INITIAL;
 359     return STRING;
 360   }
 361 }
 362
 363   /*----------------------------------------------------------.
 364   | Scanning a Bison character literal, decoding its escapes. |
 365   | The initial quote is already eaten.                       |
 366   `----------------------------------------------------------*/
 367
 368 <SC_ESCAPED_CHARACTER>
 369 {
 370   "'"|"\n" {
 371     if (yytext[0] == '\n')
 372       unexpected_newline (token_start, "'");
 373     STRING_GROW;
 374     STRING_FINISH;
 375     loc->start = token_start;
 376     val->character = last_string[1];
 377     STRING_FREE;
 378     BEGIN INITIAL;
 379     return CHAR;
 380   }
 381   <<EOF>> {
 382     unexpected_eof (token_start, "'");
 383     STRING_FINISH;
 384     loc->start = token_start;
 385     if (strlen(last_string) > 1)
 386       val->character = last_string[1];
 387     else
 388       val->character = last_string[0];
 389     STRING_FREE;
 390     BEGIN INITIAL;
 391     return CHAR;
 392   }
 393 }
 394
 395 <SC_ESCAPED_CHARACTER,SC_ESCAPED_STRING>
 396 {
 397   \0        complain_at (*loc, _("invalid null character"));
 398 }
 399
 400
 401   /*----------------------------.
 402   | Decode escaped characters.  |
 403   `----------------------------*/
 404
 405 <SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>
 406 {
 407   \\[0-7]{1,3} {
 408     unsigned long int c = strtoul (yytext + 1, NULL, 8);
 409     if (UCHAR_MAX < c)
 410       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 411     else if (! c)
 412       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 413     else
 414       obstack_1grow (&obstack_for_string, c);
 415   }
 416
 417   \\x[0-9abcdefABCDEF]+ {
 418     verify (UCHAR_MAX < ULONG_MAX);
 419     unsigned long int c = strtoul (yytext + 2, NULL, 16);
 420     if (UCHAR_MAX < c)
 421       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 422     else if (! c)
 423       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 424     else
 425       obstack_1grow (&obstack_for_string, c);
 426   }
 427
 428   \\a   obstack_1grow (&obstack_for_string, '\a');
 429   \\b   obstack_1grow (&obstack_for_string, '\b');
 430   \\f   obstack_1grow (&obstack_for_string, '\f');
 431   \\n   obstack_1grow (&obstack_for_string, '\n');
 432   \\r   obstack_1grow (&obstack_for_string, '\r');
 433   \\t   obstack_1grow (&obstack_for_string, '\t');
 434   \\v   obstack_1grow (&obstack_for_string, '\v');
 435
 436   /* \\[\"\'?\\] would be shorter, but it confuses xgettext.  */
 437   \\("\""|"'"|"?"|"\\")  obstack_1grow (&obstack_for_string, yytext[1]);
 438
 439   \\(u|U[0-9abcdefABCDEF]{4})[0-9abcdefABCDEF]{4} {
 440     int c = convert_ucn_to_byte (yytext);
 441     if (c < 0)
 442       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 443     else if (! c)
 444       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 445     else
 446       obstack_1grow (&obstack_for_string, c);
 447   }
 448   \\(.|\n)      {
 449     complain_at (*loc, _("unrecognized escape sequence: %s"), quote (yytext));
 450     STRING_GROW;
 451   }
 452 }
 453
 454   /*--------------------------------------------.
 455   | Scanning user-code characters and strings.  |
 456   `--------------------------------------------*/
 457
 458 <SC_CHARACTER,SC_STRING>
 459 {
 460   {splice}|\\{splice}[^\n\[\]]  STRING_GROW;
 461 }
 462
 463 <SC_CHARACTER>
 464 {
 465   "'"           STRING_GROW; BEGIN context_state;
 466   \n            unexpected_newline (token_start, "'"); BEGIN context_state;
 467   <<EOF>>       unexpected_eof (token_start, "'"); BEGIN context_state;
 468 }
 469
 470 <SC_STRING>
 471 {
 472   "\""          STRING_GROW; BEGIN context_state;
 473   \n            unexpected_newline (token_start, "\""); BEGIN context_state;
 474   <<EOF>>       unexpected_eof (token_start, "\""); BEGIN context_state;
 475 }
 476
 477
 478   /*---------------------------------------------------.
 479   | Strings, comments etc. can be found in user code.  |
 480   `---------------------------------------------------*/
 481
 482 <SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>
 483 {
 484   "'" {
 485     STRING_GROW;
 486     context_state = YY_START;
 487     token_start = loc->start;
 488     BEGIN SC_CHARACTER;
 489   }
 490   "\"" {
 491     STRING_GROW;
 492     context_state = YY_START;
 493     token_start = loc->start;
 494     BEGIN SC_STRING;
 495   }
 496   "/"{splice}"*" {
 497     STRING_GROW;
 498     context_state = YY_START;
 499     token_start = loc->start;
 500     BEGIN SC_COMMENT;
 501   }
 502   "/"{splice}"/" {
 503     STRING_GROW;
 504     context_state = YY_START;
 505     BEGIN SC_LINE_COMMENT;
 506   }
 507 }
 508
 509
 510
 511   /*-----------------------------------------------------------.
 512   | Scanning some code in braces (actions). The initial "{" is |
 513   | already eaten.                                             |
 514   `-----------------------------------------------------------*/
 515
 516 <SC_BRACED_CODE>
 517 {
 518   "{"|"<"{splice}"%"  STRING_GROW; braces_level++;
 519   "%"{splice}">"      STRING_GROW; braces_level--;
 520   "}" {
 521     obstack_1grow (&obstack_for_string, '}');
 522
 523     --braces_level;
 524     if (braces_level < 0)
 525       {
 526         STRING_FINISH;
 527         loc->start = code_start;
 528         val->code = last_string;
 529         BEGIN INITIAL;
 530         return BRACED_CODE;
 531       }
 532   }
 533
 534   /* Tokenize `<<%' correctly (as `<<' `%') rather than incorrrectly
 535      (as `<' `<%').  */
 536   "<"{splice}"<"  STRING_GROW;
 537
 538   <<EOF>> {
 539     unexpected_eof (code_start, "}");
 540     STRING_FINISH;
 541     loc->start = code_start;
 542     val->code = last_string;
 543     BEGIN INITIAL;
 544     return BRACED_CODE;
 545   }
 546 }
 547
 548
 549   /*--------------------------------------------------------------.
 550   | Scanning some prologue: from "%{" (already scanned) to "%}".  |
 551   `--------------------------------------------------------------*/
 552
 553 <SC_PROLOGUE>
 554 {
 555   "%}" {
 556     STRING_FINISH;
 557     loc->start = code_start;
 558     val->chars = last_string;
 559     BEGIN INITIAL;
 560     return PROLOGUE;
 561   }
 562
 563   <<EOF>> {
 564     unexpected_eof (code_start, "%}");
 565     STRING_FINISH;
 566     loc->start = code_start;
 567     val->chars = last_string;
 568     BEGIN INITIAL;
 569     return PROLOGUE;
 570   }
 571 }
 572
 573
 574   /*---------------------------------------------------------------.
 575   | Scanning the epilogue (everything after the second "%%", which |
 576   | has already been eaten).                                       |
 577   `---------------------------------------------------------------*/
 578
 579 <SC_EPILOGUE>
 580 {
 581   <<EOF>> {
 582     STRING_FINISH;
 583     loc->start = code_start;
 584     val->chars = last_string;
 585     BEGIN INITIAL;
 586     return EPILOGUE;
 587   }
 588 }
 589
 590
 591   /*-----------------------------------------------------.
 592   | By default, grow the string obstack with the input.  |
 593   `-----------------------------------------------------*/
 594
 595 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE,SC_STRING,SC_CHARACTER,SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>.      |
 596 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>\n   STRING_GROW;
 597
 598 %%
 599
 600 /* Read bytes from FP into buffer BUF of size SIZE.  Return the
 601    number of bytes read.  Remove '\r' from input, treating \r\n
 602    and isolated \r as \n.  */
 603
 604 static size_t
 605 no_cr_read (FILE *fp, char *buf, size_t size)
 606 {
 607   size_t bytes_read = fread (buf, 1, size, fp);
 608   if (bytes_read)
 609     {
 610       char *w = memchr (buf, '\r', bytes_read);
 611       if (w)
 612         {
 613           char const *r = ++w;
 614           char const *lim = buf + bytes_read;
 615
 616           for (;;)
 617             {
 618               /* Found an '\r'.  Treat it like '\n', but ignore any
 619                  '\n' that immediately follows.  */
 620               w[-1] = '\n';
 621               if (r == lim)
 622                 {
 623                   int ch = getc (fp);
 624                   if (ch != '\n' && ungetc (ch, fp) != ch)
 625                     break;
 626                 }
 627               else if (*r == '\n')
 628                 r++;
 629
 630               /* Copy until the next '\r'.  */
 631               do
 632                 {
 633                   if (r == lim)
 634                     return w - buf;
 635                 }
 636               while ((*w++ = *r++) != '\r');
 637             }
 638
 639           return w - buf;
 640         }
 641     }
 642
 643   return bytes_read;
 644 }
 645
 646
 647
 648 /*------------------------------------------------------.
 649 | Scan NUMBER for a base-BASE integer at location LOC.  |
 650 `------------------------------------------------------*/
 651
 652 static unsigned long int
 653 scan_integer (char const *number, int base, location loc)
 654 {
 655   verify (INT_MAX < ULONG_MAX);
 656   unsigned long int num = strtoul (number, NULL, base);
 657
 658   if (INT_MAX < num)
 659     {
 660       complain_at (loc, _("integer out of range: %s"), quote (number));
 661       num = INT_MAX;
 662     }
 663
 664   return num;
 665 }
 666
 667
 668 /*------------------------------------------------------------------.
 669 | Convert universal character name UCN to a single-byte character,  |
 670 | and return that character.  Return -1 if UCN does not correspond  |
 671 | to a single-byte character.                                       |
 672 `------------------------------------------------------------------*/
 673
 674 static int
 675 convert_ucn_to_byte (char const *ucn)
 676 {
 677   verify (UCHAR_MAX <= INT_MAX);
 678   unsigned long int code = strtoul (ucn + 2, NULL, 16);
 679
 680   /* FIXME: Currently we assume Unicode-compatible unibyte characters
 681      on ASCII hosts (i.e., Latin-1 on hosts with 8-bit bytes).  On
 682      non-ASCII hosts we support only the portable C character set.
 683      These limitations should be removed once we add support for
 684      multibyte characters.  */
 685
 686   if (UCHAR_MAX < code)
 687     return -1;
 688
 689 #if ! ('$' == 0x24 && '@' == 0x40 && '`' == 0x60 && '~' == 0x7e)
 690   {
 691     /* A non-ASCII host.  Use CODE to index into a table of the C
 692        basic execution character set, which is guaranteed to exist on
 693        all Standard C platforms.  This table also includes '$', '@',
 694        and '`', which are not in the basic execution character set but
 695        which are unibyte characters on all the platforms that we know
 696        about.  */
 697     static signed char const table[] =
 698       {
 699         '\0',   -1,   -1,   -1,   -1,   -1,   -1, '\a',
 700         '\b', '\t', '\n', '\v', '\f', '\r',   -1,   -1,
 701           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 702           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 703          ' ',  '!',  '"',  '#',  '$',  '%',  '&', '\'',
 704          '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
 705          '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
 706          '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
 707          '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
 708          'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
 709          'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
 710          'X',  'Y',  'Z',  '[', '\\',  ']',  '^',  '_',
 711          '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
 712          'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
 713          'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
 714          'x',  'y',  'z',  '{',  '|',  '}',  '~'
 715       };
 716
 717     code = code < sizeof table ? table[code] : -1;
 718   }
 719 #endif
 720
 721   return code;
 722 }
 723
 724
 725 /*----------------------------------------------------------------.
 726 | Handle `#line INT "FILE"'.  ARGS has already skipped `#line '.  |
 727 `----------------------------------------------------------------*/
 728
 729 static void
 730 handle_syncline (char *args, location loc)
 731 {
 732   char *after_num;
 733   unsigned long int lineno = strtoul (args, &after_num, 10);
 734   char *file = strchr (after_num, '"') + 1;
 735   *strchr (file, '"') = '\0';
 736   if (INT_MAX <= lineno)
 737     {
 738       warn_at (loc, _("line number overflow"));
 739       lineno = INT_MAX;
 740     }
 741   current_file = uniqstr_new (file);
 742   boundary_set (&scanner_cursor, current_file, lineno, 1);
 743 }
 744
 745
 746 /*----------------------------------------------------------------.
 747 | For a token or comment starting at START, report message MSGID, |
 748 | which should say that an end marker was found before            |
 749 | the expected TOKEN_END.                                         |
 750 `----------------------------------------------------------------*/
 751
 752 static void
 753 unexpected_end (boundary start, char const *msgid, char const *token_end)
 754 {
 755   location loc;
 756   loc.start = start;
 757   loc.end = scanner_cursor;
 758   complain_at (loc, _(msgid), token_end);
 759 }
 760
 761
 762 /*------------------------------------------------------------------------.
 763 | Report an unexpected EOF in a token or comment starting at START.       |
 764 | An end of file was encountered and the expected TOKEN_END was missing.  |
 765 `------------------------------------------------------------------------*/
 766
 767 static void
 768 unexpected_eof (boundary start, char const *token_end)
 769 {
 770   unexpected_end (start, N_("missing `%s' at end of file"), token_end);
 771 }
 772
 773
 774 /*----------------------------------------.
 775 | Likewise, but for unexpected newlines.  |
 776 `----------------------------------------*/
 777
 778 static void
 779 unexpected_newline (boundary start, char const *token_end)
 780 {
 781   unexpected_end (start, N_("missing `%s' at end of line"), token_end);
 782 }
 783
 784
 785 /*-------------------------.
 786 | Initialize the scanner.  |
 787 `-------------------------*/
 788
 789 void
 790 gram_scanner_initialize (void)
 791 {
 792   obstack_init (&obstack_for_string);
 793 }
 794
 795
 796 /*-----------------------------------------------.
 797 | Free all the memory allocated to the scanner.  |
 798 `-----------------------------------------------*/
 799
 800 void
 801 gram_scanner_free (void)
 802 {
 803   obstack_free (&obstack_for_string, 0);
 804   /* Reclaim Flex's buffers.  */
 805   yylex_destroy ();
 806 }