src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include <strverscmp.h>
  27
  28 #include "complain.h"
  29 #include "conflicts.h"
  30 #include "files.h"
  31 #include "getargs.h"
  32 #include "gram.h"
  33 #include "muscle_tab.h"
  34 #include "quotearg.h"
  35 #include "reader.h"
  36 #include "symlist.h"
  37 #include "scan-gram.h"
  38 #include "scan-code.h"
  39
  40 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  41 static YYLTYPE lloc_default (YYLTYPE const *, int);
  42
  43 #define YY_LOCATION_PRINT(File, Loc) \
  44           location_print (File, Loc)
  45
  46 static void version_check (location const *loc, char const *version);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 static char const *char_name (char);
  56
  57 /** Add a lex-param or a parse-param.
  58  *
  59  * \param type  \a lex_param or \a parse_param
  60  * \param decl  the formal argument
  61  * \param loc   the location in the source.
  62  */
  63 static void add_param (char const *type, char *decl, location loc);
  64
  65
  66 static symbol_class current_class = unknown_sym;
  67 static uniqstr current_type = NULL;
  68 static symbol *current_lhs;
  69 static location current_lhs_location;
  70 static int current_prec = 0;
  71
  72 #define YYTYPE_INT16 int_fast16_t
  73 #define YYTYPE_INT8 int_fast8_t
  74 #define YYTYPE_UINT16 uint_fast16_t
  75 #define YYTYPE_UINT8 uint_fast8_t
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 /* Only NUMBERS have a value.  */
  97 %union
  98 {
  99   symbol *symbol;
 100   symbol_list *list;
 101   int integer;
 102   char *chars;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119 %token PERCENT_SYMBOL_DEFAULT
 120                            "%symbol-default"
 121
 122 %token PERCENT_LEFT        "%left"
 123 %token PERCENT_RIGHT       "%right"
 124 %token PERCENT_NONASSOC    "%nonassoc"
 125
 126 %token PERCENT_PREC          "%prec"
 127 %token PERCENT_DPREC         "%dprec"
 128 %token PERCENT_MERGE         "%merge"
 129
 130
 131 /*----------------------.
 132 | Global Declarations.  |
 133 `----------------------*/
 134
 135 %token
 136   PERCENT_CODE            "%code"
 137   PERCENT_CODE_TOP        "%code-top"
 138   PERCENT_DEBUG           "%debug"
 139   PERCENT_DEFAULT_PREC    "%default-prec"
 140   PERCENT_DEFINE          "%define"
 141   PERCENT_DEFINES         "%defines"
 142   PERCENT_ERROR_VERBOSE   "%error-verbose"
 143   PERCENT_EXPECT          "%expect"
 144   PERCENT_EXPECT_RR       "%expect-rr"
 145   PERCENT_FILE_PREFIX     "%file-prefix"
 146   PERCENT_GLR_PARSER      "%glr-parser"
 147   PERCENT_INITIAL_ACTION  "%initial-action"
 148   PERCENT_LEX_PARAM       "%lex-param"
 149   PERCENT_LOCATIONS       "%locations"
 150   PERCENT_NAME_PREFIX     "%name-prefix"
 151   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 152   PERCENT_NO_LINES        "%no-lines"
 153   PERCENT_NONDETERMINISTIC_PARSER
 154                           "%nondeterministic-parser"
 155   PERCENT_OUTPUT          "%output"
 156   PERCENT_PARSE_PARAM     "%parse-param"
 157   PERCENT_PROVIDES        "%provides"
 158   PERCENT_PURE_PARSER     "%pure-parser"
 159   PERCENT_PUSH_PARSER     "%push-parser"
 160   PERCENT_REQUIRE         "%require"
 161   PERCENT_REQUIRES        "%requires"
 162   PERCENT_SKELETON        "%skeleton"
 163   PERCENT_START           "%start"
 164   PERCENT_TOKEN_TABLE     "%token-table"
 165   PERCENT_VERBOSE         "%verbose"
 166   PERCENT_YACC            "%yacc"
 167 ;
 168
 169 %token BRACED_CODE     "{...}"
 170 %token CHAR            "char"
 171 %token EPILOGUE        "epilogue"
 172 %token EQUAL           "="
 173 %token ID              "identifier"
 174 %token ID_COLON        "identifier:"
 175 %token PERCENT_PERCENT "%%"
 176 %token PIPE            "|"
 177 %token PROLOGUE        "%{...%}"
 178 %token SEMICOLON       ";"
 179 %token TYPE            "type"
 180
 181 %type <character> CHAR
 182 %printer { fputs (char_name ($$), stderr); } CHAR
 183
 184 /* braceless is not to be used for rule or symbol actions, as it
 185    calls translate_code. */
 186 %type <chars> STRING "{...}" "%{...%}" EPILOGUE braceless content content.opt
 187 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 188          STRING
 189 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 190          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 191
 192 %type <uniqstr> TYPE ID ID_COLON
 193 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 194 %printer { fputs ($$, stderr); } ID
 195 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 196
 197 %type <integer> INT
 198 %printer { fprintf (stderr, "%d", $$); } INT
 199
 200 %type <symbol> id id_colon symbol string_as_id
 201 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 202 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 203
 204 %type <assoc> precedence_declarator
 205 %type <list>  symbols.1 generic_symlist generic_symlist_item
 206 %%
 207
 208 input:
 209   prologue_declarations "%%" grammar epilogue.opt
 210 ;
 211
 212
 213         /*------------------------------------.
 214         | Declarations: before the first %%.  |
 215         `------------------------------------*/
 216
 217 prologue_declarations:
 218   /* Nothing */
 219 | prologue_declarations prologue_declaration
 220 ;
 221
 222 prologue_declaration:
 223   grammar_declaration
 224 | "%{...%}"     { prologue_augment (translate_code ($1, @1), @1, union_seen); }
 225 | "%debug"                         { debug_flag = true; }
 226 | "%define" STRING content.opt     { muscle_insert ($2, $3); }
 227 | "%defines"                       { defines_flag = true; }
 228 | "%error-verbose"                 { error_verbose = true; }
 229 | "%expect" INT                    { expected_sr_conflicts = $2; }
 230 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 231 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; }
 232 | "%glr-parser"
 233     {
 234       nondeterministic_parser = true;
 235       glr_parser = true;
 236     }
 237 | "%initial-action" "{...}"
 238     {
 239       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 240     }
 241 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 242 | "%locations"                  { locations_flag = true; }
 243 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; }
 244 | "%no-lines"                   { no_lines_flag = true; }
 245 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 246 | "%output" "=" STRING          { spec_outfile = $3; }
 247 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 248 | "%pure-parser"                { pure_parser = true; }
 249 | "%push-parser"                { push_parser = true; }
 250 | "%require" STRING             { version_check (&@2, $2); }
 251 | "%skeleton" STRING            { skeleton = $2; }
 252 | "%token-table"                { token_table_flag = true; }
 253 | "%verbose"                    { report_flag = report_states; }
 254 | "%yacc"                       { yacc_flag = true; }
 255 | /*FIXME: Err?  What is this horror doing here? */ ";"
 256 ;
 257
 258 grammar_declaration:
 259   precedence_declaration
 260 | symbol_declaration
 261 | "%start" symbol
 262     {
 263       grammar_start_symbol_set ($2, @2);
 264     }
 265 | "%destructor" "{...}" generic_symlist
 266     {
 267       symbol_list *list;
 268       const char *action = translate_symbol_action ($2, @2);
 269       for (list = $3; list; list = list->next)
 270         symbol_list_destructor_set (list, action, @2);
 271       symbol_list_free ($3);
 272     }
 273 | "%printer" "{...}" generic_symlist
 274     {
 275       symbol_list *list;
 276       const char *action = translate_symbol_action ($2, @2);
 277       for (list = $3; list; list = list->next)
 278         symbol_list_printer_set (list, action, @2);
 279       symbol_list_free ($3);
 280     }
 281 | "%default-prec"
 282     {
 283       default_prec = true;
 284     }
 285 | "%no-default-prec"
 286     {
 287       default_prec = false;
 288     }
 289 | "%code" braceless      { prologue_augment ($2, @2, true); }
 290 | "%code-top" braceless  { prologue_augment ($2, @2, false); }
 291 | "%provides" braceless  { muscle_code_grow ("provides", $2, @2); }
 292 | "%requires" braceless  { muscle_code_grow ("requires", $2, @2); }
 293 ;
 294
 295
 296 /*----------*
 297  | %union.  |
 298  *----------*/
 299
 300 %token PERCENT_UNION "%union";
 301
 302 union_name:
 303   /* Nothing. */ {}
 304 | ID             { muscle_code_grow ("union_name", $1, @1); }
 305 ;
 306
 307 grammar_declaration:
 308   "%union" union_name "{...}"
 309     {
 310       char const *body = $3;
 311
 312       /* Concatenate the %union bodies.  If this is the first %union, make sure
 313          the synchronization line appears after the opening '{' so as not to
 314          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 315          into '\n', and omit the new %union's leading '{'.  */
 316       if (!union_seen)
 317         {
 318           muscle_grow ("stype", "{", "");
 319         }
 320       else
 321         {
 322           char *code = muscle_find ("stype");
 323           code[strlen (code) - 1] = '\n';
 324         }
 325       body++;
 326
 327       union_seen = true;
 328       muscle_code_grow ("stype", body, @3);
 329     }
 330 ;
 331
 332
 333
 334
 335 symbol_declaration:
 336   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 337     {
 338       current_class = unknown_sym;
 339       current_type = NULL;
 340     }
 341 | "%token" { current_class = token_sym; } symbol_defs.1
 342     {
 343       current_class = unknown_sym;
 344       current_type = NULL;
 345     }
 346 | "%type" TYPE symbols.1
 347     {
 348       symbol_list *list;
 349       tag_seen = true;
 350       for (list = $3; list; list = list->next)
 351         symbol_type_set (list->content.sym, $2, @2);
 352       symbol_list_free ($3);
 353     }
 354 ;
 355
 356 precedence_declaration:
 357   precedence_declarator type.opt symbols.1
 358     {
 359       symbol_list *list;
 360       ++current_prec;
 361       for (list = $3; list; list = list->next)
 362         {
 363           symbol_type_set (list->content.sym, current_type, @2);
 364           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 365         }
 366       symbol_list_free ($3);
 367       current_type = NULL;
 368     }
 369 ;
 370
 371 precedence_declarator:
 372   "%left"     { $$ = left_assoc; }
 373 | "%right"    { $$ = right_assoc; }
 374 | "%nonassoc" { $$ = non_assoc; }
 375 ;
 376
 377 type.opt:
 378   /* Nothing. */ { current_type = NULL; }
 379 | TYPE           { current_type = $1; tag_seen = true; }
 380 ;
 381
 382 /* One or more symbols to be %typed. */
 383 symbols.1:
 384   symbol
 385     { $$ = symbol_list_sym_new ($1, @1); }
 386 | symbols.1 symbol
 387     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 388 ;
 389
 390 generic_symlist:
 391   generic_symlist_item { $$ = $1; }
 392 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 393 ;
 394
 395 generic_symlist_item:
 396   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 397 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 398 | "%symbol-default" { $$ = symbol_list_default_new (@1); }
 399 ;
 400
 401 /* One token definition.  */
 402 symbol_def:
 403   TYPE
 404      {
 405        current_type = $1;
 406        tag_seen = true;
 407      }
 408 | id
 409      {
 410        symbol_class_set ($1, current_class, @1, true);
 411        symbol_type_set ($1, current_type, @1);
 412      }
 413 | id INT
 414     {
 415       symbol_class_set ($1, current_class, @1, true);
 416       symbol_type_set ($1, current_type, @1);
 417       symbol_user_token_number_set ($1, $2, @2);
 418     }
 419 | id string_as_id
 420     {
 421       symbol_class_set ($1, current_class, @1, true);
 422       symbol_type_set ($1, current_type, @1);
 423       symbol_make_alias ($1, $2, @$);
 424     }
 425 | id INT string_as_id
 426     {
 427       symbol_class_set ($1, current_class, @1, true);
 428       symbol_type_set ($1, current_type, @1);
 429       symbol_user_token_number_set ($1, $2, @2);
 430       symbol_make_alias ($1, $3, @$);
 431     }
 432 ;
 433
 434 /* One or more symbol definitions. */
 435 symbol_defs.1:
 436   symbol_def
 437 | symbol_defs.1 symbol_def
 438 ;
 439
 440
 441         /*------------------------------------------.
 442         | The grammar section: between the two %%.  |
 443         `------------------------------------------*/
 444
 445 grammar:
 446   rules_or_grammar_declaration
 447 | grammar rules_or_grammar_declaration
 448 ;
 449
 450 /* As a Bison extension, one can use the grammar declarations in the
 451    body of the grammar.  */
 452 rules_or_grammar_declaration:
 453   rules
 454 | grammar_declaration ";"
 455 | error ";"
 456     {
 457       yyerrok;
 458     }
 459 ;
 460
 461 rules:
 462   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 463 ;
 464
 465 rhses.1:
 466   rhs                { grammar_current_rule_end (@1); }
 467 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 468 | rhses.1 ";"
 469 ;
 470
 471 rhs:
 472   /* Nothing.  */
 473     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 474 | rhs symbol
 475     { grammar_current_rule_symbol_append ($2, @2); }
 476 | rhs "{...}"
 477     { grammar_current_rule_action_append ($2, @2); }
 478 | rhs "%prec" symbol
 479     { grammar_current_rule_prec_set ($3, @3); }
 480 | rhs "%dprec" INT
 481     { grammar_current_rule_dprec_set ($3, @3); }
 482 | rhs "%merge" TYPE
 483     { grammar_current_rule_merge_set ($3, @3); }
 484 ;
 485
 486
 487 /*-----------*
 488  | content.  |
 489  *-----------*/
 490
 491 content:
 492   STRING
 493 | braceless
 494 ;
 495
 496 /* Some content or "1" by default. */
 497 content.opt:
 498   /* Nothing. */
 499     {
 500       static char one[] = "1";
 501       $$ = one;
 502     }
 503 | content
 504 ;
 505
 506
 507 braceless:
 508   "{...}"
 509     {
 510       $1[strlen ($1) - 1] = '\n';
 511       $$ = translate_code ($1 + 1, @1);
 512     }
 513 ;
 514
 515
 516 /*---------------*
 517  | Identifiers.  |
 518  *---------------*/
 519
 520 /* Identifiers are returned as uniqstr values by the scanner.
 521    Depending on their use, we may need to make them genuine symbols.  */
 522
 523 id:
 524   ID
 525     { $$ = symbol_from_uniqstr ($1, @1); }
 526 | CHAR
 527     {
 528       $$ = symbol_get (char_name ($1), @1);
 529       symbol_class_set ($$, token_sym, @1, false);
 530       symbol_user_token_number_set ($$, $1, @1);
 531     }
 532 ;
 533
 534 id_colon:
 535   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 536 ;
 537
 538
 539 symbol:
 540   id
 541 | string_as_id
 542 ;
 543
 544 /* A string used as an ID: quote it.  */
 545 string_as_id:
 546   STRING
 547     {
 548       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 549       symbol_class_set ($$, token_sym, @1, false);
 550     }
 551 ;
 552
 553 epilogue.opt:
 554   /* Nothing.  */
 555 | "%%" EPILOGUE
 556     {
 557       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 558       gram_scanner_last_string_free ();
 559     }
 560 ;
 561
 562 %%
 563
 564
 565 /* Return the location of the left-hand side of a rule whose
 566    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 567    the right-hand side, and return an empty location equal to the end
 568    boundary of RHS[0] if the right-hand side is empty.  */
 569
 570 static YYLTYPE
 571 lloc_default (YYLTYPE const *rhs, int n)
 572 {
 573   int i;
 574   YYLTYPE loc;
 575
 576   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 577      The bug is fixed in 7.4.2m, but play it safe for now.  */
 578   loc.start = rhs[n].end;
 579   loc.end = rhs[n].end;
 580
 581   /* Ignore empty nonterminals the start of the the right-hand side.
 582      Do not bother to ignore them at the end of the right-hand side,
 583      since empty nonterminals have the same end as their predecessors.  */
 584   for (i = 1; i <= n; i++)
 585     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 586       {
 587         loc.start = rhs[i].start;
 588         break;
 589       }
 590
 591   return loc;
 592 }
 593
 594
 595 /* Add a lex-param or a parse-param (depending on TYPE) with
 596    declaration DECL and location LOC.  */
 597
 598 static void
 599 add_param (char const *type, char *decl, location loc)
 600 {
 601   static char const alphanum[26 + 26 + 1 + 10] =
 602     "abcdefghijklmnopqrstuvwxyz"
 603     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 604     "_"
 605     "0123456789";
 606   char const *name_start = NULL;
 607   char *p;
 608
 609   /* Stop on last actual character.  */
 610   for (p = decl; p[1]; p++)
 611     if ((p == decl
 612          || ! memchr (alphanum, p[-1], sizeof alphanum))
 613         && memchr (alphanum, p[0], sizeof alphanum - 10))
 614       name_start = p;
 615
 616   /* Strip the surrounding '{' and '}', and any blanks just inside
 617      the braces.  */
 618   while (*--p == ' ' || *p == '\t')
 619     continue;
 620   p[1] = '\0';
 621   while (*++decl == ' ' || *decl == '\t')
 622     continue;
 623
 624   if (! name_start)
 625     complain_at (loc, _("missing identifier in parameter declaration"));
 626   else
 627     {
 628       char *name;
 629       size_t name_len;
 630
 631       for (name_len = 1;
 632            memchr (alphanum, name_start[name_len], sizeof alphanum);
 633            name_len++)
 634         continue;
 635
 636       name = xmalloc (name_len + 1);
 637       memcpy (name, name_start, name_len);
 638       name[name_len] = '\0';
 639       muscle_pair_list_grow (type, decl, name);
 640       free (name);
 641     }
 642
 643   gram_scanner_last_string_free ();
 644 }
 645
 646
 647 static void
 648 version_check (location const *loc, char const *version)
 649 {
 650   if (strverscmp (version, PACKAGE_VERSION) > 0)
 651     {
 652       complain_at (*loc, "require bison %s, but have %s",
 653                    version, PACKAGE_VERSION);
 654       exit (63);
 655     }
 656 }
 657
 658 static void
 659 gram_error (location const *loc, char const *msg)
 660 {
 661   complain_at (*loc, "%s", msg);
 662 }
 663
 664 char const *
 665 token_name (int type)
 666 {
 667   return yytname[YYTRANSLATE (type)];
 668 }
 669
 670 static char const *
 671 char_name (char c)
 672 {
 673   if (c == '\'')
 674     return "'\\''";
 675   else
 676     {
 677       char buf[4];
 678       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 679       return quotearg_style (escape_quoting_style, buf);
 680     }
 681 }