configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2013 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the 'configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2013])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz nostdinc
  49                  color-tests parallel-tests
  50                  silent-rules]
  51                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  52                            [gnu], [gnits]))
  53 AM_SILENT_RULES([yes])
  54 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  55
  56 # Checks for the compiler.
  57 AC_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 # Gnulib (early checks).
  61 gl_EARLY
  62
  63 # Gnulib uses '#pragma GCC diagnostic push' to silence some
  64 # warnings, but older gcc doesn't support this.
  65 AC_CACHE_CHECK([whether pragma GCC diagnostic push works],
  66   [lv_cv_gcc_pragma_push_works], [
  67   save_CFLAGS=$CFLAGS
  68   CFLAGS='-Wunknown-pragmas -Werror'
  69   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  70     #pragma GCC diagnostic push
  71     #pragma GCC diagnostic pop
  72   ]])],
  73   [lv_cv_gcc_pragma_push_works=yes],
  74   [lv_cv_gcc_pragma_push_works=no])
  75   CFLAGS=$save_CFLAGS])
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  79 [case $enable_gcc_warnings in
  80    yes|no) ;;
  81    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  82  esac],
  83               [enable_gcc_warnings=no])
  84 if test "$enable_gcc_warnings" = yes; then
  85   warn_common='-Wall -Wextra -Wno-sign-compare -Wcast-align
  86     -Wformat -Wpointer-arith -Wwrite-strings'
  87   warn_c='-Wbad-function-cast -Wshadow -Wstrict-prototypes'
  88   warn_cxx='-Wnoexcept'
  89   # Warnings for the test suite only.
  90   #
  91   # -fno-color-diagnostics: Clang's use of colors in the error
  92   # messages is confusing the tests looking at the compiler's output
  93   # (e.g., synclines.at).
  94   warn_tests='-Wundef -pedantic -Wsign-compare -fno-color-diagnostics'
  95
  96   AC_LANG_PUSH([C])
  97   # Clang supports many of GCC's -W options, but only issues warnings
  98   # on the ones it does not recognize.  In that case, gl_WARN_ADD
  99   # thinks the option is supported, and unknown options are then added
 100   # to CFLAGS.  But then, when -Werror is added in the test suite for
 101   # instance, the warning about the unknown option turns into an
 102   # error.
 103   #
 104   # This should be addressed by gnulib's gl_WARN_ADD, but in the
 105   # meanwhile, turn warnings about unknown options into errors in
 106   # CFLAGS, and restore CFLAGS after the tests.
 107   save_CFLAGS=$CFLAGS
 108   gl_WARN_ADD([-Werror=unknown-warning-option], [CFLAGS])
 109   for i in $warn_common $warn_c;
 110   do
 111     gl_WARN_ADD([$i], [WARN_CFLAGS])
 112   done
 113   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 114
 115   # Warnings for the test suite, and maybe for bison if GCC is modern
 116   # enough.
 117   gl_WARN_ADD([-Wmissing-declarations], [WARN_CFLAGS_TEST])
 118   gl_WARN_ADD([-Wmissing-prototypes], [WARN_CFLAGS_TEST])
 119   test $lv_cv_gcc_pragma_push_works = yes &&
 120     AS_VAR_APPEND([WARN_CFLAGS], [" $WARN_CFLAGS_TEST"])
 121
 122   # Warnings for the test suite only.
 123   for i in $warn_tests;
 124   do
 125     gl_WARN_ADD([$i], [WARN_CFLAGS_TEST])
 126   done
 127   CFLAGS=$save_CFLAGS
 128   AC_LANG_POP([C])
 129
 130   AC_LANG_PUSH([C++])
 131   save_CXXFLAGS=$CXXFLAGS
 132   gl_WARN_ADD([-Werror=unknown-warning-option], [CXXFLAGS])
 133   for i in $warn_common $warn_cxx;
 134   do
 135     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
 136   done
 137   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
 138               [AC_LANG_PROGRAM([], [nullptr])])
 139   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
 140   # Warnings for the test suite only.
 141   for i in $warn_tests;
 142   do
 143     gl_WARN_ADD([$i], [WARN_CXXFLAGS_TEST])
 144   done
 145   # Clang++ 3.2+ reject C code generated by Flex.
 146   gl_WARN_ADD([-Wno-null-conversion], [FLEX_SCANNER_CXXFLAGS])
 147   # So does G++ 4.8...
 148   gl_WARN_ADD([-Wno-sign-compare], [FLEX_SCANNER_CXXFLAGS])
 149   # ... possiby in std=c++11 mode.
 150   gl_WARN_ADD([-Wno-zero-as-null-pointer-constant], [FLEX_SCANNER_CXXFLAGS])
 151   CXXFLAGS=$save_CXXFLAGS
 152   AC_LANG_POP([C++])
 153 fi
 154
 155 BISON_TEST_FOR_WORKING_C_COMPILER
 156 BISON_C_COMPILER_POSIXLY_CORRECT
 157 BISON_TEST_FOR_WORKING_CXX_COMPILER
 158 BISON_CXX_COMPILER_POSIXLY_CORRECT
 159
 160 AC_ARG_ENABLE([yacc],
 161   [AC_HELP_STRING([--disable-yacc],
 162      [do not build a yacc command or an -ly library])],
 163   , [enable_yacc=yes])
 164 case $enable_yacc in
 165 yes)
 166   YACC_SCRIPT=src/yacc
 167   YACC_LIBRARY=lib/liby.a;;
 168 *)
 169   YACC_SCRIPT=
 170   YACC_LIBRARY=;;
 171 esac
 172 AC_SUBST([YACC_SCRIPT])
 173 AC_SUBST([YACC_LIBRARY])
 174
 175 # Checks for programs.
 176 AM_MISSING_PROG([DOT], [dot])
 177 AC_PROG_LEX
 178 $LEX_IS_FLEX || AC_MSG_ERROR([Flex is required])
 179 AC_PROG_YACC
 180 AC_PROG_RANLIB
 181 AC_PROG_GNU_M4
 182 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 183 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 184 supports -g, otherwise to "".])
 185 AC_PATH_PROG([PERL], [perl])
 186 if test -z "$PERL"; then
 187    AC_MSG_ERROR([perl not found])
 188 fi
 189 AM_MISSING_PROG([HELP2MAN], [help2man])
 190 AC_PATH_PROG([XSLTPROC], [xsltproc])
 191 AC_SUBST([XSLTPROC])
 192
 193 # Checks for header files.
 194 AC_CHECK_HEADERS_ONCE([locale.h])
 195
 196 # Checks for compiler characteristics.
 197 AC_C_INLINE
 198
 199 # Gnulib (later checks).  Putting them here rather than right after
 200 # gl_EARLY avoids some redundant checks.
 201 gl_INIT
 202
 203 # Checks for library functions.
 204 AC_CHECK_FUNCS_ONCE([setlocale])
 205 AM_WITH_DMALLOC
 206 BISON_PREREQ_TIMEVAR
 207
 208 # Gettext.
 209 # We use gnulib, which is only guaranteed to work properly with the
 210 # latest Gettext.
 211 AM_GNU_GETTEXT([external], [need-ngettext])
 212 AM_GNU_GETTEXT_VERSION([0.18])
 213 BISON_I18N
 214
 215 # Internationalized parsers.
 216 AC_CONFIG_FILES([runtime-po/Makefile.in])
 217 # Autoconf macros for packages using internationalized parsers.
 218 aclocaldir='${datadir}/aclocal'
 219 AC_SUBST([aclocaldir])
 220
 221 # Create the benchmark script.
 222 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 223
 224 # Initialize the test suite.
 225 AC_CONFIG_TESTDIR(tests)
 226 AC_CONFIG_FILES([tests/atlocal])
 227 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 228 AC_CHECK_PROGS([VALGRIND], [valgrind])
 229 case $VALGRIND:$host_os in
 230   '':*) ;;
 231   *:darwin*)
 232     # See README-hacking.
 233     # VALGRIND+=' --suppressions=$(abs_top_srcdir)/build-aux/darwin11.4.0.valgrind'
 234     VALGRIND=;;
 235   *:*)
 236     AC_SUBST([VALGRIND_PREBISON], ["$VALGRIND -q"]);;
 237 esac
 238
 239 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 240 # Needed by tests/atlocal.in.
 241 AC_SUBST([GCC])
 242
 243 gt_JAVACOMP([1.3], [1.4])
 244 gt_JAVAEXEC
 245
 246 AC_CONFIG_FILES([Makefile
 247                  po/Makefile.in
 248                  doc/yacc.1])
 249 AC_OUTPUT