src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include <strverscmp.h>
  27
  28 #include "complain.h"
  29 #include "conflicts.h"
  30 #include "files.h"
  31 #include "getargs.h"
  32 #include "gram.h"
  33 #include "muscle_tab.h"
  34 #include "quotearg.h"
  35 #include "reader.h"
  36 #include "symlist.h"
  37 #include "scan-gram.h"
  38 #include "scan-code.h"
  39
  40 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  41 static YYLTYPE lloc_default (YYLTYPE const *, int);
  42
  43 #define YY_LOCATION_PRINT(File, Loc) \
  44           location_print (File, Loc)
  45
  46 static void version_check (location const *loc, char const *version);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 static char const *char_name (char);
  56
  57 /** Add a lex-param or a parse-param.
  58  *
  59  * \param type  \a lex_param or \a parse_param
  60  * \param decl  the formal argument
  61  * \param loc   the location in the source.
  62  */
  63 static void add_param (char const *type, char *decl, location loc);
  64
  65
  66 static symbol_class current_class = unknown_sym;
  67 static uniqstr current_type = NULL;
  68 static symbol *current_lhs;
  69 static location current_lhs_location;
  70 static int current_prec = 0;
  71
  72 #define YYTYPE_INT16 int_fast16_t
  73 #define YYTYPE_INT8 int_fast8_t
  74 #define YYTYPE_UINT16 uint_fast16_t
  75 #define YYTYPE_UINT8 uint_fast8_t
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86
  87 %initial-action
  88 {
  89   /* Bison's grammar can initial empty locations, hence a default
  90      location is needed. */
  91   boundary_set (&@$.start, current_file, 1, 1);
  92   boundary_set (&@$.end, current_file, 1, 1);
  93 }
  94
  95 /* Only NUMBERS have a value.  */
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char *chars;
 102   assoc assoc;
 103   uniqstr uniqstr;
 104   unsigned char character;
 105 };
 106
 107 /* Define the tokens together with their human representation.  */
 108 %token GRAM_EOF 0 "end of file"
 109 %token STRING     "string"
 110 %token INT        "integer"
 111
 112 %token PERCENT_TOKEN       "%token"
 113 %token PERCENT_NTERM       "%nterm"
 114
 115 %token PERCENT_TYPE        "%type"
 116 %token PERCENT_DESTRUCTOR  "%destructor"
 117 %token PERCENT_PRINTER     "%printer"
 118
 119 %token PERCENT_LEFT        "%left"
 120 %token PERCENT_RIGHT       "%right"
 121 %token PERCENT_NONASSOC    "%nonassoc"
 122
 123 %token PERCENT_PREC          "%prec"
 124 %token PERCENT_DPREC         "%dprec"
 125 %token PERCENT_MERGE         "%merge"
 126
 127
 128 /*----------------------.
 129 | Global Declarations.  |
 130 `----------------------*/
 131
 132 %token
 133   PERCENT_AFTER_HEADER    "%after-header"
 134   PERCENT_BEFORE_HEADER   "%before-header"
 135   PERCENT_DEBUG           "%debug"
 136   PERCENT_DEFAULT_PREC    "%default-prec"
 137   PERCENT_DEFINE          "%define"
 138   PERCENT_DEFINES         "%defines"
 139   PERCENT_END_HEADER      "%end-header"
 140   PERCENT_ERROR_VERBOSE   "%error-verbose"
 141   PERCENT_EXPECT          "%expect"
 142   PERCENT_EXPECT_RR       "%expect-rr"
 143   PERCENT_FILE_PREFIX     "%file-prefix"
 144   PERCENT_GLR_PARSER      "%glr-parser"
 145   PERCENT_INITIAL_ACTION  "%initial-action"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PURE_PARSER     "%pure-parser"
 156   PERCENT_REQUIRE         "%require"
 157   PERCENT_SKELETON        "%skeleton"
 158   PERCENT_START           "%start"
 159   PERCENT_START_HEADER    "%start-header"
 160   PERCENT_TOKEN_TABLE     "%token-table"
 161   PERCENT_VERBOSE         "%verbose"
 162   PERCENT_YACC            "%yacc"
 163 ;
 164
 165 %token BRACED_CODE     "{...}"
 166 %token CHAR            "char"
 167 %token EPILOGUE        "epilogue"
 168 %token EQUAL           "="
 169 %token ID              "identifier"
 170 %token ID_COLON        "identifier:"
 171 %token PERCENT_PERCENT "%%"
 172 %token PIPE            "|"
 173 %token PROLOGUE        "%{...%}"
 174 %token SEMICOLON       ";"
 175 %token TYPE            "type"
 176
 177 %type <character> CHAR
 178 %printer { fputs (char_name ($$), stderr); } CHAR
 179
 180 /* braceless is not to be used for rule or symbol actions, as it
 181    calls translate_code. */
 182 %type <chars> STRING "{...}" "%{...%}" EPILOGUE braceless content content.opt
 183 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 184          STRING
 185 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 186          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 187
 188 %type <uniqstr> TYPE ID ID_COLON
 189 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 190 %printer { fputs ($$, stderr); } ID
 191 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 192
 193 %type <integer> INT
 194 %printer { fprintf (stderr, "%d", $$); } INT
 195
 196 %type <symbol> id id_colon symbol string_as_id
 197 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 198 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 199
 200 %type <assoc> precedence_declarator
 201 %type <list>  symbols.1
 202 %%
 203
 204 input:
 205   prologue_declarations "%%" grammar epilogue.opt
 206 ;
 207
 208
 209         /*------------------------------------.
 210         | Declarations: before the first %%.  |
 211         `------------------------------------*/
 212
 213 prologue_declarations:
 214   /* Nothing */
 215 | prologue_declarations prologue_declaration
 216 ;
 217
 218 prologue_declaration:
 219   grammar_declaration
 220 | "%{...%}"     { prologue_augment (translate_code ($1, @1), @1, union_seen); }
 221 | "%after-header" braceless        { prologue_augment ($2, @2, true); }
 222 | "%before-header" braceless       { prologue_augment ($2, @2, false); }
 223 | "%debug"                         { debug_flag = true; }
 224 | "%define" STRING content.opt     { muscle_insert ($2, $3); }
 225 | "%defines"                       { defines_flag = true; }
 226 | "%end-header" braceless          { muscle_code_grow ("end_header", $2, @2); }
 227 | "%error-verbose"                 { error_verbose = true; }
 228 | "%expect" INT                    { expected_sr_conflicts = $2; }
 229 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 230 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; }
 231 | "%glr-parser"
 232     {
 233       nondeterministic_parser = true;
 234       glr_parser = true;
 235     }
 236 | "%initial-action" "{...}"
 237     {
 238       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 239     }
 240 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 241 | "%locations"                  { locations_flag = true; }
 242 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; }
 243 | "%no-lines"                   { no_lines_flag = true; }
 244 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 245 | "%output" "=" STRING          { spec_outfile = $3; }
 246 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 247 | "%pure-parser"                { pure_parser = true; }
 248 | "%require" STRING             { version_check (&@2, $2); }
 249 | "%skeleton" STRING            { skeleton = $2; }
 250 | "%start-header" braceless     { muscle_code_grow ("start_header", $2, @2); }
 251 | "%token-table"                { token_table_flag = true; }
 252 | "%verbose"                    { report_flag = report_states; }
 253 | "%yacc"                       { yacc_flag = true; }
 254 | /*FIXME: Err?  What is this horror doing here? */ ";"
 255 ;
 256
 257 grammar_declaration:
 258   precedence_declaration
 259 | symbol_declaration
 260 | "%start" symbol
 261     {
 262       grammar_start_symbol_set ($2, @2);
 263     }
 264 | "%destructor" "{...}" symbols.1
 265     {
 266       symbol_list *list;
 267       const char *action = translate_symbol_action ($2, @2);
 268       for (list = $3; list; list = list->next)
 269         symbol_destructor_set (list->sym, action, @2);
 270       symbol_list_free ($3);
 271     }
 272 | "%printer" "{...}" symbols.1
 273     {
 274       symbol_list *list;
 275       const char *action = translate_symbol_action ($2, @2);
 276       for (list = $3; list; list = list->next)
 277         symbol_printer_set (list->sym, action, @2);
 278       symbol_list_free ($3);
 279     }
 280 | "%default-prec"
 281     {
 282       default_prec = true;
 283     }
 284 | "%no-default-prec"
 285     {
 286       default_prec = false;
 287     }
 288 ;
 289
 290
 291 /*----------*
 292  | %union.  |
 293  *----------*/
 294
 295 %token PERCENT_UNION "%union";
 296
 297 union_name:
 298   /* Nothing. */ {}
 299 | ID             { muscle_code_grow ("union_name", $1, @1); }
 300 ;
 301
 302 grammar_declaration:
 303   "%union" union_name "{...}"
 304     {
 305       char const *body = $3;
 306
 307       if (union_seen)
 308         {
 309           /* Concatenate the union bodies, turning the first one's
 310              trailing '}' into '\n', and omitting the second one's '{'.  */
 311           char *code = muscle_find ("stype");
 312           code[strlen (code) - 1] = '\n';
 313           body++;
 314         }
 315
 316       union_seen = true;
 317       muscle_code_grow ("stype", body, @3);
 318     }
 319 ;
 320
 321
 322
 323
 324 symbol_declaration:
 325   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 326     {
 327       current_class = unknown_sym;
 328       current_type = NULL;
 329     }
 330 | "%token" { current_class = token_sym; } symbol_defs.1
 331     {
 332       current_class = unknown_sym;
 333       current_type = NULL;
 334     }
 335 | "%type" TYPE symbols.1
 336     {
 337       tag_seen = true;
 338       symbol_list *list;
 339       for (list = $3; list; list = list->next)
 340         symbol_type_set (list->sym, $2, @2);
 341       symbol_list_free ($3);
 342     }
 343 ;
 344
 345 precedence_declaration:
 346   precedence_declarator type.opt symbols.1
 347     {
 348       symbol_list *list;
 349       ++current_prec;
 350       for (list = $3; list; list = list->next)
 351         {
 352           symbol_type_set (list->sym, current_type, @2);
 353           symbol_precedence_set (list->sym, current_prec, $1, @1);
 354         }
 355       symbol_list_free ($3);
 356       current_type = NULL;
 357     }
 358 ;
 359
 360 precedence_declarator:
 361   "%left"     { $$ = left_assoc; }
 362 | "%right"    { $$ = right_assoc; }
 363 | "%nonassoc" { $$ = non_assoc; }
 364 ;
 365
 366 type.opt:
 367   /* Nothing. */ { current_type = NULL; }
 368 | TYPE           { current_type = $1; tag_seen = true; }
 369 ;
 370
 371 /* One or more nonterminals to be %typed. */
 372 symbols.1:
 373   symbol            { $$ = symbol_list_new ($1, @1); }
 374 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 375 ;
 376
 377 /* One token definition.  */
 378 symbol_def:
 379   TYPE
 380      {
 381        current_type = $1;
 382        tag_seen = true;
 383      }
 384 | id
 385      {
 386        symbol_class_set ($1, current_class, @1, true);
 387        symbol_type_set ($1, current_type, @1);
 388      }
 389 | id INT
 390     {
 391       symbol_class_set ($1, current_class, @1, true);
 392       symbol_type_set ($1, current_type, @1);
 393       symbol_user_token_number_set ($1, $2, @2);
 394     }
 395 | id string_as_id
 396     {
 397       symbol_class_set ($1, current_class, @1, true);
 398       symbol_type_set ($1, current_type, @1);
 399       symbol_make_alias ($1, $2, @$);
 400     }
 401 | id INT string_as_id
 402     {
 403       symbol_class_set ($1, current_class, @1, true);
 404       symbol_type_set ($1, current_type, @1);
 405       symbol_user_token_number_set ($1, $2, @2);
 406       symbol_make_alias ($1, $3, @$);
 407     }
 408 ;
 409
 410 /* One or more symbol definitions. */
 411 symbol_defs.1:
 412   symbol_def
 413 | symbol_defs.1 symbol_def
 414 ;
 415
 416
 417         /*------------------------------------------.
 418         | The grammar section: between the two %%.  |
 419         `------------------------------------------*/
 420
 421 grammar:
 422   rules_or_grammar_declaration
 423 | grammar rules_or_grammar_declaration
 424 ;
 425
 426 /* As a Bison extension, one can use the grammar declarations in the
 427    body of the grammar.  */
 428 rules_or_grammar_declaration:
 429   rules
 430 | grammar_declaration ";"
 431 | error ";"
 432     {
 433       yyerrok;
 434     }
 435 ;
 436
 437 rules:
 438   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 439 ;
 440
 441 rhses.1:
 442   rhs                { grammar_current_rule_end (@1); }
 443 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 444 | rhses.1 ";"
 445 ;
 446
 447 rhs:
 448   /* Nothing.  */
 449     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 450 | rhs symbol
 451     { grammar_current_rule_symbol_append ($2, @2); }
 452 | rhs "{...}"
 453     { grammar_current_rule_action_append ($2, @2); }
 454 | rhs "%prec" symbol
 455     { grammar_current_rule_prec_set ($3, @3); }
 456 | rhs "%dprec" INT
 457     { grammar_current_rule_dprec_set ($3, @3); }
 458 | rhs "%merge" TYPE
 459     { grammar_current_rule_merge_set ($3, @3); }
 460 ;
 461
 462
 463 /*-----------*
 464  | content.  |
 465  *-----------*/
 466
 467 content:
 468   STRING
 469 | braceless
 470 ;
 471
 472 /* Some content or "1" by default. */
 473 content.opt:
 474   /* Nothing. */
 475     {
 476       static char one[] = "1";
 477       $$ = one;
 478     }
 479 | content
 480 ;
 481
 482
 483 braceless:
 484   "{...}"
 485     {
 486       $1[strlen ($1) - 1] = '\n';
 487       $$ = translate_code ($1 + 1, @1);
 488     }
 489 ;
 490
 491
 492 /*---------------*
 493  | Identifiers.  |
 494  *---------------*/
 495
 496 /* Identifiers are returned as uniqstr values by the scanner.
 497    Depending on their use, we may need to make them genuine symbols.  */
 498
 499 id:
 500   ID
 501     { $$ = symbol_from_uniqstr ($1, @1); }
 502 | CHAR
 503     {
 504       $$ = symbol_get (char_name ($1), @1);
 505       symbol_class_set ($$, token_sym, @1, false);
 506       symbol_user_token_number_set ($$, $1, @1);
 507     }
 508 ;
 509
 510 id_colon:
 511   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 512 ;
 513
 514
 515 symbol:
 516   id
 517 | string_as_id
 518 ;
 519
 520 /* A string used as an ID: quote it.  */
 521 string_as_id:
 522   STRING
 523     {
 524       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 525       symbol_class_set ($$, token_sym, @1, false);
 526     }
 527 ;
 528
 529 epilogue.opt:
 530   /* Nothing.  */
 531 | "%%" EPILOGUE
 532     {
 533       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 534       gram_scanner_last_string_free ();
 535     }
 536 ;
 537
 538 %%
 539
 540
 541 /* Return the location of the left-hand side of a rule whose
 542    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 543    the right-hand side, and return an empty location equal to the end
 544    boundary of RHS[0] if the right-hand side is empty.  */
 545
 546 static YYLTYPE
 547 lloc_default (YYLTYPE const *rhs, int n)
 548 {
 549   int i;
 550   YYLTYPE loc;
 551
 552   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 553      The bug is fixed in 7.4.2m, but play it safe for now.  */
 554   loc.start = rhs[n].end;
 555   loc.end = rhs[n].end;
 556
 557   /* Ignore empty nonterminals the start of the the right-hand side.
 558      Do not bother to ignore them at the end of the right-hand side,
 559      since empty nonterminals have the same end as their predecessors.  */
 560   for (i = 1; i <= n; i++)
 561     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 562       {
 563         loc.start = rhs[i].start;
 564         break;
 565       }
 566
 567   return loc;
 568 }
 569
 570
 571 /* Add a lex-param or a parse-param (depending on TYPE) with
 572    declaration DECL and location LOC.  */
 573
 574 static void
 575 add_param (char const *type, char *decl, location loc)
 576 {
 577   static char const alphanum[26 + 26 + 1 + 10] =
 578     "abcdefghijklmnopqrstuvwxyz"
 579     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 580     "_"
 581     "0123456789";
 582   char const *name_start = NULL;
 583   char *p;
 584
 585   /* Stop on last actual character.  */
 586   for (p = decl; p[1]; p++)
 587     if ((p == decl
 588          || ! memchr (alphanum, p[-1], sizeof alphanum))
 589         && memchr (alphanum, p[0], sizeof alphanum - 10))
 590       name_start = p;
 591
 592   /* Strip the surrounding '{' and '}', and any blanks just inside
 593      the braces.  */
 594   while (*--p == ' ' || *p == '\t')
 595     continue;
 596   p[1] = '\0';
 597   while (*++decl == ' ' || *decl == '\t')
 598     continue;
 599
 600   if (! name_start)
 601     complain_at (loc, _("missing identifier in parameter declaration"));
 602   else
 603     {
 604       char *name;
 605       size_t name_len;
 606
 607       for (name_len = 1;
 608            memchr (alphanum, name_start[name_len], sizeof alphanum);
 609            name_len++)
 610         continue;
 611
 612       name = xmalloc (name_len + 1);
 613       memcpy (name, name_start, name_len);
 614       name[name_len] = '\0';
 615       muscle_pair_list_grow (type, decl, name);
 616       free (name);
 617     }
 618
 619   gram_scanner_last_string_free ();
 620 }
 621
 622
 623 static void
 624 version_check (location const *loc, char const *version)
 625 {
 626   if (strverscmp (version, PACKAGE_VERSION) > 0)
 627     {
 628       complain_at (*loc, "require bison %s, but have %s",
 629                    version, PACKAGE_VERSION);
 630       exit (63);
 631     }
 632 }
 633
 634 static void
 635 gram_error (location const *loc, char const *msg)
 636 {
 637   complain_at (*loc, "%s", msg);
 638 }
 639
 640 char const *
 641 token_name (int type)
 642 {
 643   return yytname[YYTRANSLATE (type)];
 644 }
 645
 646 static char const *
 647 char_name (char c)
 648 {
 649   if (c == '\'')
 650     return "'\\''";
 651   else
 652     {
 653       char buf[4];
 654       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 655       return quotearg_style (escape_quoting_style, buf);
 656     }
 657 }