src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free
   4    Software Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle-tab.h"
  30 #include "named-ref.h"
  31 #include "quotearg.h"
  32 #include "reader.h"
  33 #include "symlist.h"
  34 #include "scan-gram.h"
  35 #include "scan-code.h"
  36
  37 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  38 static YYLTYPE lloc_default (YYLTYPE const *, int);
  39
  40 #define YY_LOCATION_PRINT(File, Loc) \
  41           location_print (File, Loc)
  42
  43 static void version_check (location const *loc, char const *version);
  44
  45 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  46    FIXME: depends on the undocumented availability of YYLLOC.  */
  47 #undef  yyerror
  48 #define yyerror(Msg) \
  49         gram_error (&yylloc, Msg)
  50 static void gram_error (location const *, char const *);
  51
  52 static char const *char_name (char);
  53
  54 /** Add a lex-param or a parse-param.
  55  *
  56  * \param type  \a lex_param or \a parse_param
  57  * \param decl  the formal argument
  58  * \param loc   the location in the source.
  59  */
  60 static void add_param (char const *type, char *decl, location loc);
  61
  62
  63 static symbol_class current_class = unknown_sym;
  64 static uniqstr current_type = NULL;
  65 static symbol *current_lhs;
  66 static location current_lhs_location;
  67 static named_ref *current_lhs_named_ref;
  68 static int current_prec = 0;
  69
  70 #define YYTYPE_INT16 int_fast16_t
  71 #define YYTYPE_INT8 int_fast8_t
  72 #define YYTYPE_UINT16 uint_fast16_t
  73 #define YYTYPE_UINT8 uint_fast8_t
  74 %}
  75
  76 %debug
  77 %verbose
  78 %defines
  79 %locations
  80 %pure-parser
  81 %error-verbose
  82 %name-prefix="gram_"
  83 %expect 0
  84
  85 %initial-action
  86 {
  87   /* Bison's grammar can initial empty locations, hence a default
  88      location is needed. */
  89   boundary_set (&@$.start, current_file, 1, 1);
  90   boundary_set (&@$.end, current_file, 1, 1);
  91 }
  92
  93 %union
  94 {
  95   symbol *symbol;
  96   symbol_list *list;
  97   int integer;
  98   char const *chars;
  99   char *code;
 100   assoc assoc;
 101   uniqstr uniqstr;
 102   unsigned char character;
 103   named_ref *named_ref;
 104 };
 105
 106 /* Define the tokens together with their human representation.  */
 107 %token GRAM_EOF 0 "end of file"
 108 %token STRING     "string"
 109 %token INT        "integer"
 110
 111 %token PERCENT_TOKEN       "%token"
 112 %token PERCENT_NTERM       "%nterm"
 113
 114 %token PERCENT_TYPE        "%type"
 115 %token PERCENT_DESTRUCTOR  "%destructor"
 116 %token PERCENT_PRINTER     "%printer"
 117
 118 %token PERCENT_LEFT        "%left"
 119 %token PERCENT_RIGHT       "%right"
 120 %token PERCENT_NONASSOC    "%nonassoc"
 121
 122 %token PERCENT_PREC          "%prec"
 123 %token PERCENT_DPREC         "%dprec"
 124 %token PERCENT_MERGE         "%merge"
 125
 126
 127 /*----------------------.
 128 | Global Declarations.  |
 129 `----------------------*/
 130
 131 %token
 132   PERCENT_CODE            "%code"
 133   PERCENT_DEBUG           "%debug"
 134   PERCENT_DEFAULT_PREC    "%default-prec"
 135   PERCENT_DEFINE          "%define"
 136   PERCENT_DEFINES         "%defines"
 137   PERCENT_ERROR_VERBOSE   "%error-verbose"
 138   PERCENT_EXPECT          "%expect"
 139   PERCENT_EXPECT_RR       "%expect-rr"
 140   PERCENT_FILE_PREFIX     "%file-prefix"
 141   PERCENT_GLR_PARSER      "%glr-parser"
 142   PERCENT_INITIAL_ACTION  "%initial-action"
 143   PERCENT_LANGUAGE        "%language"
 144   PERCENT_LEX_PARAM       "%lex-param"
 145   PERCENT_LOCATIONS       "%locations"
 146   PERCENT_NAME_PREFIX     "%name-prefix"
 147   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 148   PERCENT_NO_LINES        "%no-lines"
 149   PERCENT_NONDETERMINISTIC_PARSER
 150                           "%nondeterministic-parser"
 151   PERCENT_OUTPUT          "%output"
 152   PERCENT_PARSE_PARAM     "%parse-param"
 153   PERCENT_PURE_PARSER     "%pure-parser"
 154   PERCENT_REQUIRE         "%require"
 155   PERCENT_SKELETON        "%skeleton"
 156   PERCENT_START           "%start"
 157   PERCENT_TOKEN_TABLE     "%token-table"
 158   PERCENT_VERBOSE         "%verbose"
 159   PERCENT_YACC            "%yacc"
 160 ;
 161
 162 %token BRACED_CODE     "{...}"
 163 %token BRACKETED_ID    "[identifier]"
 164 %token CHAR            "char"
 165 %token EPILOGUE        "epilogue"
 166 %token EQUAL           "="
 167 %token ID              "identifier"
 168 %token ID_COLON        "identifier:"
 169 %token PERCENT_PERCENT "%%"
 170 %token PIPE            "|"
 171 %token PROLOGUE        "%{...%}"
 172 %token SEMICOLON       ";"
 173 %token TYPE            "type"
 174 %token TYPE_TAG_ANY    "<*>"
 175 %token TYPE_TAG_NONE   "<>"
 176
 177 %type <character> CHAR
 178 %printer { fputs (char_name ($$), stderr); } CHAR
 179
 180 /* braceless is not to be used for rule or symbol actions, as it
 181    calls code_props_plain_init.  */
 182 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 183 %type <code> "{...}"
 184 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 185          STRING
 186 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 187          braceless content.opt "{...}" "%{...%}" EPILOGUE
 188
 189 %type <uniqstr> BRACKETED_ID ID ID_COLON TYPE variable
 190 %printer { fputs ($$, stderr); } <uniqstr>
 191 %printer { fprintf (stderr, "[%s]", $$); } BRACKETED_ID
 192 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 193 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 194
 195 %type <integer> INT
 196 %printer { fprintf (stderr, "%d", $$); } <integer>
 197
 198 %type <symbol> id id_colon string_as_id symbol symbol.prec
 199 %printer { fprintf (stderr, "%s", $$->tag); } <symbol>
 200 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 201
 202 %type <assoc> precedence_declarator
 203 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 204 %type <named_ref> named_ref.opt
 205
 206 %%
 207
 208 input:
 209   prologue_declarations "%%" grammar epilogue.opt
 210 ;
 211
 212
 213         /*------------------------------------.
 214         | Declarations: before the first %%.  |
 215         `------------------------------------*/
 216
 217 prologue_declarations:
 218   /* Nothing */
 219 | prologue_declarations prologue_declaration
 220 ;
 221
 222 prologue_declaration:
 223   grammar_declaration
 224 | "%{...%}"
 225     {
 226       code_props plain_code;
 227       code_props_plain_init (&plain_code, $1, @1);
 228       code_props_translate_code (&plain_code);
 229       gram_scanner_last_string_free ();
 230       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 231                         plain_code.code, @1);
 232       code_scanner_last_string_free ();
 233     }
 234 | "%debug"                         { debug_flag = true; }
 235 | "%define" variable content.opt
 236     {
 237       muscle_percent_define_insert ($2, @2, $3,
 238                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 239     }
 240 | "%defines"                       { defines_flag = true; }
 241 | "%defines" STRING
 242     {
 243       defines_flag = true;
 244       spec_defines_file = xstrdup ($2);
 245     }
 246 | "%error-verbose"                 { error_verbose = true; }
 247 | "%expect" INT                    { expected_sr_conflicts = $2; }
 248 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 249 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 250 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 251 | "%glr-parser"
 252     {
 253       nondeterministic_parser = true;
 254       glr_parser = true;
 255     }
 256 | "%initial-action" "{...}"
 257     {
 258       code_props action;
 259       code_props_symbol_action_init (&action, $2, @2);
 260       code_props_translate_code (&action);
 261       gram_scanner_last_string_free ();
 262       muscle_code_grow ("initial_action", action.code, @2);
 263       code_scanner_last_string_free ();
 264     }
 265 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 266 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 267 | "%locations"                  { locations_flag = true; }
 268 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 269 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 270 | "%no-lines"                   { no_lines_flag = true; }
 271 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 272 | "%output" STRING              { spec_outfile = $2; }
 273 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 274 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 275 | "%pure-parser"
 276     {
 277       /* %pure-parser is deprecated in favor of `%define api.pure', so use
 278          `%define api.pure' in a backward-compatible manner here.  First, don't
 279          complain if %pure-parser is specified multiple times.  */
 280       if (!muscle_find_const ("percent_define(api.pure)"))
 281         muscle_percent_define_insert ("api.pure", @1, "",
 282                                       MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 283       /* In all cases, use api.pure now so that the backend doesn't complain if
 284          the skeleton ignores api.pure, but do warn now if there's a previous
 285          conflicting definition from an actual %define.  */
 286       if (!muscle_percent_define_flag_if ("api.pure"))
 287         muscle_percent_define_insert ("api.pure", @1, "",
 288                                       MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 289     }
 290 | "%require" STRING             { version_check (&@2, $2); }
 291 | "%skeleton" STRING
 292     {
 293       char const *skeleton_user = $2;
 294       if (strchr (skeleton_user, '/'))
 295         {
 296           size_t dir_length = strlen (current_file);
 297           char *skeleton_build;
 298           while (dir_length && current_file[dir_length - 1] != '/')
 299             --dir_length;
 300           while (dir_length && current_file[dir_length - 1] == '/')
 301             --dir_length;
 302           skeleton_build =
 303             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 304           if (dir_length > 0)
 305             {
 306               strncpy (skeleton_build, current_file, dir_length);
 307               skeleton_build[dir_length++] = '/';
 308             }
 309           strcpy (skeleton_build + dir_length, skeleton_user);
 310           skeleton_user = uniqstr_new (skeleton_build);
 311           free (skeleton_build);
 312         }
 313       skeleton_arg (skeleton_user, grammar_prio, @1);
 314     }
 315 | "%token-table"                { token_table_flag = true; }
 316 | "%verbose"                    { report_flag |= report_states; }
 317 | "%yacc"                       { yacc_flag = true; }
 318 | /*FIXME: Err?  What is this horror doing here? */ ";"
 319 ;
 320
 321 grammar_declaration:
 322   precedence_declaration
 323 | symbol_declaration
 324 | "%start" symbol
 325     {
 326       grammar_start_symbol_set ($2, @2);
 327     }
 328 | "%destructor" "{...}" generic_symlist
 329     {
 330       symbol_list *list;
 331       for (list = $3; list; list = list->next)
 332         symbol_list_destructor_set (list, $2, @2);
 333       symbol_list_free ($3);
 334     }
 335 | "%printer" "{...}" generic_symlist
 336     {
 337       symbol_list *list;
 338       for (list = $3; list; list = list->next)
 339         symbol_list_printer_set (list, $2, @2);
 340       symbol_list_free ($3);
 341     }
 342 | "%default-prec"
 343     {
 344       default_prec = true;
 345     }
 346 | "%no-default-prec"
 347     {
 348       default_prec = false;
 349     }
 350 | "%code" braceless
 351     {
 352       /* Do not invoke muscle_percent_code_grow here since it invokes
 353          muscle_user_name_list_grow.  */
 354       muscle_code_grow ("percent_code()", $2, @2);
 355       code_scanner_last_string_free ();
 356     }
 357 | "%code" ID braceless
 358     {
 359       muscle_percent_code_grow ($2, @2, $3, @3);
 360       code_scanner_last_string_free ();
 361     }
 362 ;
 363
 364
 365 /*----------*
 366  | %union.  |
 367  *----------*/
 368
 369 %token PERCENT_UNION "%union";
 370
 371 union_name:
 372   /* Nothing. */ {}
 373 | ID             { muscle_code_grow ("union_name", $1, @1); }
 374 ;
 375
 376 grammar_declaration:
 377   "%union" union_name braceless
 378     {
 379       union_seen = true;
 380       muscle_code_grow ("stype", $3, @3);
 381       code_scanner_last_string_free ();
 382     }
 383 ;
 384
 385
 386
 387
 388 symbol_declaration:
 389   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 390     {
 391       current_class = unknown_sym;
 392       current_type = NULL;
 393     }
 394 | "%token" { current_class = token_sym; } symbol_defs.1
 395     {
 396       current_class = unknown_sym;
 397       current_type = NULL;
 398     }
 399 | "%type" TYPE symbols.1
 400     {
 401       symbol_list *list;
 402       tag_seen = true;
 403       for (list = $3; list; list = list->next)
 404         symbol_type_set (list->content.sym, $2, @2);
 405       symbol_list_free ($3);
 406     }
 407 ;
 408
 409 precedence_declaration:
 410   precedence_declarator type.opt symbols.prec
 411     {
 412       symbol_list *list;
 413       ++current_prec;
 414       for (list = $3; list; list = list->next)
 415         {
 416           symbol_type_set (list->content.sym, current_type, @2);
 417           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 418         }
 419       symbol_list_free ($3);
 420       current_type = NULL;
 421     }
 422 ;
 423
 424 precedence_declarator:
 425   "%left"     { $$ = left_assoc; }
 426 | "%right"    { $$ = right_assoc; }
 427 | "%nonassoc" { $$ = non_assoc; }
 428 ;
 429
 430 type.opt:
 431   /* Nothing. */ { current_type = NULL; }
 432 | TYPE           { current_type = $1; tag_seen = true; }
 433 ;
 434
 435 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 436 symbols.prec:
 437   symbol.prec
 438     { $$ = symbol_list_sym_new ($1, @1); }
 439 | symbols.prec symbol.prec
 440     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 441 ;
 442
 443 symbol.prec:
 444     symbol { $$ = $1; }
 445   | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 446   ;
 447
 448 /* One or more symbols to be %typed. */
 449 symbols.1:
 450   symbol
 451     { $$ = symbol_list_sym_new ($1, @1); }
 452 | symbols.1 symbol
 453     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 454 ;
 455
 456 generic_symlist:
 457   generic_symlist_item { $$ = $1; }
 458 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 459 ;
 460
 461 generic_symlist_item:
 462   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 463 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 464 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 465 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 466 ;
 467
 468 /* One token definition.  */
 469 symbol_def:
 470   TYPE
 471      {
 472        current_type = $1;
 473        tag_seen = true;
 474      }
 475 | id
 476      {
 477        symbol_class_set ($1, current_class, @1, true);
 478        symbol_type_set ($1, current_type, @1);
 479      }
 480 | id INT
 481     {
 482       symbol_class_set ($1, current_class, @1, true);
 483       symbol_type_set ($1, current_type, @1);
 484       symbol_user_token_number_set ($1, $2, @2);
 485     }
 486 | id string_as_id
 487     {
 488       symbol_class_set ($1, current_class, @1, true);
 489       symbol_type_set ($1, current_type, @1);
 490       symbol_make_alias ($1, $2, @$);
 491     }
 492 | id INT string_as_id
 493     {
 494       symbol_class_set ($1, current_class, @1, true);
 495       symbol_type_set ($1, current_type, @1);
 496       symbol_user_token_number_set ($1, $2, @2);
 497       symbol_make_alias ($1, $3, @$);
 498     }
 499 ;
 500
 501 /* One or more symbol definitions. */
 502 symbol_defs.1:
 503   symbol_def
 504 | symbol_defs.1 symbol_def
 505 ;
 506
 507
 508         /*------------------------------------------.
 509         | The grammar section: between the two %%.  |
 510         `------------------------------------------*/
 511
 512 grammar:
 513   rules_or_grammar_declaration
 514 | grammar rules_or_grammar_declaration
 515 ;
 516
 517 /* As a Bison extension, one can use the grammar declarations in the
 518    body of the grammar.  */
 519 rules_or_grammar_declaration:
 520   rules
 521 | grammar_declaration ";"
 522 | error ";"
 523     {
 524       yyerrok;
 525     }
 526 ;
 527
 528 rules:
 529   id_colon named_ref.opt { current_lhs = $1; current_lhs_location = @1;
 530     current_lhs_named_ref = $2; } rhses.1
 531 ;
 532
 533 rhses.1:
 534   rhs                { grammar_current_rule_end (@1); }
 535 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 536 | rhses.1 ";"
 537 ;
 538
 539 rhs:
 540   /* Nothing.  */
 541     { grammar_current_rule_begin (current_lhs, current_lhs_location,
 542                                   current_lhs_named_ref); }
 543 | rhs symbol named_ref.opt
 544     { grammar_current_rule_symbol_append ($2, @2, $3); }
 545 | rhs "{...}" named_ref.opt
 546     { grammar_current_rule_action_append ($2, @2, $3); }
 547 | rhs "%prec" symbol
 548     { grammar_current_rule_prec_set ($3, @3); }
 549 | rhs "%dprec" INT
 550     { grammar_current_rule_dprec_set ($3, @3); }
 551 | rhs "%merge" TYPE
 552     { grammar_current_rule_merge_set ($3, @3); }
 553 ;
 554
 555 named_ref.opt:
 556   /* Nothing. */ { $$ = 0; }
 557 |
 558   BRACKETED_ID   { $$ = named_ref_new($1, @1); }
 559 ;
 560
 561
 562 /*----------------------------*
 563  | variable and content.opt.  |
 564  *---------------------------*/
 565
 566 /* The STRING form of variable is deprecated and is not M4-friendly.
 567    For example, M4 fails for `%define "[" "value"'.  */
 568 variable:
 569   ID
 570 | STRING { $$ = uniqstr_new ($1); }
 571 ;
 572
 573 /* Some content or empty by default. */
 574 content.opt:
 575   /* Nothing. */   { $$ = ""; }
 576 | ID { $$ = $1; }
 577 | STRING
 578 ;
 579
 580
 581 /*-------------*
 582  | braceless.  |
 583  *-------------*/
 584
 585 braceless:
 586   "{...}"
 587     {
 588       code_props plain_code;
 589       $1[strlen ($1) - 1] = '\n';
 590       code_props_plain_init (&plain_code, $1+1, @1);
 591       code_props_translate_code (&plain_code);
 592       gram_scanner_last_string_free ();
 593       $$ = plain_code.code;
 594     }
 595 ;
 596
 597
 598 /*---------------*
 599  | Identifiers.  |
 600  *---------------*/
 601
 602 /* Identifiers are returned as uniqstr values by the scanner.
 603    Depending on their use, we may need to make them genuine symbols.  */
 604
 605 id:
 606   ID
 607     { $$ = symbol_from_uniqstr ($1, @1); }
 608 | CHAR
 609     {
 610       $$ = symbol_get (char_name ($1), @1);
 611       symbol_class_set ($$, token_sym, @1, false);
 612       symbol_user_token_number_set ($$, $1, @1);
 613     }
 614 ;
 615
 616 id_colon:
 617   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 618 ;
 619
 620
 621 symbol:
 622   id
 623 | string_as_id
 624 ;
 625
 626 /* A string used as an ID: quote it.  */
 627 string_as_id:
 628   STRING
 629     {
 630       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 631       symbol_class_set ($$, token_sym, @1, false);
 632     }
 633 ;
 634
 635 epilogue.opt:
 636   /* Nothing.  */
 637 | "%%" EPILOGUE
 638     {
 639       code_props plain_code;
 640       code_props_plain_init (&plain_code, $2, @2);
 641       code_props_translate_code (&plain_code);
 642       gram_scanner_last_string_free ();
 643       muscle_code_grow ("epilogue", plain_code.code, @2);
 644       code_scanner_last_string_free ();
 645     }
 646 ;
 647
 648 %%
 649
 650
 651 /* Return the location of the left-hand side of a rule whose
 652    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 653    the right-hand side, and return an empty location equal to the end
 654    boundary of RHS[0] if the right-hand side is empty.  */
 655
 656 static YYLTYPE
 657 lloc_default (YYLTYPE const *rhs, int n)
 658 {
 659   int i;
 660   YYLTYPE loc;
 661
 662   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 663      The bug is fixed in 7.4.2m, but play it safe for now.  */
 664   loc.start = rhs[n].end;
 665   loc.end = rhs[n].end;
 666
 667   /* Ignore empty nonterminals the start of the the right-hand side.
 668      Do not bother to ignore them at the end of the right-hand side,
 669      since empty nonterminals have the same end as their predecessors.  */
 670   for (i = 1; i <= n; i++)
 671     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 672       {
 673         loc.start = rhs[i].start;
 674         break;
 675       }
 676
 677   return loc;
 678 }
 679
 680
 681 /* Add a lex-param or a parse-param (depending on TYPE) with
 682    declaration DECL and location LOC.  */
 683
 684 static void
 685 add_param (char const *type, char *decl, location loc)
 686 {
 687   static char const alphanum[26 + 26 + 1 + 10] =
 688     "abcdefghijklmnopqrstuvwxyz"
 689     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 690     "_"
 691     "0123456789";
 692   char const *name_start = NULL;
 693   char *p;
 694
 695   /* Stop on last actual character.  */
 696   for (p = decl; p[1]; p++)
 697     if ((p == decl
 698          || ! memchr (alphanum, p[-1], sizeof alphanum))
 699         && memchr (alphanum, p[0], sizeof alphanum - 10))
 700       name_start = p;
 701
 702   /* Strip the surrounding '{' and '}', and any blanks just inside
 703      the braces.  */
 704   while (*--p == ' ' || *p == '\t')
 705     continue;
 706   p[1] = '\0';
 707   while (*++decl == ' ' || *decl == '\t')
 708     continue;
 709
 710   if (! name_start)
 711     complain_at (loc, _("missing identifier in parameter declaration"));
 712   else
 713     {
 714       char *name;
 715       size_t name_len;
 716
 717       for (name_len = 1;
 718            memchr (alphanum, name_start[name_len], sizeof alphanum);
 719            name_len++)
 720         continue;
 721
 722       name = xmalloc (name_len + 1);
 723       memcpy (name, name_start, name_len);
 724       name[name_len] = '\0';
 725       muscle_pair_list_grow (type, decl, name);
 726       free (name);
 727     }
 728
 729   gram_scanner_last_string_free ();
 730 }
 731
 732
 733 static void
 734 version_check (location const *loc, char const *version)
 735 {
 736   if (strverscmp (version, PACKAGE_VERSION) > 0)
 737     {
 738       complain_at (*loc, "require bison %s, but have %s",
 739                    version, PACKAGE_VERSION);
 740       exit (63);
 741     }
 742 }
 743
 744 static void
 745 gram_error (location const *loc, char const *msg)
 746 {
 747   complain_at (*loc, "%s", msg);
 748 }
 749
 750 char const *
 751 token_name (int type)
 752 {
 753   return yytname[YYTRANSLATE (type)];
 754 }
 755
 756 static char const *
 757 char_name (char c)
 758 {
 759   if (c == '\'')
 760     return "'\\''";
 761   else
 762     {
 763       char buf[4];
 764       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 765       return quotearg_style (escape_quoting_style, buf);
 766     }
 767 }