data/c.m4

   1                                                             -*- Autoconf -*-
   2
   3 # C M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ## ---------------- ##
  20 ## Identification.  ##
  21 ## ---------------- ##
  22
  23 # b4_comment(TEXT)
  24 # ----------------
  25 m4_define([b4_comment], [/* m4_bpatsubst([$1], [
  26 ], [
  27    ])  */])
  28
  29 # b4_identification
  30 # -----------------
  31 # Depends on individual skeletons to define b4_pure_flag, b4_push_flag, or
  32 # b4_pull_flag if they use the values of the %define variables api.pure or
  33 # api.push_pull.
  34 m4_define([b4_identification],
  35 [[/* Identify Bison output.  */
  36 #define YYBISON 1
  37
  38 /* Bison version.  */
  39 #define YYBISON_VERSION "]b4_version["
  40
  41 /* Skeleton name.  */
  42 #define YYSKELETON_NAME ]b4_skeleton[]m4_ifdef([b4_pure_flag], [[
  43
  44 /* Pure parsers.  */
  45 #define YYPURE ]b4_pure_flag])[]m4_ifdef([b4_push_flag], [[
  46
  47 /* Push parsers.  */
  48 #define YYPUSH ]b4_push_flag])[]m4_ifdef([b4_pull_flag], [[
  49
  50 /* Pull parsers.  */
  51 #define YYPULL ]b4_pull_flag])[
  52
  53 /* Using locations.  */
  54 #define YYLSP_NEEDED ]b4_locations_flag[
  55 ]])
  56
  57
  58 ## ---------------- ##
  59 ## Default values.  ##
  60 ## ---------------- ##
  61
  62 # If the %union is not named, its name is YYSTYPE.
  63 m4_define_default([b4_union_name], [YYSTYPE])
  64
  65 # If the %name-prefix is not given, it is yy.
  66 m4_define_default([b4_prefix], [yy])
  67
  68 ## ------------------------ ##
  69 ## Pure/impure interfaces.  ##
  70 ## ------------------------ ##
  71
  72 # b4_user_args
  73 # ------------
  74 m4_define([b4_user_args],
  75 [m4_ifset([b4_parse_param], [, b4_c_args(b4_parse_param)])])
  76
  77
  78 # b4_parse_param
  79 # --------------
  80 # If defined, b4_parse_param arrives double quoted, but below we prefer
  81 # it to be single quoted.
  82 m4_define([b4_parse_param],
  83 b4_parse_param)
  84
  85
  86 # b4_parse_param_for(DECL, FORMAL, BODY)
  87 # ---------------------------------------
  88 # Iterate over the user parameters, binding the declaration to DECL,
  89 # the formal name to FORMAL, and evaluating the BODY.
  90 m4_define([b4_parse_param_for],
  91 [m4_foreach([$1_$2], m4_defn([b4_parse_param]),
  92 [m4_pushdef([$1], m4_fst($1_$2))dnl
  93 m4_pushdef([$2], m4_shift($1_$2))dnl
  94 $3[]dnl
  95 m4_popdef([$2])dnl
  96 m4_popdef([$1])dnl
  97 ])])
  98
  99 # b4_parse_param_use
 100 # ------------------
 101 # `YYUSE' all the parse-params.
 102 m4_define([b4_parse_param_use],
 103 [b4_parse_param_for([Decl], [Formal], [  YYUSE (Formal);
 104 ])dnl
 105 ])
 106
 107
 108 ## ------------ ##
 109 ## Data Types.  ##
 110 ## ------------ ##
 111
 112 # b4_int_type(MIN, MAX)
 113 # ---------------------
 114 # Return the smallest int type able to handle numbers ranging from
 115 # MIN to MAX (included).
 116 m4_define([b4_int_type],
 117 [m4_if(b4_ints_in($@,      [0],   [255]), [1], [unsigned char],
 118        b4_ints_in($@,   [-128],   [127]), [1], [signed char],
 119
 120        b4_ints_in($@,      [0], [65535]), [1], [unsigned short int],
 121        b4_ints_in($@, [-32768], [32767]), [1], [short int],
 122
 123        m4_eval([0 <= $1]),                [1], [unsigned int],
 124
 125                                                [int])])
 126
 127
 128 # b4_int_type_for(NAME)
 129 # ---------------------
 130 # Return the smallest int type able to handle numbers ranging from
 131 # `NAME_min' to `NAME_max' (included).
 132 m4_define([b4_int_type_for],
 133 [b4_int_type($1_min, $1_max)])
 134
 135 ## ---------##
 136 ## Values.  ##
 137 ## ---------##
 138
 139 # b4_null
 140 ---------
 141 # Return a null pointer constant.  NULL infringes on the user name
 142 # space in C, so use 0 rather than NULL.
 143 m4_define([b4_null], [0])
 144
 145
 146 ## ------------------------- ##
 147 ## Assigning token numbers.  ##
 148 ## ------------------------- ##
 149
 150 # b4_token_define(TOKEN-NAME, TOKEN-NUMBER)
 151 # -----------------------------------------
 152 # Output the definition of this token as #define.
 153 m4_define([b4_token_define],
 154 [#define $1 $2
 155 ])
 156
 157
 158 # b4_token_defines(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 159 # -------------------------------------------------------
 160 # Output the definition of the tokens (if there are) as #defines.
 161 m4_define([b4_token_defines],
 162 [m4_if([$@], [[]], [],
 163 [/* Tokens.  */
 164 m4_map([b4_token_define], [$@])])
 165 ])
 166
 167
 168 # b4_token_enum(TOKEN-NAME, TOKEN-NUMBER)
 169 # ---------------------------------------
 170 # Output the definition of this token as an enum.
 171 m4_define([b4_token_enum],
 172 [$1 = $2])
 173
 174
 175 # b4_token_enums(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 176 # -----------------------------------------------------
 177 # Output the definition of the tokens (if there are) as enums.
 178 m4_define([b4_token_enums],
 179 [m4_if([$@], [[]], [],
 180 [/* Tokens.  */
 181 #ifndef YYTOKENTYPE
 182 # define YYTOKENTYPE
 183    /* Put the tokens into the symbol table, so that GDB and other debuggers
 184       know about them.  */
 185    enum yytokentype {
 186 m4_map_sep([     b4_token_enum], [,
 187 ],
 188            [$@])
 189    };
 190 #endif
 191 ])])
 192
 193
 194 # b4_token_enums_defines(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 195 # -------------------------------------------------------------
 196 # Output the definition of the tokens (if there are any) as enums and, if POSIX
 197 # Yacc is enabled, as #defines.
 198 m4_define([b4_token_enums_defines],
 199 [b4_token_enums($@)b4_yacc_if([b4_token_defines($@)], [])
 200 ])
 201
 202
 203
 204 ## --------------------------------------------- ##
 205 ## Defining C functions in both K&R and ANSI-C.  ##
 206 ## --------------------------------------------- ##
 207
 208
 209 # b4_modern_c
 210 # -----------
 211 # A predicate useful in #if to determine whether C is ancient or modern.
 212 #
 213 # If __STDC__ is defined, the compiler is modern.  IBM xlc 7.0 when run
 214 # as 'cc' doesn't define __STDC__ (or __STDC_VERSION__) for pedantic
 215 # reasons, but it defines __C99__FUNC__ so check that as well.
 216 # Microsoft C normally doesn't define these macros, but it defines _MSC_VER.
 217 # Consider a C++ compiler to be modern if it defines __cplusplus.
 218 #
 219 m4_define([b4_c_modern],
 220   [[(defined __STDC__ || defined __C99__FUNC__ \
 221      || defined __cplusplus || defined _MSC_VER)]])
 222
 223 # b4_c_function_def(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 224 # ----------------------------------------------------------
 225 # Declare the function NAME.
 226 m4_define([b4_c_function_def],
 227 [#if b4_c_modern
 228 b4_c_ansi_function_def($@)
 229 #else
 230 $2
 231 $1 (b4_c_knr_formal_names(m4_shiftn(2, $@)))
 232 b4_c_knr_formal_decls(m4_shiftn(2, $@))
 233 #endif[]dnl
 234 ])
 235
 236
 237 # b4_c_ansi_function_def(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 238 # ---------------------------------------------------------------
 239 # Declare the function NAME in ANSI.
 240 m4_define([b4_c_ansi_function_def],
 241 [$2
 242 $1 (b4_c_ansi_formals(m4_shiftn(2, $@)))[]dnl
 243 ])
 244
 245
 246 # b4_c_ansi_formals([DECL1, NAME1], ...)
 247 # --------------------------------------
 248 # Output the arguments ANSI-C definition.
 249 m4_define([b4_c_ansi_formals],
 250 [m4_case([$@],
 251          [],   [void],
 252          [[]], [void],
 253                [m4_map_sep([b4_c_ansi_formal], [, ], [$@])])])
 254
 255 m4_define([b4_c_ansi_formal],
 256 [$1])
 257
 258
 259 # b4_c_knr_formal_names([DECL1, NAME1], ...)
 260 # ------------------------------------------
 261 # Output the argument names.
 262 m4_define([b4_c_knr_formal_names],
 263 [m4_map_sep([b4_c_knr_formal_name], [, ], [$@])])
 264
 265 m4_define([b4_c_knr_formal_name],
 266 [$2])
 267
 268
 269 # b4_c_knr_formal_decls([DECL1, NAME1], ...)
 270 # ------------------------------------------
 271 # Output the K&R argument declarations.
 272 m4_define([b4_c_knr_formal_decls],
 273 [m4_map_sep([b4_c_knr_formal_decl],
 274             [
 275 ],
 276             [$@])])
 277
 278 m4_define([b4_c_knr_formal_decl],
 279 [    $1;])
 280
 281
 282
 283 ## ------------------------------------------------------------ ##
 284 ## Declaring (prototyping) C functions in both K&R and ANSI-C.  ##
 285 ## ------------------------------------------------------------ ##
 286
 287
 288 # b4_c_function_decl(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 289 # -----------------------------------------------------------
 290 # Declare the function NAME.
 291 m4_define([b4_c_function_decl],
 292 [#if defined __STDC__ || defined __cplusplus
 293 b4_c_ansi_function_decl($@)
 294 #else
 295 $2 $1 ();
 296 #endif[]dnl
 297 ])
 298
 299
 300 # b4_c_ansi_function_decl(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 301 # ----------------------------------------------------------------
 302 # Declare the function NAME.
 303 m4_define([b4_c_ansi_function_decl],
 304 [$2 $1 (b4_c_ansi_formals(m4_shiftn(2, $@)));[]dnl
 305 ])
 306
 307
 308
 309
 310 ## --------------------- ##
 311 ## Calling C functions.  ##
 312 ## --------------------- ##
 313
 314
 315 # b4_c_function_call(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 316 # -----------------------------------------------------------
 317 # Call the function NAME with arguments NAME1, NAME2 etc.
 318 m4_define([b4_c_function_call],
 319 [$1 (b4_c_args(m4_shiftn(2, $@)))[]dnl
 320 ])
 321
 322
 323 # b4_c_args([DECL1, NAME1], ...)
 324 # ------------------------------
 325 # Output the arguments NAME1, NAME2...
 326 m4_define([b4_c_args],
 327 [m4_map_sep([b4_c_arg], [, ], [$@])])
 328
 329 m4_define([b4_c_arg],
 330 [$2])
 331
 332
 333 ## ----------- ##
 334 ## Synclines.  ##
 335 ## ----------- ##
 336
 337 # b4_sync_start(LINE, FILE)
 338 # -----------------------
 339 m4_define([b4_sync_start], [[#]line $1 $2])
 340
 341
 342 ## -------------- ##
 343 ## User actions.  ##
 344 ## -------------- ##
 345
 346 # b4_case(LABEL, STATEMENTS)
 347 # --------------------------
 348 m4_define([b4_case],
 349 [  case $1:
 350 $2
 351     break;])
 352
 353 # b4_symbol_actions(FILENAME, LINENO,
 354 #                   SYMBOL-TAG, SYMBOL-NUM,
 355 #                   SYMBOL-ACTION, SYMBOL-TYPENAME)
 356 # -------------------------------------------------
 357 m4_define([b4_symbol_actions],
 358 [m4_pushdef([b4_dollar_dollar],
 359    [m4_ifval([$6], [(yyvaluep->$6)], [(*yyvaluep)])])dnl
 360 m4_pushdef([b4_at_dollar], [(*yylocationp)])dnl
 361       case $4: /* $3 */
 362 b4_syncline([$2], [$1])
 363         $5;
 364 b4_syncline([@oline@], [@ofile@])
 365         break;
 366 m4_popdef([b4_at_dollar])dnl
 367 m4_popdef([b4_dollar_dollar])dnl
 368 ])
 369
 370
 371 # b4_yydestruct_generate(FUNCTION-DECLARATOR)
 372 # -------------------------------------------
 373 # Generate the "yydestruct" function, which declaration is issued using
 374 # FUNCTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
 375 # or "b4_c_function_def" for K&R.
 376 m4_define_default([b4_yydestruct_generate],
 377 [[/*-----------------------------------------------.
 378 | Release the memory associated to this symbol.  |
 379 `-----------------------------------------------*/
 380
 381 /*ARGSUSED*/
 382 ]$1([yydestruct],
 383     [static void],
 384     [[const char *yymsg],    [yymsg]],
 385     [[int yytype],           [yytype]],
 386     [[YYSTYPE *yyvaluep],    [yyvaluep]][]dnl
 387 b4_locations_if(            [, [[YYLTYPE *yylocationp], [yylocationp]]])[]dnl
 388 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 389 {
 390   YYUSE (yyvaluep);
 391 ]b4_locations_if([  YYUSE (yylocationp);
 392 ])dnl
 393 b4_parse_param_use[]dnl
 394 [
 395   if (!yymsg)
 396     yymsg = "Deleting";
 397   YY_SYMBOL_PRINT (yymsg, yytype, yyvaluep, yylocationp);
 398
 399   switch (yytype)
 400     {
 401 ]m4_map([b4_symbol_actions], m4_defn([b4_symbol_destructors]))[
 402       default:
 403         break;
 404     }
 405 }]dnl
 406 ])
 407
 408
 409 # b4_yy_symbol_print_generate(FUNCTION-DECLARATOR)
 410 # ------------------------------------------------
 411 # Generate the "yy_symbol_print" function, which declaration is issued using
 412 # FUNCTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
 413 # or "b4_c_function_def" for K&R.
 414 m4_define_default([b4_yy_symbol_print_generate],
 415 [[
 416 /*--------------------------------.
 417 | Print this symbol on YYOUTPUT.  |
 418 `--------------------------------*/
 419
 420 /*ARGSUSED*/
 421 ]$1([yy_symbol_value_print],
 422     [static void],
 423                [[FILE *yyoutput],                       [yyoutput]],
 424                [[int yytype],                           [yytype]],
 425                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 426 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 427 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 428 {
 429   if (!yyvaluep)
 430     return;
 431 ]b4_locations_if([  YYUSE (yylocationp);
 432 ])dnl
 433 b4_parse_param_use[]dnl
 434 [# ifdef YYPRINT
 435   if (yytype < YYNTOKENS)
 436     YYPRINT (yyoutput, yytoknum[yytype], *yyvaluep);
 437 # else
 438   YYUSE (yyoutput);
 439 # endif
 440   switch (yytype)
 441     {
 442 ]m4_map([b4_symbol_actions], m4_defn([b4_symbol_printers]))dnl
 443 [      default:
 444         break;
 445     }
 446 }
 447
 448
 449 /*--------------------------------.
 450 | Print this symbol on YYOUTPUT.  |
 451 `--------------------------------*/
 452
 453 ]$1([yy_symbol_print],
 454     [static void],
 455                [[FILE *yyoutput],                       [yyoutput]],
 456                [[int yytype],                           [yytype]],
 457                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 458 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 459 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 460 {
 461   if (yytype < YYNTOKENS)
 462     YYFPRINTF (yyoutput, "token %s (", yytname[yytype]);
 463   else
 464     YYFPRINTF (yyoutput, "nterm %s (", yytname[yytype]);
 465
 466 ]b4_locations_if([  YY_LOCATION_PRINT (yyoutput, *yylocationp);
 467   YYFPRINTF (yyoutput, ": ");
 468 ])dnl
 469 [  yy_symbol_value_print (yyoutput, yytype, yyvaluep]dnl
 470 b4_locations_if([, yylocationp])[]b4_user_args[);
 471   YYFPRINTF (yyoutput, ")");
 472 }]dnl
 473 ])