src/scan-gram.l

   1 /* Bison Grammar Scanner                             -*- C -*-
   2
   3    Copyright (C) 2002-2012 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software: you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation, either version 3 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  19
  20 %option debug nodefault noinput noyywrap never-interactive
  21 %option prefix="gram_" outfile="lex.yy.c"
  22
  23 %{
  24 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  25    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  26 #undef gram_wrap
  27 #define gram_wrap() 1
  28
  29 #define FLEX_PREFIX(Id) gram_ ## Id
  30 #include <src/flex-scanner.h>
  31
  32 #include <src/complain.h>
  33 #include <src/files.h>
  34 #include <src/getargs.h>
  35 #include <src/gram.h>
  36 #include <quotearg.h>
  37 #include <src/reader.h>
  38 #include <src/uniqstr.h>
  39
  40 #include <c-ctype.h>
  41 #include <mbswidth.h>
  42 #include <quote.h>
  43
  44 #include <src/scan-gram.h>
  45
  46 #define YY_DECL GRAM_LEX_DECL
  47
  48 #define YY_USER_INIT                                    \
  49    code_start = scanner_cursor = loc->start;            \
  50
  51 /* Location of scanner cursor.  */
  52 static boundary scanner_cursor;
  53
  54 #define YY_USER_ACTION  location_compute (loc, &scanner_cursor, yytext, yyleng);
  55
  56 static size_t no_cr_read (FILE *, char *, size_t);
  57 #define YY_INPUT(buf, result, size) ((result) = no_cr_read (yyin, buf, size))
  58
  59 #define RETURN_PERCENT_PARAM(Value)                     \
  60   RETURN_VALUE(PERCENT_PARAM, param, param_ ## Value)
  61
  62 #define RETURN_PERCENT_FLAG(Value)                              \
  63   RETURN_VALUE(PERCENT_FLAG, uniqstr, uniqstr_new (Value))
  64
  65 #define RETURN_VALUE(Token, Field, Value)       \
  66   do {                                          \
  67     val->Field = Value;                         \
  68     return Token;                               \
  69   } while (0)
  70
  71 #define ROLLBACK_CURRENT_TOKEN                                  \
  72   do {                                                          \
  73     scanner_cursor.column -= mbsnwidth (yytext, yyleng, 0);     \
  74     yyless (0);                                                 \
  75   } while (0)
  76
  77 #define DEPRECATED(Msg)                                         \
  78   do {                                                          \
  79     size_t i;                                                   \
  80     complain (loc, Wdeprecated,                                 \
  81               _("deprecated directive: %s, use %s"),            \
  82               quote (yytext), quote_n (1, Msg));                \
  83     scanner_cursor.column -= mbsnwidth (Msg, strlen (Msg), 0);  \
  84     for (i = strlen (Msg); i != 0; --i)                         \
  85       unput (Msg[i - 1]);                                       \
  86   } while (0)
  87
  88 /* A string representing the most recently saved token.  */
  89 static char *last_string;
  90
  91 /* Bracketed identifier. */
  92 static uniqstr bracketed_id_str = 0;
  93 static location bracketed_id_loc;
  94 static boundary bracketed_id_start;
  95 static int bracketed_id_context_state = 0;
  96
  97 void
  98 gram_scanner_last_string_free (void)
  99 {
 100   STRING_FREE;
 101 }
 102
 103 static void handle_syncline (char *, location);
 104 static unsigned long int scan_integer (char const *p, int base, location loc);
 105 static int convert_ucn_to_byte (char const *hex_text);
 106 static void unexpected_eof (boundary, char const *);
 107 static void unexpected_newline (boundary, char const *);
 108
 109 %}
 110  /* A C-like comment in directives/rules. */
 111 %x SC_YACC_COMMENT
 112  /* Strings and characters in directives/rules. */
 113 %x SC_ESCAPED_STRING SC_ESCAPED_CHARACTER
 114  /* A identifier was just read in directives/rules.  Special state
 115     to capture the sequence 'identifier :'. */
 116 %x SC_AFTER_IDENTIFIER
 117  /* A complex tag, with nested angles brackets. */
 118 %x SC_TAG
 119
 120  /* Four types of user code:
 121     - prologue (code between '%{' '%}' in the first section, before %%);
 122     - actions, printers, union, etc, (between braced in the middle section);
 123     - epilogue (everything after the second %%).
 124     - predicate (code between '%?{' and '{' in middle section); */
 125 %x SC_PROLOGUE SC_BRACED_CODE SC_EPILOGUE SC_PREDICATE
 126  /* C and C++ comments in code. */
 127 %x SC_COMMENT SC_LINE_COMMENT
 128  /* Strings and characters in code. */
 129 %x SC_STRING SC_CHARACTER
 130  /* Bracketed identifiers support. */
 131 %x SC_BRACKETED_ID SC_RETURN_BRACKETED_ID
 132
 133 letter    [.abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_]
 134 id        {letter}({letter}|[-0-9])*
 135 directive %{id}
 136 int       [0-9]+
 137
 138 /* POSIX says that a tag must be both an id and a C union member, but
 139    historically almost any character is allowed in a tag.  We disallow
 140    NUL, as this simplifies our implementation.  We disallow angle
 141    bracket to match them in nested pairs: several languages use them
 142    for generics/template types.  */
 143 tag      [^\0<>]+
 144
 145 /* Zero or more instances of backslash-newline.  Following GCC, allow
 146    white space between the backslash and the newline.  */
 147 splice   (\\[ \f\t\v]*\n)*
 148
 149 /* An equal sign, with optional leading whitespaces. This is used in some
 150    deprecated constructs. */
 151 eqopt    ([[:space:]]*=)?
 152
 153 %%
 154 %{
 155   /* Nesting level.  Either for nested braces, or nested angle brackets
 156      (but not mixed).  */
 157   int nesting PACIFY_CC (= 0);
 158
 159   /* Parent context state, when applicable.  */
 160   int context_state PACIFY_CC (= 0);
 161
 162   /* Location of most recent identifier, when applicable.  */
 163   location id_loc PACIFY_CC (= empty_location);
 164
 165   /* Where containing code started, when applicable.  Its initial
 166      value is relevant only when yylex is invoked in the SC_EPILOGUE
 167      start condition.  */
 168   boundary code_start = scanner_cursor;
 169
 170   /* Where containing comment or string or character literal started,
 171      when applicable.  */
 172   boundary token_start PACIFY_CC (= scanner_cursor);
 173 %}
 174
 175
 176   /*-----------------------.
 177   | Scanning white space.  |
 178   `-----------------------*/
 179
 180 <INITIAL,SC_AFTER_IDENTIFIER,SC_BRACKETED_ID,SC_RETURN_BRACKETED_ID>
 181 {
 182   /* Comments and white space.  */
 183   "," {
 184      complain (loc, Wother, _("stray ',' treated as white space"));
 185   }
 186   [ \f\n\t\v]  |
 187   "//".*       ;
 188   "/*" {
 189     token_start = loc->start;
 190     context_state = YY_START;
 191     BEGIN SC_YACC_COMMENT;
 192   }
 193
 194   /* #line directives are not documented, and may be withdrawn or
 195      modified in future versions of Bison.  */
 196   ^"#line "{int}" \"".*"\"\n" {
 197     handle_syncline (yytext + sizeof "#line " - 1, *loc);
 198   }
 199 }
 200
 201
 202   /*----------------------------.
 203   | Scanning Bison directives.  |
 204   `----------------------------*/
 205
 206   /* For directives that are also command line options, the regex must be
 207         "%..."
 208      after "[-_]"s are removed, and the directive must match the --long
 209      option name, with a single string argument.  Otherwise, add exceptions
 210      to ../build-aux/cross-options.pl.  */
 211
 212 <INITIAL>
 213 {
 214   "%binary"                         return PERCENT_NONASSOC;
 215   "%code"                           return PERCENT_CODE;
 216   "%debug"                          RETURN_PERCENT_FLAG("parse.trace");
 217   "%default-prec"                   return PERCENT_DEFAULT_PREC;
 218   "%define"                         return PERCENT_DEFINE;
 219   "%defines"                        return PERCENT_DEFINES;
 220   "%destructor"                     return PERCENT_DESTRUCTOR;
 221   "%dprec"                          return PERCENT_DPREC;
 222   "%error-verbose"                  return PERCENT_ERROR_VERBOSE;
 223   "%expect"                         return PERCENT_EXPECT;
 224   "%expect-rr"                      return PERCENT_EXPECT_RR;
 225   "%file-prefix"                    return PERCENT_FILE_PREFIX;
 226   "%fixed-output-files"             return PERCENT_YACC;
 227   "%initial-action"                 return PERCENT_INITIAL_ACTION;
 228   "%glr-parser"                     return PERCENT_GLR_PARSER;
 229   "%language"                       return PERCENT_LANGUAGE;
 230   "%left"                           return PERCENT_LEFT;
 231   "%lex-param"                      RETURN_PERCENT_PARAM(lex);
 232   "%locations"                      RETURN_PERCENT_FLAG("locations");
 233   "%merge"                          return PERCENT_MERGE;
 234   "%name-prefix"                    return PERCENT_NAME_PREFIX;
 235   "%no-default-prec"                return PERCENT_NO_DEFAULT_PREC;
 236   "%no-lines"                       return PERCENT_NO_LINES;
 237   "%nonassoc"                       return PERCENT_NONASSOC;
 238   "%nondeterministic-parser"        return PERCENT_NONDETERMINISTIC_PARSER;
 239   "%nterm"                          return PERCENT_NTERM;
 240   "%output"                         return PERCENT_OUTPUT;
 241   "%param"                          RETURN_PERCENT_PARAM(both);
 242   "%parse-param"                    RETURN_PERCENT_PARAM(parse);
 243   "%prec"                           return PERCENT_PREC;
 244   "%precedence"                     return PERCENT_PRECEDENCE;
 245   "%printer"                        return PERCENT_PRINTER;
 246   "%pure-parser"                    RETURN_PERCENT_FLAG("api.pure");
 247   "%require"                        return PERCENT_REQUIRE;
 248   "%right"                          return PERCENT_RIGHT;
 249   "%skeleton"                       return PERCENT_SKELETON;
 250   "%start"                          return PERCENT_START;
 251   "%term"                           return PERCENT_TOKEN;
 252   "%token"                          return PERCENT_TOKEN;
 253   "%token-table"                    return PERCENT_TOKEN_TABLE;
 254   "%type"                           return PERCENT_TYPE;
 255   "%union"                          return PERCENT_UNION;
 256   "%verbose"                        return PERCENT_VERBOSE;
 257   "%yacc"                           return PERCENT_YACC;
 258
 259   /* deprecated */
 260   "%default"[-_]"prec"              DEPRECATED("%default-prec");
 261   "%error"[-_]"verbose"             DEPRECATED("%define parse.error verbose");
 262   "%expect"[-_]"rr"                 DEPRECATED("%expect-rr");
 263   "%file-prefix"{eqopt}             DEPRECATED("%file-prefix");
 264   "%fixed"[-_]"output"[-_]"files"   DEPRECATED("%fixed-output-files");
 265   "%name"[-_]"prefix"{eqopt}        DEPRECATED("%name-prefix");
 266   "%no"[-_]"default"[-_]"prec"      DEPRECATED("%no-default-prec");
 267   "%no"[-_]"lines"                  DEPRECATED("%no-lines");
 268   "%output"{eqopt}                  DEPRECATED("%output");
 269   "%pure"[-_]"parser"               DEPRECATED("%pure-parser");
 270   "%token"[-_]"table"               DEPRECATED("%token-table");
 271
 272   {directive} {
 273     complain (loc, complaint, _("invalid directive: %s"), quote (yytext));
 274   }
 275
 276   "="                     return EQUAL;
 277   "|"                     return PIPE;
 278   ";"                     return SEMICOLON;
 279
 280   {id} {
 281     val->uniqstr = uniqstr_new (yytext);
 282     id_loc = *loc;
 283     bracketed_id_str = NULL;
 284     BEGIN SC_AFTER_IDENTIFIER;
 285   }
 286
 287   {int} {
 288     val->integer = scan_integer (yytext, 10, *loc);
 289     return INT;
 290   }
 291   0[xX][0-9abcdefABCDEF]+ {
 292     val->integer = scan_integer (yytext, 16, *loc);
 293     return INT;
 294   }
 295
 296   /* Identifiers may not start with a digit.  Yet, don't silently
 297      accept "1FOO" as "1 FOO".  */
 298   {int}{id} {
 299     complain (loc, complaint, _("invalid identifier: %s"), quote (yytext));
 300   }
 301
 302   /* Characters.  */
 303   "'"         token_start = loc->start; BEGIN SC_ESCAPED_CHARACTER;
 304
 305   /* Strings. */
 306   "\""        token_start = loc->start; BEGIN SC_ESCAPED_STRING;
 307
 308   /* Prologue. */
 309   "%{"        code_start = loc->start; BEGIN SC_PROLOGUE;
 310
 311   /* Code in between braces.  */
 312   "{" {
 313     STRING_GROW;
 314     nesting = 0;
 315     code_start = loc->start;
 316     BEGIN SC_BRACED_CODE;
 317   }
 318
 319   /* Semantic predicate. */
 320   "%?"[ \f\n\t\v]*"{" {
 321     nesting = 0;
 322     code_start = loc->start;
 323     BEGIN SC_PREDICATE;
 324   }
 325
 326   /* A type. */
 327   "<*>"       return TAG_ANY;
 328   "<>"        return TAG_NONE;
 329   "<"{tag}">" {
 330     obstack_grow (&obstack_for_string, yytext + 1, yyleng - 2);
 331     STRING_FINISH;
 332     val->uniqstr = uniqstr_new (last_string);
 333     STRING_FREE;
 334     return TAG;
 335   }
 336   "<"         {
 337     nesting = 0;
 338     token_start = loc->start;
 339     BEGIN SC_TAG;
 340   }
 341
 342   "%%" {
 343     static int percent_percent_count;
 344     if (++percent_percent_count == 2)
 345       BEGIN SC_EPILOGUE;
 346     return PERCENT_PERCENT;
 347   }
 348
 349   "[" {
 350     bracketed_id_str = NULL;
 351     bracketed_id_start = loc->start;
 352     bracketed_id_context_state = YY_START;
 353     BEGIN SC_BRACKETED_ID;
 354   }
 355
 356   . {
 357     complain (loc, complaint, _("invalid character: %s"), quote (yytext));
 358   }
 359
 360   <<EOF>> {
 361     loc->start = loc->end = scanner_cursor;
 362     yyterminate ();
 363   }
 364 }
 365
 366
 367   /*--------------------------------------------------------------.
 368   | Supporting \0 complexifies our implementation for no expected |
 369   | added value.                                                  |
 370   `--------------------------------------------------------------*/
 371
 372 <SC_ESCAPED_CHARACTER,SC_ESCAPED_STRING,SC_TAG>
 373 {
 374   \0        complain (loc, complaint, _("invalid null character"));
 375 }
 376
 377
 378   /*-----------------------------------------------------------------.
 379   | Scanning after an identifier, checking whether a colon is next.  |
 380   `-----------------------------------------------------------------*/
 381
 382 <SC_AFTER_IDENTIFIER>
 383 {
 384   "[" {
 385     if (bracketed_id_str)
 386       {
 387         ROLLBACK_CURRENT_TOKEN;
 388         BEGIN SC_RETURN_BRACKETED_ID;
 389         *loc = id_loc;
 390         return ID;
 391       }
 392     else
 393       {
 394         bracketed_id_start = loc->start;
 395         bracketed_id_context_state = YY_START;
 396         BEGIN SC_BRACKETED_ID;
 397       }
 398   }
 399   ":" {
 400     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 401     *loc = id_loc;
 402     return ID_COLON;
 403   }
 404   . {
 405     ROLLBACK_CURRENT_TOKEN;
 406     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 407     *loc = id_loc;
 408     return ID;
 409   }
 410   <<EOF>> {
 411     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 412     *loc = id_loc;
 413     return ID;
 414   }
 415 }
 416
 417   /*--------------------------------.
 418   | Scanning bracketed identifiers. |
 419   `--------------------------------*/
 420
 421 <SC_BRACKETED_ID>
 422 {
 423   {id} {
 424     if (bracketed_id_str)
 425       {
 426         complain (loc, complaint,
 427                   _("unexpected identifier in bracketed name: %s"),
 428                   quote (yytext));
 429       }
 430     else
 431       {
 432         bracketed_id_str = uniqstr_new (yytext);
 433         bracketed_id_loc = *loc;
 434       }
 435   }
 436   "]" {
 437     BEGIN bracketed_id_context_state;
 438     if (bracketed_id_str)
 439       {
 440         if (INITIAL == bracketed_id_context_state)
 441           {
 442             val->uniqstr = bracketed_id_str;
 443             bracketed_id_str = 0;
 444             *loc = bracketed_id_loc;
 445             return BRACKETED_ID;
 446           }
 447       }
 448     else
 449       complain (loc, complaint, _("an identifier expected"));
 450   }
 451   . {
 452     complain (loc, complaint, _("invalid character in bracketed name: %s"),
 453                  quote (yytext));
 454   }
 455   <<EOF>> {
 456     BEGIN bracketed_id_context_state;
 457     unexpected_eof (bracketed_id_start, "]");
 458   }
 459 }
 460
 461 <SC_RETURN_BRACKETED_ID>
 462 {
 463   . {
 464     ROLLBACK_CURRENT_TOKEN;
 465     val->uniqstr = bracketed_id_str;
 466     bracketed_id_str = 0;
 467     *loc = bracketed_id_loc;
 468     BEGIN INITIAL;
 469     return BRACKETED_ID;
 470   }
 471 }
 472
 473
 474   /*---------------------------------------------------------------.
 475   | Scanning a Yacc comment.  The initial '/ *' is already eaten.  |
 476   `---------------------------------------------------------------*/
 477
 478 <SC_YACC_COMMENT>
 479 {
 480   "*/"     BEGIN context_state;
 481   .|\n     ;
 482   <<EOF>>  unexpected_eof (token_start, "*/"); BEGIN context_state;
 483 }
 484
 485
 486   /*------------------------------------------------------------.
 487   | Scanning a C comment.  The initial '/ *' is already eaten.  |
 488   `------------------------------------------------------------*/
 489
 490 <SC_COMMENT>
 491 {
 492   "*"{splice}"/"  STRING_GROW; BEGIN context_state;
 493   <<EOF>>         unexpected_eof (token_start, "*/"); BEGIN context_state;
 494 }
 495
 496
 497   /*--------------------------------------------------------------.
 498   | Scanning a line comment.  The initial '//' is already eaten.  |
 499   `--------------------------------------------------------------*/
 500
 501 <SC_LINE_COMMENT>
 502 {
 503   "\n"           STRING_GROW; BEGIN context_state;
 504   {splice}       STRING_GROW;
 505   <<EOF>>        BEGIN context_state;
 506 }
 507
 508
 509   /*------------------------------------------------.
 510   | Scanning a Bison string, including its escapes. |
 511   | The initial quote is already eaten.             |
 512   `------------------------------------------------*/
 513
 514 <SC_ESCAPED_STRING>
 515 {
 516   "\""|"\n" {
 517     if (yytext[0] == '\n')
 518       unexpected_newline (token_start, "\"");
 519     STRING_FINISH;
 520     loc->start = token_start;
 521     val->chars = last_string;
 522     BEGIN INITIAL;
 523     return STRING;
 524   }
 525   <<EOF>> {
 526     unexpected_eof (token_start, "\"");
 527     STRING_FINISH;
 528     loc->start = token_start;
 529     val->chars = last_string;
 530     BEGIN INITIAL;
 531     return STRING;
 532   }
 533 }
 534
 535   /*----------------------------------------------------------.
 536   | Scanning a Bison character literal, decoding its escapes. |
 537   | The initial quote is already eaten.                       |
 538   `----------------------------------------------------------*/
 539
 540 <SC_ESCAPED_CHARACTER>
 541 {
 542   "'"|"\n" {
 543     STRING_FINISH;
 544     loc->start = token_start;
 545     val->character = last_string[0];
 546     {
 547       /* FIXME: Eventually, make these errors.  */
 548       if (last_string[0] == '\0')
 549         {
 550           complain (loc, Wother, _("empty character literal"));
 551           /* '\0' seems dangerous even if we are about to complain.  */
 552           val->character = '\'';
 553         }
 554       else if (last_string[1] != '\0')
 555         complain (loc, Wother,
 556                   _("extra characters in character literal"));
 557     }
 558     if (yytext[0] == '\n')
 559       unexpected_newline (token_start, "'");
 560     STRING_FREE;
 561     BEGIN INITIAL;
 562     return CHAR;
 563   }
 564   <<EOF>> {
 565     STRING_FINISH;
 566     loc->start = token_start;
 567     val->character = last_string[0];
 568     {
 569       /* FIXME: Eventually, make these errors.  */
 570       if (last_string[0] == '\0')
 571         {
 572           complain (loc, Wother, _("empty character literal"));
 573           /* '\0' seems dangerous even if we are about to complain.  */
 574           val->character = '\'';
 575         }
 576       else if (last_string[1] != '\0')
 577         complain (loc, Wother,
 578                   _("extra characters in character literal"));
 579     }
 580     unexpected_eof (token_start, "'");
 581     STRING_FREE;
 582     BEGIN INITIAL;
 583     return CHAR;
 584   }
 585 }
 586
 587   /*-----------------------------------------------------------.
 588   | Scanning a Bison nested tag.  The initial angle bracket is |
 589   | already eaten.                                             |
 590   `-----------------------------------------------------------*/
 591
 592 <SC_TAG>
 593 {
 594   ">" {
 595     --nesting;
 596     if (nesting < 0)
 597       {
 598         STRING_FINISH;
 599         loc->start = token_start;
 600         val->uniqstr = uniqstr_new (last_string);
 601         STRING_FREE;
 602         BEGIN INITIAL;
 603         return TAG;
 604       }
 605     STRING_GROW;
 606   }
 607
 608   [^<>]+ STRING_GROW;
 609   "<"+   STRING_GROW; nesting += yyleng;
 610
 611   <<EOF>> {
 612     unexpected_eof (token_start, ">");
 613     STRING_FINISH;
 614     loc->start = token_start;
 615     val->uniqstr = uniqstr_new (last_string);
 616     STRING_FREE;
 617     BEGIN INITIAL;
 618     return TAG;
 619   }
 620 }
 621
 622   /*----------------------------.
 623   | Decode escaped characters.  |
 624   `----------------------------*/
 625
 626 <SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>
 627 {
 628   \\[0-7]{1,3} {
 629     unsigned long int c = strtoul (yytext + 1, NULL, 8);
 630     if (!c || UCHAR_MAX < c)
 631       complain (loc, complaint, _("invalid number after \\-escape: %s"),
 632                    yytext+1);
 633     else
 634       obstack_1grow (&obstack_for_string, c);
 635   }
 636
 637   \\x[0-9abcdefABCDEF]+ {
 638     verify (UCHAR_MAX < ULONG_MAX);
 639     unsigned long int c = strtoul (yytext + 2, NULL, 16);
 640     if (!c || UCHAR_MAX < c)
 641       complain (loc, complaint, _("invalid number after \\-escape: %s"),
 642                    yytext+1);
 643     else
 644       obstack_1grow (&obstack_for_string, c);
 645   }
 646
 647   \\a   obstack_1grow (&obstack_for_string, '\a');
 648   \\b   obstack_1grow (&obstack_for_string, '\b');
 649   \\f   obstack_1grow (&obstack_for_string, '\f');
 650   \\n   obstack_1grow (&obstack_for_string, '\n');
 651   \\r   obstack_1grow (&obstack_for_string, '\r');
 652   \\t   obstack_1grow (&obstack_for_string, '\t');
 653   \\v   obstack_1grow (&obstack_for_string, '\v');
 654
 655   /* \\[\"\'?\\] would be shorter, but it confuses xgettext.  */
 656   \\("\""|"'"|"?"|"\\")  obstack_1grow (&obstack_for_string, yytext[1]);
 657
 658   \\(u|U[0-9abcdefABCDEF]{4})[0-9abcdefABCDEF]{4} {
 659     int c = convert_ucn_to_byte (yytext);
 660     if (c <= 0)
 661       complain (loc, complaint, _("invalid number after \\-escape: %s"),
 662                    yytext+1);
 663     else
 664       obstack_1grow (&obstack_for_string, c);
 665   }
 666   \\(.|\n)      {
 667     char const *p = yytext + 1;
 668     /* Quote only if escaping won't make the character visible.  */
 669     if (c_isspace ((unsigned char) *p) && c_isprint ((unsigned char) *p))
 670       p = quote (p);
 671     else
 672       p = quotearg_style_mem (escape_quoting_style, p, 1);
 673     complain (loc, complaint, _("invalid character after \\-escape: %s"),
 674                  p);
 675   }
 676 }
 677
 678   /*--------------------------------------------.
 679   | Scanning user-code characters and strings.  |
 680   `--------------------------------------------*/
 681
 682 <SC_CHARACTER,SC_STRING>
 683 {
 684   {splice}|\\{splice}[^\n\[\]]  STRING_GROW;
 685 }
 686
 687 <SC_CHARACTER>
 688 {
 689   "'"           STRING_GROW; BEGIN context_state;
 690   \n            unexpected_newline (token_start, "'"); BEGIN context_state;
 691   <<EOF>>       unexpected_eof (token_start, "'"); BEGIN context_state;
 692 }
 693
 694 <SC_STRING>
 695 {
 696   "\""          STRING_GROW; BEGIN context_state;
 697   \n            unexpected_newline (token_start, "\""); BEGIN context_state;
 698   <<EOF>>       unexpected_eof (token_start, "\""); BEGIN context_state;
 699 }
 700
 701
 702   /*---------------------------------------------------.
 703   | Strings, comments etc. can be found in user code.  |
 704   `---------------------------------------------------*/
 705
 706 <SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE,SC_PREDICATE>
 707 {
 708   "'" {
 709     STRING_GROW;
 710     context_state = YY_START;
 711     token_start = loc->start;
 712     BEGIN SC_CHARACTER;
 713   }
 714   "\"" {
 715     STRING_GROW;
 716     context_state = YY_START;
 717     token_start = loc->start;
 718     BEGIN SC_STRING;
 719   }
 720   "/"{splice}"*" {
 721     STRING_GROW;
 722     context_state = YY_START;
 723     token_start = loc->start;
 724     BEGIN SC_COMMENT;
 725   }
 726   "/"{splice}"/" {
 727     STRING_GROW;
 728     context_state = YY_START;
 729     BEGIN SC_LINE_COMMENT;
 730   }
 731 }
 732
 733
 734
 735   /*-----------------------------------------------------------.
 736   | Scanning some code in braces (actions, predicates). The    |
 737   | initial "{" is already eaten.                              |
 738   `-----------------------------------------------------------*/
 739
 740 <SC_BRACED_CODE,SC_PREDICATE>
 741 {
 742   "{"|"<"{splice}"%"  STRING_GROW; nesting++;
 743   "%"{splice}">"      STRING_GROW; nesting--;
 744
 745   /* Tokenize '<<%' correctly (as '<<' '%') rather than incorrrectly
 746      (as '<' '<%').  */
 747   "<"{splice}"<"  STRING_GROW;
 748
 749   <<EOF>> {
 750     int token = (YY_START == SC_BRACED_CODE) ? BRACED_CODE : BRACED_PREDICATE;
 751     unexpected_eof (code_start, "}");
 752     STRING_FINISH;
 753     loc->start = code_start;
 754     val->code = last_string;
 755     BEGIN INITIAL;
 756     return token;
 757   }
 758 }
 759
 760 <SC_BRACED_CODE>
 761 {
 762   "}" {
 763     obstack_1grow (&obstack_for_string, '}');
 764
 765     --nesting;
 766     if (nesting < 0)
 767       {
 768         STRING_FINISH;
 769         loc->start = code_start;
 770         val->code = last_string;
 771         BEGIN INITIAL;
 772         return BRACED_CODE;
 773       }
 774   }
 775 }
 776
 777 <SC_PREDICATE>
 778 {
 779   "}" {
 780     --nesting;
 781     if (nesting < 0)
 782       {
 783         STRING_FINISH;
 784         loc->start = code_start;
 785         val->code = last_string;
 786         BEGIN INITIAL;
 787         return BRACED_PREDICATE;
 788       }
 789     else
 790       obstack_1grow (&obstack_for_string, '}');
 791   }
 792 }
 793
 794   /*--------------------------------------------------------------.
 795   | Scanning some prologue: from "%{" (already scanned) to "%}".  |
 796   `--------------------------------------------------------------*/
 797
 798 <SC_PROLOGUE>
 799 {
 800   "%}" {
 801     STRING_FINISH;
 802     loc->start = code_start;
 803     val->chars = last_string;
 804     BEGIN INITIAL;
 805     return PROLOGUE;
 806   }
 807
 808   <<EOF>> {
 809     unexpected_eof (code_start, "%}");
 810     STRING_FINISH;
 811     loc->start = code_start;
 812     val->chars = last_string;
 813     BEGIN INITIAL;
 814     return PROLOGUE;
 815   }
 816 }
 817
 818
 819   /*---------------------------------------------------------------.
 820   | Scanning the epilogue (everything after the second "%%", which |
 821   | has already been eaten).                                       |
 822   `---------------------------------------------------------------*/
 823
 824 <SC_EPILOGUE>
 825 {
 826   <<EOF>> {
 827     STRING_FINISH;
 828     loc->start = code_start;
 829     val->chars = last_string;
 830     BEGIN INITIAL;
 831     return EPILOGUE;
 832   }
 833 }
 834
 835
 836   /*-----------------------------------------------------.
 837   | By default, grow the string obstack with the input.  |
 838   `-----------------------------------------------------*/
 839
 840 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PREDICATE,SC_PROLOGUE,SC_EPILOGUE,SC_STRING,SC_CHARACTER,SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>. |
 841   <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PREDICATE,SC_PROLOGUE,SC_EPILOGUE>\n    STRING_GROW;
 842
 843 %%
 844
 845 /* Read bytes from FP into buffer BUF of size SIZE.  Return the
 846    number of bytes read.  Remove '\r' from input, treating \r\n
 847    and isolated \r as \n.  */
 848
 849 static size_t
 850 no_cr_read (FILE *fp, char *buf, size_t size)
 851 {
 852   size_t bytes_read = fread (buf, 1, size, fp);
 853   if (bytes_read)
 854     {
 855       char *w = memchr (buf, '\r', bytes_read);
 856       if (w)
 857         {
 858           char const *r = ++w;
 859           char const *lim = buf + bytes_read;
 860
 861           for (;;)
 862             {
 863               /* Found an '\r'.  Treat it like '\n', but ignore any
 864                  '\n' that immediately follows.  */
 865               w[-1] = '\n';
 866               if (r == lim)
 867                 {
 868                   int ch = getc (fp);
 869                   if (ch != '\n' && ungetc (ch, fp) != ch)
 870                     break;
 871                 }
 872               else if (*r == '\n')
 873                 r++;
 874
 875               /* Copy until the next '\r'.  */
 876               do
 877                 {
 878                   if (r == lim)
 879                     return w - buf;
 880                 }
 881               while ((*w++ = *r++) != '\r');
 882             }
 883
 884           return w - buf;
 885         }
 886     }
 887
 888   return bytes_read;
 889 }
 890
 891
 892
 893 /*------------------------------------------------------.
 894 | Scan NUMBER for a base-BASE integer at location LOC.  |
 895 `------------------------------------------------------*/
 896
 897 static unsigned long int
 898 scan_integer (char const *number, int base, location loc)
 899 {
 900   verify (INT_MAX < ULONG_MAX);
 901   unsigned long int num = strtoul (number, NULL, base);
 902
 903   if (INT_MAX < num)
 904     {
 905       complain (&loc, complaint, _("integer out of range: %s"),
 906                    quote (number));
 907       num = INT_MAX;
 908     }
 909
 910   return num;
 911 }
 912
 913
 914 /*------------------------------------------------------------------.
 915 | Convert universal character name UCN to a single-byte character,  |
 916 | and return that character.  Return -1 if UCN does not correspond  |
 917 | to a single-byte character.                                       |
 918 `------------------------------------------------------------------*/
 919
 920 static int
 921 convert_ucn_to_byte (char const *ucn)
 922 {
 923   verify (UCHAR_MAX <= INT_MAX);
 924   unsigned long int code = strtoul (ucn + 2, NULL, 16);
 925
 926   /* FIXME: Currently we assume Unicode-compatible unibyte characters
 927      on ASCII hosts (i.e., Latin-1 on hosts with 8-bit bytes).  On
 928      non-ASCII hosts we support only the portable C character set.
 929      These limitations should be removed once we add support for
 930      multibyte characters.  */
 931
 932   if (UCHAR_MAX < code)
 933     return -1;
 934
 935 #if ! ('$' == 0x24 && '@' == 0x40 && '`' == 0x60 && '~' == 0x7e)
 936   {
 937     /* A non-ASCII host.  Use CODE to index into a table of the C
 938        basic execution character set, which is guaranteed to exist on
 939        all Standard C platforms.  This table also includes '$', '@',
 940        and '`', which are not in the basic execution character set but
 941        which are unibyte characters on all the platforms that we know
 942        about.  */
 943     static signed char const table[] =
 944       {
 945         '\0',   -1,   -1,   -1,   -1,   -1,   -1, '\a',
 946         '\b', '\t', '\n', '\v', '\f', '\r',   -1,   -1,
 947           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 948           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 949          ' ',  '!',  '"',  '#',  '$',  '%',  '&', '\'',
 950          '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
 951          '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
 952          '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
 953          '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
 954          'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
 955          'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
 956          'X',  'Y',  'Z',  '[', '\\',  ']',  '^',  '_',
 957          '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
 958          'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
 959          'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
 960          'x',  'y',  'z',  '{',  '|',  '}',  '~'
 961       };
 962
 963     code = code < sizeof table ? table[code] : -1;
 964   }
 965 #endif
 966
 967   return code;
 968 }
 969
 970
 971 /*----------------------------------------------------------------.
 972 | Handle '#line INT "FILE"'.  ARGS has already skipped '#line '.  |
 973 `----------------------------------------------------------------*/
 974
 975 static void
 976 handle_syncline (char *args, location loc)
 977 {
 978   char *after_num;
 979   unsigned long int lineno = strtoul (args, &after_num, 10);
 980   char *file = strchr (after_num, '"') + 1;
 981   *strchr (file, '"') = '\0';
 982   if (INT_MAX <= lineno)
 983     {
 984       complain (&loc, Wother, _("line number overflow"));
 985       lineno = INT_MAX;
 986     }
 987   current_file = uniqstr_new (file);
 988   boundary_set (&scanner_cursor, current_file, lineno, 1);
 989 }
 990
 991
 992 /*----------------------------------------------------------------.
 993 | For a token or comment starting at START, report message MSGID, |
 994 | which should say that an end marker was found before            |
 995 | the expected TOKEN_END.                                         |
 996 `----------------------------------------------------------------*/
 997
 998 static void
 999 unexpected_end (boundary start, char const *msgid, char const *token_end)
