src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001-2015 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software: you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation, either version 3 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  19
  20 %option nodefault noyywrap noinput nounput never-interactive debug
  21 %option prefix="skel_" outfile="lex.yy.c"
  22
  23 %{
  24 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  25    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  26 #undef skel_wrap
  27 #define skel_wrap() 1
  28
  29 #define FLEX_PREFIX(Id) skel_ ## Id
  30 #include <src/flex-scanner.h>
  31
  32 #include <dirname.h>
  33 #include <error.h>
  34 #include <quotearg.h>
  35
  36 #include <src/complain.h>
  37 #include <src/getargs.h>
  38 #include <src/files.h>
  39 #include <src/scan-skel.h>
  40
  41 #define YY_DECL static int skel_lex (void)
  42 YY_DECL;
  43
  44 typedef void (*at_directive)(int, char**, char **, int*);
  45 static void at_init (int *argc, char *argv[], at_directive *at_ptr, at_directive fun);
  46 static void at_basename (int argc, char *argv[], char**, int*);
  47 static void at_complain (int argc, char *argv[], char**, int*);
  48 static void at_output (int argc, char *argv[], char **name, int *lineno);
  49 static void fail_for_at_directive_too_many_args (char const *at_directive_name);
  50 static void fail_for_at_directive_too_few_args (char const *at_directive_name);
  51 static void fail_for_invalid_at (char const *at);
  52 %}
  53
  54 %x SC_AT_DIRECTIVE_ARGS
  55 %x SC_AT_DIRECTIVE_SKIP_WS
  56
  57 %%
  58
  59 %{
  60   int out_lineno PACIFY_CC (= 0);
  61   char *out_name = NULL;
  62
  63   /* Currently, only the @complain directive takes multiple arguments, and
  64      never more than 7, with argv[0] being the directive name and argv[1]
  65      being the type of complaint to dispatch. */
  66 #define ARGC_MAX 9
  67   int argc = 0;
  68   char *argv[ARGC_MAX];
  69   at_directive at_ptr = NULL;
  70 %}
  71
  72 "@@" fputc ('@', yyout);
  73 "@{" fputc ('[', yyout);
  74 "@}" fputc (']', yyout);
  75 "@'" continue;  /* Used by b4_cat in ../data/bison.m4.  */
  76 @\n  continue;
  77
  78 "@oline@"  fprintf (yyout, "%d", out_lineno + 1);
  79 "@ofile@"  fputs (quotearg_style (c_quoting_style, out_name), yyout);
  80
  81 "@basename("    at_init (&argc, argv, &at_ptr, &at_basename);
  82 "@complain("    at_init (&argc, argv, &at_ptr, &at_complain);
  83 "@output("      at_init (&argc, argv, &at_ptr, &at_output);
  84
  85   /* This pattern must not match more than the previous @ patterns. */
  86 @[^@{}\'(\n]*   fail_for_invalid_at (yytext);
  87 \n              out_lineno++; ECHO;
  88 [^@\n]+         ECHO;
  89
  90 <INITIAL><<EOF>> {
  91   if (out_name)
  92     {
  93       free (out_name);
  94       xfclose (yyout);
  95     }
  96   return EOF;
  97 }
  98
  99 <SC_AT_DIRECTIVE_ARGS>
 100 {
 101   [^@]+  STRING_GROW;
 102
 103   "@@"   obstack_1grow (&obstack_for_string, '@');
 104   "@{"   obstack_1grow (&obstack_for_string, '[');
 105   "@}"   obstack_1grow (&obstack_for_string, ']');
 106   "@'"   continue; /* For starting an argument that begins with whitespace. */
 107   @\n    continue;
 108
 109   @[,)] {
 110     if (argc >= ARGC_MAX)
 111       fail_for_at_directive_too_many_args (argv[0]);
 112
 113     argv[argc++] = obstack_finish0 (&obstack_for_string);
 114
 115     /* Like M4, skip whitespace after a comma.  */
 116     if (yytext[1] == ',')
 117       BEGIN SC_AT_DIRECTIVE_SKIP_WS;
 118     else
 119       {
 120         aver (at_ptr);
 121         at_ptr (argc, argv, &out_name, &out_lineno);
 122         obstack_free (&obstack_for_string, argv[0]);
 123         argc = 0;
 124         BEGIN INITIAL;
 125       }
 126   }
 127
 128   @.?  fail_for_invalid_at (yytext);
 129 }
 130
 131 <SC_AT_DIRECTIVE_SKIP_WS>
 132 {
 133   [ \t\r\n]    continue;
 134   .            yyless (0); BEGIN SC_AT_DIRECTIVE_ARGS;
 135 }
 136
 137 <SC_AT_DIRECTIVE_ARGS,SC_AT_DIRECTIVE_SKIP_WS>
 138 {
 139   <<EOF>>  complain (NULL, fatal, _("unclosed %s directive in skeleton"), argv[0]);
 140 }
 141
 142 %%
 143
 144 static void
 145 at_init (int *argc, char *argv[], at_directive *at_ptr, at_directive fun)
 146 {
 147   *at_ptr = fun;
 148   yytext[yyleng-1] = '\0';
 149   obstack_grow (&obstack_for_string, yytext, yyleng);
 150   argv[(*argc)++] = obstack_finish (&obstack_for_string);
 151   BEGIN SC_AT_DIRECTIVE_ARGS;
 152 }
 153
 154 /*------------------------.
 155 | Scan a Bison skeleton.  |
 156 `------------------------*/
 157
 158 void
 159 scan_skel (FILE *in)
 160 {
 161   static bool initialized = false;
 162   if (!initialized)
 163     {
 164       initialized = true;
 165       obstack_init (&obstack_for_string);
 166     }
 167   skel_in = in;
 168   skel__flex_debug = trace_flag & trace_skeleton;
 169   skel_lex ();
 170 }
 171
 172 void
 173 skel_scanner_free (void)
 174 {
 175   obstack_free (&obstack_for_string, 0);
 176   /* Reclaim Flex's buffers.  */
 177   yylex_destroy ();
 178 }
 179
 180 static inline warnings
 181 flag (const char *arg)
 182 {
 183   /* compare with values issued from b4_error */
 184   if (STREQ (arg, "complain"))
 185     return complaint;
 186   else if (STREQ (arg, "deprecated"))
 187     return Wdeprecated;
 188   else if (STREQ (arg, "fatal"))
 189     return fatal;
 190   else if (STREQ (arg, "note"))
 191     return silent | complaint | no_caret;
 192   else if (STREQ (arg, "warn"))
 193     return Wother;
 194   else
 195     abort ();
 196 }
 197
 198 static void
 199 at_basename (int argc, char *argv[], char **out_namep, int *out_linenop)
 200 {
 201   (void) out_namep;
 202   (void) out_linenop;
 203   if (2 < argc)
 204     fail_for_at_directive_too_many_args (argv[0]);
 205   fputs (last_component (argv[1]), yyout);
 206 }
 207
 208 static void
 209 at_complain (int argc, char *argv[], char **out_namep, int *out_linenop)
 210 {
 211   static unsigned indent;
 212   warnings w = flag (argv[1]);
 213   location loc;
 214   location *locp = NULL;
 215
 216   (void) out_namep;
 217   (void) out_linenop;
 218
 219   if (argc < 4)
 220     fail_for_at_directive_too_few_args (argv[0]);
 221   if (argv[2] && argv[2][0])
 222     {
 223       boundary_set_from_string (&loc.start, argv[2]);
 224       boundary_set_from_string (&loc.end, argv[3]);
 225       locp = &loc;
 226     }
 227   if (w & silent)
 228     indent += SUB_INDENT;
 229   else
 230     indent = 0;
 231   complain_args (locp, w, &indent, argc - 4, argv + 4);
 232   if (w & silent)
 233     indent -= SUB_INDENT;
 234 }
 235
 236 static void
 237 at_output (int argc, char *argv[], char **out_namep, int *out_linenop)
 238 {
 239   if (2 < argc)
 240     fail_for_at_directive_too_many_args (argv[0]);
 241   if (*out_namep)
 242     {
 243       free (*out_namep);
 244       xfclose (yyout);
 245     }
 246   *out_namep = xstrdup (argv[1]);
 247   output_file_name_check (out_namep, true);
 248   /* If there were errors, do not generate the output.  */
 249   yyout = xfopen (complaint_status ? "/dev/null" : *out_namep, "w");
 250   *out_linenop = 1;
 251 }
 252
 253 static void
 254 fail_for_at_directive_too_few_args (char const *at_directive_name)
 255 {
 256   complain (NULL, fatal, _("too few arguments for %s directive in skeleton"),
 257             at_directive_name);
 258 }
 259
 260 static void
 261 fail_for_at_directive_too_many_args (char const *at_directive_name)
 262 {
 263   complain (NULL, fatal, _("too many arguments for %s directive in skeleton"),
 264             at_directive_name);
 265 }
 266
 267 static void
 268 fail_for_invalid_at (char const *at)
 269 {
 270   complain (NULL, fatal, "invalid @ in skeleton: %s", at);
 271 }