tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 ## ------------- ##
  33 ## Basic tests.  ##
  34 ## ------------- ##
  35
  36 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  37 # ------------------------------------------
  38 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  39 # taken in "slurp" mode, i.e., one can match end-of-lines.
  40 m4_define([AT_MATCHES_CHECK],
  41 [AT_CHECK([$PERL -0777 -ne '
  42 my $count = 0;
  43 s{$2}{ ++$count; "" }gem;
  44 printf "$count\n";' $1], [0], [$3
  45 ])])
  46
  47
  48 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  49 # ------------------------------------------------
  50 # Don't interfere with caller's files.
  51 m4_divert_text([PREPARE_TESTS],
  52 [at_save_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       as_fn_error 1 "fatal error: back-up on top of a back-up"
  58     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  59   done
  60 }
  61
  62 at_restore_special_files ()
  63 {
  64   for at_save_file in stderr experr expout
  65   do
  66     test ! -f at-bison-check-$at_save_file.bak ||
  67       mv at-bison-check-$at_save_file.bak $at_save_file
  68   done
  69 }
  70 ])
  71
  72 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  73 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  74
  75
  76
  77 ## ------------------------------- ##
  78 ## Macros decoding Bison options.  ##
  79 ## ------------------------------- ##
  80
  81 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  82 # ----------------------------------------------------------------
  83 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  84 m4_define([AT_LOC_PUSHDEF],
  85 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  86 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  87 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  88 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  89
  90 # AT_LOC_POPDEF
  91 # -------------
  92 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  93 m4_define([AT_LOC_POPDEF],
  94 [m4_popdef([AT_LOC_FIRST_LINE])
  95 m4_popdef([AT_LOC_FIRST_COLUMN])
  96 m4_popdef([AT_LOC_LAST_LINE])
  97 m4_popdef([AT_LOC_LAST_COLUMN])])
  98
  99
 100
 101 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 102 # -----------------------------------------
 103 m4_define([AT_BISON_OPTION_PUSHDEFS],
 104 [m4_divert_text([KILL],
 105                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 106
 107
 108 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 109 # --------------------------------------------------
 110 # This macro works around the impossibility to define macros
 111 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 112 # This sucks hard, GNU M4 should really provide M5 like $$1.
 113 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 114 [m4_if([$1$2], $[1]$[2], [],
 115        [m4_fatal([$0: Invalid arguments: $@])])dnl
 116 m4_pushdef([AT_DEFINES_IF],
 117 [m4_bmatch([$3], [%defines], [$1], [$2])])
 118 m4_pushdef([AT_SKEL_CC_IF],
 119 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 120 m4_pushdef([AT_SKEL_JAVA_IF],
 121 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 122 m4_pushdef([AT_LANG],
 123 [AT_SKEL_JAVA_IF([java],
 124                  [AT_SKEL_CC_IF([c++],
 125                                 [c])])])
 126 m4_pushdef([AT_GLR_IF],
 127 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 128 m4_pushdef([AT_LALR1_CC_IF],
 129 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 130 m4_pushdef([AT_GLR_CC_IF],
 131 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 132 # Using yacc.c?
 133 m4_pushdef([AT_YACC_IF],
 134 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 135 m4_pushdef([AT_LEXPARAM_IF],
 136 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 137 m4_pushdef([AT_LOCATION_IF],
 138 [m4_bmatch([$3], [%locations], [$1], [$2])])
 139 m4_pushdef([AT_LOCATION_TYPE_IF],
 140 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 141 m4_pushdef([AT_PARAM_IF],
 142 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 143 m4_pushdef([AT_PURE_IF],
 144 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 145            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 146            [$2])])
 147 m4_pushdef([AT_PURE_AND_LOC_IF],
 148 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 149 m4_pushdef([AT_GLR_OR_PARAM_IF],
 150 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 151 m4_pushdef([AT_NAME_PREFIX],
 152 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 153            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 154            [yy])])
 155 m4_pushdef([AT_API_prefix],
 156 [m4_bmatch([$3], [%define api\.prefix ".*"],
 157            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 158            [yy])])
 159 m4_pushdef([AT_API_PREFIX],
 160 [m4_toupper(AT_API_prefix)])
 161 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 162 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 163 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 164                     [$2])])
 165 # yyerror always sees the locations (when activated), except if
 166 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 167 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 168 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 169                                         [$1])],
 170                             [$1])],
 171                 [$2])])
 172
 173 # The interface is pure: either because %define api.pure, or because we
 174 # are using the C++ parsers.
 175 m4_pushdef([AT_PURE_LEX_IF],
 176 [AT_PURE_IF([$1],
 177             [AT_SKEL_CC_IF([$1], [$2])])])
 178
 179 m4_pushdef([AT_YYSTYPE],
 180 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 181                [AT_API_PREFIX[STYPE]])])
 182 m4_pushdef([AT_YYLTYPE],
 183 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 184                [AT_API_PREFIX[LTYPE]])])
 185
 186
 187 AT_PURE_LEX_IF(
 188 [m4_pushdef([AT_LOC], [(*llocp)])
 189  m4_pushdef([AT_VAL], [(*lvalp)])
 190  m4_pushdef([AT_YYLEX_FORMALS],
 191             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 192  m4_pushdef([AT_YYLEX_ARGS],
 193             [lvalp[]AT_LOCATION_IF([, llocp])])
 194  m4_pushdef([AT_USE_LEX_ARGS],
 195             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 196  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 197             [AT_YYLEX_FORMALS, ])
 198  m4_pushdef([AT_YYLEX_PRE_ARGS],
 199             [AT_YYLEX_ARGS, ])
 200 ],
 201 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 202  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 203  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 204  m4_pushdef([AT_YYLEX_ARGS],        [])
 205  m4_pushdef([AT_USE_LEX_ARGS],    [])
 206  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 207  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 208 ])
 209
 210 # Handle the different types of location components.
 211
 212 AT_SKEL_CC_IF(
 213   [AT_LOCATION_TYPE_IF(
 214     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 215     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 216   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 217
 218 ])# _AT_BISON_OPTION_PUSHDEFS
 219
 220
 221 # AT_BISON_OPTION_POPDEFS
 222 # -----------------------
 223 m4_define([AT_BISON_OPTION_POPDEFS],
 224 [m4_divert_text([KILL],
 225 [m4_popdef([AT_YYLEX_PRE_ARGS])
 226 m4_popdef([AT_YYLEX_PRE_FORMALS])
 227 m4_popdef([AT_USE_LEX_ARGS])
 228 m4_popdef([AT_YYLEX_ARGS])
 229 m4_popdef([AT_YYLEX_FORMALS])
 230 m4_popdef([AT_YYLTYPE])
 231 m4_popdef([AT_YYSTYPE])
 232 m4_popdef([AT_VAL])
 233 m4_popdef([AT_LOC])
 234 m4_popdef([AT_PURE_LEX_IF])
 235 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 236 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 237 m4_popdef([AT_API_PREFIX])
 238 m4_popdef([AT_API_prefix])
 239 m4_popdef([AT_NAME_PREFIX])
 240 m4_popdef([AT_GLR_OR_PARAM_IF])
 241 m4_popdef([AT_PURE_AND_LOC_IF])
 242 m4_popdef([AT_LOCATION_TYPE_IF])
 243 m4_popdef([AT_LOCATION_IF])
 244 m4_popdef([AT_PARAM_IF])
 245 m4_popdef([AT_LEXPARAM_IF])
 246 m4_popdef([AT_YACC_IF])
 247 m4_popdef([AT_GLR_IF])
 248 m4_popdef([AT_SKEL_CC_IF])
 249 m4_popdef([AT_LANG])
 250 m4_popdef([AT_SKEL_JAVA_IF])
 251 m4_popdef([AT_GLR_CC_IF])
 252 m4_popdef([AT_LALR1_CC_IF])
 253 m4_popdef([AT_DEFINES_IF])
 254 AT_LOC_POPDEF])dnl
 255 ])# AT_BISON_OPTION_POPDEFS
 256
 257
 258
 259 ## -------------------------- ##
 260 ## Generating Grammar Files.  ##
 261 ## -------------------------- ##
 262
 263 # AT_DATA_SOURCE_PROLOGUE
 264 # ------------------------
 265 # The prologue that should be included in any source code that is
 266 # meant to be compiled.
 267 m4_define([AT_DATA_SOURCE_PROLOGUE],
 268 [[#include <config.h>
 269 /* We don't need perfect functions for these tests. */
 270 #undef malloc
 271 #undef memcmp
 272 #undef realloc
 273 ]])
 274
 275 # AT_DATA_GRAMMAR_PROLOGUE
 276 # ------------------------
 277 # The prologue that should be included in any grammar which parser is
 278 # meant to be compiled.
 279 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 280 [[%code top {
 281 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 282 [}
 283 ]])
 284
 285 # AT_DATA_SOURCE(NAME, CONTENT)
 286 # -----------------------------
 287 # Generate the file NAME, which CONTENT is preceded by
 288 # AT_DATA_SOURCE_PROLOGUE.
 289 m4_define([AT_DATA_SOURCE],
 290 [AT_DATA([$1],
 291 [AT_DATA_SOURCE_PROLOGUE
 292 $2])
 293 ])
 294
 295 # AT_DATA_GRAMMAR(NAME, CONTENT)
 296 # ------------------------------
 297 # Generate the file NAME, which CONTENT is preceded by
 298 # AT_DATA_GRAMMAR_PROLOGUE.
 299 m4_define([AT_DATA_GRAMMAR],
 300 [AT_DATA([$1],
 301 [AT_DATA_GRAMMAR_PROLOGUE
 302 $2])
 303 ])
 304
 305 # AT_YYLEX_PROTOTYPE
 306 # AT_YYLEX_DECLARE_EXTERN
 307 # AT_YYLEX_DECLARE
 308 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 309 # ----------------------------------
 310 # INPUT can be empty, or in double quotes, or a list (in braces).
 311 # ACTION may compute yylval for instance, using "res" as token type,
 312 # and "toknum" as the number of calls to yylex (starting at 0).
 313 m4_define([AT_YYLEX_PROTOTYPE],
 314 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 315 ])
 316
 317 m4_define([AT_YYLEX_DECLARE_EXTERN],
 318 [AT_YYLEX_PROTOTYPE;dnl
 319 ])
 320
 321 m4_define([AT_YYLEX_DECLARE],
 322 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 323 ])
 324
 325 m4_define([AT_YYLEX_DEFINE],
 326 [[#include <assert.h>
 327 static
 328 ]AT_YYLEX_PROTOTYPE[
 329 {
 330   ]m4_bmatch([$1], [^\(".*"\)?$],
 331              [[static char const input[] = ]m4_default([$1], [""])],
 332              [[static int const input[] = ]$1])[;
 333   static size_t toknum = 0;
 334   int res;
 335   ]AT_USE_LEX_ARGS[;
 336   assert (toknum < sizeof input / sizeof input[0]);
 337   res = input[toknum++];
 338   ]$2[;]AT_LOCATION_IF([[
 339   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 340   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 341   return res;
 342 }]dnl
 343 ])
 344
 345 # AT_YYERROR_PROTOTYPE
 346 # AT_YYERROR_DECLARE_EXTERN
 347 # AT_YYERROR_DECLARE
 348 # AT_YYERROR_DEFINE
 349 # -------------------------
 350 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 351 m4_define([AT_YYERROR_FORMALS],
 352 [m4_case(AT_LANG,
 353 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE *llocp, ])[const char *msg]])[]dnl
 354 ])
 355
 356 m4_define([AT_YYERROR_PROTOTYPE],
 357 [m4_case(AT_LANG,
 358 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 359 ])
 360
 361 m4_define([AT_YYERROR_DECLARE_EXTERN],
 362 [m4_case(AT_LANG,
 363 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 364 ])
 365
 366 m4_define([AT_YYERROR_DECLARE],
 367 [m4_case(AT_LANG,
 368 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 369 ])
 370
 371 m4_define([AT_YYERROR_DEFINE],
 372 [m4_case(AT_LANG,
 373 [c], [[#include <stdio.h>
 374 /* A C error reporting function.  */
 375 static
 376 ]AT_YYERROR_PROTOTYPE[
 377 {
 378 ]AT_YYERROR_SEES_LOC_IF([[
 379   fprintf (stderr, "%d.%d",
 380            ]AT_LOC_FIRST_LINE[, ]AT_LOC_FIRST_COLUMN[);
 381   if (]AT_LOC_FIRST_LINE[ != ]AT_LOC_LAST_LINE[)
 382     fprintf (stderr, "-%d.%d",
 383              ]AT_LOC_LAST_LINE[,  ]AT_LOC_LAST_COLUMN[ - 1);
 384   else if (]AT_LOC_FIRST_COLUMN[ != ]AT_LOC_LAST_COLUMN[ - 1)
 385     fprintf (stderr, "-%d",
 386              ]AT_LOC_LAST_COLUMN[ - 1);
 387   fprintf (stderr, ": ");]])[
 388   fprintf (stderr, "%s\n", msg);
 389 }]],
 390 [c++], [[/* A C++ error reporting function.  */
 391 void
 392 ]AT_NAME_PREFIX[::parser::error (const location_type& l, const std::string& m)
 393 {
 394   (void) l;
 395   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 396 }]],
 397 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 398   {
 399     if (l == null)
 400       System.err.println (s);
 401     else
 402       System.err.println (l + ": " + s);
 403   }
 404 ]], [[
 405   public void yyerror (String s)
 406   {
 407     System.err.println (s);
 408   }]])],
 409 [m4_fatal([$0: invalid language: ]AT_LANG)])dnl
 410 ])
 411
 412
 413 ## --------------- ##
 414 ## Running Bison.  ##
 415 ## --------------- ##
 416
 417 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 418 # -------------------------------------------------
 419 # High-level routine that may call bison several times, under different
 420 # conditions.
 421 #
 422 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 423 # shell constructs (such as redirection or pipes) that would prevent
 424 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 425 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 426 #
 427 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 428 # Bison in the test suite.  For now it ensures that:
 429 #
 430 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 431 #      a non-zero exit status since Bison doesn't always try to free all memory
 432 #      in that case.
 433 #
 434 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 435 #      --graph and --report=all output for every working grammar.
 436 #
 437 #   3. If stderr contains a warning, -Werror and --warnings=error
 438 #      convert the warning to an error.
 439 #
 440 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 441 m4_define([AT_BISON_CHECK],
 442 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 443 AT_BISON_CHECK_NO_XML($@)])
 444
 445 m4_define([AT_BISON_WERROR_MSG],
 446           [[bison: warnings being treated as errors]])
 447
 448
 449 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 450 # --------------------------------------------------
 451 # Low-level macro to run bison once.
 452 m4_define([AT_BISON_CHECK_],
 453 [AT_CHECK(AT_QUELL_VALGRIND[[ bison ]]$@)])
 454
 455
 456 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 457 # ----------------------------------------------------------
 458 # Check that warnings (if some are expected) are correctly
 459 # turned into errors with -Werror, etc.
 460 m4_define([AT_BISON_CHECK_WARNINGS],
 461 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 462       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 463
 464 m4_define([AT_BISON_CHECK_WARNINGS_],
 465 [[# Defining POSIXLY_CORRECT causes bison to complain if options
 466 # are added after the grammar file name, so skip these checks
 467 # in that case.
 468 if test -z "${POSIXLY_CORRECT+set}"; then
 469   ]AT_SAVE_SPECIAL_FILES[
 470
 471   # To avoid expanding it repeatedly, store specified stdout.
 472   ]AT_DATA([expout], [$3])[
 473
 474   # Run with -Werror.
 475   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 476
 477   # Build expected stderr up to and including the "warnings being
 478   # treated as errors" message.
 479   ]AT_DATA([[at-bison-check-warnings]], [$4])[
 480   at_bison_check_first=`sed -n \
 481     '/: warning: /{=;q;}' at-bison-check-warnings`
 482   : ${at_bison_check_first:=1}
 483   at_bison_check_first_tmp=`sed -n \
 484     '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 485   : ${at_bison_check_first_tmp:=1}
 486   if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 487     at_bison_check_first=$at_bison_check_first_tmp
 488   fi
 489   if test $at_bison_check_first -gt 1; then
 490     sed -n "1,`expr $at_bison_check_first - 1`"p \
 491       at-bison-check-warnings > experr
 492   fi
 493   echo ']AT_BISON_WERROR_MSG[' >> experr
 494
 495   # Finish building expected stderr and check.  Unlike warnings,
 496   # complaints cause bison to exit early.  Thus, with -Werror, bison
 497   # does not necessarily report all warnings that it does without
 498   # -Werror, but it at least reports one.
 499   at_bison_check_last=`sed -n '$=' stderr`
 500   : ${at_bison_check_last:=1}
 501   at_bison_check_last=`expr $at_bison_check_last - 1`
 502   sed -n "$at_bison_check_first,$at_bison_check_last"p \
 503     at-bison-check-warnings >> experr
 504   ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 505               stderr 1>&2]], [[0]], [[]], [experr])[
 506
 507   # Now check --warnings=error.
 508   cp stderr experr
 509   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 510
 511   # Now check -Wnone and --warnings=none by making sure that
 512   # -Werror doesn't change the exit status when -Wnone or
 513   # --warnings=none is specified.
 514   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 515   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 516
 517   ]AT_RESTORE_SPECIAL_FILES[
 518 fi]dnl
 519 ])
 520
 521 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 522 # --------------------------------------------------------
 523 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 524 # when a tortured grammar's XML is known to be too large for xsltproc to
 525 # handle.
 526 m4_define([AT_BISON_CHECK_NO_XML],
 527 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison ]]$@)
 528 AT_BISON_CHECK_WARNINGS($@)])
 529
 530 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 531 # -----------------------------------------------------
 532 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 533 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 534 # have a non-zero exit status.
 535 m4_define([AT_BISON_CHECK_XML],
 536 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 537   AT_SAVE_SPECIAL_FILES
 538   [mkdir xml-tests]
 539   m4_pushdef([AT_BISON_ARGS],
 540              [m4_bpatsubsts([[$1]],
 541                             [--report(-file)?=[^][ ]*], [],
 542                             [--graph=[^][ ]*], [],
 543                             [--xml=[^][ ]*], [])])dnl
 544   # Don't combine these Bison invocations since we want to be sure that
 545   # --report=all isn't required to get the full XML file.
 546   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 547                   --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 548                   [[0]], [ignore], [ignore])
 549   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 550                  [[0]], [ignore], [ignore])
 551   m4_popdef([AT_BISON_ARGS])dnl
 552   [cp xml-tests/test.output expout]
 553   AT_CHECK([[$XSLTPROC \
 554              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 555              xml-tests/test.xml]], [[0]], [expout])
 556   [cp xml-tests/test.dot expout]
 557   AT_CHECK([[$XSLTPROC \
 558              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 559              xml-tests/test.xml]], [[0]], [expout])
 560   [rm -rf xml-tests expout]
 561   AT_RESTORE_SPECIAL_FILES
 562 [fi]])
 563
 564 # AT_QUELL_VALGRIND
 565 # -----------------
 566 # Put this before a Bison invocation to keep Valgrind from complaining about
 567 # reachable memory.
 568 #
 569 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 570 # The triple quoting below will cause test cases to fail if you do.  If you do
 571 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 572 # will then fail to shell-escape its contents when attempting to print them.
 573 # The testsuite verbose output, at least, will be incorrect, but nothing may
 574 # fail to make sure you notice.
 575 m4_define([AT_QUELL_VALGRIND],
 576 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 577
 578
 579
 580 ## ------------------------ ##
 581 ## Compiling C, C++ Files.  ##
 582 ## ------------------------ ##
 583
 584
 585 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 586 # ----------------------------------------
 587 # Compile SOURCES into OUTPUT.
 588 #
 589 # If OUTPUT does not contain '.', assume that we are linking too,
 590 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 591 # with trailing .o removed, and ".c" appended.
 592 m4_define([AT_COMPILE],
 593 [AT_CHECK(m4_join([ ],
 594                   [$CC $CFLAGS $CPPFLAGS],
 595                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 596                   [-o $1],
 597                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 598                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 599            0, [ignore], [ignore])])
 600
 601 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 602 # ---------------------------------------------
 603 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 604 # ignore the test.
 605 #
 606 # If OUTPUT does not contain '.', assume that we are linking too,
 607 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 608 # with trailing .o removed, and ".cc" appended.
 609 m4_define([AT_COMPILE_CXX],
 610 [AT_KEYWORDS(c++)
 611 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 612 AT_CHECK(m4_join([ ],
 613                  [$CXX $CXXFLAGS $CPPFLAGS],
 614                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 615                  [-o $1],
 616                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 617                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 618          0, [ignore], [ignore])])
 619
 620 # AT_JAVA_COMPILE(SOURCES)
 621 # ------------------------
 622 # Compile SOURCES into Java class files.  Skip the test if java or javac
 623 # is not installed.
 624 m4_define([AT_JAVA_COMPILE],
 625 [AT_KEYWORDS(java)
 626 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 627 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 628 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 629          [[0]], [ignore], [ignore])])
 630
 631 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 632 # --------------------------------------------
 633 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 634 #
 635 # If OUTPUT does not contain '.', assume that we are linking too,
 636 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 637 # with trailing .o removed, and ".c"/".cc" appended.
 638 m4_define([AT_LANG_COMPILE],
 639 [m4_case(AT_LANG,
 640 [c],    [AT_COMPILE([$1], [$2])],
 641 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 642 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 643         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 644 ])
 645
 646 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 647 # -------------------------------------------
 648 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 649 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 650 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 651 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 652 # AT_SKEL_JAVA_IF.
 653 m4_define([AT_FULL_COMPILE],
 654 [m4_case(AT_LANG,
 655 [java],
 656   [AT_BISON_CHECK([-o $1.java $1.y])
 657    AT_LANG_COMPILE([$1],
 658                    m4_join([ ],
 659                            [$1.java],
 660                            m4_ifval($2, [[$1-$2.java]]),
 661                            m4_ifval($3, [[$1-$3.java]])))],
 662 [c++],
 663   [AT_BISON_CHECK([-o $1.cc $1.y])
 664    AT_LANG_COMPILE([$1],
 665                    m4_join([ ],
 666                            [$1.cc],
 667                            m4_ifval($2, [[$1-$2.cc]]),
 668                            m4_ifval($3, [[$1-$3.cc]])))],
 669 [c],
 670   [AT_BISON_CHECK([-o $1.c $1.y])
 671    AT_LANG_COMPILE([$1],
 672                    m4_join([ ],
 673                            [$1.c],
 674                            m4_ifval($2, [[$1-$2.c]]),
 675                            m4_ifval($3, [[$1-$3.c]])))])
 676 ])
 677
 678
 679 ## ---------------------------- ##
 680 ## Running a generated parser.  ##
 681 ## ---------------------------- ##
 682
 683
 684 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 685 # ------------------------------------------------------------
 686 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 687 #
 688 # Get rid of spurious messages when compiled with --coverage:
 689 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 690 m4_define([AT_PARSER_CHECK],
 691 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 692 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 693          [0], [], [$4])
 694 ])
 695
 696
 697 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 698 # -----------------------------------------------------------------
 699 m4_define([AT_JAVA_PARSER_CHECK],
 700 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 701
 702
 703 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 704 #                          DECLS, GRAMMAR, INPUT,
 705 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 706 #                          [OTHER-CHECKS],
 707 #                          [PARSER-EXIT-VALUE],
 708 #                          [PARSER-STDOUT], [PARSER-STDERR])
 709 # -------------------------------------------------------------
 710 # Using TITLE as the test group title, check the generated parser tables
 711 # and parser for a specified grammar file under a condition labeled by
 712 # COND-VALUE.
 713 #
 714 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 715 # recognized attribute is described below where it is relevant.
 716 #
 717 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 718 # the grammar file.  Insert basic yyerror, yylex, and main function
 719 # definitions as well.  Hardcode yylex to return the (possibly empty)
 720 # comma-delimited series of tokens in INPUT followed by token 0.
 721 #
 722 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 723 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 724 # On the bison command-line, specify `--report=all --defines'.  Check
 725 # that Bison exits with value 0, has no stdout, and has stderr
 726 # BISON-STDERR.
 727 #
 728 # If TEST-SPEC contains the attribute `last-state', check that the value
 729 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 730 # the grammar; in other words, check the number of states (minus one).
 731 # Otherwise, check that everything in the `.output' file starting with
 732 # the definition of state 0 is the same as the entire value of
 733 # TABLES-OR-LAST-STATE.
 734 #
 735 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 736 # `.output' file, which is named `input.output', and/or grammar file,
 737 # which is named `input.y'.
 738 #
 739 # Finally, compile the generated parser and then run it using
 740 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 741 # PARSER-STDERR as the 2nd-4th arguments.
 742 #
 743 # As a precondition, you must properly double-quote all arguments that
 744 # are to be interpreted as strings.
 745 #
 746 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 747 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 748 # first argument.  This is useful, for example, when wrapping multiple
 749 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 750 # condition, in another macro.
 751 #
 752 # For example:
 753 #
 754 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 755 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 756 #   # ---------------------------------------------------------------------
 757 #   m4_define([AT_TEST_SYNTAX_ERROR],
 758 #   [
 759 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 760 #                              [[last-state]],
 761 #                              [[%error-verbose ]$2], [$3], [$4],
 762 #                              [[]], [$5], [], [$6], [$7], [$8])
 763 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 764 #                              [[last-state]],
 765 #                              [$2], [$3], [$4],
 766 #                              [[]], [$5], [], [$6], [$7], [$8])
 767 #   ])
 768 #
 769 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 770 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 771 #                        [[3]],
 772 #                        [[1]], [[]],
 773 #                        [AT_COND_CASE([[no verbose]],
 774 #                                      [[syntax error
 775 #   ]],
 776 #                                      [[syntax error, unexpected 'b', expecting $end
 777 #   ]])])
 778 m4_define([AT_TEST_TABLES_AND_PARSE],
 779 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 780
 781 AT_SETUP([$1])
 782 AT_BISON_OPTION_PUSHDEFS([$4])
 783 AT_DATA_GRAMMAR([[input.y]],
 784 [[%code {
 785   #include <stdio.h>
 786   ]AT_YYERROR_DECLARE[
 787   ]AT_YYLEX_DECLARE[
 788 }
 789
 790 ]$4[
 791
 792 %%
 793
 794 ]$5[
 795
 796 %%
 797 ]AT_YYERROR_DEFINE[
 798 static int
 799 yylex (void)
 800 {
 801   static int const input[] = {
 802     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 803   };
 804   static int const *inputp = input;
 805   return *inputp++;
 806 }
 807
 808 int
 809 main (void)
 810 {
 811   return yyparse ();
 812 }
 813 ]])
 814
 815 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 816 # expanding macros, so it corrupts some special characters in the
 817 # macros.  To avoid this, expand now and pass it the result with proper
 818 # string quotation.  Assume args 7 through 12 expand to properly quoted
 819 # strings.
 820
 821 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 822       [AT_BISON_CHECK],
 823       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 824                                [0], [], m4_dquote($7))
 825
 826 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 827       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 828                 m4_dquote($8))],
 829       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 830                 m4_dquote($8)[[
 831 ]])])
 832
 833 $9
 834
 835 # Canonical LR generates very large tables, resulting in very long
 836 # files with #line directives that may overflow what the standards
 837 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 838 # will issue an error.
 839 #
 840 # There is no "" around `wc` since some indent the result.
 841 m4_bmatch([$4], [%define lr.type canonical-lr],
 842 [if test 32767 -lt `wc -l < input.c`; then
 843   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 844   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 845 fi])
 846 AT_COMPILE([[input]])
 847
 848 AT_PARSER_CHECK([[./input]],
 849                 m4_ifval([$10], [m4_dquote($10)]),
 850                 m4_ifval([$11], [m4_dquote($11)]),
 851                 m4_ifval([$12], [m4_dquote($12)]))
 852
 853 AT_BISON_OPTION_POPDEFS
 854 AT_CLEANUP
 855
 856 m4_popdef([AT_COND_CASE])])
 857
 858
 859
 860 ## ----------------------- ##
 861 ## Launch the test suite.  ##
 862 ## ----------------------- ##
 863
 864 AT_INIT
 865
 866 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 867 # options are processed, so we don't know the value of CXX and
 868 # CXXFLAGS yet.
 869 #
 870 # Note that it also means that command line values for CXX and
 871 # CXXFLAGS will not be propagated to CC and CFLAGS.
 872 AT_ARG_OPTION([compile-c-with-cxx],
 873               [compile C parsers with the C++ compiler])
 874
 875 AT_COLOR_TESTS
 876
 877 AT_TESTED([bison])