1000 {
1001   location loc;
1002   loc.start = start;
1003   loc.end = scanner_cursor;
1004   token_end = quote (token_end);
1005   // Instead of '\'', display "'".
1006   if (STREQ (token_end, "'\\''"))
1007     token_end = "\"'\"";
1008   complain (&loc, complaint, _(msgid), token_end);
1009 }
1010
1011
1012 /*------------------------------------------------------------------------.
1013 | Report an unexpected EOF in a token or comment starting at START.       |
1014 | An end of file was encountered and the expected TOKEN_END was missing.  |
1015 `------------------------------------------------------------------------*/
1016
1017 static void
1018 unexpected_eof (boundary start, char const *token_end)
1019 {
1020   unexpected_end (start, N_("missing %s at end of file"), token_end);
1021 }
1022
1023
1024 /*----------------------------------------.
1025 | Likewise, but for unexpected newlines.  |
1026 `----------------------------------------*/
1027
1028 static void
1029 unexpected_newline (boundary start, char const *token_end)
1030 {
1031   unexpected_end (start, N_("missing %s at end of line"), token_end);
1032 }
1033
1034
1035 /*-------------------------.
1036 | Initialize the scanner.  |
1037 `-------------------------*/
1038
1039 void
1040 gram_scanner_initialize (void)
1041 {
1042   obstack_init (&obstack_for_string);
1043 }
1044
1045
1046 /*-----------------------------------------------.
1047 | Free all the memory allocated to the scanner.  |
1048 `-----------------------------------------------*/
1049
1050 void
1051 gram_scanner_free (void)
1052 {
1053   obstack_free (&obstack_for_string, 0);
1054   /* Reclaim Flex's buffers.  */
1055   yylex_destroy ();
1056 }