configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19
  20 # We need a recent Autoconf to avoid the message
  21 # "autom4te: unknown language: Autoconf-without-aclocal-m4".
  22 AC_PREREQ(2.58)
  23
  24 AC_INIT([GNU Bison], [1.875e], [bug-bison@gnu.org])
  25 AC_CONFIG_AUX_DIR([config])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 AM_INIT_AUTOMAKE([1.7 check-news readme-alpha dist-bzip2])
  29 AC_CONFIG_HEADERS([config.h:config.hin])
  30
  31 gl_USE_SYSTEM_EXTENSIONS
  32
  33 # Checks for the compiler.
  34 AC_PROG_CC
  35 AM_PROG_CC_STDC
  36 AC_ARG_ENABLE(gcc-warnings,
  37 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  38 [case "${enableval}" in
  39    yes|no) ;;
  40    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  41  esac],
  42               [enableval=no])
  43 if test "${enableval}" = yes; then
  44   BISON_WARNING(-Werror)
  45   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  46   WARNING_CFLAGS=
  47   BISON_WARNING(-W)
  48   BISON_WARNING(-Wall)
  49   BISON_WARNING(-Wcast-align)
  50   BISON_WARNING(-Wcast-qual)
  51   BISON_WARNING(-Wformat)
  52   BISON_WARNING(-Wwrite-strings)
  53   AC_SUBST([WARNING_CXXFLAGS], [$WARNING_CFLAGS])
  54   # The following warnings are not suitable for C++.
  55   BISON_WARNING(-Wbad-function-cast)
  56   BISON_WARNING(-Wmissing-declarations)
  57   BISON_WARNING(-Wmissing-prototypes)
  58   BISON_WARNING(-Wnested-externs)
  59   BISON_WARNING(-Wshadow)
  60   BISON_WARNING(-Wstrict-prototypes)
  61   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  62 fi
  63
  64 AC_ARG_ENABLE([yacc],
  65   [AC_HELP_STRING([--disable-yacc],
  66      [do not build a yacc command or an -ly library])],
  67   , [enable_yacc=yes])
  68 case $enable_yacc in
  69 yes)
  70   YACC_SCRIPT=yacc
  71   YACC_LIBRARY=liby.a;;
  72 *)
  73   YACC_SCRIPT=
  74   YACC_LIBRARY=;;
  75 esac
  76 AC_SUBST([YACC_SCRIPT])
  77 AC_SUBST([YACC_LIBRARY])
  78
  79 # Checks for programs.
  80 AC_PROG_LEX
  81 AC_PROG_YACC
  82 AC_PROG_RANLIB
  83 BISON_PROG_GNU_M4
  84 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  85   AC_MSG_ERROR([GNU M4 1.4 is required])
  86 fi
  87 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  88
  89 # Checks for header files.
  90 AC_CHECK_HEADERS_ONCE([locale.h])
  91 AM_STDBOOL_H
  92
  93 # Checks for compiler characteristics.
  94 AC_C_INLINE
  95
  96 # Checks for types.
  97 AC_CHECK_TYPES([uintptr_t])
  98
  99 # Checks for library functions.
 100 AC_CHECK_FUNCS_ONCE([setlocale])
 101 AM_WITH_DMALLOC
 102 BISON_PREREQ_SUBPIPE
 103 BISON_PREREQ_TIMEVAR
 104
 105 # gnulib and gettext.
 106 GNULIB_AUTOCONF_SNIPPET
 107 AM_GNU_GETTEXT_VERSION([0.11.5])
 108
 109 # Initialize the test suite.
 110 AC_CONFIG_TESTDIR(tests)
 111 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 112 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 113 AC_CHECK_PROGS([VALGRIND], [valgrind])
 114 AC_PROG_CXX
 115 BISON_TEST_FOR_WORKING_CXX_COMPILER
 116 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 117 # Needed by tests/atlocal.in.
 118 AC_SUBST([GCC])
 119 O0CFLAGS=`echo $CFLAGS | sed 's/-O[0-9] *//'`
 120 AC_SUBST([O0CFLAGS])
 121
 122 AC_CONFIG_FILES([Makefile
 123                  config/Makefile
 124                  po/Makefile.in
 125                  data/Makefile
 126                  lib/Makefile src/Makefile doc/Makefile])
 127 AC_OUTPUT