tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  41 # ------------------------------------------------
  42 # Don't interfere with caller's files.
  43 m4_divert_text([PREPARE_TESTS],
  44 [at_save_special_files ()
  45 {
  46   for at_save_file in stderr experr expout
  47   do
  48     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  49   done
  50 }
  51
  52 at_restore_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       mv at-bison-check-$at_save_file.bak $at_save_file
  58   done
  59 }
  60 ])
  61
  62 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  63 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  64
  65
  66
  67 ## ------------------------------- ##
  68 ## Macros decoding Bison options.  ##
  69 ## ------------------------------- ##
  70
  71 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  72 # ----------------------------------------------------------------
  73 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  74 m4_define([AT_LOC_PUSHDEF],
  75 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  76 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  77 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  78 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  79
  80 # AT_LOC_POPDEF
  81 # -------------
  82 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  83 m4_define([AT_LOC_POPDEF],
  84 [m4_popdef([AT_LOC_FIRST_LINE])
  85 m4_popdef([AT_LOC_FIRST_COLUMN])
  86 m4_popdef([AT_LOC_LAST_LINE])
  87 m4_popdef([AT_LOC_LAST_COLUMN])])
  88
  89
  90
  91 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  92 # -----------------------------------------
  93 m4_define([AT_BISON_OPTION_PUSHDEFS],
  94 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  95
  96
  97 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  98 # --------------------------------------------------
  99 # This macro works around the impossibility to define macros
 100 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 101 # This sucks hard, GNU M4 should really provide M5 like $$1.
 102 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 103 [m4_if([$1$2], $[1]$[2], [],
 104        [m4_fatal([$0: Invalid arguments: $@])])dnl
 105 m4_pushdef([AT_DEFINES_IF],
 106 [m4_bmatch([$3], [%defines], [$1], [$2])])
 107 m4_pushdef([AT_SKEL_CC_IF],
 108 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 109 m4_pushdef([AT_SKEL_JAVA_IF],
 110 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 111 m4_pushdef([AT_GLR_IF],
 112 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
 113 m4_pushdef([AT_LALR1_CC_IF],
 114 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 115 m4_pushdef([AT_GLR_CC_IF],
 116 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 117 # Using yacc.c?
 118 m4_pushdef([AT_YACC_IF],
 119 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 120 m4_pushdef([AT_LEXPARAM_IF],
 121 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 122 m4_pushdef([AT_LOCATION_IF],
 123 [m4_bmatch([$3], [%locations], [$1], [$2])])
 124 m4_pushdef([AT_LOCATION_TYPE_IF],
 125 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 126 m4_pushdef([AT_PARAM_IF],
 127 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 128 m4_pushdef([AT_PURE_IF],
 129 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 130            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 131            [$2])])
 132 m4_pushdef([AT_PURE_AND_LOC_IF],
 133 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 134 m4_pushdef([AT_GLR_OR_PARAM_IF],
 135 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 136 m4_pushdef([AT_NAME_PREFIX],
 137 [m4_bmatch([$3], [%name-prefix ".*"],
 138            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 139            [yy])])
 140 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 141 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 142 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 143                     [$2])])
 144 # yyerror always sees the locations (when activated), except if
 145 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 146 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 147 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 148                                         [$1])],
 149                             [$1])],
 150                 [$2])])
 151
 152 # The interface is pure: either because %define api.pure, or because we
 153 # are using the C++ parsers.
 154 m4_pushdef([AT_PURE_LEX_IF],
 155 [AT_PURE_IF([$1],
 156             [AT_SKEL_CC_IF([$1], [$2])])])
 157
 158 AT_PURE_LEX_IF(
 159 [m4_pushdef([AT_LOC], [(*llocp)])
 160  m4_pushdef([AT_VAL], [(*lvalp)])
 161  m4_pushdef([AT_LEX_FORMALS],
 162             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 163  m4_pushdef([AT_LEX_ARGS],
 164             [lvalp[]AT_LOCATION_IF([, llocp])])
 165  m4_pushdef([AT_USE_LEX_ARGS],
 166             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 167  m4_pushdef([AT_LEX_PRE_FORMALS],
 168             [AT_LEX_FORMALS, ])
 169  m4_pushdef([AT_LEX_PRE_ARGS],
 170             [AT_LEX_ARGS, ])
 171 ],
 172 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 173  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 174  m4_pushdef([AT_LEX_FORMALS],     [void])
 175  m4_pushdef([AT_LEX_ARGS],        [])
 176  m4_pushdef([AT_USE_LEX_ARGS],    [])
 177  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 178  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 179 ])
 180
 181 # Handle the different types of location components.
 182
 183 AT_SKEL_CC_IF(
 184   [AT_LOCATION_TYPE_IF(
 185     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 186     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 187   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 188
 189 ])# _AT_BISON_OPTION_PUSHDEFS
 190
 191
 192 # AT_BISON_OPTION_POPDEFS
 193 # -----------------------
 194 m4_define([AT_BISON_OPTION_POPDEFS],
 195 [m4_popdef([AT_LEX_PRE_ARGS])
 196 m4_popdef([AT_LEX_PRE_FORMALS])
 197 m4_popdef([AT_USE_LEX_ARGS])
 198 m4_popdef([AT_LEX_ARGS])
 199 m4_popdef([AT_LEX_FORMALS])
 200 m4_popdef([AT_VAL])
 201 m4_popdef([AT_LOC])
 202 m4_popdef([AT_PURE_LEX_IF])
 203 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 204 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 205 m4_popdef([AT_NAME_PREFIX])
 206 m4_popdef([AT_GLR_OR_PARAM_IF])
 207 m4_popdef([AT_PURE_AND_LOC_IF])
 208 m4_popdef([AT_LOCATION_TYPE_IF])
 209 m4_popdef([AT_LOCATION_IF])
 210 m4_popdef([AT_PARAM_IF])
 211 m4_popdef([AT_LEXPARAM_IF])
 212 m4_popdef([AT_YACC_IF])
 213 m4_popdef([AT_GLR_IF])
 214 m4_popdef([AT_SKEL_CC_IF])
 215 m4_popdef([AT_SKEL_JAVA_IF])
 216 m4_popdef([AT_GLR_CC_IF])
 217 m4_popdef([AT_LALR1_CC_IF])
 218 m4_popdef([AT_DEFINES_IF])
 219 AT_LOC_POPDEF
 220 ])# AT_BISON_OPTION_POPDEFS
 221
 222
 223
 224 ## -------------------------- ##
 225 ## Generating Grammar Files.  ##
 226 ## -------------------------- ##
 227
 228 # AT_DATA_SOURCE_PROLOGUE
 229 # ------------------------
 230 # The prologue that should be included in any source code that is
 231 # meant to be compiled.
 232 m4_define([AT_DATA_SOURCE_PROLOGUE],
 233 [[#include <config.h>
 234 /* We don't need perfect functions for these tests. */
 235 #undef malloc
 236 #undef memcmp
 237 #undef realloc
 238 ]])
 239
 240 # AT_DATA_GRAMMAR_PROLOGUE
 241 # ------------------------
 242 # The prologue that should be included in any grammar which parser is
 243 # meant to be compiled.
 244 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 245 [[%code top {
 246 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 247 [}
 248 ]])
 249
 250 # AT_DATA_SOURCE(NAME, CONTENT)
 251 # -----------------------------
 252 # Generate the file NAME, which CONTENT is preceded by
 253 # AT_DATA_SOURCE_PROLOGUE.
 254 m4_define([AT_DATA_SOURCE],
 255 [AT_DATA([$1],
 256 [AT_DATA_SOURCE_PROLOGUE
 257 $2])
 258 ])
 259
 260 # AT_DATA_GRAMMAR(NAME, CONTENT)
 261 # ------------------------------
 262 # Generate the file NAME, which CONTENT is preceded by
 263 # AT_DATA_GRAMMAR_PROLOGUE.
 264 m4_define([AT_DATA_GRAMMAR],
 265 [AT_DATA([$1],
 266 [AT_DATA_GRAMMAR_PROLOGUE
 267 $2])
 268 ])
 269
 270 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 271 # -------------------------------------------------
 272 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 273 # shell constructs (such as redirection or pipes) that would prevent
 274 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 275 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 276 #
 277 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 278 # Bison in the test suite.  For now it ensures that:
 279 #
 280 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 281 #      a non-zero exit status since Bison doesn't always try to free all memory
 282 #      in that case.
 283 #
 284 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 285 #      --graph and --report=all output for every working grammar.
 286 #
 287 #   3. If stderr contains a warning, -Werror and --warnings=error
 288 #      convert the warning to an error.
 289 #
 290 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 291 m4_define([AT_BISON_CHECK],
 292 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 293        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 294 AT_BISON_CHECK_NO_XML($@)])
 295
 296 m4_define([AT_BISON_WERROR_MSG],
 297           [[bison: warnings being treated as errors]])
 298
 299 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 300 # --------------------------------------------------------
 301 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 302 # when a tortured grammar's XML is known to be too large for xsltproc to
 303 # handle.
 304 m4_define([AT_BISON_CHECK_NO_XML],
 305 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 306                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 307 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 308       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 309         # Defining POSIXLY_CORRECT causes bison to complain if options
 310         # are added after the grammar file name, so skip these checks
 311         # in that case.
 312         if test -z "${POSIXLY_CORRECT+set}"; then
 313           ]AT_SAVE_SPECIAL_FILES[
 314
 315           # To avoid expanding it repeatedly, store specified stdout.
 316           ]AT_DATA([expout], [$3])[
 317
 318           # Run with -Werror.
 319           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 320                     [[1]], [expout], [stderr])[
 321
 322           # Build expected stderr up to and including the "warnings being
 323           # treated as errors" message.
 324           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 325           at_bison_check_first=`sed -n \
 326             '/: warning: /{=;q;}' at-bison-check-warnings`
 327           : ${at_bison_check_first:=1}
 328           at_bison_check_first_tmp=`sed -n \
 329             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 330           : ${at_bison_check_first_tmp:=1}
 331           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 332             at_bison_check_first=$at_bison_check_first_tmp
 333           fi
 334           if test $at_bison_check_first -gt 1; then
 335             sed -n "1,`expr $at_bison_check_first - 1`"p \
 336               at-bison-check-warnings > experr
 337           fi
 338           echo ']AT_BISON_WERROR_MSG[' >> experr
 339
 340           # Finish building expected stderr and check.  Unlike warnings,
 341           # complaints cause bison to exit early.  Thus, with -Werror, bison
 342           # does not necessarily report all warnings that it does without
 343           # -Werror, but it at least reports one.
 344           at_bison_check_last=`sed -n '$=' stderr`
 345           : ${at_bison_check_last:=1}
 346           at_bison_check_last=`expr $at_bison_check_last - 1`
 347           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 348             at-bison-check-warnings >> experr
 349           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 350                       stderr 1>&2]], [[0]], [[]], [experr])[
 351
 352           # Now check --warnings=error.
 353           cp stderr experr
 354           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 355                     [[1]], [expout], [experr])[
 356
 357           # Now check -Wnone and --warnings=none by making sure that
 358           # -Werror doesn't change the exit status when -Wnone or
 359           # --warnings=none is specified.
 360           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 361                     [[0]], [expout])[
 362           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 363                     -Werror]], [[0]], [expout])[
 364
 365           ]AT_RESTORE_SPECIAL_FILES[
 366         fi
 367       ]])
 368 ])
 369
 370 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 371 # -----------------------------------------------------
 372 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 373 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 374 # have a non-zero exit status.
 375 m4_define([AT_BISON_CHECK_XML],
 376 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 377   AT_SAVE_SPECIAL_FILES
 378   [mkdir xml-tests]
 379   m4_pushdef([AT_BISON_ARGS],
 380              [m4_bpatsubsts([[$1]],
 381                             [--report(-file)?=[^][ ]*], [],
 382                             [--graph=[^][ ]*], [],
 383                             [--xml=[^][ ]*], [])])dnl
 384   # Don't combine these Bison invocations since we want to be sure that
 385   # --report=all isn't required to get the full XML file.
 386   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 387              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 388            [[0]], [ignore], [ignore])
 389   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 390            [[0]], [ignore], [ignore])
 391   m4_popdef([AT_BISON_ARGS])dnl
 392   [cp xml-tests/test.output expout]
 393   AT_CHECK([[$XSLTPROC \
 394              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 395              xml-tests/test.xml]], [[0]], [expout])
 396   [cp xml-tests/test.dot expout]
 397   AT_CHECK([[$XSLTPROC \
 398              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 399              xml-tests/test.xml]], [[0]], [expout])
 400   [rm -rf xml-tests expout]
 401   AT_RESTORE_SPECIAL_FILES
 402 [fi]])
 403
 404 # AT_QUELL_VALGRIND
 405 # -----------------
 406 # Put this before a Bison invocation to keep Valgrind from complaining about
 407 # reachable memory.
 408 #
 409 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 410 # The triple quoting below will cause test cases to fail if you do.  If you do
 411 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 412 # will then fail to shell-escape its contents when attempting to print them.
 413 # The testsuite verbose output, at least, will be incorrect, but nothing may
 414 # fail to make sure you notice.
 415 m4_define([AT_QUELL_VALGRIND],
 416 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 417
 418 ## ------------------------ ##
 419 ## Compiling C, C++ Files.  ##
 420 ## ------------------------ ##
 421
 422
 423 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 424 # ----------------------------------------
 425 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 426 # assume that we are linking too; this is a hack.
 427 m4_define([AT_COMPILE],
 428 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 429            0, [ignore], [ignore])])
 430
 431 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 432 # --------------------------------------------
 433 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 434 # assume that we are linking too; this is a hack.
 435 # If the C++ compiler does not work, ignore the test.
 436 m4_define([AT_COMPILE_CXX],
 437 [AT_KEYWORDS(c++)
 438 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 439 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 440          0, [ignore], [ignore])])
 441
 442 # AT_JAVA_COMPILE(SOURCES)
 443 # ------------------------
 444 # Compile SOURCES into Java class files.  Skip the test if java or javac
 445 # is not installed.
 446 m4_define([AT_JAVA_COMPILE],
 447 [AT_KEYWORDS(java)
 448 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 449            test -n "$CONF_JAVAC" || exit 77]])
 450 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 451          [[0]], [ignore], [ignore])])
 452
 453 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 454 # -------------------------------------------
 455 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 456 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 457 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 458 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 459 # AT_SKEL_JAVA_IF.
 460 m4_define([AT_FULL_COMPILE], [
 461   AT_SKEL_JAVA_IF([
 462     AT_BISON_CHECK([-o $1.java $1.y])
 463     AT_JAVA_COMPILE([$1.java],
 464                     m4_join([ ],
 465                             [$1.java],
 466                             m4_ifval($2, [[$1-$2.java]]),
 467                             m4_ifval($3, [[$1-$3.java]])))
 468   ], [
 469     AT_SKEL_CC_IF([
 470       AT_BISON_CHECK([-o $1.cc $1.y])
 471       AT_COMPILE_CXX([$1],
 472                      m4_join([ ],
 473                              [$1.cc],
 474                              m4_ifval($2, [[$1-$2.cc]]),
 475                              m4_ifval($3, [[$1-$3.cc]])))
 476     ], [
 477       AT_BISON_CHECK([-o $1.c $1.y])
 478       AT_COMPILE([$1],
 479                   m4_join([ ],
 480                           [$1.c],
 481                           m4_ifval($2, [[$1-$2.c]]),
 482                           m4_ifval($3, [[$1-$3.c]])))
 483     ])
 484   ])
 485 ])
 486
 487
 488 ## ---------------------------- ##
 489 ## Running a generated parser.  ##
 490 ## ---------------------------- ##
 491
 492
 493 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 494 # ------------------------------------------------------------
 495 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 496 #
 497 # Get rid of spurious messages when compiled with --coverage:
 498 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 499 m4_define([AT_PARSER_CHECK],
 500 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 501 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 502          [0], [], [$4])
 503 ])
 504
 505
 506 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 507 # -----------------------------------------------------------------
 508 m4_define([AT_JAVA_PARSER_CHECK],
 509 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 510
 511
 512 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 513 #                          DECLS, GRAMMAR, INPUT,
 514 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 515 #                          [OTHER-CHECKS],
 516 #                          [PARSER-EXIT-VALUE],
 517 #                          [PARSER-STDOUT], [PARSER-STDERR])
 518 # -------------------------------------------------------------
 519 # Using TITLE as the test group title, check the generated parser tables
 520 # and parser for a specified grammar file under a condition labeled by
 521 # COND-VALUE.
 522 #
 523 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 524 # recognized attribute is described below where it is relevant.
 525 #
 526 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 527 # the grammar file.  Insert basic yyerror, yylex, and main function
 528 # definitions as well.  Hardcode yylex to return the (possibly empty)
 529 # comma-delimited series of tokens in INPUT followed by token 0.
 530 #
 531 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 532 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 533 # On the bison command-line, specify `--report=all --defines'.  Check
 534 # that Bison exits with value 0, has no stdout, and has stderr
 535 # BISON-STDERR.
 536 #
 537 # If TEST-SPEC contains the attribute `last-state', check that the value
 538 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 539 # the grammar; in other words, check the number of states (minus one).
 540 # Otherwise, check that everything in the `.output' file starting with
 541 # the definition of state 0 is the same as the entire value of
 542 # TABLES-OR-LAST-STATE.
 543 #
 544 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 545 # `.output' file, which is named `input.output', and/or grammar file,
 546 # which is named `input.y'.
 547 #
 548 # Finally, compile the generated parser and then run it using
 549 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 550 # PARSER-STDERR as the 2nd-4th arguments.
 551 #
 552 # As a precondition, you must properly double-quote all arguments that
 553 # are to be interpreted as strings.
 554 #
 555 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 556 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 557 # first argument.  This is useful, for example, when wrapping multiple
 558 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 559 # condition, in another macro.
 560 #
 561 # For example:
 562 #
 563 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 564 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 565 #   # ---------------------------------------------------------------------
 566 #   m4_define([AT_TEST_SYNTAX_ERROR],
 567 #   [
 568 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 569 #                              [[last-state]],
 570 #                              [[%error-verbose ]$2], [$3], [$4],
 571 #                              [[]], [$5], [], [$6], [$7], [$8])
 572 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 573 #                              [[last-state]],
 574 #                              [$2], [$3], [$4],
 575 #                              [[]], [$5], [], [$6], [$7], [$8])
 576 #   ])
 577 #
 578 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 579 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 580 #                        [[3]],
 581 #                        [[1]], [[]],
 582 #                        [AT_COND_CASE([[no verbose]],
 583 #                                      [[syntax error
 584 #   ]],
 585 #                                      [[syntax error, unexpected 'b', expecting $end
 586 #   ]])])
 587 m4_define([AT_TEST_TABLES_AND_PARSE],
 588 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 589
 590 AT_SETUP([$1])
 591
 592 AT_DATA_GRAMMAR([[input.y]],
 593 [[%code {
 594   #include <stdio.h>
 595   static void yyerror (char const *msg);
 596   static int yylex (void);
 597 }
 598
 599 ]$4[
 600
 601 %%
 602
 603 ]$5[
 604
 605 %%
 606
 607 static void
 608 yyerror (char const *msg)
 609 {
 610   fprintf (stderr, "%s\n", msg);
 611 }
 612
 613 static int
 614 yylex (void)
 615 {
 616   static int const input[] = {
 617     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 618   };
 619   static int const *inputp = input;
 620   return *inputp++;
 621 }
 622
 623 int
 624 main (void)
 625 {
 626   return yyparse ();
 627 }
 628 ]])
 629
 630 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 631 # expanding macros, so it corrupts some special characters in the
 632 # macros.  To avoid this, expand now and pass it the result with proper
 633 # string quotation.  Assume args 7 through 12 expand to properly quoted
 634 # strings.
 635
 636 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 637       [AT_BISON_CHECK],
 638       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 639                                [0], [], m4_dquote($7))
 640
 641 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 642       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 643                 m4_dquote($8))],
 644       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 645                 m4_dquote($8)[[
 646 ]])])
 647
 648 $9
 649
 650 # Canonical LR generates very large tables, resulting in very long
 651 # files with #line directives that may overflow what the standards
 652 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 653 # will issue an error.
 654 #
 655 # There is no "" around `wc` since some indent the result.
 656 m4_bmatch([$4], [%define lr.type canonical-lr],
 657 [if test 32767 -lt `wc -l < input.c`; then
 658   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 659   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 660 fi])
 661 AT_COMPILE([[input]])
 662
 663 AT_PARSER_CHECK([[./input]],
 664                 m4_ifval([$10], [m4_dquote($10)]),
 665                 m4_ifval([$11], [m4_dquote($11)]),
 666                 m4_ifval([$12], [m4_dquote($12)]))
 667
 668 AT_CLEANUP
 669
 670 m4_popdef([AT_COND_CASE])])
 671
 672
 673
 674 ## ----------------------- ##
 675 ## Launch the test suite.  ##
 676 ## ----------------------- ##
 677
 678 AT_INIT
 679
 680 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 681 # options are processed, so we don't know the value of CXX and
 682 # CXXFLAGS yet.
 683 #
 684 # Note that it also means that command line values for CXX and
 685 # CXXFLAGS will not be propagated to CC and CFLAGS.
 686 AT_ARG_OPTION([compile-c-with-cxx],
 687               [compile C parsers with the C++ compiler])
 688
 689 AT_COLOR_TESTS
 690
 691 AT_TESTED([bison])