configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006 Free Software
   4 # Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301  USA
  20
  21 # We have strange test case titles, so we need Autoconf 2.61 or better.
  22 AC_PREREQ(2.61)
  23
  24 AC_INIT([GNU Bison], [2.3a+], [bug-bison@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 # We don't have a file m4/Makefile.am, so we need Automake 1.8 or later.
  29 AM_INIT_AUTOMAKE([1.8 check-news readme-alpha dist-bzip2])
  30 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  31
  32 # Checks for the compiler.
  33 AC_PROG_CC_STDC
  34
  35 # Gnulib (early checks).
  36 gl_EARLY
  37
  38 AC_ARG_ENABLE(gcc-warnings,
  39 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  40 [case "${enableval}" in
  41    yes|no) ;;
  42    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  43  esac],
  44               [enableval=no])
  45 if test "${enableval}" = yes; then
  46   gl_WARNING_CFLAGS([-Werror])
  47   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  48   WARNING_CFLAGS=
  49   gl_WARNING_CFLAGS([-Wall])
  50   gl_WARNING_CFLAGS([-Wextra -Wno-sign-compare])
  51   gl_WARNING_CFLAGS([-Wcast-align])
  52   gl_WARNING_CFLAGS([-Wcast-qual])
  53   gl_WARNING_CFLAGS([-Wformat])
  54   gl_WARNING_CFLAGS([-Wpointer-arith])
  55   gl_WARNING_CFLAGS([-Wwrite-strings])
  56   AC_SUBST([WARNING_CXXFLAGS], [$WARNING_CFLAGS])
  57   # The following warnings are not suitable for C++.
  58   gl_WARNING_CFLAGS([-Wbad-function-cast])
  59   gl_WARNING_CFLAGS([-Wmissing-declarations])
  60   gl_WARNING_CFLAGS([-Wmissing-prototypes])
  61   gl_WARNING_CFLAGS([-Wshadow])
  62   gl_WARNING_CFLAGS([-Wstrict-prototypes])
  63   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  64 fi
  65
  66 BISON_TEST_FOR_WORKING_C_COMPILER
  67
  68 AC_ARG_ENABLE([yacc],
  69   [AC_HELP_STRING([--disable-yacc],
  70      [do not build a yacc command or an -ly library])],
  71   , [enable_yacc=yes])
  72 case $enable_yacc in
  73 yes)
  74   YACC_SCRIPT=yacc
  75   YACC_LIBRARY=liby.a;;
  76 *)
  77   YACC_SCRIPT=
  78   YACC_LIBRARY=;;
  79 esac
  80 AC_SUBST([YACC_SCRIPT])
  81 AC_SUBST([YACC_LIBRARY])
  82
  83 # Checks for programs.
  84 AC_PROG_LEX
  85 AC_PROG_YACC
  86 AC_PROG_RANLIB
  87 BISON_PROG_GNU_M4
  88 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  89   AC_MSG_ERROR([GNU M4 1.4 is required])
  90 fi
  91 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  92
  93 # Checks for header files.
  94 AC_CHECK_HEADERS_ONCE([locale.h])
  95
  96 # Checks for compiler characteristics.
  97 AC_C_INLINE
  98
  99 # Gnulib (later checks).  Putting them here rather than right after
 100 # gl_EARLY avoids some redundant checks.
 101 gl_INIT
 102
 103 # Checks for library functions.
 104 AC_CHECK_FUNCS_ONCE([setlocale])
 105 AM_WITH_DMALLOC
 106 BISON_PREREQ_SUBPIPE
 107 BISON_PREREQ_TIMEVAR
 108
 109 # Gettext.
 110 # We've never tested with gettext versions before 0.15, so play it safe.
 111 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 112 AM_GNU_GETTEXT_VERSION([0.15])
 113 BISON_I18N
 114
 115 # Internationalized parsers.
 116 AC_CONFIG_FILES([runtime-po/Makefile.in])
 117 # Autoconf macros for packages using internationalized parsers.
 118 aclocaldir='${datadir}/aclocal'
 119 AC_SUBST([aclocaldir])
 120
 121 # Create the benchmark script.
 122 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 123
 124 # Initialize the test suite.
 125 AC_CONFIG_TESTDIR(tests)
 126 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 127 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 128 AC_CHECK_PROGS([VALGRIND], [valgrind])
 129 AC_PROG_CXX
 130 BISON_TEST_FOR_WORKING_CXX_COMPILER
 131 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 132 # Needed by tests/atlocal.in.
 133 AC_SUBST([GCC])
 134 O0CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]] *//'`
 135 AC_SUBST([O0CFLAGS])
 136 O0CXXFLAGS=`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`
 137 AC_SUBST([O0CXXFLAGS])
 138
 139 AC_CONFIG_FILES([Makefile
 140                  build-aux/Makefile
 141                  po/Makefile.in
 142                  data/Makefile
 143                  etc/Makefile
 144                  examples/Makefile
 145                     examples/calc++/Makefile
 146                  lib/Makefile src/Makefile doc/Makefile])
 147 AC_OUTPUT