data/java.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Java language support for Bison
   4
   5 # Copyright (C) 2007, 2008 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 # b4_comment(TEXT)
  22 # ----------------
  23 m4_define([b4_comment], [/* m4_bpatsubst([$1], [
  24 ], [
  25    ])  */])
  26
  27
  28 # b4_list2(LIST1, LIST2)
  29 # --------------------------
  30 # Join two lists with a comma if necessary.
  31 m4_define([b4_list2],
  32           [$1[]m4_ifval(m4_quote($1), [m4_ifval(m4_quote($2), [[, ]])])[]$2])
  33
  34
  35 # b4_percent_define_get3(DEF, PRE, POST, NOT)
  36 # -------------------------------------------
  37 # Expand to the value of DEF surrounded by PRE and POST if it's %define'ed,
  38 # otherwise NOT.
  39 m4_define([b4_percent_define_get3],
  40           [m4_ifval(m4_quote(b4_percent_define_get([$1])),
  41                 [$2[]b4_percent_define_get([$1])[]$3], [$4])])
  42
  43
  44
  45 # b4_flag_value(BOOLEAN-FLAG)
  46 # ---------------------------
  47 m4_define([b4_flag_value], [b4_flag_if([$1], [true], [false])])
  48
  49
  50 # b4_public_if(TRUE, FALSE)
  51 # -------------------------
  52 b4_percent_define_default([[public]], [[false]])
  53 m4_define([b4_public_if],
  54 [b4_percent_define_flag_if([public], [$1], [$2])])
  55
  56
  57 # b4_abstract_if(TRUE, FALSE)
  58 # ---------------------------
  59 b4_percent_define_default([[abstract]], [[false]])
  60 m4_define([b4_abstract_if],
  61 [b4_percent_define_flag_if([abstract], [$1], [$2])])
  62
  63
  64 # b4_final_if(TRUE, FALSE)
  65 # ---------------------------
  66 b4_percent_define_default([[final]], [[false]])
  67 m4_define([b4_final_if],
  68 [b4_percent_define_flag_if([final], [$1], [$2])])
  69
  70
  71 # b4_strictfp_if(TRUE, FALSE)
  72 # ---------------------------
  73 b4_percent_define_default([[strictfp]], [[false]])
  74 m4_define([b4_strictfp_if],
  75 [b4_percent_define_flag_if([strictfp], [$1], [$2])])
  76
  77
  78 # b4_lexer_if(TRUE, FALSE)
  79 # ------------------------
  80 m4_define([b4_lexer_if],
  81 [b4_percent_code_ifdef([[lexer]], [$1], [$2])])
  82
  83
  84 # b4_identification
  85 # -----------------
  86 m4_define([b4_identification],
  87 [  /** Version number for the Bison executable that generated this parser.  */
  88   public static final String bisonVersion = "b4_version";
  89
  90   /** Name of the skeleton that generated this parser.  */
  91   public static final String bisonSkeleton = b4_skeleton;
  92 ])
  93
  94
  95 ## ------------ ##
  96 ## Data types.  ##
  97 ## ------------ ##
  98
  99 # b4_int_type(MIN, MAX)
 100 # ---------------------
 101 # Return the smallest int type able to handle numbers ranging from
 102 # MIN to MAX (included).
 103 m4_define([b4_int_type],
 104 [m4_if(b4_ints_in($@,   [-128],   [127]), [1], [byte],
 105        b4_ints_in($@, [-32768], [32767]), [1], [short],
 106                                                [int])])
 107
 108 # b4_int_type_for(NAME)
 109 # ---------------------
 110 # Return the smallest int type able to handle numbers ranging from
 111 # `NAME_min' to `NAME_max' (included).
 112 m4_define([b4_int_type_for],
 113 [b4_int_type($1_min, $1_max)])
 114
 115 # b4_null
 116 # -------
 117 m4_define([b4_null], [null])
 118
 119
 120 # b4_typed_parser_table(TYPE, NAME, DATA)
 121 # ---------------------------------------
 122 m4_define([b4_typed_parser_table],
 123 [[private static final ]$1[ $2[] = $2init();
 124   private static final ]$1[[] $2init()
 125   {
 126     return new ]$1[[]
 127     {
 128   ]$3[
 129     };
 130   }]])
 131
 132
 133 # b4_integral_parser_table(NAME, DATA)
 134 #-------------------------------------
 135 m4_define([b4_integral_parser_table],
 136 [b4_typed_parser_table([b4_int_type_for([$2])], [$1], [$2])])
 137
 138
 139 ## ------------------------- ##
 140 ## Assigning token numbers.  ##
 141 ## ------------------------- ##
 142
 143 # b4_token_enum(TOKEN-NAME, TOKEN-NUMBER)
 144 # ---------------------------------------
 145 # Output the definition of this token as an enum.
 146 m4_define([b4_token_enum],
 147 [    /** Token number, to be returned by the scanner.  */
 148     static final int $1 = $2;
 149 ])
 150
 151
 152 # b4_token_enums(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 153 # -----------------------------------------------------
 154 # Output the definition of the tokens (if there are) as enums.
 155 m4_define([b4_token_enums],
 156 [m4_if([$#$1], [1], [],
 157 [/* Tokens.  */
 158 m4_map([b4_token_enum], [$@])])
 159 ])
 160
 161 # b4-case(ID, CODE)
 162 # -----------------
 163 # We need to fool Java's stupid unreachable code detection.
 164 m4_define([b4_case], [  case $1:
 165   if (yyn == $1)
 166     $2;
 167   break;
 168     ])
 169
 170
 171 ## ---------------- ##
 172 ## Default values.  ##
 173 ## ---------------- ##
 174
 175 m4_define([b4_yystype], [b4_percent_define_get([[stype]])])
 176 b4_percent_define_default([[stype]], [[Object]])
 177
 178 # %name-prefix
 179 m4_define_default([b4_prefix], [[YY]])
 180
 181 b4_percent_define_default([[parser_class_name]], [b4_prefix[]Parser])
 182 m4_define([b4_parser_class_name], [b4_percent_define_get([[parser_class_name]])])
 183
 184 b4_percent_define_default([[lex_throws]], [[java.io.IOException]])
 185 m4_define([b4_lex_throws], [b4_percent_define_get([[lex_throws]])])
 186
 187 b4_percent_define_default([[throws]], [])
 188 m4_define([b4_throws], [b4_percent_define_get([[throws]])])
 189
 190 b4_percent_define_default([[init_throws]], [])
 191 m4_define([b4_init_throws], [b4_percent_define_get([[init_throws]])])
 192
 193 b4_percent_define_default([[location_type]], [Location])
 194 m4_define([b4_location_type], [b4_percent_define_get([[location_type]])])
 195
 196 b4_percent_define_default([[position_type]], [Position])
 197 m4_define([b4_position_type], [b4_percent_define_get([[position_type]])])
 198
 199
 200 ## ----------------- ##
 201 ## Semantic Values.  ##
 202 ## ----------------- ##
 203
 204
 205 # b4_lhs_value([TYPE])
 206 # --------------------
 207 # Expansion of $<TYPE>$.
 208 m4_define([b4_lhs_value], [yyval])
 209
 210
 211 # b4_rhs_value(RULE-LENGTH, NUM, [TYPE])
 212 # --------------------------------------
 213 # Expansion of $<TYPE>NUM, where the current rule has RULE-LENGTH
 214 # symbols on RHS.
 215 #
 216 # In this simple implementation, %token and %type have class names
 217 # between the angle brackets.
 218 m4_define([b4_rhs_value],
 219 [(m4_ifval($3, [($3)])[](yystack.valueAt ($1-($2))))])
 220
 221 # b4_lhs_location()
 222 # -----------------
 223 # Expansion of @$.
 224 m4_define([b4_lhs_location],
 225 [(yyloc)])
 226
 227
 228 # b4_rhs_location(RULE-LENGTH, NUM)
 229 # ---------------------------------
 230 # Expansion of @NUM, where the current rule has RULE-LENGTH symbols
 231 # on RHS.
 232 m4_define([b4_rhs_location],
 233 [yystack.locationAt ($1-($2))])
 234
 235
 236 # b4_lex_param
 237 # b4_parse_param
 238 # --------------
 239 # If defined, b4_lex_param arrives double quoted, but below we prefer
 240 # it to be single quoted.  Same for b4_parse_param.
 241
 242 # TODO: should be in bison.m4
 243 m4_define_default([b4_lex_param], [[]])
 244 m4_define([b4_lex_param], b4_lex_param)
 245 m4_define([b4_parse_param], b4_parse_param)
 246
 247 # b4_lex_param_decl
 248 # -------------------
 249 # Extra formal arguments of the constructor.
 250 m4_define([b4_lex_param_decl],
 251 [m4_ifset([b4_lex_param],
 252           [b4_remove_comma([$1],
 253                            b4_param_decls(b4_lex_param))],
 254           [$1])])
 255
 256 m4_define([b4_param_decls],
 257           [m4_map([b4_param_decl], [$@])])
 258 m4_define([b4_param_decl], [, $1])
 259
 260 m4_define([b4_remove_comma], [m4_ifval(m4_quote($1), [$1, ], [])m4_shift2($@)])
 261
 262
 263
 264 # b4_parse_param_decl
 265 # -------------------
 266 # Extra formal arguments of the constructor.
 267 m4_define([b4_parse_param_decl],
 268 [m4_ifset([b4_parse_param],
 269           [b4_remove_comma([$1],
 270                            b4_param_decls(b4_parse_param))],
 271           [$1])])
 272
 273
 274
 275 # b4_lex_param_call
 276 # -------------------
 277 # Delegating the lexer parameters to the lexer constructor.
 278 m4_define([b4_lex_param_call],
 279           [m4_ifset([b4_lex_param],
 280                     [b4_remove_comma([$1],
 281                                      b4_param_calls(b4_lex_param))],
 282                     [$1])])
 283 m4_define([b4_param_calls],
 284           [m4_map([b4_param_call], [$@])])
 285 m4_define([b4_param_call], [, $2])
 286
 287
 288
 289 # b4_parse_param_cons
 290 # -------------------
 291 # Extra initialisations of the constructor.
 292 m4_define([b4_parse_param_cons],
 293           [m4_ifset([b4_parse_param],
 294                     [b4_constructor_calls(b4_parse_param)])])
 295
 296 m4_define([b4_constructor_calls],
 297           [m4_map([b4_constructor_call], [$@])])
 298 m4_define([b4_constructor_call],
 299           [this.$2 = $2;
 300           ])
 301
 302
 303
 304 # b4_parse_param_vars
 305 # -------------------
 306 # Extra instance variables.
 307 m4_define([b4_parse_param_vars],
 308           [m4_ifset([b4_parse_param],
 309                     [
 310     /* User arguments.  */
 311 b4_var_decls(b4_parse_param)])])
 312
 313 m4_define([b4_var_decls],
 314           [m4_map_sep([b4_var_decl], [
 315 ], [$@])])
 316 m4_define([b4_var_decl],
 317           [    protected final $1;])
 318
 319
 320
 321 # b4_maybe_throws(THROWS)
 322 # -----------------------
 323 # Expand to either an empty string or "throws THROWS".
 324 m4_define([b4_maybe_throws],
 325           [m4_ifval($1, [throws $1])])